ProHoster > Blog > Pulega > Iloiloga ole mea faigaluega saoloto SQLIndexManager
Iloiloga ole mea faigaluega saoloto SQLIndexManager
E pei ona e iloa, o fa'asinomaga e iai sona sao taua i se DBMS, e maua ai se su'esu'ega vave i fa'amaumauga mana'omia. O le mafuaaga lena e taua tele ai le tautuaina i latou i se taimi talafeagai. E tele naua mea na tusia e uiga i suʻesuʻega ma faʻataʻitaʻiga, e aofia ai luga ole Initaneti. Mo se faʻataʻitaʻiga, o lenei autu na toe iloiloina talu ai nei i lenei lolomiga.
E tele fofo totogi ma leai se totogi mo lenei mea. Mo se faʻataʻitaʻiga, o loʻo i ai se mea ua saunia решение, e fa'avae i luga o se fa'avasegaga fa'avasegaina fa'atatau.
Le isi, se'i o tatou va'ai i le fa'aoga fua SQLIndexManager, tusia e AlanDenton.
O le eseesega faʻapitoa faʻapitoa i le va o SQLIndexManager ma le tele o isi analogues o loʻo tuʻuina mai e le tusitala lava ia iinei и iinei.
I totonu o lenei tusiga, o le a tatou vaʻavaʻai i fafo i le poloketi ma le gafatia faʻaogaina o lenei fofo polokalama.
Talanoaina lenei aoga iinei.
I le aluga o taimi, o le tele o faʻamatalaga ma mea sese na faʻasaʻo.
O lea la, sei o tatou agai atu nei i le SQLIndexManager aoga lava ia.
O lo'o tusia le talosaga ile C# .NET Framework 4.5 ile Visual Studio 2017 ma fa'aoga DevExpress mo fomu:
ma foliga faʻapenei:
O talosaga uma e faia i faila nei:
limatusi
Fesili
Query Engine
ServerInfo
Pe a faʻafesoʻotaʻi i se faʻamaumauga ma tuʻuina atu fesili i le DBMS, o le talosaga e sainia e faʻapea:
ApplicationName=”SQLIndexManager”
A e faʻalauiloa le talosaga, o le a tatalaina se faʻamalama faʻapipiʻi e faʻaopoopo se fesoʻotaʻiga:
O iinei, o le utaina o se lisi atoa o MS SQL Server mea uma e mafai ona maua i luga o fesoʻotaiga i le lotoifale e leʻi galue.
E mafai fo'i ona e fa'aopoopoina se feso'ota'iga e fa'aoga ai le ki agavale ile lisi autu:
O le isi, o fesili nei i le DBMS o le a faʻalauiloaina:
Maua se lisi o fa'amaumauga o lo'o avanoa ma a latou meatotino pu'upu'u
SELECT DatabaseName = t.[name]
, d.DataSize
, DataUsedSize = CAST(NULL AS BIGINT)
, d.LogSize
, LogUsedSize = CAST(NULL AS BIGINT)
, RecoveryModel = t.recovery_model_desc
, LogReuseWait = t.log_reuse_wait_desc
FROM sys.databases t WITH(NOLOCK)
LEFT JOIN (
SELECT [database_id]
, DataSize = SUM(CASE WHEN [type] = 0 THEN CAST(size AS BIGINT) END)
, LogSize = SUM(CASE WHEN [type] = 1 THEN CAST(size AS BIGINT) END)
FROM sys.master_files WITH(NOLOCK)
GROUP BY [database_id]
) d ON d.[database_id] = t.[database_id]
WHERE t.[state] = 0
AND t.[database_id] != 2
AND ISNULL(HAS_DBACCESS(t.[name]), 1) = 1
A maeʻa ona faʻatino tusitusiga o loʻo i luga, o le a faʻaalia se faamalama o loʻo i ai faʻamatalaga puʻupuʻu e uiga i faʻamaumauga o le faʻataʻitaʻiga filifilia o le MS SQL Server:
E taua le matauina o faʻamatalaga faʻalautele e faʻaalia e faʻavae i luga o aia tatau. Afai o iai sysadmin, ona mafai lea ona e filifilia faʻamatalaga mai le vaaiga sys.master_files. Afai e leai ni aia tatau, ona itiiti ifo lea o faʻamaumauga e toe faʻafoʻi mai ina ia aua neʻi faʻagesegese le talosaga.
O iinei e te manaʻomia e filifili ai faʻamaumauga o tului ma kiliki i le "OK" button.
O le isi, o le tusitusiga o loʻo mulimuli mai o le a faʻatinoina mo faʻamaumauga filifilia taʻitasi e iloilo ai le tulaga o faʻasino igoa:
Su'esu'ega tulaga fa'asino
declare @Fragmentation float=15;
declare @MinIndexSize bigint=768;
declare @MaxIndexSize bigint=1048576;
declare @PreDescribeSize bigint=32768;
SET NOCOUNT ON
SET ARITHABORT ON
SET NUMERIC_ROUNDABORT OFF
IF OBJECT_ID('tempdb.dbo.#AllocationUnits') IS NOT NULL
DROP TABLE #AllocationUnits
CREATE TABLE #AllocationUnits (
ContainerID BIGINT PRIMARY KEY
, ReservedPages BIGINT NOT NULL
, UsedPages BIGINT NOT NULL
)
INSERT INTO #AllocationUnits (ContainerID, ReservedPages, UsedPages)
SELECT [container_id]
, SUM([total_pages])
, SUM([used_pages])
FROM sys.allocation_units WITH(NOLOCK)
GROUP BY [container_id]
HAVING SUM([total_pages]) BETWEEN @MinIndexSize AND @MaxIndexSize
IF OBJECT_ID('tempdb.dbo.#ExcludeList') IS NOT NULL
DROP TABLE #ExcludeList
CREATE TABLE #ExcludeList (ID INT PRIMARY KEY)
INSERT INTO #ExcludeList
SELECT [object_id]
FROM sys.objects WITH(NOLOCK)
WHERE [type] IN ('V', 'U')
AND ( [is_ms_shipped] = 1 )
IF OBJECT_ID('tempdb.dbo.#Partitions') IS NOT NULL
DROP TABLE #Partitions
SELECT [object_id]
, [index_id]
, [partition_id]
, [partition_number]
, [rows]
, [data_compression]
INTO #Partitions
FROM sys.partitions WITH(NOLOCK)
WHERE [object_id] > 255
AND [rows] > 0
AND [object_id] NOT IN (SELECT * FROM #ExcludeList)
IF OBJECT_ID('tempdb.dbo.#Indexes') IS NOT NULL
DROP TABLE #Indexes
CREATE TABLE #Indexes (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IndexName SYSNAME NULL
, PagesCount BIGINT NOT NULL
, UnusedPagesCount BIGINT NOT NULL
, PartitionNumber INT NOT NULL
, RowsCount BIGINT NOT NULL
, IndexType TINYINT NOT NULL
, IsAllowPageLocks BIT NOT NULL
, DataSpaceID INT NOT NULL
, DataCompression TINYINT NOT NULL
, IsUnique BIT NOT NULL
, IsPK BIT NOT NULL
, FillFactorValue INT NOT NULL
, IsFiltered BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Indexes
SELECT ObjectID = i.[object_id]
, IndexID = i.index_id
, IndexName = i.[name]
, PagesCount = a.ReservedPages
, UnusedPagesCount = CASE WHEN ABS(a.ReservedPages - a.UsedPages) > 32 THEN a.ReservedPages - a.UsedPages ELSE 0 END
, PartitionNumber = p.[partition_number]
, RowsCount = ISNULL(p.[rows], 0)
, IndexType = i.[type]
, IsAllowPageLocks = i.[allow_page_locks]
, DataSpaceID = i.[data_space_id]
, DataCompression = p.[data_compression]
, IsUnique = i.[is_unique]
, IsPK = i.[is_primary_key]
, FillFactorValue = i.[fill_factor]
, IsFiltered = i.[has_filter]
FROM #AllocationUnits a
JOIN #Partitions p ON a.ContainerID = p.[partition_id]
JOIN sys.indexes i WITH(NOLOCK) ON i.[object_id] = p.[object_id] AND p.[index_id] = i.[index_id]
WHERE i.[type] IN (0, 1, 2, 5, 6)
AND i.[object_id] > 255
DECLARE @files TABLE (ID INT PRIMARY KEY)
INSERT INTO @files
SELECT DISTINCT [data_space_id]
FROM sys.database_files WITH(NOLOCK)
WHERE [state] != 0
AND [type] = 0
IF @@ROWCOUNT > 0 BEGIN
DELETE FROM i
FROM #Indexes i
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
WHERE ISNULL(dds.[data_space_id], i.DataSpaceID) IN (SELECT * FROM @files)
END
DECLARE @DBID INT
, @DBNAME SYSNAME
SET @DBNAME = DB_NAME()
SELECT @DBID = [database_id]
FROM sys.databases WITH(NOLOCK)
WHERE [name] = @DBNAME
IF OBJECT_ID('tempdb.dbo.#Fragmentation') IS NOT NULL
DROP TABLE #Fragmentation
CREATE TABLE #Fragmentation (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, PartitionNumber INT NOT NULL
, Fragmentation FLOAT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Fragmentation (ObjectID, IndexID, PartitionNumber, Fragmentation)
SELECT i.ObjectID
, i.IndexID
, i.PartitionNumber
, r.[avg_fragmentation_in_percent]
FROM #Indexes i
CROSS APPLY sys.dm_db_index_physical_stats(@DBID, i.ObjectID, i.IndexID, i.PartitionNumber, 'LIMITED') r
WHERE i.PagesCount <= @PreDescribeSize
AND r.[index_level] = 0
AND r.[alloc_unit_type_desc] = 'IN_ROW_DATA'
AND i.IndexType IN (0, 1, 2)
IF OBJECT_ID('tempdb.dbo.#Columns') IS NOT NULL
DROP TABLE #Columns
CREATE TABLE #Columns (
ObjectID INT NOT NULL
, ColumnID INT NOT NULL
, ColumnName SYSNAME NULL
, SystemTypeID TINYINT NULL
, IsSparse BIT
, IsColumnSet BIT
, MaxLen INT
, PRIMARY KEY (ObjectID, ColumnID)
)
INSERT INTO #Columns
SELECT ObjectID = [object_id]
, ColumnID = [column_id]
, ColumnName = [name]
, SystemTypeID = [system_type_id]
, IsSparse = [is_sparse]
, IsColumnSet = [is_column_set]
, MaxLen = [max_length]
FROM sys.columns WITH(NOLOCK)
WHERE [object_id] IN (SELECT DISTINCT i.ObjectID FROM #Indexes i)
IF OBJECT_ID('tempdb.dbo.#IndexColumns') IS NOT NULL
DROP TABLE #IndexColumns
CREATE TABLE #IndexColumns (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, OrderID INT NOT NULL
, ColumnID INT NOT NULL
, IsIncluded BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, ColumnID)
)
INSERT INTO #IndexColumns
SELECT ObjectID = [object_id]
, IndexID = [index_id]
, OrderID = CASE WHEN [is_included_column] = 0 THEN [key_ordinal] ELSE [index_column_id] END
, ColumnID = [column_id]
, IsIncluded = ISNULL([is_included_column], 0)
FROM sys.index_columns ic WITH(NOLOCK)
WHERE EXISTS(
SELECT *
FROM #Indexes i
WHERE i.ObjectID = ic.[object_id]
AND i.IndexID = ic.[index_id]
AND i.IndexType IN (1, 2)
)
IF OBJECT_ID('tempdb.dbo.#Lob') IS NOT NULL
DROP TABLE #Lob
CREATE TABLE #Lob (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IsLobLegacy BIT
, IsLob BIT
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #Lob (ObjectID, IndexID, IsLobLegacy, IsLob)
SELECT c.ObjectID
, IndexID = ISNULL(i.IndexID, 1)
, IsLobLegacy = MAX(CASE WHEN c.SystemTypeID IN (34, 35, 99) THEN 1 END)
, IsLob = 0
FROM #Columns c
LEFT JOIN #IndexColumns i ON c.ObjectID = i.ObjectID AND c.ColumnID = i.ColumnID
WHERE c.SystemTypeID IN (34, 35, 99)
GROUP BY c.ObjectID
, i.IndexID
IF OBJECT_ID('tempdb.dbo.#Sparse') IS NOT NULL
DROP TABLE #Sparse
CREATE TABLE #Sparse (ObjectID INT PRIMARY KEY)
INSERT INTO #Sparse
SELECT DISTINCT ObjectID
FROM #Columns
WHERE IsSparse = 1
OR IsColumnSet = 1
IF OBJECT_ID('tempdb.dbo.#AggColumns') IS NOT NULL
DROP TABLE #AggColumns
CREATE TABLE #AggColumns (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IndexColumns NVARCHAR(MAX)
, IncludedColumns NVARCHAR(MAX)
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #AggColumns
SELECT t.ObjectID
, t.IndexID
, IndexColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 0
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
, IncludedColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 1
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
FROM (
SELECT DISTINCT ObjectID, IndexID
FROM #Indexes
WHERE IndexType IN (1, 2)
) t
SELECT i.ObjectID
, i.IndexID
, i.IndexName
, ObjectName = o.[name]
, SchemaName = s.[name]
, i.PagesCount
, i.UnusedPagesCount
, i.PartitionNumber
, i.RowsCount
, i.IndexType
, i.IsAllowPageLocks
, u.TotalWrites
, u.TotalReads
, u.TotalSeeks
, u.TotalScans
, u.TotalLookups
, u.LastUsage
, i.DataCompression
, f.Fragmentation
, IndexStats = STATS_DATE(i.ObjectID, i.IndexID)
, IsLobLegacy = ISNULL(lob.IsLobLegacy, 0)
, IsLob = ISNULL(lob.IsLob, 0)
, IsSparse = CAST(CASE WHEN p.ObjectID IS NULL THEN 0 ELSE 1 END AS BIT)
, IsPartitioned = CAST(CASE WHEN dds.[data_space_id] IS NOT NULL THEN 1 ELSE 0 END AS BIT)
, FileGroupName = fg.[name]
, i.IsUnique
, i.IsPK
, i.FillFactorValue
, i.IsFiltered
, a.IndexColumns
, a.IncludedColumns
FROM #Indexes i
JOIN sys.objects o WITH(NOLOCK) ON o.[object_id] = i.ObjectID
JOIN sys.schemas s WITH(NOLOCK) ON s.[schema_id] = o.[schema_id]
LEFT JOIN #AggColumns a ON a.ObjectID = i.ObjectID AND a.IndexID = i.IndexID
LEFT JOIN #Sparse p ON p.ObjectID = i.ObjectID
LEFT JOIN #Fragmentation f ON f.ObjectID = i.ObjectID AND f.IndexID = i.IndexID AND f.PartitionNumber = i.PartitionNumber
LEFT JOIN (
SELECT ObjectID = [object_id]
, IndexID = [index_id]
, TotalWrites = NULLIF([user_updates], 0)
, TotalReads = NULLIF([user_seeks] + [user_scans] + [user_lookups], 0)
, TotalSeeks = NULLIF([user_seeks], 0)
, TotalScans = NULLIF([user_scans], 0)
, TotalLookups = NULLIF([user_lookups], 0)
, LastUsage = (
SELECT MAX(dt)
FROM (
VALUES ([last_user_seek])
, ([last_user_scan])
, ([last_user_lookup])
, ([last_user_update])
) t(dt)
)
FROM sys.dm_db_index_usage_stats WITH(NOLOCK)
WHERE [database_id] = @DBID
) u ON i.ObjectID = u.ObjectID AND i.IndexID = u.IndexID
LEFT JOIN #Lob lob ON lob.ObjectID = i.ObjectID AND lob.IndexID = i.IndexID
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
JOIN sys.filegroups fg WITH(NOLOCK) ON ISNULL(dds.[data_space_id], i.DataSpaceID) = fg.[data_space_id]
WHERE o.[type] IN ('V', 'U')
AND (
f.Fragmentation >= @Fragmentation
OR
i.PagesCount > @PreDescribeSize
OR
i.IndexType IN (5, 6)
)
E pei ona mafai ona vaʻaia mai fesili lava ia, o laulau le tumau e faʻaaoga soo. E faia lenei mea ina ia leai ni toe faʻapipiʻiina, ma i le tulaga o se fuafuaga tele, e mafai ona faʻatupuina le fuafuaga faʻatasi pe a faʻapipiʻi faʻamaumauga, talu ai o le faʻaofiina o fesuiaiga o laulau e mafai naʻo le tasi filo.
A maeʻa ona faʻatinoina le tusitusiga o loʻo i luga, o le a faʻaalia se faamalama ma se laulau faʻasino:
E mafai fo'i ona e fa'aali atu isi fa'amatalaga au'ili'ili iinei, e pei o:
fa'amaumauga
numera o vaega
aso ma le taimi o le valaau mulimuli
faʻapipiʻi
failagroup
ma isi.
O failauga lava ia e mafai ona faʻapipiʻiina:
I totonu o sela o le koluma Fix, e mafai ona e filifili pe o le a le gaioiga o le a faia i le taimi o le faʻaleleia. E le gata i lea, a maeʻa le faʻataʻitaʻiga, e filifilia se gaioiga faʻaletonu e faʻatatau i tulaga filifilia:
E tatau ona e filifilia fa'ailoga e mana'omia mo le fa'agaioiga.
I le faʻaaogaina o le lisi autu, e mafai ona e faʻasaoina le faʻamaumauga (o le ki lava e tasi e amata ai le faʻasologa o faʻasologa o faʻamatalaga):
ma faʻasaoina le laulau i faʻasologa eseese (o le ki lava e tasi e mafai ai ona e tatalaina faʻamatalaga auʻiliʻili mo le suʻesuʻeina ma le faʻamalamalamaina o faʻamatalaga):
E mafai foi ona e faʻafouina faʻamatalaga e ala i le kilikiina o le ki lona tolu i le agavale i le lisi autu i tafatafa o le tioata faʻalautele.
O le fa'amau fa'atasi ma se tioata fa'alautele e mafai ai ona e filifilia fa'amaumauga mana'omia mo le iloiloga.
I le taimi nei e leai se faiga fesoasoani atoatoa. O le mea lea, oomi le "?" button e na'o le fa'atupuina o se fa'amalama fa'ata'ita'i e aliali mai o lo'o iai fa'amatalaga fa'avae e uiga i le oloa faakomepiuta:
I le faaopoopo atu i mea uma o loʻo faʻamatalaina i luga, o le lisi autu o loʻo i ai se pa suʻesuʻe:
A amata le fa'asologa o fa'asologa o fa'asinomaga:
E mafai fo'i ona e va'ai i se fa'amaumauga o gaioiga na faia i le pito i lalo o le fa'amalama:
I le faʻamatalaga faʻamatalaga faʻamalama mo le suʻesuʻeina o faʻamatalaga ma le faʻataʻitaʻiga, e mafai ona e faʻatulagaina ni filifiliga faʻapitoa:
Talosaga mo le talosaga:
ia mafai ona filifili faʻafou fuainumera e le gata mo faʻasinomaga ma faʻapea foʻi i auala eseese (faʻafouina atoatoa poʻo se vaega)
e le gata ina mafai ona filifili se faʻamaumauga, ae faʻapea foʻi 'auʻaunaga eseese (e faigofie tele pe a tele taimi ole MS SQL Server)
Mo le sili atu le fetuutuunai i le faʻaaogaina, e fautuaina e afifi poloaiga i faletusi ma tuʻuina atu i PowerShell poloaiga, e pei ona faia, mo se faʻataʻitaʻiga, iinei:
fa'afaigofie ona fa'asaoina ma suia tulaga patino mo le talosaga atoa ma, pe a mana'omia, mo fa'ata'ita'iga ta'itasi o le MS SQL Server ma fa'amaumauga ta'itasi.
Mai manatu 2 ma le 4, e mulimuli mai e te manaʻo e fatuina vaega e ala i faʻamaumauga ma vaega e MS SQL Server faʻataʻitaʻiga, lea e tutusa ai tulaga.
su'esu'e mo fa'ailoga fa'alua (atoa ma le le atoatoa, e ese teisi pe 'ese'ese i na'o koluma o lo'o aofia ai)
Talu ai o SQLIndexManager e faʻaaogaina mo naʻo MS SQL Server DBMS, e tatau ona atagia lenei mea i le igoa, mo se faʻataʻitaʻiga, e pei ona taua i lalo: SQLIndexManager mo MS SQL Server
Fa'asolo uma vaega e le o ni GUI o le talosaga i ni vaega eseese ma toe tusi i le .NET Core 2.1
I le taimi na tusia ai, o le mea 6 o manaʻoga o loʻo galue malosi ma o loʻo i ai le lagolago i le tulaga o le suʻeina o kopi atoatoa ma tutusa: