Dib u eegista qalabka bilaashka ah ee SQLIndexManager
Sidaad ogtahay, tusmooyinku waxay door muhiim ah ka ciyaaraan DBMS, iyagoo siinaya baaritaan degdeg ah diiwaanada loo baahan yahay. Taasi waa sababta ay muhiim u tahay in loo adeego waqti ku habboon. Wax badan ayaa laga qoray falanqaynta iyo hagaajinta, oo ay ku jiraan internetka. Tusaale ahaan, mawduucan dhawaan ayaa dib loo eegay daabacaadan.
Waxaa jira xalal badan oo lacag iyo lacag la'aan ah tan. Tusaale ahaan, waxaa jira mid diyaarsan go'aanka, oo ku salaysan habka tusmaynta la qabsiga.
Marka xigta, aan eegno adeegga bilaashka ah Maamulaha SQLIndex, waxaa qoray AlanDenton.
Farqiga ugu weyn ee farsamo ee u dhexeeya SQLIndexManager iyo tiro analoog oo kale ah waxaa bixiyay qoraaga laftiisa halkan ΠΈ halkan.
Maqaalkan, waxaan ku eegi doonaa dibadda ee mashruuca iyo awoodaha hawlgelinta ee xal software this.
Ka doodista utility this halkan.
Muddo ka dib, inta badan faallooyinka iyo kutaannada waa la saxay.
Marka, aan hadda u gudubno utility SQLIndexManager laftiisa.
Codsiga wuxuu ku qoran yahay C # .NET Framework 4.5 gudaha Visual Studio 2017 wuxuuna u isticmaalaa DevExpress foomamka:
waxayna u egtahay sidan:
Dhammaan codsiyada waxaa lagu soo saaray faylasha soo socda:
Index
Su'aasha
Injin waydiinta
ServerInfo
Marka lagu xidho xogta xogta oo aad u dirayso weydiimaha DBMS, arjiga waxa loo saxeexaa sidan soo socota:
ApplicationName=βSQLIndexManagerβ
Markaad bilowdo arjiga, daaqad modal ah ayaa furmi doonta si loogu daro xidhiidh:
Halkan, rarista liis dhamaystiran ee dhammaan tusaalooyinka Server-ka MS SQL ee laga heli karo shabakadaha maxalliga ah wali ma shaqaynayo.
Waxa kale oo aad ku dari kartaa xidhiidh adiga oo isticmaalaya badhanka bidix ee ugu dambeeya ee liiska muhiimka ah:
Marka xigta, su'aalaha soo socda ee DBMS ayaa la bilaabi doonaa:
Helitaanka liiska kaydka macluumaadka ee jira oo leh hantidooda kooban
SELECT DatabaseName = t.[name]
, d.DataSize
, DataUsedSize = CAST(NULL AS BIGINT)
, d.LogSize
, LogUsedSize = CAST(NULL AS BIGINT)
, RecoveryModel = t.recovery_model_desc
, LogReuseWait = t.log_reuse_wait_desc
FROM sys.databases t WITH(NOLOCK)
LEFT JOIN (
SELECT [database_id]
, DataSize = SUM(CASE WHEN [type] = 0 THEN CAST(size AS BIGINT) END)
, LogSize = SUM(CASE WHEN [type] = 1 THEN CAST(size AS BIGINT) END)
FROM sys.master_files WITH(NOLOCK)
GROUP BY [database_id]
) d ON d.[database_id] = t.[database_id]
WHERE t.[state] = 0
AND t.[database_id] != 2
AND ISNULL(HAS_DBACCESS(t.[name]), 1) = 1
Ka dib marka la fuliyo qoraallada sare, daaqad ayaa soo bixi doonta oo ay ku jiraan macluumaad kooban oo ku saabsan kaydinta tusaalaha la doortay ee MS SQL Server:
Waxaa xusid mudan in macluumaadka la dheereeyay la muujiyo iyadoo lagu saleynayo xuquuqda. Haddii ay jiraan sysadmin, ka dibna waxaad dooran kartaa xogta aragtida sys.master_files. Haddii aysan jirin xuquuqahaas, markaas xog yar ayaa si fudud loo soo celiyaa si aysan u yarayn codsiga.
Halkan waxa aad u baahan tahay inaad doorato kaydka xogta ee xiisaha oo guji "OK" badhanka.
Marka xigta, qoraalkan soo socda ayaa loo fulin doonaa xog kasta oo la xushay si loo falanqeeyo xaaladda tusmooyinka:
Falanqaynta heerka index
declare @Fragmentation float=15;
declare @MinIndexSize bigint=768;
declare @MaxIndexSize bigint=1048576;
declare @PreDescribeSize bigint=32768;
SET NOCOUNT ON
SET ARITHABORT ON
SET NUMERIC_ROUNDABORT OFF
IF OBJECT_ID('tempdb.dbo.#AllocationUnits') IS NOT NULL
DROP TABLE #AllocationUnits
CREATE TABLE #AllocationUnits (
ContainerID BIGINT PRIMARY KEY
, ReservedPages BIGINT NOT NULL
, UsedPages BIGINT NOT NULL
)
INSERT INTO #AllocationUnits (ContainerID, ReservedPages, UsedPages)
SELECT [container_id]
, SUM([total_pages])
, SUM([used_pages])
FROM sys.allocation_units WITH(NOLOCK)
GROUP BY [container_id]
HAVING SUM([total_pages]) BETWEEN @MinIndexSize AND @MaxIndexSize
IF OBJECT_ID('tempdb.dbo.#ExcludeList') IS NOT NULL
DROP TABLE #ExcludeList
CREATE TABLE #ExcludeList (ID INT PRIMARY KEY)
INSERT INTO #ExcludeList
SELECT [object_id]
FROM sys.objects WITH(NOLOCK)
WHERE [type] IN ('V', 'U')
AND ( [is_ms_shipped] = 1 )
IF OBJECT_ID('tempdb.dbo.#Partitions') IS NOT NULL
DROP TABLE #Partitions
SELECT [object_id]
, [index_id]
, [partition_id]
, [partition_number]
, [rows]
, [data_compression]
INTO #Partitions
FROM sys.partitions WITH(NOLOCK)
WHERE [object_id] > 255
AND [rows] > 0
AND [object_id] NOT IN (SELECT * FROM #ExcludeList)
IF OBJECT_ID('tempdb.dbo.#Indexes') IS NOT NULL
DROP TABLE #Indexes
CREATE TABLE #Indexes (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IndexName SYSNAME NULL
, PagesCount BIGINT NOT NULL
, UnusedPagesCount BIGINT NOT NULL
, PartitionNumber INT NOT NULL
, RowsCount BIGINT NOT NULL
, IndexType TINYINT NOT NULL
, IsAllowPageLocks BIT NOT NULL
, DataSpaceID INT NOT NULL
, DataCompression TINYINT NOT NULL
, IsUnique BIT NOT NULL
, IsPK BIT NOT NULL
, FillFactorValue INT NOT NULL
, IsFiltered BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Indexes
SELECT ObjectID = i.[object_id]
, IndexID = i.index_id
, IndexName = i.[name]
, PagesCount = a.ReservedPages
, UnusedPagesCount = CASE WHEN ABS(a.ReservedPages - a.UsedPages) > 32 THEN a.ReservedPages - a.UsedPages ELSE 0 END
, PartitionNumber = p.[partition_number]
, RowsCount = ISNULL(p.[rows], 0)
, IndexType = i.[type]
, IsAllowPageLocks = i.[allow_page_locks]
, DataSpaceID = i.[data_space_id]
, DataCompression = p.[data_compression]
, IsUnique = i.[is_unique]
, IsPK = i.[is_primary_key]
, FillFactorValue = i.[fill_factor]
, IsFiltered = i.[has_filter]
FROM #AllocationUnits a
JOIN #Partitions p ON a.ContainerID = p.[partition_id]
JOIN sys.indexes i WITH(NOLOCK) ON i.[object_id] = p.[object_id] AND p.[index_id] = i.[index_id]
WHERE i.[type] IN (0, 1, 2, 5, 6)
AND i.[object_id] > 255
DECLARE @files TABLE (ID INT PRIMARY KEY)
INSERT INTO @files
SELECT DISTINCT [data_space_id]
FROM sys.database_files WITH(NOLOCK)
WHERE [state] != 0
AND [type] = 0
IF @@ROWCOUNT > 0 BEGIN
DELETE FROM i
FROM #Indexes i
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
WHERE ISNULL(dds.[data_space_id], i.DataSpaceID) IN (SELECT * FROM @files)
END
DECLARE @DBID INT
, @DBNAME SYSNAME
SET @DBNAME = DB_NAME()
SELECT @DBID = [database_id]
FROM sys.databases WITH(NOLOCK)
WHERE [name] = @DBNAME
IF OBJECT_ID('tempdb.dbo.#Fragmentation') IS NOT NULL
DROP TABLE #Fragmentation
CREATE TABLE #Fragmentation (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, PartitionNumber INT NOT NULL
, Fragmentation FLOAT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Fragmentation (ObjectID, IndexID, PartitionNumber, Fragmentation)
SELECT i.ObjectID
, i.IndexID
, i.PartitionNumber
, r.[avg_fragmentation_in_percent]
FROM #Indexes i
CROSS APPLY sys.dm_db_index_physical_stats(@DBID, i.ObjectID, i.IndexID, i.PartitionNumber, 'LIMITED') r
WHERE i.PagesCount <= @PreDescribeSize
AND r.[index_level] = 0
AND r.[alloc_unit_type_desc] = 'IN_ROW_DATA'
AND i.IndexType IN (0, 1, 2)
IF OBJECT_ID('tempdb.dbo.#Columns') IS NOT NULL
DROP TABLE #Columns
CREATE TABLE #Columns (
ObjectID INT NOT NULL
, ColumnID INT NOT NULL
, ColumnName SYSNAME NULL
, SystemTypeID TINYINT NULL
, IsSparse BIT
, IsColumnSet BIT
, MaxLen INT
, PRIMARY KEY (ObjectID, ColumnID)
)
INSERT INTO #Columns
SELECT ObjectID = [object_id]
, ColumnID = [column_id]
, ColumnName = [name]
, SystemTypeID = [system_type_id]
, IsSparse = [is_sparse]
, IsColumnSet = [is_column_set]
, MaxLen = [max_length]
FROM sys.columns WITH(NOLOCK)
WHERE [object_id] IN (SELECT DISTINCT i.ObjectID FROM #Indexes i)
IF OBJECT_ID('tempdb.dbo.#IndexColumns') IS NOT NULL
DROP TABLE #IndexColumns
CREATE TABLE #IndexColumns (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, OrderID INT NOT NULL
, ColumnID INT NOT NULL
, IsIncluded BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, ColumnID)
)
INSERT INTO #IndexColumns
SELECT ObjectID = [object_id]
, IndexID = [index_id]
, OrderID = CASE WHEN [is_included_column] = 0 THEN [key_ordinal] ELSE [index_column_id] END
, ColumnID = [column_id]
, IsIncluded = ISNULL([is_included_column], 0)
FROM sys.index_columns ic WITH(NOLOCK)
WHERE EXISTS(
SELECT *
FROM #Indexes i
WHERE i.ObjectID = ic.[object_id]
AND i.IndexID = ic.[index_id]
AND i.IndexType IN (1, 2)
)
IF OBJECT_ID('tempdb.dbo.#Lob') IS NOT NULL
DROP TABLE #Lob
CREATE TABLE #Lob (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IsLobLegacy BIT
, IsLob BIT
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #Lob (ObjectID, IndexID, IsLobLegacy, IsLob)
SELECT c.ObjectID
, IndexID = ISNULL(i.IndexID, 1)
, IsLobLegacy = MAX(CASE WHEN c.SystemTypeID IN (34, 35, 99) THEN 1 END)
, IsLob = 0
FROM #Columns c
LEFT JOIN #IndexColumns i ON c.ObjectID = i.ObjectID AND c.ColumnID = i.ColumnID
WHERE c.SystemTypeID IN (34, 35, 99)
GROUP BY c.ObjectID
, i.IndexID
IF OBJECT_ID('tempdb.dbo.#Sparse') IS NOT NULL
DROP TABLE #Sparse
CREATE TABLE #Sparse (ObjectID INT PRIMARY KEY)
INSERT INTO #Sparse
SELECT DISTINCT ObjectID
FROM #Columns
WHERE IsSparse = 1
OR IsColumnSet = 1
IF OBJECT_ID('tempdb.dbo.#AggColumns') IS NOT NULL
DROP TABLE #AggColumns
CREATE TABLE #AggColumns (
ObjectID INT NOT NULL
, IndexID INT NOT NULL
, IndexColumns NVARCHAR(MAX)
, IncludedColumns NVARCHAR(MAX)
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #AggColumns
SELECT t.ObjectID
, t.IndexID
, IndexColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 0
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
, IncludedColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 1
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
FROM (
SELECT DISTINCT ObjectID, IndexID
FROM #Indexes
WHERE IndexType IN (1, 2)
) t
SELECT i.ObjectID
, i.IndexID
, i.IndexName
, ObjectName = o.[name]
, SchemaName = s.[name]
, i.PagesCount
, i.UnusedPagesCount
, i.PartitionNumber
, i.RowsCount
, i.IndexType
, i.IsAllowPageLocks
, u.TotalWrites
, u.TotalReads
, u.TotalSeeks
, u.TotalScans
, u.TotalLookups
, u.LastUsage
, i.DataCompression
, f.Fragmentation
, IndexStats = STATS_DATE(i.ObjectID, i.IndexID)
, IsLobLegacy = ISNULL(lob.IsLobLegacy, 0)
, IsLob = ISNULL(lob.IsLob, 0)
, IsSparse = CAST(CASE WHEN p.ObjectID IS NULL THEN 0 ELSE 1 END AS BIT)
, IsPartitioned = CAST(CASE WHEN dds.[data_space_id] IS NOT NULL THEN 1 ELSE 0 END AS BIT)
, FileGroupName = fg.[name]
, i.IsUnique
, i.IsPK
, i.FillFactorValue
, i.IsFiltered
, a.IndexColumns
, a.IncludedColumns
FROM #Indexes i
JOIN sys.objects o WITH(NOLOCK) ON o.[object_id] = i.ObjectID
JOIN sys.schemas s WITH(NOLOCK) ON s.[schema_id] = o.[schema_id]
LEFT JOIN #AggColumns a ON a.ObjectID = i.ObjectID AND a.IndexID = i.IndexID
LEFT JOIN #Sparse p ON p.ObjectID = i.ObjectID
LEFT JOIN #Fragmentation f ON f.ObjectID = i.ObjectID AND f.IndexID = i.IndexID AND f.PartitionNumber = i.PartitionNumber
LEFT JOIN (
SELECT ObjectID = [object_id]
, IndexID = [index_id]
, TotalWrites = NULLIF([user_updates], 0)
, TotalReads = NULLIF([user_seeks] + [user_scans] + [user_lookups], 0)
, TotalSeeks = NULLIF([user_seeks], 0)
, TotalScans = NULLIF([user_scans], 0)
, TotalLookups = NULLIF([user_lookups], 0)
, LastUsage = (
SELECT MAX(dt)
FROM (
VALUES ([last_user_seek])
, ([last_user_scan])
, ([last_user_lookup])
, ([last_user_update])
) t(dt)
)
FROM sys.dm_db_index_usage_stats WITH(NOLOCK)
WHERE [database_id] = @DBID
) u ON i.ObjectID = u.ObjectID AND i.IndexID = u.IndexID
LEFT JOIN #Lob lob ON lob.ObjectID = i.ObjectID AND lob.IndexID = i.IndexID
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
JOIN sys.filegroups fg WITH(NOLOCK) ON ISNULL(dds.[data_space_id], i.DataSpaceID) = fg.[data_space_id]
WHERE o.[type] IN ('V', 'U')
AND (
f.Fragmentation >= @Fragmentation
OR
i.PagesCount > @PreDescribeSize
OR
i.IndexType IN (5, 6)
)
Sida laga arki karo su'aalaha laftooda, miisaska ku meel gaarka ah ayaa badanaa la isticmaalaa. Tan waxaa loo sameeyaa si aysan jirin dib-u-soo-ururin, iyo marka la eego qorshe ballaaran, qorshaha waxaa la soo saari karaa si isku mid ah marka la gelinayo xogta, maaddaama gelinta doorsoomayaasha miiska ay suurtogal tahay oo keliya hal dun.
Ka dib marka la fuliyo qoraalka sare, daaqad leh tusmooyin ayaa soo bixi doona:
Waxaad sidoo kale halkan ku soo bandhigi kartaa macluumaad kale oo faahfaahsan, sida:
database
tirada qaybaha
taariikhda iyo wakhtiga wacitaanka ugu dambeeya
tuujin
kooxda file
iyo wixii la mid ah.
Kuwa ku hadla laftooda waa la habeyn karaa:
Unugyada tiirka Fix, waxaad dooran kartaa ficilka la samayn doono inta lagu jiro hagaajinta. Sidoo kale, marka sawirku dhammeeyo, ficilka caadiga ah ayaa la doortaa iyadoo lagu salaynayo goobaha la doortay:
Waa inaad doorataa tusmooyinka la rabo si loo habeeyo.
oo u kaydi miiska qaabab kala duwan (badhan isku mid ah ayaa kuu oggolaanaya inaad furto dejin faahfaahsan oo falanqaynta iyo hagaajinta tusmooyinka):
Waxaad sidoo kale cusbooneysiin kartaa macluumaadka adigoo gujinaya batoonka saddexaad ee bidix ee liiska weyn ee ku xiga muraayadda weyneynta.
Badhanka leh muraayad weyn ayaa kuu ogolaanaya inaad doorato xogta macluumaadka ee la rabo si loo tixgeliyo.
Hadda ma jiro nidaam caawimo oo dhammaystiran. Sidaa darteed, riix batoonka "?" waxay si fudud u keeni doontaa daaqada modal inay u muuqato oo ay ku jiraan macluumaadka aasaasiga ah ee ku saabsan badeecada software:
Marka lagu daro wax kasta oo kor lagu sharaxay, menu-ka ugu weyn wuxuu leeyahay bar goobeed:
Marka la bilaabayo habka wanaajinta tusmada:
Waxa kale oo aad arki kartaa log of falalka la qabtay xagga hoose ee daaqada:
Daaqadda goobaha faahfaahsan ee falanqaynta tusmooyinka iyo hagaajinta, waxaad habayn kartaa doorashooyin badan oo khiyaano leh:
Codsiyada codsiga:
suurtagal ka dhig in si xulashada ah loo cusboonaysiiyo tirokoobyada ma aha oo kaliya tusmooyinka iyo sidoo kale siyaabo kala duwan (si buuxda u cusbooneysii ama qayb ahaan)
suurto gal ma aha oo kaliya in la doorto database, laakiin sidoo kale servero kala duwan (tani waa mid aad u habboon marka ay jiraan xaalado badan oo MS SQL Server)
Dabacsanaan badan oo isticmaalka, waxaa la soo jeediyay in lagu duubo amarada maktabadaha oo loo soo saaro amarrada PowerShell, sida la sameeyo, tusaale ahaan, halkan:
suurtagal ka dhig in la kaydiyo oo la beddelo goobaha gaarka ah labadaba codsiga oo dhan iyo, haddii loo baahdo, tusaale kasta oo MS SQL Server iyo xog kasta
Laga soo bilaabo dhibcaha 2 iyo 4, waxay ku socotaa inaad rabto inaad ku abuurto kooxo by databases iyo kooxo by MS SQL Server tusaale ahaan, kuwaas oo goobaha ay isku mid yihiin.
raadi tusmooyin nuqul ah (dhamays ah oo aan dhamaystirnayn, kuwaas oo ama waxyar ka duwan yihiin ama ku kala duwan yihiin kaliya tiirarka lagu soo daray)
Maadaama SQLIndexManager loo isticmaalo kaliya MS SQL Server DBMS, waa lagama maarmaan in tan lagu muujiyo magaca, tusaale ahaan, sida soo socota: SQLIndexManager ee MS SQL Server
U rar dhammaan qaybaha aan ahayn GUI ee arjiga una beddelo qaybo kala duwan oo dib ugu qor .NET Core 2.1
Waqtiga qorista, shayga 6 ee rabitaanka ayaa si firfircoon loo horumarinayaa waxaana hore u jiray taageero qaab raadinta nuqullo dhammaystiran oo la mid ah: