🥇Industrial Ninja හි අඩිපාරේ: Positive Hack Days 9 හි PLC එකක් හැක් කළ ආකාරය

පසුගිය PHDays 9 හිදී අපි ගෑස් පොම්පාගාරයක් හැක් කිරීමේ තරඟයක් පැවැත්වුවා - තරඟය කාර්මික නින්ජා. එකම කාර්මික ක්‍රියාවලිය අනුකරණය කරමින් විවිධ ආරක්‍ෂක පරාමිතීන් සහිත (ආරක්ෂාව නැත, අඩු ආරක්‍ෂාව, ඉහළ ආරක්‍ෂාව) සහිත ස්ථාන තුනක් වෙබ් අඩවියේ තිබී ඇත: පීඩනය යටතේ වාතය බැලූනයකට පොම්ප කරන ලදී (පසුව මුදා හරින ලදී).

විවිධ ආරක්ෂණ පරාමිතීන් තිබියදීත්, ස්ථාවරයේ දෘඪාංග සංයුතිය සමාන විය: Siemens Simatic PLC S7-300 ශ්රේණි; හදිසි අවධමන බොත්තම සහ පීඩන මැනීමේ උපකරණය (PLC ඩිජිටල් යෙදවුම් (DI) වෙත සම්බන්ධ කර ඇත); වාතයේ උද්ධමනය සහ අවධමනය සඳහා ක්‍රියාත්මක වන කපාට (PLC (DO) හි ඩිජිටල් නිමැවුම්වලට සම්බන්ධ) - පහත රූපය බලන්න.

පීඑල්සී, පීඩන කියවීම් මත පදනම්ව සහ එහි වැඩසටහනට අනුකූලව, පන්දුව පිම්බීමට හෝ පිම්බීමට තීරණයක් ගත්තේය (අනුරූප වෑල්ව විවෘත කර වසා දමන ලදී). කෙසේ වෙතත්, සියලුම නැවතුම්වල අතින් පාලන මාදිලියක් තිබූ අතර එමඟින් කිසිදු සීමාවකින් තොරව කපාටවල තත්වයන් පාලනය කිරීමට හැකි විය.

මෙම මාදිලිය සක්‍රීය කිරීමේ සංකීර්ණතාවයෙන් ස්ථාවරය වෙනස් විය: අනාරක්ෂිත ස්ථාවරයේදී මෙය කිරීම පහසුම වූ අතර අධි ආරක්ෂිත ස්ථාවරයේදී එය ඊට අනුරූපව වඩාත් අපහසු විය.

ගැටලු හයෙන් පහක් දින දෙකකින් විසඳා ඇත; පළමු ස්ථානයට සහභාගී වූ තැනැත්තා ලකුණු 233 ක් ලබා ගත්තේය (ඔහු තරඟය සඳහා සූදානම් වෙමින් සතියක් ගත කළේය). ජයග්‍රාහකයින් තිදෙනෙක්: මම ස්ථානය - a1exdandy, II - Rubikoid, III - Ze.

කෙසේ වෙතත්, PHDays අතරතුර, සහභාගී වූ කිසිවකුට ස්ටෑන්ඩ් තුනම ජය ගැනීමට නොහැකි වූ නිසා, අපි මාර්ගගත තරඟයක් කිරීමට තීරණය කළ අතර ජුනි මස මුලදී වඩාත්ම දුෂ්කර කාර්යය ප්‍රකාශයට පත් කළෙමු. සහභාගිවන්නන්ට මාසයක් ඇතුළත කාර්යය සම්පූර්ණ කිරීමටත්, ධජය සොයා ගැනීමටත්, විසඳුම විස්තරාත්මකව හා රසවත් ලෙස විස්තර කිරීමටත් සිදු විය.

කප්පාදුවට පහළින් අපි මාසය පුරා එවන ලද අයගෙන් කාර්යයට හොඳම විසඳුම පිළිබඳ විශ්ලේෂණයක් ප්‍රකාශයට පත් කරමු, එය PHDays අතරතුර තරඟයේ 1 වන ස්ථානය ලබා ගත් Digital Security සමාගමේ Alexey Kovrizhnykh (aXNUMXexdandy) විසින් සොයා ගන්නා ලදී. පහතින් අපි එහි පාඨය අපගේ අදහස් සමඟ ඉදිරිපත් කරමු.

