Toen we ons verdiepten in het onderwerp hoe 1C-producten werken in de Linux-omgeving, werd één nadeel ontdekt: het ontbreken van een handige grafische multi-platformtool voor het beheren van een cluster van 1C-servers. En er werd besloten dit nadeel te corrigeren door een GUI te schrijven voor het raceconsole-hulpprogramma. Tcl/tk werd als ontwikkeltaal gekozen, omdat dit naar mijn mening het meest geschikt is voor deze taak. En dus zou ik in dit materiaal enkele interessante aspecten van de oplossing willen presenteren.
Om te werken heb je tcl/tk- en 1C-distributies nodig. En aangezien ik heb besloten om de mogelijkheden van de basislevering van tcl/tk optimaal te benutten zonder pakketten van derden te gebruiken, heb ik versie 8.6.7 nodig, die ttk bevat - een pakket met aanvullende grafische elementen, waarvan we voornamelijk ttk nodig hebben ::TreeView, maakt het mogelijk gegevens zowel in de vorm van een boomstructuur als in de vorm van een tabel (lijst) weer te geven. Ook is in de nieuwe versie het werk met uitzonderingen herwerkt (de try-opdracht, die in het project wordt gebruikt bij het uitvoeren van externe opdrachten).
Het project bestaat uit verschillende bestanden (hoewel niets je ervan weerhoudt alles in één te doen):
rac_gui.cfg - standaardconfiguratie
rac_gui.tcl - hoofdstartscript
De map lib bevat bestanden die automatisch worden geladen bij het opstarten:
function.tcl - bestand met procedures
gui.tcl - belangrijkste grafische interface
images.tcl - base64-afbeeldingsbibliotheek
Het bestand rac_gui.tcl start in feite de tolk, initialiseert variabelen, laadt modules, configuraties, enzovoort. Inhoud van het bestand met commentaar:
rac_gui.tcl
#!/bin/sh
exec wish "$0" -- "$@"
# Устанавливаем текущий каталог
set dir(root) [pwd]
# Устанавливаем рабочий каталог, если его нет то создаём
set dir(work) [file join $env(HOME) .rac_gui]
if {[file exists $dir(work)] == 0 } {
file mkdir $dir(work)
}
# каталог с модулями
set dir(lib) "[file join $dir(root) lib]"
# загружаем пользовательский конфиг, если он отсутствует, то копируем дефолтный
if {[file exists [file join $dir(work) rac_gui.cfg]] ==0} {
file copy [file join [pwd] rac_gui.cfg] [file join $dir(work) rac_gui.cfg]
}
source [file join $dir(work) rac_gui.cfg]
# Код проверки наличия rac и правильности указания пути в конфиге
# если программа не найдена то будет выведен диалог для указания корректного пути
# и этот путь будет записан в пользовательский конфиг
if {[file exists $rac_cmd] == 0} {
set rac_cmd [tk_getOpenFile -initialdir $env(HOME) -parent . -title "Укажите путь до rac" -initialfile rac]
file copy [file join $dir(work) rac_gui.cfg] [file join $dir(work) rac_gui.cfg.bak]
set orig_file [open [file join $dir(work) rac_gui.cfg.bak] "r"]
set file [open [file join $dir(work) rac_gui.cfg] "w"]
while {[gets $orig_file line] >=0 } {
if {[string match "set rac_cmd*" $line]} {
puts $file "set rac_cmd $rac_cmd"
} else {
puts $file $line
}
}
close $file
close $orig_file
#return "$host:$port"
file delete [file join $dir(work) 1c_srv.cfg.bak]
} else {
puts "Found $rac_cmd"
}
set cluster_user ""
set cluster_pwd ""
set agent_user ""
set agent_pwd ""
## LOAD FILE ##
# Загружаем модули кроме gui.tcl так как его надо загрузить последним
foreach modFile [lsort [glob -nocomplain [file join $dir(lib) *.tcl]]] {
if {[file tail $modFile] ne "gui.tcl"} {
source $modFile
puts "Loaded module $modFile"
}
}
source [file join $dir(lib) gui.tcl]
source [file join $dir(work) rac_gui.cfg]
# Читаем файл со списком серверов 1С
# и добавляем в дерево
if [file exists [file join $dir(work) 1c_srv.cfg]] {
set f [open [file join $dir(work) 1c_srv.cfg] "RDONLY"]
while {[gets $f line] >=0} {
.frm_tree.tree insert {} end -id "server::$line" -text "$line" -values "$line"
}
}Na het downloaden van alles wat nodig is en het controleren op de aanwezigheid van het rac-hulpprogramma, wordt een grafisch venster geopend. De programma-interface bestaat uit drie elementen:
Werkbalk, boom en lijst
Ik heb de inhoud van de “boom” zo vergelijkbaar mogelijk gemaakt met de standaard Windows-apparatuur uit 1C.
De hoofdcode waaruit dit venster bestaat, bevindt zich in het bestand
lib/gui.tcl
# установка размера и положения основного окна
# можно установить в переменную topLevelGeometry в конфиг программы
if {[info exists topLevelGeometry]} {
wm geometry . $topLevelGeometry
} else {
wm geometry . 1024x768
}
# Заголовок окна
wm title . "1C Rac GUI"
wm iconname . "1C Rac Gui"
# иконка окна (берется из файла lib/imges.tcl)
wm iconphoto . tcl
wm protocol . WM_DELETE_WINDOW Quit
wm overrideredirect . 0
wm positionfrom . user
ttk::style theme use clam
# Панель инсрументов
set frm_tool [frame .frm_tool]
pack $frm_tool -side left -fill y
ttk::panedwindow .panel -orient horizontal -style TPanedwindow
pack .panel -expand true -fill both
pack propagate .panel false
ttk::button $frm_tool.btn_add -command Add -image add_grey_32
ttk::button $frm_tool.btn_del -command Del -image del_grey_32
ttk::button $frm_tool.btn_edit -command Edit -image edit_grey_32
ttk::button $frm_tool.btn_quit -command Quit -image quit_grey_32
pack $frm_tool.btn_add $frm_tool.btn_del $frm_tool.btn_edit -side top -padx 5 -pady 5
pack $frm_tool.btn_quit -side bottom -padx 5 -pady 5
# Дерево с полосами прокрутки
set frm_tree [frame .frm_tree]
ttk::scrollbar $frm_tree.hsb1 -orient horizontal -command [list $frm_tree.tree xview]
ttk::scrollbar $frm_tree.vsb1 -orient vertical -command [list $frm_tree.tree yview]
set tree [ttk::treeview $frm_tree.tree -show tree
-xscrollcommand [list $frm_tree.hsb1 set] -yscrollcommand [list $frm_tree.vsb1 set]]
grid $tree -row 0 -column 0 -sticky nsew
grid $frm_tree.vsb1 -row 0 -column 1 -sticky nsew
grid $frm_tree.hsb1 -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_tree 0 -weight 1
grid rowconfigure $frm_tree 0 -weight 1
# назначение обработчика нажатия кнопкой мыши
bind $frm_tree.tree <ButtonRelease> "TreePress $frm_tree.tree"
# Список для данных (таблица)
set frm_work [frame .frm_work]
ttk::scrollbar $frm_work.hsb -orient horizontal -command [list $frm_work.tree_work xview]
ttk::scrollbar $frm_work.vsb -orient vertical -command [list $frm_work.tree_work yview]
set tree_work [
ttk::treeview $frm_work.tree_work
-show headings -columns "par val" -displaycolumns "par val"
-xscrollcommand [list $frm_work.hsb set]
-yscrollcommand [list $frm_work.vsb set]
]
# Установка цветов для чередования в таблице
$tree_work tag configure dark -background $color(dark_table_bg)
$tree_work tag configure light -background $color(light_table_bg)
# Размещение элементов на форме
grid $tree_work -row 0 -column 0 -sticky nsew
grid $frm_work.vsb -row 0 -column 1 -sticky nsew
grid $frm_work.hsb -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_work 0 -weight 1
grid rowconfigure $frm_work 0 -weight 1
pack $frm_tree $frm_work -side left -expand true -fill both
#.panel add $frm_tool -weight 1
.panel add $frm_tree -weight 1
.panel add $frm_work -weight 1
Het algoritme voor het werken met het programma is als volgt:
1. Eerst moet u de hoofdclusterserver toevoegen (d.w.z. de clusterbeheerserver (in Linux wordt het beheer gestart met de opdracht “/opt/1C/v8.3/x86_64/ras cluster —daemon”)).
Om dit te doen, klikt u op de knop "+" en voert u in het geopende venster het serveradres en de poort in:
Daarna verschijnt onze server in de boom door erop te klikken, een lijst met clusters wordt geopend of er wordt een verbindingsfout weergegeven.
2. Als u op de clusternaam klikt, wordt een lijst met beschikbare functies geopend.
3. ...
En zo verder, d.w.z. Om een nieuw cluster toe te voegen, selecteert u een beschikbaar cluster in de lijst en drukt u op de knop “+” in de werkbalk. Het dialoogvenster voor het toevoegen van een nieuw cluster wordt weergegeven:
De knoppen in de werkbalk voeren functies uit afhankelijk van de context, d.w.z. Afhankelijk van welk element van de boom of lijst is geselecteerd, wordt een of andere procedure uitgevoerd.
Laten we eens kijken naar het voorbeeld van de knop Toevoegen (“+”):
Code voor het genereren van knoppen:
ttk::button $frm_tool.btn_add -command Add -image add_grey_32Hier zien we dat wanneer de knop wordt ingedrukt, de procedure "Toevoegen" wordt uitgevoerd, de code:
proc Add {} {
global active_cluster host
# Определяем идентификатор выделенного элемента
set id [.frm_tree.tree selection]
# Определяем значение этого элемента
set values [.frm_tree.tree item [.frm_tree.tree selection] -values]
set key [lindex [split $id "::"] 0]
# в зависимости от того что выделили будет запущена нужная процедура
if {$key eq "" || $key eq "server"} {
set host [ Add::server ]
return
}
Add::$key .frm_tree.tree $host $values
}Hier is een van de voordelen van tickle: je kunt de waarde van een variabele doorgeven als procedurenaam:
Add::$key .frm_tree.tree $host $valuesDat wil zeggen, als we bijvoorbeeld naar de hoofdserver wijzen en op “+” drukken, dan wordt de Add::server-procedure gestart, als bij het cluster - Add::cluster enzovoort (ik zal schrijven over waar de noodzakelijke “sleutels” komen verderop vandaan), tekenen de vermelde procedures grafische elementen die geschikt zijn voor de context.
Zoals je misschien al hebt opgemerkt, zijn de formulieren qua stijl vergelijkbaar - dit is niet verrassend, omdat ze worden weergegeven door één procedure, meer bepaald het hoofdframe van het formulier (venster, knoppen, afbeelding, label), de naam van de procedure TopLevel toevoegen
proc AddToplevel {lbl img {win_name .add}} {
set cmd "destroy $win_name"
if [winfo exists $win_name] {destroy $win_name}
toplevel $win_name
wm title $win_name $lbl
wm iconphoto $win_name tcl
# метка с иконкой
ttk::label $win_name.lbl -image $img
# фрейм с полями ввода
set frm [ttk::labelframe $win_name.frm -text $lbl -labelanchor nw]
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
# фрейм и кнопки
set frm_btn [frame $win_name.frm_btn -border 0]
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }
ttk::button $frm_btn.btn_cancel -command $cmd -image quit_grey_24
grid $win_name.lbl -row 0 -column 0 -sticky nw -padx 5 -pady 10
grid $frm -row 0 -column 1 -sticky nw -padx 5 -pady 5
grid $frm_btn -row 1 -column 1 -sticky se -padx 5 -pady 5
pack $frm_btn.btn_cancel -side right
pack $frm_btn.btn_ok -side right -padx 10
return $frm
}
Oproepparameters: titel, afbeeldingsnaam voor het pictogram uit de bibliotheek (lib/images.tcl) en een optionele vensternaamparameter (standaard .add). Als we dus de bovenstaande voorbeelden nemen voor het toevoegen van de hoofdserver en het cluster, zal de aanroep dienovereenkomstig zijn:
AddToplevel "Добавление основного сервера" server_grey_64of
AddToplevel "Добавление кластера" cluster_grey_64Als ik verder ga met deze voorbeelden, zal ik de procedures laten zien die dialoogvensters voor toevoegen voor een server of cluster weergeven.
Server toevoegen
proc Add::server {} {
global default
# выводим основную форму
set frm [AddToplevel "Добавление основного сервера" server_grey_64]
# добавляем етки и поля ввода на эту форму
label $frm.lbl_host -text "Адрес сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
#set frm_btn [frame .add.frm_btn -border 0]
# переопределяем обработчик нажатия кнопки
.add.frm_btn.btn_ok configure -command {
set host [SaveMainServer [.add.frm.ent_host get] [.add.frm.ent_port get]]
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"
destroy .add
return $host
}
return $frm
}Voeg::cluster toe
proc Add::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes
agent_user agent_pwd cluster_user cluster_pwd auth_agent
if {$agent_user ne "" && $agent_pwd ne ""} {
set auth_agent "--agent-user=$agent_user --agent-pwd=$agent_pwd"
} else {
set auth_agent ""
}
# устанавливаем глобальные переменные ()
set lifetime_limit $default(lifetime_limit)
set expiration_timeout $default(expiration_timeout)
set session_fault_tolerance_level $default(session_fault_tolerance_level)
set max_memory_size $default(max_memory_size)
set max_memory_time_limit $default(max_memory_time_limit)
set errors_count_threshold $default(errors_count_threshold)
set security_level [lindex $default(security_level) 0]
set load_balancing_mode [lindex $default(load_balancing_mode) 0]
set frm [AddToplevel "Добавление кластера" cluster_grey_64]
label $frm.lbl_host -text "Адрес основного сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
label $frm.lbl_name -text "Название кластера"
entry $frm.ent_name
label $frm.lbl_secure_connect -text "Защищённое соединение"
ttk::combobox $frm.cb_security_level -textvariable security_level -values $default(security_level)
label $frm.lbl_expiration_timeout -text "Останавливать выключенные процессы через:"
entry $frm.ent_expiration_timeout -textvariable expiration_timeout
label $frm.lbl_session_fault_tolerance_level -text "Уровень отказоустойчивости"
entry $frm.ent_session_fault_tolerance_level -textvariable session_fault_tolerance_level
label $frm.lbl_load_balancing_mode -text "Режим распределения нагрузки"
ttk::combobox $frm.cb_load_balancing_mode -textvariable load_balancing_mode
-values $default(load_balancing_mode)
label $frm.lbl_errors_count_threshold -text "Допустимое отклонение количества ошибок сервера, %"
entry $frm.ent_errors_count_threshold -textvariable errors_count_threshold
label $frm.lbl_processes -text "Рабочие процессы:"
label $frm.lbl_lifetime_limit -text "Период перезапуска, сек."
entry $frm.ent_lifetime_limit -textvariable lifetime_limit
label $frm.lbl_max_memory_size -text "Допустимый объём памяти, КБ"
entry $frm.ent_max_memory_size -textvariable max_memory_size
label $frm.lbl_max_memory_time_limit -text "Интервал превышения допустимого объёма памяти, сек."
entry $frm.ent_max_memory_time_limit -textvariable max_memory_time_limit
label $frm.lbl_kill_problem_processes -justify left -anchor nw -text "Принудительно завершать проблемные процессы"
checkbutton $frm.check_kill_problem_processes -variable kill_problem_processes -onvalue yes -offvalue no
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_name -row 2 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_name -row 2 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_secure_connect -row 3 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_security_level -row 3 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_expiration_timeout -row 4 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_expiration_timeout -row 4 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_session_fault_tolerance_level -row 5 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_session_fault_tolerance_level -row 5 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_load_balancing_mode -row 6 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_load_balancing_mode -row 6 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_errors_count_threshold -row 7 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_errors_count_threshold -row 7 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_processes -row 8 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.lbl_lifetime_limit -row 9 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_lifetime_limit -row 9 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_size -row 10 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_size -row 10 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_time_limit -row 11 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_time_limit -row 11 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_kill_problem_processes -row 12 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.check_kill_problem_processes -row 12 -column 1 -sticky nw -padx 5 -pady 5
# переопределяем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
return $frm
}Bij het vergelijken van de code van deze procedures is het verschil met het blote oog zichtbaar; ik zal me concentreren op de “Ok”-knophandler. In Tk kunnen de eigenschappen van grafische elementen tijdens de uitvoering van het programma worden overschreven met behulp van de optie configureer. Het initiële commando om de knop weer te geven:
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }Maar in onze formulieren is de opdracht afhankelijk van de vereiste functionaliteit:
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
In het bovenstaande voorbeeld start de knop ‘verstopt’ de procedure voor het toevoegen van een cluster.
Hier is het de moeite waard om een uitweiding te maken naar het werken met grafische elementen in Tk - voor verschillende gegevensinvoerelementen (invoer, combobox, checkbutton, enz.) is een parameter geïntroduceerd als tekstvariabele:
entry $frm.ent_lifetime_limit -textvariable lifetime_limitDeze variabele wordt gedefinieerd in de globale naamruimte en bevat de momenteel ingevoerde waarde. Die. om de ingevoerde tekst uit het veld te halen, hoeft u alleen maar de waarde te lezen die overeenkomt met de variabele (uiteraard op voorwaarde dat deze is gedefinieerd bij het maken van het element).
De tweede methode voor het ophalen van de ingevoerde tekst (voor elementen van het invoertype) is door het get-commando te gebruiken:
.add.frm.ent_name getBeide methoden zijn te zien in de bovenstaande code.
Als u in dit geval op deze knop klikt, wordt de RunCommand-procedure gestart met de gegenereerde opdrachtregel voor het toevoegen van een cluster in termen van rac:
/opt/1C/v8.3/x86_64/rac cluster insert --host=localhost --port=1540 --name=dsdsds --expiration-timeout=0 --lifetime-limit=0 --max-memory-size=0 --max-memory-time-limit=0 --security-level=0 --session-fault-tolerance-level=0 --load-balancing-mode=performance --errors-count-threshold=0 --kill-problem-processes=no localhost:1545Nu komen we bij het hoofdcommando, dat de lancering van rac bestuurt met de parameters die we nodig hebben, en ook de uitvoer van commando's in lijsten analyseert en indien nodig retourneert:
Opdracht uitvoeren
proc RunCommand {root par} {
global dir rac_cmd cluster work_list_row_count agent_user agent_pwd cluster_user cluster_pwd
puts "$rac_cmd $par"
set work_list_row_count 0
# открываем канал в неблокирующем режиме
# $rac - команда с полным путём
# $par - сформированные ключи запуска и опции
set pipe [open "|$rac_cmd $par" "r"]
try {
set lst ""
set l ""
# вывод команды добавляем в список списков
while {[gets $pipe line]>=0} {
#puts $line
if {$line eq ""} {
lappend l $lst
set lst ""
} else {
lappend lst [string trim $line]
}
}
close $pipe
return $l
} on error {result options} {
# Запуск обработчика ошибок
ErrorParcing $result $options
return ""
}
}Na het invoeren van de hoofdservergegevens worden deze aan de boom toegevoegd. Hiervoor is in de bovenstaande Add:server-procedure de volgende code verantwoordelijk:
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"Door nu op de servernaam in de boomstructuur te klikken, krijgen we een lijst met clusters die door die server worden beheerd, en door op een cluster te klikken krijgen we een lijst met clusterelementen (servers, infobases, enz.). Dit is geïmplementeerd in de TreePress-procedure (bestand lib/function.tcl):
proc TreePress {tree} {
global host server active_cluster infobase
# определяем выделенный элемент
set id [$tree selection]
# устанавливаем нужные глобальные переменные
SetGlobalVarFromTreeItems $tree $id
# Определяем ключ и значение, т.е. именно тип выбранного элемента
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
# и в зависимости от того что выбрали будет запущена соответствующая процедура
# в пространстве имён Run
Run::$key $tree $host $values
}Dienovereenkomstig wordt Run::server gestart voor de hoofdserver (voor een cluster - Run::cluster, voor een werkende server - Run::work_server, enz.). Die. de waarde van de variabele $key maakt deel uit van de naam van het boomelement dat door de optie is opgegeven -ID kaart.
Laten we aandacht besteden aan de procedure
Uitvoeren::server
proc Run::server {tree host values} {
# получаем список кластеров требуемого сервера
set lst [RunCommand server::$host "cluster list $host"]
if {$lst eq ""} {return}
set l [lindex $lst 0]
#puts $lst
# удаляем лишнее из списка
.frm_work.tree_work delete [ .frm_work.tree_work children {}]
# читаем список
foreach cluster_list $lst {
# Заполняем список полученными значениями
InsertItemsWorkList $cluster_list
# обрабатываем вывод (список) для добавления данных в дерево
foreach i $cluster_list {
#puts $i
set cluster_list [split $i ":"]
if {[string trim [lindex $cluster_list 0]] eq "cluster"} {
set cluster_id [string trim [lindex $cluster_list 1]]
lappend cluster($cluster_id) $cluster_id
}
if {[string trim [lindex $cluster_list 0]] eq "name"} {
lappend cluster($cluster_id) [string trim [lindex $cluster_list 1]]
}
}
}
# добавляем кластеры в дерево
foreach x [array names cluster] {
set id [lindex $cluster($x) 0]
if { [$tree exists "cluster::$id"] == 0 } {
$tree insert "server::$host" end -id "cluster::$id" -text "[lindex $cluster($x) 1]" -values "$id"
# добавляем элементы в кластер
InsertClusterItems $tree $id
}
}
if { [$tree exists "agent_admins::$id"] == 0 } {
$tree insert "server::$host" end -id "agent_admins::$id" -text "Администраторы" -values "$id"
#InsertClusterItems $tree $id
}
}Deze procedure verwerkt wat er van de server is ontvangen via de RunCommand-opdracht en voegt allerlei dingen aan de boom toe: clusters, verschillende rootelementen (bases, werkende servers, sessies, enzovoort). Als u goed kijkt, ziet u een oproep naar de InsertItemsWorkList-procedure binnenin. Het wordt gebruikt om elementen aan een grafische lijst toe te voegen door de uitvoer van het rac-consolehulpprogramma te verwerken, dat eerder als een lijst aan de $lst-variabele werd geretourneerd. Dit is een lijst met lijsten die paren elementen bevatten, gescheiden door een dubbele punt.
Bijvoorbeeld een lijst met clusterverbindingen:
svk@svk ~]$ /opt/1C/v8.3/x86_64/rac connection list --cluster=783d2170-56c3-11e8-c586-fc75165efbb2 localhost:1545
connection : dcf5991c-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:49:51
session-number : 0
blocked-by-ls : 0
connection : b993293a-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:48:52
session-number : 0
blocked-by-ls : 0
In grafische vorm zal het er ongeveer zo uitzien:
De bovenstaande procedure selecteert de namen van elementen voor de koptekst en gegevens om de tabel in te vullen:
InsertItemsWorkList
proc InsertItemsWorkList {lst} {
global work_list_row_count
# установка чередования цвета для строки
if [expr $work_list_row_count % 2] {
set tag dark
} else {
set tag light
}
# разбор строк на пары ключ - значение
foreach i $lst {
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
lappend column_list [string trim $param]
lappend value_list [string trim $value]
}
}
# заполнение таблицы
.frm_work.tree_work configure -columns $column_list -displaycolumns $column_list
.frm_work.tree_work insert {} end -values $value_list -tags $tag
.frm_work.tree_work column #0 -stretch
# установка заголовков
foreach j $column_list {
.frm_work.tree_work heading $j -text $j
}
incr work_list_row_count
}Hier wordt, in plaats van een eenvoudig commando [split $str ], dat de string opsplitst in elementen gescheiden door : en een lijst retourneert, een reguliere expressie gebruikt, aangezien sommige elementen ook een dubbele punt bevatten.
De InsertClusterItems-procedure (een van de vele soortgelijke) voegt eenvoudigweg een lijst met onderliggende elementen met bijbehorende identificatiegegevens toe aan de boomstructuur van het vereiste clusterelement
ClusterItems invoegen
proc InsertClusterItems {tree id} {
set parent "cluster::$id"
$tree insert $parent end -id "infobases::$id" -text "Информационные базы" -values "$id"
$tree insert $parent end -id "servers::$id" -text "Рабочие серверы" -values "$id"
$tree insert $parent end -id "admins::$id" -text "Администраторы" -values "$id"
$tree insert $parent end -id "managers::$id" -text "Менеджеры кластера" -values $id
$tree insert $parent end -id "processes::$id" -text "Рабочие процессы" -values "workprocess-all"
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "sessions-all"
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "blocks-all"
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "connections-all"
$tree insert $parent end -id "profiles::$id" -text "Профили безопасности" -values $id
}
U kunt nog twee opties overwegen om een soortgelijke procedure te implementeren, waarbij duidelijk zichtbaar zal zijn hoe u repetitieve opdrachten kunt optimaliseren en verwijderen:
In deze procedure worden het toevoegen en controleren direct opgelost:
VoegBaseItems in
proc InsertBaseItems {tree id} {
set parent "infobase::$id"
if { [$tree exists "sessions::$id"] == 0 } {
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "$id"
}
if { [$tree exists "locks::$id"] == 0 } {
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "$id"
}
if { [$tree exists "connections::$id"] == 0 } {
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "$id"
}
}
Hier is een correctere aanpak:
ProfielItems invoegen
proc InsertProfileItems {tree id} {
set parent "profile::$id"
set lst {
{dir "Виртуальные каталоги"}
{com "Разрешённые COM-классы"}
{addin "Внешние компоненты"}
{module "Внешние отчёты и обработки"}
{app "Разрешённые приложения"}
{inet "Ресурсы интернет"}
}
foreach i $lst {
append item [lindex $i 0] "::$id"
if { [$tree exists $item] == 0 } {
$tree insert $parent end -id $item -text [lindex $i 1] -values "$id"
}
unset item
}
}Het verschil tussen beide is het gebruik van een lus, waarin de herhaalde opdracht(en) worden uitgevoerd. Welke aanpak moet worden gebruikt, is ter beoordeling van de ontwikkelaar.
We hebben het toevoegen van elementen en het ophalen van gegevens besproken, nu is het tijd om ons te concentreren op het bewerken. Omdat voor het bewerken en toevoegen (met uitzondering van de informatiebank) in principe dezelfde parameters worden gebruikt, worden dezelfde dialoogvormen gebruikt. Het algoritme voor het aanroepen van procedures voor het toevoegen ziet er als volgt uit:
Toevoegen::$key->ToevoegenTopniveau
En voor het bewerken als volgt:
Bewerken::$key->Toevoegen::$key->TopLevel toevoegen
Laten we bijvoorbeeld een cluster bewerken, d.w.z. Nadat u op de naam van het cluster in de boom hebt geklikt, drukt u op de knop Bewerken in de werkbalk (potlood) en het bijbehorende formulier wordt op het scherm weergegeven:
Bewerken::cluster
proc Edit::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes active_cluster
agent_user agent_pwd cluster_user cluster_pwd auth
if {$cluster_user ne "" && $cluster_pwd ne ""} {
set auth "--cluster-user=$cluster_user --cluster-pwd=$cluster_pwd"
} else {
set auth ""
}
# рисуем форму для кластера
set frm [Add::cluster $tree $host $values]
# меняем текст на метке
$frm configure -text "Редактирование кластера"
set active_cluster $values
# получаем данные по выделенному кластеру
set lst [RunCommand cluster::$values "cluster info --cluster=$active_cluster $host"]
# заполняем поля
FormFieldsDataInsert $frm $lst
# выключаем поля, редактирование которых запрещено
$frm.ent_host configure -state disable
$frm.ent_port configure -state disable
# переназначаем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster update
--cluster=$active_cluster $auth
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth $host"
$tree delete "cluster::$active_cluster"
Run::server $tree $host ""
destroy .add
}
}Op basis van het commentaar in de code is in principe alles duidelijk, behalve dat de knophandlercode wordt overschreven en er een FormFieldsDataInsert-procedure is die de velden met gegevens vult en de variabelen initialiseert:
FormFieldsDataInsert
proc FormFieldsDataInsert {frm lst} {
foreach i [lindex $lst 0] {
# получаем список параметров и значений
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
# меняем символы
regsub -all -- "-" [string trim $param] "_" entry_name
# заполняем данными
if [winfo exists $frm.ent_$entry_name] {
$frm.ent_$entry_name delete 0 end
$frm.ent_$entry_name insert end [string trim $value """]
}
if [winfo exists $frm.cb_$entry_name] {
global $entry_name
set $entry_name [string trim $value """]
}
# для чекбоксов меняем значения
if [winfo exists $frm.check_$entry_name] {
global $entry_name
if {$value eq "0"} {
set $entry_name no
} elseif {$value eq "1"} {
set $entry_name yes
} else {
set $entry_name $value
}
}
}
}
}
In deze procedure kwam nog een voordeel van tcl naar voren: de waarden van andere variabelen worden vervangen als variabelenamen. Die. Om het invullen van formulieren en het initialiseren van variabelen te automatiseren, komen de namen van velden en variabelen overeen met de opdrachtregelschakelaars van het rac-hulpprogramma en de namen van opdrachtuitvoerparameters, op enkele uitzonderingen na: het streepje wordt vervangen door een onderstrepingsteken. Bijv geplande banen-weigeren past bij het veld ent_scheduled_jobs_deny en variabel geplande_jobs_deny.
Formulieren voor het toevoegen en bewerken kunnen verschillen in de samenstelling van de velden, bijvoorbeeld door te werken met een informatiebank:
Informatiebeveiliging toevoegen
Informatiebeveiliging bewerken
In de bewerkingsprocedure Edit::infobase worden de verplichte velden aan het formulier toegevoegd; de code is omvangrijk, daarom presenteer ik deze hier niet.
Naar analogie worden voor andere elementen procedures voor het toevoegen, bewerken en verwijderen geïmplementeerd.
Omdat de werking van het hulpprogramma een onbeperkt aantal servers, clusters, informatiebases, enz. impliceert, om te bepalen welk cluster tot welke server of informatiebeveiligingssysteem behoort, zijn er verschillende globale variabelen geïntroduceerd, waarvan de waarden elk worden ingesteld keer dat u op de elementen van de boom klikt. Die. de procedure loopt recursief door alle bovenliggende elementen en stelt de variabelen in:
SetGlobalVarFromTreeItems
proc SetGlobalVarFromTreeItems {tree id} {
global host server active_cluster infobase
set parent [$tree parent $id]
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
switch -- $key {
server {set host $values}
work_server {set server $values}
cluster {set active_cluster $values}
infobase {set infobase $values}
}
if {$parent eq ""} {
return
} else {
SetGlobalVarFromTreeItems $tree $parent
}
}
Met het 1C-cluster kunt u met of zonder autorisatie werken. Er zijn twee typen beheerders: clusteragentbeheerder en clusterbeheerder. Voor een correcte werking zijn er daarom nog 4 globale variabelen geïntroduceerd, die de login en het wachtwoord van de beheerder bevatten. Die. Als er een beheerdersaccount in het cluster aanwezig is, wordt er een dialoogvenster weergegeven waarin u uw gebruikersnaam en wachtwoord kunt invoeren. De gegevens worden in het geheugen opgeslagen en in elke opdracht voor het overeenkomstige cluster ingevoegd.
Dit is de verantwoordelijkheid van de foutafhandelingsprocedure.
Fout bij parkeren
proc ErrorParcing {err opt} {
global cluster_user cluster_pwd agent_user agent_pwd
switch -regexp -- $err {
"Cluster administrator is not authenticated" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Central server administrator is not authenticated" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
"Администратор кластера не аутентифицирован" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Администратор центрального сервера не аутентифицирован" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
(.+) {
tk_messageBox -type ok -icon error -message "$err"
}
}
}Die. afhankelijk van wat het commando retourneert, zal de reactie dienovereenkomstig zijn.
Op dit moment is ongeveer 95 procent van de functionaliteit geïmplementeerd, het enige dat overblijft is het werken met beveiligingsprofielen implementeren en testen =). Dat is alles. Mijn excuses voor het verkreukelde verhaal.
De code is traditioneel beschikbaar .
Update: ik ben klaar met werken met beveiligingsprofielen. Nu is de functionaliteit 100% geïmplementeerd.
Update 2: lokalisatie naar Engels en Russisch is toegevoegd, werk in win7 is getest
Bron: www.habr.com