Pe măsură ce am aprofundat în subiectul cum funcționează produsele 1C în mediul Linux, a fost descoperit un dezavantaj - lipsa unui instrument grafic multiplatform convenabil pentru gestionarea unui cluster de servere 1C. Și sa decis să corectăm acest dezavantaj prin scrierea unui GUI pentru utilitarul consolei rac. Tcl/tk a fost ales ca limbaj de dezvoltare ca fiind, în opinia mea, cel mai potrivit pentru această sarcină. Așadar, aș dori să prezint câteva aspecte interesante ale soluției din acest material.
Pentru a funcționa veți avea nevoie de distribuții tcl/tk și 1C. Și din moment ce am decis să profit la maximum de capabilitățile livrării de bază tcl/tk fără a folosi pachete terțe, voi avea nevoie de versiunea 8.6.7, care include ttk - un pachet cu elemente grafice suplimentare, din care avem nevoie în principal de ttk ::TreeView, permite afișarea datelor atât sub forma unei structuri arborescente, cât și sub forma unui tabel (listă). De asemenea, în noua versiune, lucrarea cu excepții a fost reluată (comanda try, care este utilizată în proiect atunci când rulează comenzi externe).
Proiectul constă din mai multe fișiere (deși nimic nu vă împiedică să faceți totul într-unul singur):
rac_gui.cfg - configurație implicită
rac_gui.tcl - scriptul principal de lansare
Directorul lib conține fișiere care sunt încărcate automat la pornire:
function.tcl - fisier cu proceduri
gui.tcl - interfata grafica principala
images.tcl - biblioteca de imagini base64
Fișierul rac_gui.tcl, de fapt, pornește interpretul, inițializează variabile, încarcă module, configurații și așa mai departe. Conținutul fișierului cu comentarii:
rac_gui.tcl
#!/bin/sh
exec wish "$0" -- "$@"
# Устанавливаем текущий каталог
set dir(root) [pwd]
# Устанавливаем рабочий каталог, если его нет то создаём
set dir(work) [file join $env(HOME) .rac_gui]
if {[file exists $dir(work)] == 0 } {
file mkdir $dir(work)
}
# каталог с модулями
set dir(lib) "[file join $dir(root) lib]"
# загружаем пользовательский конфиг, если он отсутствует, то копируем дефолтный
if {[file exists [file join $dir(work) rac_gui.cfg]] ==0} {
file copy [file join [pwd] rac_gui.cfg] [file join $dir(work) rac_gui.cfg]
}
source [file join $dir(work) rac_gui.cfg]
# Код проверки наличия rac и правильности указания пути в конфиге
# если программа не найдена то будет выведен диалог для указания корректного пути
# и этот путь будет записан в пользовательский конфиг
if {[file exists $rac_cmd] == 0} {
set rac_cmd [tk_getOpenFile -initialdir $env(HOME) -parent . -title "Укажите путь до rac" -initialfile rac]
file copy [file join $dir(work) rac_gui.cfg] [file join $dir(work) rac_gui.cfg.bak]
set orig_file [open [file join $dir(work) rac_gui.cfg.bak] "r"]
set file [open [file join $dir(work) rac_gui.cfg] "w"]
while {[gets $orig_file line] >=0 } {
if {[string match "set rac_cmd*" $line]} {
puts $file "set rac_cmd $rac_cmd"
} else {
puts $file $line
}
}
close $file
close $orig_file
#return "$host:$port"
file delete [file join $dir(work) 1c_srv.cfg.bak]
} else {
puts "Found $rac_cmd"
}
set cluster_user ""
set cluster_pwd ""
set agent_user ""
set agent_pwd ""
## LOAD FILE ##
# Загружаем модули кроме gui.tcl так как его надо загрузить последним
foreach modFile [lsort [glob -nocomplain [file join $dir(lib) *.tcl]]] {
if {[file tail $modFile] ne "gui.tcl"} {
source $modFile
puts "Loaded module $modFile"
}
}
source [file join $dir(lib) gui.tcl]
source [file join $dir(work) rac_gui.cfg]
# Читаем файл со списком серверов 1С
# и добавляем в дерево
if [file exists [file join $dir(work) 1c_srv.cfg]] {
set f [open [file join $dir(work) 1c_srv.cfg] "RDONLY"]
while {[gets $f line] >=0} {
.frm_tree.tree insert {} end -id "server::$line" -text "$line" -values "$line"
}
}După descărcarea a tot ceea ce este necesar și verificarea prezenței utilitarului rac, va fi lansată o fereastră grafică. Interfața programului constă din trei elemente:
Bara de instrumente, arbore și listă
Am făcut conținutul „arborei” cât mai asemănător cu echipamentul standard Windows de la 1C.
Codul principal care formează această fereastră este conținut în fișier
lib/gui.tcl
# установка размера и положения основного окна
# можно установить в переменную topLevelGeometry в конфиг программы
if {[info exists topLevelGeometry]} {
wm geometry . $topLevelGeometry
} else {
wm geometry . 1024x768
}
# Заголовок окна
wm title . "1C Rac GUI"
wm iconname . "1C Rac Gui"
# иконка окна (берется из файла lib/imges.tcl)
wm iconphoto . tcl
wm protocol . WM_DELETE_WINDOW Quit
wm overrideredirect . 0
wm positionfrom . user
ttk::style theme use clam
# Панель инсрументов
set frm_tool [frame .frm_tool]
pack $frm_tool -side left -fill y
ttk::panedwindow .panel -orient horizontal -style TPanedwindow
pack .panel -expand true -fill both
pack propagate .panel false
ttk::button $frm_tool.btn_add -command Add -image add_grey_32
ttk::button $frm_tool.btn_del -command Del -image del_grey_32
ttk::button $frm_tool.btn_edit -command Edit -image edit_grey_32
ttk::button $frm_tool.btn_quit -command Quit -image quit_grey_32
pack $frm_tool.btn_add $frm_tool.btn_del $frm_tool.btn_edit -side top -padx 5 -pady 5
pack $frm_tool.btn_quit -side bottom -padx 5 -pady 5
# Дерево с полосами прокрутки
set frm_tree [frame .frm_tree]
ttk::scrollbar $frm_tree.hsb1 -orient horizontal -command [list $frm_tree.tree xview]
ttk::scrollbar $frm_tree.vsb1 -orient vertical -command [list $frm_tree.tree yview]
set tree [ttk::treeview $frm_tree.tree -show tree
-xscrollcommand [list $frm_tree.hsb1 set] -yscrollcommand [list $frm_tree.vsb1 set]]
grid $tree -row 0 -column 0 -sticky nsew
grid $frm_tree.vsb1 -row 0 -column 1 -sticky nsew
grid $frm_tree.hsb1 -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_tree 0 -weight 1
grid rowconfigure $frm_tree 0 -weight 1
# назначение обработчика нажатия кнопкой мыши
bind $frm_tree.tree <ButtonRelease> "TreePress $frm_tree.tree"
# Список для данных (таблица)
set frm_work [frame .frm_work]
ttk::scrollbar $frm_work.hsb -orient horizontal -command [list $frm_work.tree_work xview]
ttk::scrollbar $frm_work.vsb -orient vertical -command [list $frm_work.tree_work yview]
set tree_work [
ttk::treeview $frm_work.tree_work
-show headings -columns "par val" -displaycolumns "par val"
-xscrollcommand [list $frm_work.hsb set]
-yscrollcommand [list $frm_work.vsb set]
]
# Установка цветов для чередования в таблице
$tree_work tag configure dark -background $color(dark_table_bg)
$tree_work tag configure light -background $color(light_table_bg)
# Размещение элементов на форме
grid $tree_work -row 0 -column 0 -sticky nsew
grid $frm_work.vsb -row 0 -column 1 -sticky nsew
grid $frm_work.hsb -row 1 -column 0 -sticky nsew
grid columnconfigure $frm_work 0 -weight 1
grid rowconfigure $frm_work 0 -weight 1
pack $frm_tree $frm_work -side left -expand true -fill both
#.panel add $frm_tool -weight 1
.panel add $frm_tree -weight 1
.panel add $frm_work -weight 1
Algoritmul de lucru cu programul este următorul:
1. Mai întâi, trebuie să adăugați serverul cluster principal (adică, serverul de gestionare a clusterului (în Linux, managementul este lansat cu comanda „/opt/1C/v8.3/x86_64/ras cluster —daemon”)).
Pentru a face acest lucru, faceți clic pe butonul „+” și în fereastra care se deschide, introduceți adresa și portul serverului:
Ulterior, serverul nostru va apărea în arbore făcând clic pe el, se va deschide o listă de clustere sau se va afișa o eroare de conexiune.
2. Făcând clic pe numele clusterului se va deschide o listă de funcții disponibile pentru acesta.
3. ...
Și așa mai departe, adică pentru a adăuga un cluster nou, selectați unul disponibil în listă și apăsați butonul „+” din bara de instrumente și va fi afișat dialogul pentru adăugare nou:
Butoanele din bara de instrumente îndeplinesc funcții în funcție de context, de exemplu. În funcție de ce element al arborelui sau listei este selectat, se va efectua una sau alta procedură.
Să ne uităm la exemplul butonului de adăugare („+”):
Cod generare butoane:
ttk::button $frm_tool.btn_add -command Add -image add_grey_32Aici vedem că atunci când butonul este apăsat, se va executa procedura „Adăugați”, codul său:
proc Add {} {
global active_cluster host
# Определяем идентификатор выделенного элемента
set id [.frm_tree.tree selection]
# Определяем значение этого элемента
set values [.frm_tree.tree item [.frm_tree.tree selection] -values]
set key [lindex [split $id "::"] 0]
# в зависимости от того что выделили будет запущена нужная процедура
if {$key eq "" || $key eq "server"} {
set host [ Add::server ]
return
}
Add::$key .frm_tree.tree $host $values
}Iată unul dintre avantajele tickle: puteți trece valoarea unei variabile ca nume de procedură:
Add::$key .frm_tree.tree $host $valuesAdică, de exemplu, dacă indicăm spre serverul principal și apăsăm „+”, atunci se va lansa procedura Add::server, dacă la cluster - Add::cluster și așa mai departe (voi scrie despre unde este „cheile” necesare provin din puțin mai jos), procedurile enumerate desenează elemente grafice adecvate contextului.
După cum probabil ați observat deja, formularele sunt similare ca stil - acest lucru nu este surprinzător, deoarece sunt afișate printr-o singură procedură, mai precis cadrul principal al formularului (fereastră, butoane, imagine, etichetă), numele procedurii AddTopLevel
proc AddToplevel {lbl img {win_name .add}} {
set cmd "destroy $win_name"
if [winfo exists $win_name] {destroy $win_name}
toplevel $win_name
wm title $win_name $lbl
wm iconphoto $win_name tcl
# метка с иконкой
ttk::label $win_name.lbl -image $img
# фрейм с полями ввода
set frm [ttk::labelframe $win_name.frm -text $lbl -labelanchor nw]
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
# фрейм и кнопки
set frm_btn [frame $win_name.frm_btn -border 0]
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }
ttk::button $frm_btn.btn_cancel -command $cmd -image quit_grey_24
grid $win_name.lbl -row 0 -column 0 -sticky nw -padx 5 -pady 10
grid $frm -row 0 -column 1 -sticky nw -padx 5 -pady 5
grid $frm_btn -row 1 -column 1 -sticky se -padx 5 -pady 5
pack $frm_btn.btn_cancel -side right
pack $frm_btn.btn_ok -side right -padx 10
return $frm
}
Parametri de apel: titlu, numele imaginii pentru pictograma din bibliotecă (lib/images.tcl) și un parametru opțional pentru numele ferestrei (implicit .add). Astfel, dacă luăm exemplele de mai sus pentru adăugarea serverului principal și a clusterului, apelul va fi corespunzător:
AddToplevel "Добавление основного сервера" server_grey_64sau
AddToplevel "Добавление кластера" cluster_grey_64Ei bine, continuând cu aceste exemple, voi arăta procedurile care afișează dialoguri de adăugare pentru un server sau cluster.
Adauga server
proc Add::server {} {
global default
# выводим основную форму
set frm [AddToplevel "Добавление основного сервера" server_grey_64]
# добавляем етки и поля ввода на эту форму
label $frm.lbl_host -text "Адрес сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid columnconfigure $frm 0 -weight 1
grid rowconfigure $frm 0 -weight 1
#set frm_btn [frame .add.frm_btn -border 0]
# переопределяем обработчик нажатия кнопки
.add.frm_btn.btn_ok configure -command {
set host [SaveMainServer [.add.frm.ent_host get] [.add.frm.ent_port get]]
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"
destroy .add
return $host
}
return $frm
}Adaugă::cluster
proc Add::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes
agent_user agent_pwd cluster_user cluster_pwd auth_agent
if {$agent_user ne "" && $agent_pwd ne ""} {
set auth_agent "--agent-user=$agent_user --agent-pwd=$agent_pwd"
} else {
set auth_agent ""
}
# устанавливаем глобальные переменные ()
set lifetime_limit $default(lifetime_limit)
set expiration_timeout $default(expiration_timeout)
set session_fault_tolerance_level $default(session_fault_tolerance_level)
set max_memory_size $default(max_memory_size)
set max_memory_time_limit $default(max_memory_time_limit)
set errors_count_threshold $default(errors_count_threshold)
set security_level [lindex $default(security_level) 0]
set load_balancing_mode [lindex $default(load_balancing_mode) 0]
set frm [AddToplevel "Добавление кластера" cluster_grey_64]
label $frm.lbl_host -text "Адрес основного сервера"
entry $frm.ent_host
label $frm.lbl_port -text "Порт"
entry $frm.ent_port
$frm.ent_port insert end $default(port)
label $frm.lbl_name -text "Название кластера"
entry $frm.ent_name
label $frm.lbl_secure_connect -text "Защищённое соединение"
ttk::combobox $frm.cb_security_level -textvariable security_level -values $default(security_level)
label $frm.lbl_expiration_timeout -text "Останавливать выключенные процессы через:"
entry $frm.ent_expiration_timeout -textvariable expiration_timeout
label $frm.lbl_session_fault_tolerance_level -text "Уровень отказоустойчивости"
entry $frm.ent_session_fault_tolerance_level -textvariable session_fault_tolerance_level
label $frm.lbl_load_balancing_mode -text "Режим распределения нагрузки"
ttk::combobox $frm.cb_load_balancing_mode -textvariable load_balancing_mode
-values $default(load_balancing_mode)
label $frm.lbl_errors_count_threshold -text "Допустимое отклонение количества ошибок сервера, %"
entry $frm.ent_errors_count_threshold -textvariable errors_count_threshold
label $frm.lbl_processes -text "Рабочие процессы:"
label $frm.lbl_lifetime_limit -text "Период перезапуска, сек."
entry $frm.ent_lifetime_limit -textvariable lifetime_limit
label $frm.lbl_max_memory_size -text "Допустимый объём памяти, КБ"
entry $frm.ent_max_memory_size -textvariable max_memory_size
label $frm.lbl_max_memory_time_limit -text "Интервал превышения допустимого объёма памяти, сек."
entry $frm.ent_max_memory_time_limit -textvariable max_memory_time_limit
label $frm.lbl_kill_problem_processes -justify left -anchor nw -text "Принудительно завершать проблемные процессы"
checkbutton $frm.check_kill_problem_processes -variable kill_problem_processes -onvalue yes -offvalue no
grid $frm.lbl_host -row 0 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_host -row 0 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_port -row 1 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_port -row 1 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_name -row 2 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_name -row 2 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_secure_connect -row 3 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_security_level -row 3 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_expiration_timeout -row 4 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_expiration_timeout -row 4 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_session_fault_tolerance_level -row 5 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_session_fault_tolerance_level -row 5 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_load_balancing_mode -row 6 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.cb_load_balancing_mode -row 6 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_errors_count_threshold -row 7 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_errors_count_threshold -row 7 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_processes -row 8 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.lbl_lifetime_limit -row 9 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_lifetime_limit -row 9 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_size -row 10 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_size -row 10 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_max_memory_time_limit -row 11 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.ent_max_memory_time_limit -row 11 -column 1 -sticky nsew -padx 5 -pady 5
grid $frm.lbl_kill_problem_processes -row 12 -column 0 -sticky nw -padx 5 -pady 5
grid $frm.check_kill_problem_processes -row 12 -column 1 -sticky nw -padx 5 -pady 5
# переопределяем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
return $frm
}Când compar codul acestor proceduri, diferența este vizibilă cu ochiul liber; mă voi concentra pe gestionarea butonului „Ok”. În Tk, proprietățile elementelor grafice pot fi suprascrise în timpul execuției programului folosind opțiunea configura. De exemplu, comanda inițială pentru afișarea butonului:
ttk::button $frm_btn.btn_ok -image ok_grey_24 -command { }Dar în formularele noastre, comanda depinde de funcționalitatea necesară:
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster insert
--host=[.add.frm.ent_host get]
--port=[.add.frm.ent_port get]
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth_agent $host"
Run::server $tree $host ""
destroy .add
}
În exemplul de mai sus, butonul „înfundat” începe procedura de adăugare a unui cluster.
Aici merită să facem o digresiune către lucrul cu elemente grafice în Tk - pentru diferite elemente de intrare a datelor (intrare, casetă combinată, buton de verificare etc.) a fost introdus un parametru ca variabilă text:
entry $frm.ent_lifetime_limit -textvariable lifetime_limitAceastă variabilă este definită în spațiul de nume global și conține valoarea introdusă curent. Acestea. pentru a obține textul introdus din câmp, trebuie doar să citiți valoarea corespunzătoare variabilei (desigur, cu condiția ca aceasta să fie definită la crearea elementului).
A doua metodă de preluare a textului introdus (pentru elemente de tip de intrare) este utilizarea comenzii get:
.add.frm.ent_name getAmbele metode pot fi văzute în codul de mai sus.
Făcând clic pe acest buton, în acest caz, lansează procedura RunCommand cu linia de comandă generată pentru adăugarea unui cluster în termeni de rac:
/opt/1C/v8.3/x86_64/rac cluster insert --host=localhost --port=1540 --name=dsdsds --expiration-timeout=0 --lifetime-limit=0 --max-memory-size=0 --max-memory-time-limit=0 --security-level=0 --session-fault-tolerance-level=0 --load-balancing-mode=performance --errors-count-threshold=0 --kill-problem-processes=no localhost:1545Acum ajungem la comanda principală, care controlează lansarea rac cu parametrii de care avem nevoie, analizează și ieșirea comenzilor în liste și returnează, dacă este necesar:
Executa comanda
proc RunCommand {root par} {
global dir rac_cmd cluster work_list_row_count agent_user agent_pwd cluster_user cluster_pwd
puts "$rac_cmd $par"
set work_list_row_count 0
# открываем канал в неблокирующем режиме
# $rac - команда с полным путём
# $par - сформированные ключи запуска и опции
set pipe [open "|$rac_cmd $par" "r"]
try {
set lst ""
set l ""
# вывод команды добавляем в список списков
while {[gets $pipe line]>=0} {
#puts $line
if {$line eq ""} {
lappend l $lst
set lst ""
} else {
lappend lst [string trim $line]
}
}
close $pipe
return $l
} on error {result options} {
# Запуск обработчика ошибок
ErrorParcing $result $options
return ""
}
}După introducerea datelor serverului principal, acestea vor fi adăugate în arbore, pentru aceasta, în procedura Add:server de mai sus, este responsabil următorul cod:
.frm_tree.tree insert {} end -id "server::$host" -text "$host" -values "$host"Acum, făcând clic pe numele serverului din arbore, obținem o listă de clustere administrate de acel server, iar făcând clic pe un cluster, obținem o listă de elemente de cluster (servere, baze de informații etc.). Acest lucru este implementat în procedura TreePress (fișier lib/function.tcl):
proc TreePress {tree} {
global host server active_cluster infobase
# определяем выделенный элемент
set id [$tree selection]
# устанавливаем нужные глобальные переменные
SetGlobalVarFromTreeItems $tree $id
# Определяем ключ и значение, т.е. именно тип выбранного элемента
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
# и в зависимости от того что выбрали будет запущена соответствующая процедура
# в пространстве имён Run
Run::$key $tree $host $values
}În consecință, Run::server va fi lansat pentru serverul principal (pentru un cluster - Run::cluster, pentru un server funcțional - Run::work_server, etc.). Acestea. valoarea variabilei $key face parte din numele elementului arborescent specificat de opțiune -id.
Să fim atenți la procedură
Run::server
proc Run::server {tree host values} {
# получаем список кластеров требуемого сервера
set lst [RunCommand server::$host "cluster list $host"]
if {$lst eq ""} {return}
set l [lindex $lst 0]
#puts $lst
# удаляем лишнее из списка
.frm_work.tree_work delete [ .frm_work.tree_work children {}]
# читаем список
foreach cluster_list $lst {
# Заполняем список полученными значениями
InsertItemsWorkList $cluster_list
# обрабатываем вывод (список) для добавления данных в дерево
foreach i $cluster_list {
#puts $i
set cluster_list [split $i ":"]
if {[string trim [lindex $cluster_list 0]] eq "cluster"} {
set cluster_id [string trim [lindex $cluster_list 1]]
lappend cluster($cluster_id) $cluster_id
}
if {[string trim [lindex $cluster_list 0]] eq "name"} {
lappend cluster($cluster_id) [string trim [lindex $cluster_list 1]]
}
}
}
# добавляем кластеры в дерево
foreach x [array names cluster] {
set id [lindex $cluster($x) 0]
if { [$tree exists "cluster::$id"] == 0 } {
$tree insert "server::$host" end -id "cluster::$id" -text "[lindex $cluster($x) 1]" -values "$id"
# добавляем элементы в кластер
InsertClusterItems $tree $id
}
}
if { [$tree exists "agent_admins::$id"] == 0 } {
$tree insert "server::$host" end -id "agent_admins::$id" -text "Администраторы" -values "$id"
#InsertClusterItems $tree $id
}
}Această procedură procesează ceea ce a fost primit de la server prin comanda RunCommand și adaugă tot felul de lucruri în arbore - clustere, diferite elemente rădăcină (baze, servere de lucru, sesiuni și așa mai departe). Dacă vă uitați cu atenție, veți observa un apel la procedura InsertItemsWorkList în interior. Este folosit pentru a adăuga elemente la o listă grafică prin procesarea rezultatului utilitarului rac console, care a fost returnat anterior ca o listă la variabila $lst. Aceasta este o listă de liste care conțin perechi de elemente separate prin două puncte.
De exemplu, o listă de conexiuni de cluster:
svk@svk ~]$ /opt/1C/v8.3/x86_64/rac connection list --cluster=783d2170-56c3-11e8-c586-fc75165efbb2 localhost:1545
connection : dcf5991c-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:49:51
session-number : 0
blocked-by-ls : 0
connection : b993293a-7d24-11e8-1690-fc75165efbb2
conn-id : 0
host : svk.home
process : 79de2e16-56c3-11e8-c586-fc75165efbb2
infobase : 00000000-0000-0000-0000-000000000000
application : "JobScheduler"
connected-at : 2018-07-01T14:48:52
session-number : 0
blocked-by-ls : 0
În formă grafică va arăta cam așa:
Procedura de mai sus selectează numele elementelor pentru antet și datele pentru a completa tabelul:
InsertItemsWorkList
proc InsertItemsWorkList {lst} {
global work_list_row_count
# установка чередования цвета для строки
if [expr $work_list_row_count % 2] {
set tag dark
} else {
set tag light
}
# разбор строк на пары ключ - значение
foreach i $lst {
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
lappend column_list [string trim $param]
lappend value_list [string trim $value]
}
}
# заполнение таблицы
.frm_work.tree_work configure -columns $column_list -displaycolumns $column_list
.frm_work.tree_work insert {} end -values $value_list -tags $tag
.frm_work.tree_work column #0 -stretch
# установка заголовков
foreach j $column_list {
.frm_work.tree_work heading $j -text $j
}
incr work_list_row_count
}Aici, în loc de o comandă simplă [split $str ":"], care împarte șirul în elemente separate prin ":" și returnează o listă, se folosește o expresie regulată, deoarece unele elemente conțin și două puncte.
Procedura InsertClusterItems (una dintre mai multe similare) adaugă pur și simplu o listă de elemente copil cu identificatorii corespunzători la arborele elementului de cluster necesar
InsertClusterItems
proc InsertClusterItems {tree id} {
set parent "cluster::$id"
$tree insert $parent end -id "infobases::$id" -text "Информационные базы" -values "$id"
$tree insert $parent end -id "servers::$id" -text "Рабочие серверы" -values "$id"
$tree insert $parent end -id "admins::$id" -text "Администраторы" -values "$id"
$tree insert $parent end -id "managers::$id" -text "Менеджеры кластера" -values $id
$tree insert $parent end -id "processes::$id" -text "Рабочие процессы" -values "workprocess-all"
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "sessions-all"
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "blocks-all"
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "connections-all"
$tree insert $parent end -id "profiles::$id" -text "Профили безопасности" -values $id
}
Puteți lua în considerare încă două opțiuni pentru implementarea unei proceduri similare, unde va fi clar vizibil cum puteți optimiza și scăpa de comenzile repetitive:
În această procedură, adăugarea și verificarea sunt rezolvate direct:
InsertBaseItems
proc InsertBaseItems {tree id} {
set parent "infobase::$id"
if { [$tree exists "sessions::$id"] == 0 } {
$tree insert $parent end -id "sessions::$id" -text "Сеансы" -values "$id"
}
if { [$tree exists "locks::$id"] == 0 } {
$tree insert $parent end -id "locks::$id" -text "Блокировки" -values "$id"
}
if { [$tree exists "connections::$id"] == 0 } {
$tree insert $parent end -id "connections::$id" -text "Соединения" -values "$id"
}
}
Iată o abordare mai corectă:
InsertProfileItems
proc InsertProfileItems {tree id} {
set parent "profile::$id"
set lst {
{dir "Виртуальные каталоги"}
{com "Разрешённые COM-классы"}
{addin "Внешние компоненты"}
{module "Внешние отчёты и обработки"}
{app "Разрешённые приложения"}
{inet "Ресурсы интернет"}
}
foreach i $lst {
append item [lindex $i 0] "::$id"
if { [$tree exists $item] == 0 } {
$tree insert $parent end -id $item -text [lindex $i 1] -values "$id"
}
unset item
}
}Diferența dintre ele este utilizarea unei bucle, în care sunt executate comenzile repetate. Ce abordare de utilizat este la discreția dezvoltatorului.
Am abordat adăugarea de elemente și preluarea datelor, acum este timpul să ne concentrăm pe editare. Deoarece, practic, se folosesc aceiași parametri pentru editare și adăugare (cu excepția bazei de informații), se folosesc aceleași forme de dialog. Algoritmul pentru apelarea procedurilor de adăugare arată astfel:
Adaugă::$key->AddToplevel
Și pentru editare astfel:
Editare::$key->Add::$key->AddTopLevel
De exemplu, să luăm editarea unui cluster, de exemplu. După ce ați făcut clic pe numele clusterului din arbore, apăsați butonul de editare din bara de instrumente (creion) și pe ecran va fi afișat formularul corespunzător:
Edit::cluster
proc Edit::cluster {tree host values} {
global default lifetime_limit expiration_timeout session_fault_tolerance_level
global max_memory_size max_memory_time_limit errors_count_threshold security_level
global load_balancing_mode kill_problem_processes active_cluster
agent_user agent_pwd cluster_user cluster_pwd auth
if {$cluster_user ne "" && $cluster_pwd ne ""} {
set auth "--cluster-user=$cluster_user --cluster-pwd=$cluster_pwd"
} else {
set auth ""
}
# рисуем форму для кластера
set frm [Add::cluster $tree $host $values]
# меняем текст на метке
$frm configure -text "Редактирование кластера"
set active_cluster $values
# получаем данные по выделенному кластеру
set lst [RunCommand cluster::$values "cluster info --cluster=$active_cluster $host"]
# заполняем поля
FormFieldsDataInsert $frm $lst
# выключаем поля, редактирование которых запрещено
$frm.ent_host configure -state disable
$frm.ent_port configure -state disable
# переназначаем обработчик
.add.frm_btn.btn_ok configure -command {
RunCommand "" "cluster update
--cluster=$active_cluster $auth
--name=[.add.frm.ent_name get]
--expiration-timeout=$expiration_timeout
--lifetime-limit=$lifetime_limit
--max-memory-size=$max_memory_size
--max-memory-time-limit=$max_memory_time_limit
--security-level=$security_level
--session-fault-tolerance-level=$session_fault_tolerance_level
--load-balancing-mode=$load_balancing_mode
--errors-count-threshold=$errors_count_threshold
--kill-problem-processes=$kill_problem_processes
$auth $host"
$tree delete "cluster::$active_cluster"
Run::server $tree $host ""
destroy .add
}
}Pe baza comentariilor din cod, în principiu, totul este clar, cu excepția faptului că codul de gestionare a butoanelor este suprascris și există o procedură FormFieldsDataInsert care umple câmpurile cu date și inițializează variabilele:
FormFieldsDataInsert
proc FormFieldsDataInsert {frm lst} {
foreach i [lindex $lst 0] {
# получаем список параметров и значений
if [regexp -nocase -all -- {(D+)(s*?|)(:)(s*?|)(.*)} $i match param v2 v3 v4 value] {
# меняем символы
regsub -all -- "-" [string trim $param] "_" entry_name
# заполняем данными
if [winfo exists $frm.ent_$entry_name] {
$frm.ent_$entry_name delete 0 end
$frm.ent_$entry_name insert end [string trim $value """]
}
if [winfo exists $frm.cb_$entry_name] {
global $entry_name
set $entry_name [string trim $value """]
}
# для чекбоксов меняем значения
if [winfo exists $frm.check_$entry_name] {
global $entry_name
if {$value eq "0"} {
set $entry_name no
} elseif {$value eq "1"} {
set $entry_name yes
} else {
set $entry_name $value
}
}
}
}
}
În această procedură, a apărut un alt avantaj al tcl - valorile altor variabile sunt înlocuite ca nume de variabile. Acestea. pentru a automatiza completarea formularelor și inițializarea variabilelor, numele câmpurilor și variabilelor corespund comutatoarelor din linia de comandă ale utilitarului rac și numelor parametrilor de ieșire a comenzii, cu unele excepții - liniuța este înlocuită cu un caracter de subliniere. De exemplu slujbe-programate-refuză se potrivește cu terenul ent_scheduled_jobs_deny și variabilă joburi_programate.
Formularele pentru adăugare și editare pot diferi în compoziția câmpurilor, de exemplu, lucrul cu o bază de informații:
Adăugarea securității informațiilor
Editarea securității informațiilor
În procedura de editare Edit::infobase, în formular se adaugă câmpurile obligatorii; codul este voluminos, de aceea nu îl prezint aici.
Prin analogie, procedurile de adăugare, editare, ștergere sunt implementate pentru alte elemente.
Întrucât funcționarea utilitarului presupune un număr nelimitat de servere, clustere, baze de informații etc., pentru a determina ce cluster îi aparține cărui server sau sistem de securitate a informațiilor, au fost introduse mai multe variabile globale, ale căror valori sunt stabilite fiecare. când faceți clic pe elementele arborelui. Acestea. procedura rulează recursiv prin toate elementele părinte și setează variabilele:
SetGlobalVarFromTreeItems
proc SetGlobalVarFromTreeItems {tree id} {
global host server active_cluster infobase
set parent [$tree parent $id]
set values [$tree item $id -values]
set key [lindex [split $id "::"] 0]
switch -- $key {
server {set host $values}
work_server {set server $values}
cluster {set active_cluster $values}
infobase {set infobase $values}
}
if {$parent eq ""} {
return
} else {
SetGlobalVarFromTreeItems $tree $parent
}
}
Clusterul 1C vă permite să lucrați cu sau fără autorizație. Există două tipuri de administratori — administrator de agent de cluster și administrator de cluster. În consecință, pentru funcționarea corectă, au fost introduse încă 4 variabile globale care conțin autentificarea și parola de administrator. Acestea. dacă există un cont de administrator în cluster, va fi afișat un dialog pentru a vă introduce login-ul și parola, datele vor fi salvate în memorie și inserate în fiecare comandă pentru cluster-ul corespunzător.
Aceasta este responsabilitatea procedurii de tratare a erorilor.
ErrorParcing
proc ErrorParcing {err opt} {
global cluster_user cluster_pwd agent_user agent_pwd
switch -regexp -- $err {
"Cluster administrator is not authenticated" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Central server administrator is not authenticated" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
"Администратор кластера не аутентифицирован" {
AuthorisationDialog "Администратор кластера"
.auth_win.frm_btn.btn_ok configure -command {
set cluster_user [.auth_win.frm.ent_name get]
set cluster_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
#RunCommand $root $par
}
"Администратор центрального сервера не аутентифицирован" {
AuthorisationDialog "Администратор агента кластера"
.auth_win.frm_btn.btn_ok configure -command {
set agent_user [.auth_win.frm.ent_name get]
set agent_pwd [.auth_win.frm.ent_pwd get]
destroy .auth_win
}
}
(.+) {
tk_messageBox -type ok -icon error -message "$err"
}
}
}Acestea. in functie de ce returneaza comanda, reactia va fi pe masura.
În acest moment, aproximativ 95 la sută din funcționalitate a fost implementată, tot ce rămâne este să implementezi lucrul cu profiluri de securitate și să o testezi =). Asta e tot. Îmi cer scuze pentru povestea mototolită.
Codul este disponibil în mod tradițional .
Actualizare: am terminat de lucrat cu profilurile de securitate. Acum funcționalitatea este implementată 100%.
Actualizare 2: a fost adăugată localizarea în engleză și rusă, lucrul în win7 a fost testat
Sursa: www.habr.com