Da vi fordypet oss i emnet om hvordan 1C-produkter fungerer i Linux-miljøet, ble en ulempe oppdaget - mangelen på et praktisk grafisk multiplattformverktøy for å administrere en klynge med 1C-servere. Og det ble besluttet å rette opp denne ulempen ved å skrive en GUI for rac-konsollen. Tcl/tk ble valgt som utviklingsspråk som etter min mening best egnet for denne oppgaven. Og så vil jeg presentere noen interessante aspekter ved løsningen i dette materialet.
For å jobbe trenger du tcl/tk og 1C distribusjoner. Og siden jeg bestemte meg for å utnytte mulighetene til den grunnleggende tcl/tk-leveringen uten å bruke tredjepartspakker, trenger jeg versjon 8.6.7, som inkluderer ttk - en pakke med ekstra grafiske elementer, som vi hovedsakelig trenger ttk av. ::TreeView, den tillater visning av data både i form av en trestruktur og i form av en tabell (liste). I den nye versjonen har også arbeidet med unntak blitt omarbeidet (prøv-kommandoen, som brukes i prosjektet når du kjører eksterne kommandoer).
Prosjektet består av flere filer (selv om ingenting hindrer deg i å gjøre alt i en):
rac_gui.cfg - standard konfig
rac_gui.tcl - hovedlanseringsskript
Lib-katalogen inneholder filer som lastes automatisk ved oppstart:
function.tcl - fil med prosedyrer
gui.tcl - grafisk hovedgrensesnitt
images.tcl - base64 bildebibliotek
rac_gui.tcl-filen starter faktisk tolken, initialiserer variabler, laster inn moduler, konfigurasjoner og så videre. Innhold i filen med kommentarer:
rac_gui.tcl
#!/bin/sh
exec wish "$0" -- "$@"
# Устанавливаем текущий каталог
set dir(root) [pwd]
# Устанавливаем рабочий каталог, если его нет то создаём
set dir(work) [file join $env(HOME) .rac_gui]
if {[file exists $dir(work)] == 0 } {
file mkdir $dir(work)
}
# каталог с модулями
set dir(lib) "[file join $dir(root) lib]"
# загружаем пользовательский конфиг, если он отсутствует, то копируем дефолтный
if {[file exists [file join $dir(work) rac_gui.cfg]] ==0} {
file copy [file join [pwd] rac_gui.cfg] [file join $dir(work) rac_gui.cfg]
}
source [file join $dir(work) rac_gui.cfg]
# Код проверки наличия rac и правильности указания пути в конфиге
# если программа не найдена то будет выведен диалог для указания корректного пути
# и этот путь будет записан в пользовательский конфиг
if {[file exists $rac_cmd] == 0} {
set rac_cmd [tk_getOpenFile -initialdir $env(HOME) -parent . -title "Укажите путь до rac" -initialfile rac]
file copy [file join $dir(work) rac_gui.cfg] [file join $dir(work) rac_gui.cfg.bak]
set orig_file [open [file join $dir(work) rac_gui.cfg.bak] "r"]
set file [open [file join $dir(work) rac_gui.cfg] "w"]
while {[gets $orig_file line] >=0 } {
if {[string match "set rac_cmd*" $line]} {
puts $file "set rac_cmd $rac_cmd"
} else {
puts $file $line
}
}
close $file
close $orig_file
#return "$host:$port"
file delete [file join $dir(work) 1c_srv.cfg.bak]
} else {
puts "Found $rac_cmd"
}
set cluster_user ""
set cluster_pwd ""
set agent_user ""
set agent_pwd ""
## LOAD FILE ##
# Загружаем модули кроме gui.tcl так как его надо загрузить последним
foreach modFile [lsort [glob -nocomplain [file join $dir(lib) *.tcl]]] {
if {[file tail $modFile] ne "gui.tcl"} {
source $modFile
puts "Loaded module $modFile"
}
}
source [file join $dir(lib) gui.tcl]
source [file join $dir(work) rac_gui.cfg]
# Читаем файл со списком серверов 1С
# и добавляем в дерево
if [file exists [file join $dir(work) 1c_srv.cfg]] {
set f [open [file join $dir(work) 1c_srv.cfg] "RDONLY"]
while {[gets $f line] >=0} {
.frm_tree.tree insert {} end -id "server::$line" -text "$line" -values "$line"
}
}Etter å ha lastet ned alt som kreves og sjekket for tilstedeværelsen av rac-verktøyet, vil et grafisk vindu bli lansert. Programgrensesnittet består av tre elementer:
Verktøylinje, tre og liste
Jeg gjorde innholdet i "treet" så likt som mulig med standard Windows-utstyr fra 1C.
Hovedkoden som danner dette vinduet finnes i filen
lib/gui.tcl
# установка размера и положения основного окна
# можно установить в переменную topLevelGeometry в конфиг программы
if {[info exists topLevelGeometry]} {
wm geometry . $topLevelGeometry
} else {
wm geometry . 1024x768
}
# Заголовок окна
wm title . "1C Rac GUI"
wm iconname . "1C Rac Gui"
# иконка окна (берется из файла lib/imges.tcl)
wm iconphoto . tcl
wm protocol . WM_DELETE_WINDOW Quit
wm overrideredirect . 0
wm positionfrom . user
ttk::style theme use clam
# Панель инсрументов
set frm_tool [frame .frm_tool]
pack $frm_tool -side left -fill y
ttk::panedwindow .panel -orient horizontal -style TPanedwindow
pack .panel -expand true -fill both
pack propagate .panel false
ttk::button $frm_tool.btn_add -command Add -image add_grey_32
ttk::button $frm_tool.btn_del -command Del -image del_grey_32
ttk::button $frm_tool.btn_edit -command Edit -image edit_grey_32
ttk::button $frm_tool.btn_quit -command Quit -image quit_grey_32
pack $frm_tool.btn_add $frm_tool.btn_del $frm_tool.btn_edit -side top -padx 5 -pady 5
pack $frm_tool.btn_quit -side bottom -padx 5 -pady 5
# Дерево с полосами прокрутки
set frm_tree [frame .frm_tree]
ttk::scrollbar $frm_tree.hsb1 -orient horizontal -command [list $frm_tree.tree xview]
ttk::scrollbar $frm_tree.vsb1 -orient vertical -command [list $frm_tree.tree yview]
set tree [ttk::treeview $frm_tree.tree -show tree
-xscrollcommand [list $frm_tree.hsb1 set] -yscrollcommand [list $frm_tree.vsb1 set]]
grid $tree -row 0 -column 0 -sticky nsew
grid $frm_tree.vsb1 -row 0 -column 1 -sticky nsew
grid $frm_tree.hsb1 -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_tree 0 -weight 1
grid rowconfigure $frm_tree 0 -weight 1
# назначение обработчика нажатия кнопкой мыши
bind $frm_tree.tree <ButtonRelease> "TreePress $frm_tree.tree"
# Список для данных (таблица)
set frm_work [frame .frm_work]
ttk::scrollbar $frm_work.hsb -orient horizontal -command [list $frm_work.tree_work xview]
ttk::scrollbar $frm_work.vsb -orient vertical -command [list $frm_work.tree_work yview]
set tree_work [
ttk::treeview $frm_work.tree_work
-show headings -columns "par val" -displaycolumns "par val"
-xscrollcommand [list $frm_work.hsb set]
-yscrollcommand [list $frm_work.vsb set]
]
# Установка цветов для чередования в таблице
$tree_work tag configure dark -background $color(dark_table_bg)
$tree_work tag configure light -background $color(light_table_bg)
# Размещение элементов на форме
grid $tree_work -row 0 -column 0 -sticky nsew
grid $frm_work.vsb -row 0 -column 1 -sticky nsew
grid $frm_work.hsb -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_work 0 -weight 1
grid rowconfigure $frm_work 0 -weight 1
pack $frm_tree $frm_work -side left -expand true -fill both
#.panel add $frm_tool -weight 1
.panel add $frm_tree -weight 1
.panel add $frm_work -weight 1
Algoritmen for å jobbe med programmet er som følger:
1. Først må du legge til hovedklyngeserveren (dvs. klyngeadministrasjonsserveren (i Linux lanseres administrasjonen med kommandoen “/opt/1C/v8.3/x86_64/ras cluster —daemon”)).
For å gjøre dette, klikk på "+"-knappen og skriv inn serveradressen og porten i vinduet som åpnes:
Etterpå vil serveren vår vises i treet ved å klikke på den, en liste over klynger åpnes eller en tilkoblingsfeil vises.
2. Ved å klikke på klyngenavnet åpnes en liste over funksjoner som er tilgjengelige for den.
3. ...
Og så videre, dvs. for å legge til en ny klynge, velg hvilken som helst tilgjengelig i listen og trykk på "+"-knappen i verktøylinjen, og legg til ny dialog vil vises:
Knappene i verktøylinjen utfører funksjoner avhengig av konteksten, dvs. Avhengig av hvilket element i treet eller listen som er valgt, vil en eller annen prosedyre bli utført.
La oss se på eksemplet med legg til-knappen (“+”):
Knappgenereringskode:
ttk::button $frm_tool.btn_add -command Add -image add_grey_32Her ser vi at når knappen trykkes, vil "Legg til"-prosedyren bli utført, dens kode:
proc Add {} {
global active_cluster host
# Определяем идентификатор выделенного элемента
set id [.frm_tree.tree selection]
# Определяем значение этого элемента
set values [.frm_tree.tree item [.frm_tree.tree selection] -values]
set key [lindex [split $id "::"] 0]
# в зависимости от того что выделили будет запущена нужная процедура
if {$key eq "" || $key eq "server"} {
set host [ Add::server ]
return
}
Add::$key .frm_tree.tree $host $values
}Her er en av fordelene med tickle: du kan sende verdien til en variabel som et prosedyrenavn:
Add::$key .frm_tree.tree $host $valuesDet vil si at hvis vi for eksempel peker på hovedserveren og trykker “+”, så vil Add::server-prosedyren startes, hvis på klyngen - Add::cluster og så videre (jeg skal skrive om hvor nødvendige "nøkler" kommer fra litt nedenfor), tegner de oppførte prosedyrene grafiske elementer som passer til konteksten.
Som du kanskje allerede har lagt merke til, er skjemaene like i stil - dette er ikke overraskende, fordi de vises ved en prosedyre, mer presist hovedrammen til skjemaet (vindu, knapper, bilde, etikett), navnet på prosedyren AddTopLevel
proc AddToplevel {lbl img {win_name .add}} {
set cmd "destroy $win_name"
if [winfo exists $win_name] {destroy $win_name}
toplevel $win_name
wm title $win_name $lbl
wm iconphoto $win_name tcl
# метка с иконкой
ttk::label $win_name.lbl -image $img
# фрейм с полями ввода
set frm [ttk::labelframe $win_name.frm -text $lbl -labelanchor nw]
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
# фрейм и кнопки
set frm_btn [frame $win_name.frm_btn -border 0]
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }
ttk::button $frm_btn.btn_cancel -command $cmd -image quit_grey_24
grid $win_name.lbl -row 0 -column 0 -sticky nw -padx 5 -pady 10
grid $frm -row 0 -column 1 -sticky nw -padx 5 -pady 5
grid $frm_btn -row 1 -column 1 -sticky se -padx 5 -pady 5
pack $frm_btn.btn_cancel -side right
pack $frm_btn.btn_ok -side right -padx 10
return $frm
}
Anropsparametere: tittel, bildenavn for ikonet fra biblioteket (lib/images.tcl) og en valgfri parameter for vindunavn (standard .add). Derfor, hvis vi tar eksemplene ovenfor for å legge til hovedserveren og klyngen, vil kallet være tilsvarende:
AddToplevel "Добавление основного сервера" server_grey_64eller
AddToplevel "Добавление кластера" cluster_grey_64Vel, fortsetter med disse eksemplene, vil jeg vise prosedyrene som viser legg til dialoger for en server eller klynge.
Legg til::server
proc Add::server {} {
global default
# выводим основную форму
set frm [AddToplevel "Добавление основного сервера" server_grey_64]
# добавляем етки и поля ввода на эту форму
label $frm.lbl_host -text "Адрес сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
#set frm_btn [frame .add.frm_btn -border 0]
# переопределяем обработчик нажатия кнопки
.add.frm_btn.btn_ok configure -command {
set host [SaveMainServer [.add.frm.ent_host get] [.add.frm.ent_port get]]
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"
destroy .add
return $host
}
return $frm
}Legg til::cluster
proc Add::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes
agent_user agent_pwd cluster_user cluster_pwd auth_agent
if {$agent_user ne "" && $agent_pwd ne ""} {
set auth_agent "--agent-user=$agent_user --agent-pwd=$agent_pwd"
} else {
set auth_agent ""
}
# устанавливаем глобальные переменные ()
set lifetime_limit $default(lifetime_limit)
set expiration_timeout $default(expiration_timeout)
set session_fault_tolerance_level $default(session_fault_tolerance_level)
set max_memory_size $default(max_memory_size)
set max_memory_time_limit $default(max_memory_time_limit)
set errors_count_threshold $default(errors_count_threshold)
set security_level [lindex $default(security_level) 0]
set load_balancing_mode [lindex $default(load_balancing_mode) 0]
set frm [AddToplevel "Добавление кластера" cluster_grey_64]
label $frm.lbl_host -text "Адрес основного сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
label $frm.lbl_name -text "Название кластера"
entry $frm.ent_name
label $frm.lbl_secure_connect -text "Защищённое соединение"
ttk::combobox $frm.cb_security_level -textvariable security_level -values $default(security_level)
label $frm.lbl_expiration_timeout -text "Останавливать выключенные процессы через:"
entry $frm.ent_expiration_timeout -textvariable expiration_timeout
label $frm.lbl_session_fault_tolerance_level -text "Уровень отказоустойчивости"
entry $frm.ent_session_fault_tolerance_level -textvariable session_fault_tolerance_level
label $frm.lbl_load_balancing_mode -text "Режим распределения нагрузки"
ttk::combobox $frm.cb_load_balancing_mode -textvariable load_balancing_mode
-values $default(load_balancing_mode)
label $frm.lbl_errors_count_threshold -text "Допустимое отклонение количества ошибок сервера, %"
entry $frm.ent_errors_count_threshold -textvariable errors_count_threshold
label $frm.lbl_processes -text "Рабочие процессы:"
label $frm.lbl_lifetime_limit -text "Период перезапуска, сек."
entry $frm.ent_lifetime_limit -textvariable lifetime_limit
label $frm.lbl_max_memory_size -text "Допустимый объём памяти, КБ"
entry $frm.ent_max_memory_size -textvariable max_memory_size
label $frm.lbl_max_memory_time_limit -text "Интервал превышения допустимого объёма памяти, сек."
entry $frm.ent_max_memory_time_limit -textvariable max_memory_time_limit
label $frm.lbl_kill_problem_processes -justify left -anchor nw -text "Принудительно завершать проблемные процессы"
checkbutton $frm.check_kill_problem_processes -variable kill_problem_processes -onvalue yes -offvalue no
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_name -row 2 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_name -row 2 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_secure_connect -row 3 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_security_level -row 3 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_expiration_timeout -row 4 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_expiration_timeout -row 4 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_session_fault_tolerance_level -row 5 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_session_fault_tolerance_level -row 5 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_load_balancing_mode -row 6 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_load_balancing_mode -row 6 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_errors_count_threshold -row 7 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_errors_count_threshold -row 7 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_processes -row 8 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.lbl_lifetime_limit -row 9 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_lifetime_limit -row 9 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_size -row 10 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_size -row 10 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_time_limit -row 11 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_time_limit -row 11 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_kill_problem_processes -row 12 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.check_kill_problem_processes -row 12 -column 1 -sticky nw -padx 5 -pady 5
# переопределяем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
return $frm
}Når du sammenligner koden for disse prosedyrene, er forskjellen synlig for det blotte øye; Jeg vil fokusere på "Ok"-knappbehandleren. I Tk kan egenskapene til grafiske elementer overstyres under programkjøring ved å bruke alternativet konfigurere. For eksempel, den første kommandoen for å vise knappen:
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }Men i skjemaene våre avhenger kommandoen av den nødvendige funksjonaliteten:
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
I eksemplet ovenfor starter "tilstoppet"-knappen prosedyren for å legge til en klynge.
Her er det verdt å gjøre en digresjon mot å jobbe med grafiske elementer i Tk - for ulike datainndataelementer (entry, combobox, checkbutton, etc.) er en parameter introdusert som en tekstvariabel:
entry $frm.ent_lifetime_limit -textvariable lifetime_limitDenne variabelen er definert i det globale navneområdet og inneholder den gjeldende angitte verdien. De. for å få den angitte teksten fra feltet, trenger du bare å lese verdien som tilsvarer variabelen (selvfølgelig forutsatt at den er definert når du oppretter elementet).
Den andre metoden for å hente inn teksten (for elementer av oppføringstype) er å bruke get-kommandoen:
.add.frm.ent_name getBegge disse metodene kan sees i koden ovenfor.
Ved å klikke på denne knappen, i dette tilfellet, starter RunCommand-prosedyren med den genererte kommandolinjen for å legge til en klynge når det gjelder rac:
/opt/1C/v8.3/x86_64/rac cluster insert --host=localhost --port=1540 --name=dsdsds --expiration-timeout=0 --lifetime-limit=0 --max-memory-size=0 --max-memory-time-limit=0 --security-level=0 --session-fault-tolerance-level=0 --load-balancing-mode=performance --errors-count-threshold=0 --kill-problem-processes=no localhost:1545Nå kommer vi til hovedkommandoen, som kontrollerer lanseringen av rac med parametrene vi trenger, også analyserer utdataene til kommandoer i lister og returnerer, om nødvendig:
Kjør kommando
proc RunCommand {root par} {
global dir rac_cmd cluster work_list_row_count agent_user agent_pwd cluster_user cluster_pwd
puts "$rac_cmd $par"
set work_list_row_count 0
# открываем канал в неблокирующем режиме
# $rac - команда с полным путём
# $par - сформированные ключи запуска и опции
set pipe [open "|$rac_cmd $par" "r"]
try {
set lst ""
set l ""
# вывод команды добавляем в список списков
while {[gets $pipe line]>=0} {
#puts $line
if {$line eq ""} {
lappend l $lst
set lst ""
} else {
lappend lst [string trim $line]
}
}
close $pipe
return $l
} on error {result options} {
# Запуск обработчика ошибок
ErrorParcing $result $options
return ""
}
}Etter å ha lagt inn hovedserverdataene, vil de bli lagt til treet, for dette, i Add:server-prosedyren ovenfor, er følgende kode ansvarlig:
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"Nå, ved å klikke på servernavnet i treet, får vi en liste over klynger administrert av den serveren, og ved å klikke på en klynge får vi en liste over klyngeelementer (servere, infobaser, etc.). Dette er implementert i TreePress-prosedyren (fil lib/function.tcl):
proc TreePress {tree} {
global host server active_cluster infobase
# определяем выделенный элемент
set id [$tree selection]
# устанавливаем нужные глобальные переменные
SetGlobalVarFromTreeItems $tree $id
# Определяем ключ и значение, т.е. именно тип выбранного элемента
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
# и в зависимости от того что выбрали будет запущена соответствующая процедура
# в пространстве имён Run
Run::$key $tree $host $values
}Følgelig vil Run::server bli lansert for hovedserveren (for en klynge - Run::cluster, for en fungerende server - Run::work_server, etc.). De. verdien av $key-variabelen er en del av navnet på treelementet spesifisert av alternativet id.
La oss ta hensyn til prosedyren
Kjør::server
proc Run::server {tree host values} {
# получаем список кластеров требуемого сервера
set lst [RunCommand server::$host "cluster list $host"]
if {$lst eq ""} {return}
set l [lindex $lst 0]
#puts $lst
# удаляем лишнее из списка
.frm_work.tree_work delete [ .frm_work.tree_work children {}]
# читаем список
foreach cluster_list $lst {
# Заполняем список полученными значениями
InsertItemsWorkList $cluster_list
# обрабатываем вывод (список) для добавления данных в дерево
foreach i $cluster_list {
#puts $i
set cluster_list [split $i ":"]
if {[string trim [lindex $cluster_list 0]] eq "cluster"} {
set cluster_id [string trim [lindex $cluster_list 1]]
lappend cluster($cluster_id) $cluster_id
}
if {[string trim [lindex $cluster_list 0]] eq "name"} {
lappend cluster($cluster_id) [string trim [lindex $cluster_list 1]]
}
}
}
# добавляем кластеры в дерево
foreach x [array names cluster] {
set id [lindex $cluster($x) 0]
if { [$tree exists "cluster::$id"] == 0 } {
$tree insert "server::$host" end -id "cluster::$id" -text "[lindex $cluster($x) 1]" -values "$id"
# добавляем элементы в кластер
InsertClusterItems $tree $id
}
}
if { [$tree exists "agent_admins::$id"] == 0 } {
$tree insert "server::$host" end -id "agent_admins::$id" -text "Администраторы" -values "$id"
#InsertClusterItems $tree $id
}
}Denne prosedyren behandler det som ble mottatt fra serveren gjennom RunCommand-kommandoen og legger til alle slags ting til treet - klynger, ulike rotelementer (baser, fungerende servere, sesjoner og så videre). Hvis du ser nøye etter, vil du legge merke til et kall til InsertItemsWorkList-prosedyren inne. Den brukes til å legge til elementer i en grafisk liste ved å behandle utdataene fra rac-konsollen, som tidligere ble returnert som en liste til $lst-variabelen. Dette er en liste over lister som inneholder par av elementer atskilt med et kolon.
For eksempel en liste over klyngeforbindelser:
svk@svk ~]$ /opt/1C/v8.3/x86_64/rac connection list --cluster=783d2170-56c3-11e8-c586-fc75165efbb2 localhost:1545
connection : dcf5991c-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:49:51
session-number : 0
blocked-by-ls : 0
connection : b993293a-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:48:52
session-number : 0
blocked-by-ls : 0
I grafisk form vil det se omtrent slik ut:
Prosedyren ovenfor velger navn på elementer for overskriften og dataene for å fylle ut tabellen:
InsertItemsWorkList
proc InsertItemsWorkList {lst} {
global work_list_row_count
# установка чередования цвета для строки
if [expr $work_list_row_count % 2] {
set tag dark
} else {
set tag light
}
# разбор строк на пары ключ - значение
foreach i $lst {
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
lappend column_list [string trim $param]
lappend value_list [string trim $value]
}
}
# заполнение таблицы
.frm_work.tree_work configure -columns $column_list -displaycolumns $column_list
.frm_work.tree_work insert {} end -values $value_list -tags $tag
.frm_work.tree_work column #0 -stretch
# установка заголовков
foreach j $column_list {
.frm_work.tree_work heading $j -text $j
}
incr work_list_row_count
}Her, i stedet for en enkel kommando [split $str ":"], som deler opp strengen i elementer atskilt med ":" og returnerer en liste, brukes et regulært uttrykk, siden noen elementer også inneholder et kolon.
Prosedyren InsertClusterItems (en av flere lignende) legger ganske enkelt til en liste over underordnede elementer med tilsvarende identifikatorer til treet til det nødvendige klyngeelementet
Sett inn ClusterItems
proc InsertClusterItems {tree id} {
set parent "cluster::$id"
$tree insert $parent end -id "infobases::$id" -text "Информационные базы" -values "$id"
$tree insert $parent end -id "servers::$id" -text "Рабочие серверы" -values "$id"
$tree insert $parent end -id "admins::$id" -text "Администраторы" -values "$id"
$tree insert $parent end -id "managers::$id" -text "Менеджеры кластера" -values $id
$tree insert $parent end -id "processes::$id" -text "Рабочие процессы" -values "workprocess-all"
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "sessions-all"
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "blocks-all"
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "connections-all"
$tree insert $parent end -id "profiles::$id" -text "Профили безопасности" -values $id
}
Du kan vurdere ytterligere to alternativer for å implementere en lignende prosedyre, der det vil være tydelig synlig hvordan du kan optimalisere og bli kvitt repeterende kommandoer:
I denne prosedyren løses det å legge til og sjekke direkte:
InsertBaseItems
proc InsertBaseItems {tree id} {
set parent "infobase::$id"
if { [$tree exists "sessions::$id"] == 0 } {
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "$id"
}
if { [$tree exists "locks::$id"] == 0 } {
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "$id"
}
if { [$tree exists "connections::$id"] == 0 } {
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "$id"
}
}
Her er en mer korrekt tilnærming:
InsertProfileItems
proc InsertProfileItems {tree id} {
set parent "profile::$id"
set lst {
{dir "Виртуальные каталоги"}
{com "Разрешённые COM-классы"}
{addin "Внешние компоненты"}
{module "Внешние отчёты и обработки"}
{app "Разрешённые приложения"}
{inet "Ресурсы интернет"}
}
foreach i $lst {
append item [lindex $i 0] "::$id"
if { [$tree exists $item] == 0 } {
$tree insert $parent end -id $item -text [lindex $i 1] -values "$id"
}
unset item
}
}Forskjellen mellom dem er bruken av en løkke, der de gjentatte kommandoene utføres. Hvilken tilnærming som skal brukes er etter utviklerens skjønn.
Vi har dekket å legge til elementer og hente data, nå er det på tide å fokusere på redigering. Siden i utgangspunktet de samme parameterne brukes for redigering og tilføyelse (med unntak av informasjonsbasen), brukes de samme dialogskjemaene. Algoritmen for å kalle prosedyrer for å legge til ser slik ut:
Legg til::$key->AddToplevel
Og for redigering som dette:
Rediger::$key->Add::$key->AddTopLevel
La oss for eksempel ta redigering av en klynge, dvs. Etter å ha klikket på navnet på klyngen i treet, trykk på redigeringsknappen i verktøylinjen (blyant) og det tilsvarende skjemaet vil vises på skjermen:
Edit::cluster
proc Edit::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes active_cluster
agent_user agent_pwd cluster_user cluster_pwd auth
if {$cluster_user ne "" && $cluster_pwd ne ""} {
set auth "--cluster-user=$cluster_user --cluster-pwd=$cluster_pwd"
} else {
set auth ""
}
# рисуем форму для кластера
set frm [Add::cluster $tree $host $values]
# меняем текст на метке
$frm configure -text "Редактирование кластера"
set active_cluster $values
# получаем данные по выделенному кластеру
set lst [RunCommand cluster::$values "cluster info --cluster=$active_cluster $host"]
# заполняем поля
FormFieldsDataInsert $frm $lst
# выключаем поля, редактирование которых запрещено
$frm.ent_host configure -state disable
$frm.ent_port configure -state disable
# переназначаем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster update
--cluster=$active_cluster $auth
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth $host"
$tree delete "cluster::$active_cluster"
Run::server $tree $host ""
destroy .add
}
}Basert på kommentarene i koden er i prinsippet alt klart, bortsett fra at knappehåndteringskoden overstyres og det er en FormFieldsDataInsert-prosedyre som fyller feltene med data og initialiserer variablene:
FormFieldsDataInsert
proc FormFieldsDataInsert {frm lst} {
foreach i [lindex $lst 0] {
# получаем список параметров и значений
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
# меняем символы
regsub -all -- "-" [string trim $param] "_" entry_name
# заполняем данными
if [winfo exists $frm.ent_$entry_name] {
$frm.ent_$entry_name delete 0 end
$frm.ent_$entry_name insert end [string trim $value """]
}
if [winfo exists $frm.cb_$entry_name] {
global $entry_name
set $entry_name [string trim $value """]
}
# для чекбоксов меняем значения
if [winfo exists $frm.check_$entry_name] {
global $entry_name
if {$value eq "0"} {
set $entry_name no
} elseif {$value eq "1"} {
set $entry_name yes
} else {
set $entry_name $value
}
}
}
}
}
I denne prosedyren dukket det opp en annen fordel med tcl - verdiene til andre variabler erstattes som variabelnavn. De. for å automatisere utfylling av skjemaer og initialisering av variabler, tilsvarer navnene på feltene og variablene kommandolinjebryterne til rac-verktøyet og navnene på kommandoutgangsparametere med noen unntak - bindestreken erstattes av en understreking. F.eks planlagte-jobber-nekt matcher feltet ent_scheduled_jobs_deny og variabel planlagte_jobber_nekt.
Skjemaer for å legge til og redigere kan variere i sammensetningen av feltene, for eksempel ved å jobbe med en informasjonsbase:
Legger til informasjonssikkerhet
Redigering av informasjonssikkerhet
I redigeringsprosedyren Edit::infobase legges de obligatoriske feltene til skjemaet; koden er omfangsrik, derfor presenterer jeg den ikke her.
Analogt er prosedyrer for å legge til, redigere, slette implementert for andre elementer.
Siden driften av verktøyet innebærer et ubegrenset antall servere, klynger, informasjonsbaser, etc., for å bestemme hvilken klynge som tilhører hvilken server eller informasjonssikkerhetssystem, har flere globale variabler blitt introdusert, hvis verdier settes hver. gang du klikker på elementene i treet. De. prosedyren går rekursivt gjennom alle overordnede elementer og setter variablene:
SetGlobalVarFromTreeItems
proc SetGlobalVarFromTreeItems {tree id} {
global host server active_cluster infobase
set parent [$tree parent $id]
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
switch -- $key {
server {set host $values}
work_server {set server $values}
cluster {set active_cluster $values}
infobase {set infobase $values}
}
if {$parent eq ""} {
return
} else {
SetGlobalVarFromTreeItems $tree $parent
}
}
1C-klyngen lar deg jobbe med eller uten autorisasjon. Det finnes to typer administratorer – klyngeagentadministrator og klyngeadministrator. Følgelig, for korrekt drift, ble det introdusert ytterligere 4 globale variabler som inneholder administratorinnlogging og passord. De. hvis det er en administratorkonto i klyngen, vises en dialogboks for å angi pålogging og passord, dataene vil bli lagret i minnet og satt inn i hver kommando for den tilsvarende klyngen.
Dette er ansvaret til feilhåndteringsprosedyren.
Feilparsering
proc ErrorParcing {err opt} {
global cluster_user cluster_pwd agent_user agent_pwd
switch -regexp -- $err {
"Cluster administrator is not authenticated" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Central server administrator is not authenticated" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
"Администратор кластера не аутентифицирован" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Администратор центрального сервера не аутентифицирован" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
(.+) {
tk_messageBox -type ok -icon error -message "$err"
}
}
}De. avhengig av hva kommandoen returnerer, vil reaksjonen være deretter.
For øyeblikket er ca 95 prosent av funksjonaliteten implementert, det gjenstår bare å implementere arbeid med sikkerhetsprofiler og teste det =). Det er alt. Jeg beklager den krøllete historien.
Koden er tradisjonelt tilgjengelig .
Oppdatering: Jeg er ferdig med å jobbe med sikkerhetsprofiler. Nå er funksjonaliteten 100 % implementert.
Oppdatering 2: lokalisering til engelsk og russisk er lagt til, arbeid i win7 er testet
Kilde: www.habr.com