මූලික විශ්ලේෂණය

එබැවින්, කාර්යයේ පහත ලිපිගොනු සහිත සංරක්ෂිතයක් අඩංගු විය:

block_upload_traffic.pcapng
DB100.bin
ඉඟි.txt

hints.txt ගොනුවේ කාර්යය විසඳීම සඳහා අවශ්ය තොරතුරු සහ ඉඟි අඩංගු වේ. එහි අන්තර්ගතය මෙන්න:

Petrovich මට ඊයේ කිව්වා ඔයාට PlcSim එකෙන් Step7 වලට blocks load කරන්න පුළුවන් කියලා.

Siemens Simatic S7-300 ශ්‍රේණියේ PLC ස්ථාවරය තුළ භාවිතා කරන ලදී.

PlcSim යනු ඔබට Siemens S7 PLC සඳහා වැඩසටහන් ධාවනය කිරීමට සහ දෝෂහරණය කිරීමට ඉඩ සලසන PLC ඉමුලේටරයකි.

DB100.bin ගොනුවේ DB100 PLC දත්ත කොටස අඩංගු බව පෙනේ: 00000000: 0100 0102 6e02 0401 0206 0100 0101 0102 ....n......... 00000010: 1002 0501 0202 2002 ..... ......... 0501: 0206 0100 0102 00000020 0102 7702 0401 0206a0100 ..w............. 0103: 0102 0 02 00000030 0501 ................ 0202: 1602 0501 0206 0100 0104 0102 00000040a7502 0401 u............ 0206: 0100 0105 0102 0 02 0501 00000050 0202............1602. 0501: 0206 0100 0106 0102 3402 4 00000060 0401 .........&..... 0206: 0100c0107 0102 2602 0501 0202 00000070 4 : 02 0501 0206 0100 0108a0102 3302 0401 3 ................ 00000080: 0206 0100 0109 0102a 0 02 0501 0202 .........1602. 00000090a0501: 0206 0100b 010 0102 3702 0401 0206 7 ....".....F... 000000b0: 0100 010 0102c 2202 0501 0202 4602........ .. 0501c000000: 0d 0206 0100a010 0102 3302 0401 0206 0100 ................ 3d000000: 0 010e 0102 0d02 0501 0202 1602. .... 0501e0206: 000000 0 0100 010 0102 6 02 0401 ........#...... 0206f0100: 010 000000 0 0102 1102 0501.. 0202 ..... 2302: 0501 0206 0100 000000 0 0110 0102 3502 ......%......... 0401: 0206 0100 0111 0102 5 00000100. .....&. 1202: 0501 0202 2502c0501 0206 0100 0112 ....L......

නමට අනුව, block_upload_traffic.pcapng ගොනුවේ PLC වෙත අවහිර උඩුගත කිරීමේ තදබදයක් අඩංගු වේ.

සම්මන්ත්‍රණය අතරතුර තරඟ අඩවියේ මෙම රථවාහන ඩම්ප් ලබා ගැනීම ටිකක් අපහසු වූ බව සඳහන් කිරීම වටී. මෙය සිදු කිරීම සඳහා, TeslaSCADA2 සඳහා වන ව්‍යාපෘති ගොනුවෙන් ස්ක්‍රිප්ට් තේරුම් ගැනීම අවශ්‍ය විය. RC4 භාවිතයෙන් සංකේතනය කරන ලද ඩම්ප් එක පිහිටා ඇත්තේ කොතැනද සහ එය විකේතනය කිරීමට භාවිතා කළ යුතු යතුර කුමක්ද යන්න එයින් තේරුම් ගත හැකි විය. S7 ප්‍රොටෝකෝල සේවාලාභියා භාවිතයෙන් වෙබ් අඩවියේ ඇති දත්ත කොටස් ඩම්ප් ලබා ගත හැක. මේ සඳහා මම Snap7 පැකේජයේ demo client එක භාවිතා කළා.

රථවාහන ඩම්ප් එකකින් සංඥා සැකසුම් කුට්ටි නිස්සාරණය කිරීම

ඩම්ප් එකේ අන්තර්ගතය දෙස බලන විට, එහි OB1, FC1, FC2 සහ FC3 යන සංඥා සැකසුම් කුට්ටි අඩංගු බව ඔබට තේරුම් ගත හැකිය:

මෙම කුට්ටි ඉවත් කළ යුතුය. මෙය සිදු කළ හැකිය, උදාහරණයක් ලෙස, පහත දැක්වෙන ස්ක්‍රිප්ටය සමඟ, පෙර ගමනාගමනය pcapng ආකෘතියෙන් pcap වෙත පරිවර්තනය කර ඇත:

#!/usr/bin/env python2

import struct
from scapy.all import *

packets = rdpcap('block_upload_traffic.pcap')
s7_hdr_struct = '>BBHHHHBB'
s7_hdr_sz = struct.calcsize(s7_hdr_struct)
tpkt_cotp_sz = 7
names = iter(['OB1.bin', 'FC1.bin', 'FC2.bin', 'FC3.bin'])
buf = ''

for packet in packets:
    if packet.getlayer(IP).src == '10.0.102.11':
        tpkt_cotp_s7 = str(packet.getlayer(TCP).payload)
        if len(tpkt_cotp_s7) < tpkt_cotp_sz + s7_hdr_sz:
            continue
        s7 = tpkt_cotp_s7[tpkt_cotp_sz:]
        s7_hdr = s7[:s7_hdr_sz]
        param_sz = struct.unpack(s7_hdr_struct, s7_hdr)[4]
        s7_param = s7[12:12+param_sz]
        s7_data = s7[12+param_sz:]
        if s7_param in ('x1ex00', 'x1ex01'):  # upload
            buf += s7_data[4:]
        elif s7_param == 'x1f':
            with open(next(names), 'wb') as f:
                f.write(buf)
            buf = ''

ලැබෙන කුට්ටි පරීක්ෂා කිරීමෙන් පසු, ඒවා සෑම විටම බයිට් 70 70 (pp) වලින් ආරම්භ වන බව ඔබට පෙනෙනු ඇත. දැන් ඔබ ඒවා විශ්ලේෂණය කරන්නේ කෙසේදැයි ඉගෙන ගත යුතුය. පැවරුම් ඉඟිය යෝජනා කරන්නේ ඔබ මේ සඳහා PlcSim භාවිතා කළ යුතු බවයි.

බ්ලොක් වලින් මිනිසුන්ට කියවිය හැකි උපදෙස් ලබා ගැනීම

පළමුව, Simatic Manager මෘදුකාංගය භාවිතයෙන් පුනරාවර්තන උපදෙස් (= Q 7) සහිත බ්ලොක් කිහිපයක් එයට පූරණය කිරීමෙන් සහ emulator එකෙන් ලබාගත් PLC උදාහරණය.plc ගොනුවට සුරැකීමෙන් S0.0-PlcSim වැඩසටහන් කිරීමට උත්සාහ කරමු. ගොනුවේ අන්තර්ගතය දෙස බැලීමෙන්, අප කලින් සොයාගත් 70 70 අත්සන මගින් බාගත කළ කොටස්වල ආරම්භය ඔබට පහසුවෙන් තීරණය කළ හැකිය. බ්ලොක් වලට පෙර, පෙනෙන විදිහට, බ්ලොක් ප්‍රමාණය 4-බයිට් ලිට්ල්-එන්ඩියන් අගයක් ලෙස ලියා ඇත.

plc ගොනු වල ව්‍යුහය පිළිබඳ තොරතුරු අපට ලැබුණු පසු, PLC S7 වැඩසටහන් කියවීම සඳහා පහත ක්‍රියාකාරී සැලැස්ම දර්ශනය විය:

Simatic Manager භාවිතා කරමින්, අපි ඩම්ප් එකෙන් ලැබුණු ආකාරයටම S7-PlcSim හි බ්ලොක් ව්‍යුහයක් සාදන්නෙමු. බ්ලොක් ප්‍රමාණයන් ගැලපිය යුතුය (මෙය සාක්ෂාත් කරගනු ලබන්නේ අවශ්‍ය උපදෙස් ගණන සමඟ කුට්ටි පිරවීමෙන්) සහ ඒවායේ හඳුනාගැනීම් (OB1, FC1, FC2, FC3).
PLC ගොනුවකට සුරකින්න.
අපි රථවාහන ඩම්ප් වලින් බ්ලොක් සමඟ ප්රතිඵල ගොනුවේ ඇති බ්ලොක් වල අන්තර්ගතය ප්රතිස්ථාපනය කරමු. බ්ලොක් වල ආරම්භය අත්සනින් තීරණය වේ.
අපි ප්රතිඵල ගොනුව S7-PlcSim වෙත පැටවීම සහ සිමාටික් කළමනාකරු තුළ ඇති බ්ලොක් වල අන්තර්ගතය දෙස බලන්න.

බ්ලොක් ආදේශ කළ හැකිය, උදාහරණයක් ලෙස, පහත කේතය සමඟ:

with open('original.plc', 'rb') as f:
    plc = f.read()
blocks = []
for fname in ['OB1.bin', 'FC1.bin', 'FC2.bin', 'FC3.bin']:
    with open(fname, 'rb') as f:
        blocks.append(f.read())

i = plc.find(b'pp')
for block in blocks:
    plc = plc[:i] + block + plc[i+len(block):]
    i = plc.find(b'pp', i + 1)

with open('target.plc', 'wb') as f:
    f.write(plc)

ඇලෙක්සි වඩාත් දුෂ්කර නමුත් තවමත් නිවැරදි මාර්ගයක් ගත්තේය. PlcSim හට ජාලය හරහා සන්නිවේදනය කිරීමටත්, Snap7 හරහා PlcSim වෙත බ්ලොක් උඩුගත කිරීමටත්, සංවර්ධන පරිසරය භාවිතයෙන් PlcSim වෙතින් ව්‍යාපෘතියක් ලෙස මෙම බ්ලොක් බාගැනීමටත් හැකි වන පරිදි සහභාගිවන්නන් NetToPlcSim වැඩසටහන භාවිතා කරනු ඇතැයි අපි උපකල්පනය කළෙමු.

ලැබෙන ගොනුව S7-PlcSim හි විවෘත කිරීමෙන්, ඔබට සිමාටික් කළමණාකරු භාවිතයෙන් උඩින් ලියන ලද බ්ලොක් කියවිය හැක. ප්රධාන උපාංග පාලන කාර්යයන් බ්ලොක් FC1 හි සටහන් කර ඇත. විශේෂයෙන් සැලකිය යුතු වන්නේ #TEMP0 විචල්‍යය, එය සක්‍රිය කළ විට M2.2 සහ M2.3 bit මතක අගයන් මත පදනම්ව PLC පාලනය හස්තීය ප්‍රකාරයට සකසන බව පෙනේ. #TEMP0 අගය FC3 ශ්‍රිතය මඟින් සකසා ඇත.

ගැටළුව විසඳීම සඳහා, ඔබ FC3 ශ්‍රිතය විශ්ලේෂණය කර එය තාර්කික එකක් ලබා දීම සඳහා කළ යුතු දේ තේරුම් ගත යුතුය.

තරඟ අඩවියේ Low Security Stand එකේ PLC signal processing blocks එක සමාන ආකාරයට සකසා තිබුනද #TEMP0 විචල්‍යයේ අගය සැකසීමට DB1 බ්ලොක් එකට my ninja way යන රේඛාව ලිවීම ප්‍රමාණවත් විය. බ්ලොක් එකක අගය පරීක්ෂා කිරීම තේරුම් ගැනීමට පහසු වූ අතර බ්ලොක් ක්‍රමලේඛන භාෂාව පිළිබඳ ගැඹුරු දැනුමක් අවශ්‍ය නොවීය. නිසැකවම, අධි ආරක්ෂිත මට්ටමින්, අතින් පාලනය සාක්ෂාත් කර ගැනීම වඩා දුෂ්කර වනු ඇති අතර, STL භාෂාවේ සංකීර්ණතා තේරුම් ගැනීම අවශ්ය වේ (S7 PLC වැඩසටහන්ගත කිරීමේ එක් ක්රමයක්).

ප්‍රතිලෝම බ්ලොක් FC3

STL නියෝජනය තුළ FC3 කොටසෙහි අන්තර්ගතය:

      L     B#16#0
      T     #TEMP13
      T     #TEMP15
      L     P#DBX 0.0
      T     #TEMP4
      CLR   
      =     #TEMP14
M015: L     #TEMP4
      LAR1  
      OPN   DB   100
      L     DBLG
      TAR1  
      <=D   
      JC    M016
      L     DW#16#0
      T     #TEMP0
      L     #TEMP6
      L     W#16#0
      <>I   
      JC    M00d
      L     P#DBX 0.0
      LAR1  
M00d: L     B [AR1,P#0.0]
      T     #TEMP5
      L     W#16#1
      ==I   
      JC    M007
      L     #TEMP5
      L     W#16#2
      ==I   
      JC    M008
      L     #TEMP5
      L     W#16#3
      ==I   
      JC    M00f
      L     #TEMP5
      L     W#16#4
      ==I   
      JC    M00e
      L     #TEMP5
      L     W#16#5
      ==I   
      JC    M011
      L     #TEMP5
      L     W#16#6
      ==I   
      JC    M012
      JU    M010
M007: +AR1  P#1.0
      L     P#DBX 0.0
      LAR2  
      L     B [AR1,P#0.0]
      L     C#8
      *I    
      +AR2  
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M003
      JU    M001
      JU    M002
      JU    M004
M003: JU    M005
M001: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP0
      JU    M006
M002: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP1
      JU    M006
M004: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP2
      JU    M006
M00f: +AR1  P#1.0
      L     B [AR1,P#0.0]
      L     C#8
      *I    
      T     #TEMP11
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      TAR1  #TEMP4
      OPN   DB   101
      L     P#DBX 0.0
      LAR1  
      L     #TEMP11
      +AR1  
      LAR2  #TEMP9
      L     B [AR2,P#0.0]
      T     B [AR1,P#0.0]
      L     #TEMP4
      LAR1  
      JU    M006
M008: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP3
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M009
      JU    M00b
      JU    M00a
      JU    M00c
M009: JU    M005
M00b: L     #TEMP3
      T     #TEMP0
      JU    M006
M00a: L     #TEMP3
      T     #TEMP1
      JU    M006
M00c: L     #TEMP3
      T     #TEMP2
      JU    M006
M00e: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      AW    
      INVI  
      T     #TEMP12
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      OW    
      L     #TEMP12
      AW    
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #TEMP0
      L     MB   101
      T     #TEMP1
      L     MB   102
      T     #TEMP2
      L     #TEMP4
      LAR1  
      JU    M006
M011: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      -I    
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #TEMP0
      L     MB   101
      T     #TEMP1
      L     MB   102
      T     #TEMP2
      L     #TEMP4
      LAR1  
      JU    M006
M012: L     #TEMP15
      INC   1
      T     #TEMP15
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      ==I   
      JCN   M013
      JU    M014
M013: L     P#DBX 0.0
      LAR1  
      T     #TEMP4
      L     B#16#0
      T     #TEMP6
      JU    M006
M014: L     #TEMP4
      LAR1  
      L     #TEMP13
      L     L#1
      +I    
      T     #TEMP13
      JU    M006
M006: L     #TEMP0
      T     MB   100
      L     #TEMP1
      T     MB   101
      L     #TEMP2
      T     MB   102
      +AR1  P#1.0
      L     #TEMP6
      +     1
      T     #TEMP6
      JU    M005
M010: L     P#DBX 0.0
      LAR1  
      L     0
      T     #TEMP6
      TAR1  #TEMP4
M005: TAR1  #TEMP4
      CLR   
      =     #TEMP16
      L     #TEMP13
      L     L#20
      ==I   
      S     #TEMP16
      L     #TEMP15
      ==I   
      A     #TEMP16
      JC    M017
      L     #TEMP13
      L     L#20
      <I    
      S     #TEMP16
      L     #TEMP15
      ==I   
      A     #TEMP16
      JC    M018
      JU    M019
M017: SET   
      =     #TEMP14
      JU    M016
M018: CLR   
      =     #TEMP14
      JU    M016
M019: CLR   
      O     #TEMP14
      =     #RET_VAL
      JU    M015
M016: CLR   
      O     #TEMP14
      =     #RET_VAL

Код довольно объемный и человеку, незнакомому с STL, может показаться сложным. Разбирать каждую инструкцию в рамках данной статьи нет смысла, подробно с инструкциями и возможностями языка STL можно ознакомиться в соответствующем мануале: S7-300 සහ S7-400 ක්‍රමලේඛනය සඳහා ප්‍රකාශ ලැයිස්තුව (STL).. මෙහිදී මම සැකසීමෙන් පසු එම කේතයම ඉදිරිපත් කරමි - ලේබල් සහ විචල්‍ය නැවත නම් කිරීම සහ මෙහෙයුම් ඇල්ගොරිතම සහ සමහර STL භාෂා නිර්මාණ විස්තර කරන අදහස් එකතු කිරීම. ප්‍රශ්නගත බ්ලොක් එකේ අප දන්නා DB100 බ්ලොක් එකේ ඇති යම් බයිට්කේතයක් ක්‍රියාත්මක කරන අතථ්‍ය යන්ත්‍රයක් අඩංගු බව මම වහාම සටහන් කරමි. අතථ්‍ය යන්ත්‍ර උපදෙස් මෙහෙයුම් කේතයේ බයිට් 1 කින් සහ තර්ක බයිට් වලින් සමන්විත වේ, එක් එක් තර්කය සඳහා එක් බයිටයක්. සලකා බලන සියලුම උපදෙස් වලට තර්ක දෙකක් ඇත; මම අදහස් දැක්වීමේදී ඒවායේ අගයන් X සහ Y ලෙස නම් කළෙමි.

සැකසීමෙන් පසු කේතය]

# Инициализация различных переменных
      L     B#16#0
      T     #CHECK_N        # Счетчик успешно пройденных проверок
      T     #COUNTER_N      # Счетчик общего количества проверок
      L     P#DBX 0.0
      T     #POINTER        # Указатель на текущую инструкцию
      CLR   
      =     #PRE_RET_VAL

# Основной цикл работы интерпретатора байт-кода
LOOP: L     #POINTER
      LAR1  
      OPN   DB   100
      L     DBLG
      TAR1  
      <=D                   # Проверка выхода указателя за пределы программы
      JC    FINISH
      L     DW#16#0
      T     #REG0
      L     #TEMP6
      L     W#16#0
      <>I   
      JC    M00d
      L     P#DBX 0.0
      LAR1  

# Конструкция switch - case для обработки различных опкодов
M00d: L     B [AR1,P#0.0]
      T     #OPCODE
      L     W#16#1
      ==I   
      JC    OPCODE_1
      L     #OPCODE
      L     W#16#2
      ==I   
      JC    OPCODE_2
      L     #OPCODE
      L     W#16#3
      ==I   
      JC    OPCODE_3
      L     #OPCODE
      L     W#16#4
      ==I   
      JC    OPCODE_4
      L     #OPCODE
      L     W#16#5
      ==I   
      JC    OPCODE_5
      L     #OPCODE
      L     W#16#6
      ==I   
      JC    OPCODE_6
      JU    OPCODE_OTHER

# Обработчик опкода 01: загрузка значения из DB101[X] в регистр Y
# OP01(X, Y): REG[Y] = DB101[X]
OPCODE_1: +AR1  P#1.0
      L     P#DBX 0.0
      LAR2  
      L     B [AR1,P#0.0]   # Загрузка аргумента X (индекс в DB101)
      L     C#8
      *I    
      +AR2  
      +AR1  P#1.0
      L     B [AR1,P#0.0]   # Загрузка аргумента Y (индекс регистра)
      JL    M003            # Аналог switch - case на основе значения Y
      JU    M001            # для выбора необходимого регистра для записи.
      JU    M002            # Подобные конструкции используются и в других
      JU    M004            # операциях ниже для аналогичных целей
M003: JU    LOOPEND
M001: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG0           # Запись значения DB101[X] в REG[0]
      JU    PRE_LOOPEND
M002: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG1           # Запись значения DB101[X] в REG[1]
      JU    PRE_LOOPEND
M004: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG2           # Запись значения DB101[X] в REG[2]
      JU    PRE_LOOPEND

# Обработчик опкода 02: загрузка значения X в регистр Y
# OP02(X, Y): REG[Y] = X
OPCODE_2: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP3
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M009
      JU    M00b
      JU    M00a
      JU    M00c
M009: JU    LOOPEND
M00b: L     #TEMP3
      T     #REG0
      JU    PRE_LOOPEND
M00a: L     #TEMP3
      T     #REG1
      JU    PRE_LOOPEND
M00c: L     #TEMP3
      T     #REG2
      JU    PRE_LOOPEND

# Опкод 03 не используется в программе, поэтому пропустим его
...

# Обработчик опкода 04: сравнение регистров X и Y
# OP04(X, Y): REG[0] = 0; REG[X] = (REG[X] == REG[Y])
OPCODE_4: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7          # первый аргумент - X
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          # REG[X]
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9          # REG[X]
      LAR2  #TEMP10         # REG[Y]
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      AW    
      INVI  
      T     #TEMP12         # ~(REG[Y] & REG[X])
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      OW    
      L     #TEMP12
      AW                    # (~(REG[Y] & REG[X])) & (REG[Y] | REG[X]) - аналог проверки на равенство
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #REG0
      L     MB   101
      T     #REG1
      L     MB   102
      T     #REG2
      L     #POINTER
      LAR1  
      JU    PRE_LOOPEND

# Обработчик опкода 05: вычитание регистра Y из X
# OP05(X, Y): REG[0] = 0; REG[X] = REG[X] - REG[Y]
OPCODE_5: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          # REG[X]
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      -I                    # ACCU1 = ACCU2 - ACCU1, REG[X] - REG[Y]
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #REG0
      L     MB   101
      T     #REG1
      L     MB   102
      T     #REG2
      L     #POINTER
      LAR1  
      JU    PRE_LOOPEND

# Обработчик опкода 06: инкремент #CHECK_N при равенстве регистров X и Y
# OP06(X, Y): #CHECK_N += (1 if REG[X] == REG[Y] else 0)
OPCODE_6: L     #COUNTER_N
      INC   1
      T     #COUNTER_N
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7          #  REG[X]     
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          #  REG[X]  
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9          # REG[Y]
      LAR2  #TEMP10         # REG[X]
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      ==I   
      JCN   M013
      JU    M014
M013: L     P#DBX 0.0
      LAR1  
      T     #POINTER
      L     B#16#0
      T     #TEMP6
      JU    PRE_LOOPEND
M014: L     #POINTER
      LAR1  
# Инкремент значения #CHECK_N
      L     #CHECK_N
      L     L#1
      +I    
      T     #CHECK_N
      JU    PRE_LOOPEND

PRE_LOOPEND: L     #REG0
      T     MB   100
      L     #REG1
      T     MB   101
      L     #REG2
      T     MB   102
      +AR1  P#1.0
      L     #TEMP6
      +     1
      T     #TEMP6
      JU    LOOPEND

OPCODE_OTHER: L     P#DBX 0.0
      LAR1  
      L     0
      T     #TEMP6
      TAR1  #POINTER

LOOPEND: TAR1  #POINTER
      CLR   
      =     #TEMP16
      L     #CHECK_N
      L     L#20
      ==I   
      S     #TEMP16
      L     #COUNTER_N
      ==I   
      A     #TEMP16
# Все проверки пройдены, если #CHECK_N == #COUNTER_N == 20
      JC    GOOD
      L     #CHECK_N
      L     L#20
      <I    
      S     #TEMP16
      L     #COUNTER_N
      ==I   
      A     #TEMP16
      JC    FAIL
      JU    M019
GOOD: SET   
      =     #PRE_RET_VAL
      JU    FINISH
FAIL: CLR   
      =     #PRE_RET_VAL
      JU    FINISH
M019: CLR   
      O     #PRE_RET_VAL
      =     #RET_VAL
      JU    LOOP
FINISH: CLR   
      O     #PRE_RET_VAL
      =     #RET_VAL

අතථ්‍ය යන්ත්‍ර උපදෙස් පිළිබඳ අදහසක් ලබා ගැනීමෙන්, DB100 බ්ලොක් එකේ බයිට්කේතය විග්‍රහ කිරීමට කුඩා disassembler එකක් ලියමු:

import string
alph = string.ascii_letters + string.digits

with open('DB100.bin', 'rb') as f:
    m = f.read()

pc = 0

while pc < len(m):
    op = m[pc]
    if op == 1:
        print('R{} = DB101[{}]'.format(m[pc + 2], m[pc + 1]))
        pc += 3
    elif op == 2:
        c = chr(m[pc + 1])
        c = c if c in alph else '?'
        print('R{} = {:02x} ({})'.format(m[pc + 2], m[pc + 1], c))
        pc += 3
    elif op == 4:
        print('R0 = 0; R{} = (R{} == R{})'.format(
            m[pc + 1], m[pc + 1], m[pc + 2]))
        pc += 3
    elif op == 5:
        print('R0 = 0; R{} = R{} - R{}'.format(
            m[pc + 1], m[pc + 1], m[pc + 2]))
        pc += 3
    elif op == 6:
        print('CHECK (R{} == R{})n'.format(
            m[pc + 1], m[pc + 2]))
        pc += 3
    else:
        print('unk opcode {}'.format(op))
        break

එහි ප්‍රතිඵලයක් වශයෙන්, අපට පහත අථත්‍ය යන්ත්‍ර කේතය ලැබේ:

අතථ්‍ය යන්ත්‍ර කේතය

R1 = DB101[0]
R2 = 6e (n)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[1]
R2 = 10 (?)
R0 = 0; R1 = R1 - R2
R2 = 20 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[2]
R2 = 77 (w)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[3]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[4]
R2 = 75 (u)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[5]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[6]
R2 = 34 (4)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[7]
R2 = 26 (?)
R0 = 0; R1 = R1 - R2
R2 = 4c (L)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[8]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[9]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[10]
R2 = 37 (7)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[11]
R2 = 22 (?)
R0 = 0; R1 = R1 - R2
R2 = 46 (F)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[12]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[13]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[14]
R2 = 6d (m)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[15]
R2 = 11 (?)
R0 = 0; R1 = R1 - R2
R2 = 23 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[16]
R2 = 35 (5)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[17]
R2 = 12 (?)
R0 = 0; R1 = R1 - R2
R2 = 25 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[18]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[19]
R2 = 26 (?)
R0 = 0; R1 = R1 - R2
R2 = 4c (L)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

ඔබට පෙනෙන පරිදි, මෙම වැඩසටහන DB101 සිට එක් එක් අක්ෂරය නිශ්චිත අගයකට සමානාත්මතාවය සඳහා සරලව පරීක්ෂා කරයි. සියලුම චෙක්පත් සම්මත කිරීම සඳහා අවසාන පේළිය වන්නේ: n0w u 4r3 7h3 m4573r. මෙම රේඛාව DB101 බ්ලොක් එකේ තැබුවහොත්, අතින් PLC පාලනය ක්‍රියාත්මක වන අතර එය බැලූනය පිපිරවීමට හෝ පිපිරවීමට හැකි වනු ඇත. 

එච්චරයි! ඇලෙක්සි කාර්මික නින්ජා කෙනෙකුට සුදුසු ඉහළ මට්ටමේ දැනුමක් පෙන්නුම් කළේය :) අපි ජයග්‍රාහකයාට අමතක නොවන ත්‍යාග යැව්වෙමු. සියලුම සහභාගිවන්නන්ට බොහෝම ස්තූතියි!

මූලාශ්රය: www.habr.com

Industrial Ninja හි අඩිපාරේ: Positive Hack Days 9 හි PLC එකක් හැක් කළ ආකාරය

මූලික විශ්ලේෂණය

රථවාහන ඩම්ප් එකකින් සංඥා සැකසුම් කුට්ටි නිස්සාරණය කිරීම

බ්ලොක් වලින් මිනිසුන්ට කියවිය හැකි උපදෙස් ලබා ගැනීම

ප්‍රතිලෝම බ්ලොක් FC3

අදහස් එක් කරන්න ඊ-මේල් මගින් පිලිතුරු දෙන්න අවලංගු

අදහස් එක් කරන්න