Awood u siinta fog ee qoraalada Mikrotik ee Telegram v 2.0

Ciid wanaagsan qof walba. Mawduucan ayaa ka wanaagsan version ee waxa aan dib u qoray 2016 halkan.

Guud ahaan, mabda'a hawlgalka isma bedelin, farqiga kaliya ayaa ah in hadda uu si dhakhso ah u shaqeeyo iyada oo aan dib loo dhigin.

Waxaan u rarnaa qoraalka Mikrotik, waxaan u beddelnaa BotID-ga iyo ChatID-ga annaga oo u abuurna jadwal. Deji halbeegga "Waqtiga Bilowga" si aad u bilowdo (Ku socodsii qoraalka marka aad bilowdo.)
"Interval": 00:00:00
Haddii kale wax walba waa sidii ay ahaayeen.

Telegram-v2

:delay 10
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;
:local chatId 0;
:local messageId 0;


:local parse do={
  :local startLoc ([:find $content $variable -1] + [:len $variable] + 2);
  :local commaLoc ([:find $content "," $startLoc] - 1 + 1);
  :local braceLoc ([:find $content "}" $startLoc] - 1 + 1);
  :local endLoc $commaLoc;
  :local startSymbol [:pick $content $startLoc]
  :if ($braceLoc != 0 and ($commaLoc = 0 or $braceLoc < $commaLoc)) do={
    :set endLoc $braceLoc;
  };
  :if ($startSymbol = "{") do={
    :set endLoc ($braceLoc + 1);
  };
  :if ($quotas = true) do={
    :set startLoc ($startLoc + 1);
    :set endLoc ($endLoc - 1);
  }
  :if ($endLoc < $startLoc) do={
    :set endLoc ($startLoc + 1);
  };
  :local message [:pick $content $startLoc $endLoc]
  #:log info $message;
  :return $message;
}


:while ( true ) do={
  :do {
    #:log info "https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60";
    :tool fetch url=("https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60") dst-path="getUpdates";
    :local content [/file get [/file find name=getUpdates] contents] ;
    #:log info $content;
    :if ([:len $content] > 30) do={
      :set messageId ([$parse content=$content variable="update_id"] + 1)
      :local message [$parse content=$content variable="text" quotas=true]
      :local chat [$parse content=$content variable="chat"]
      :local chatId [$parse content=$chat variable="id"]      
      
      :if (($chatId = $myChatID) and ([/system script find name=$message] != "")) do={
        :system script run $message;
      } else={
        :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$chatId&text=$mtIdentity: Unknown command: $message") keep-result=no
      }
    }
  } on-error={}
};

Dhowr sano oo la isticmaalay ka dib, waxaa la helay bug: sababo aan la garanayn, Mikrotik daciif ah ayaa joojiya qoraalka, laakiin kuwa ka xoog badan wuxuu u shaqeeyaa isagoon joojin.

Ujeedooyinkan daraaddood, waxaan ku tuuray crutch WatchDog. Halkan waxaan ku beddeleynaa magaca qoraalka oo aan u beddelnay midka kor lagu tilmaamay. oo u dhig inta u dhaxaysa dib u bilaabashada ilaa 5 daqiiqo. 5tii daqiiqaba "watchdog" ayaa hubin doona qoraalka haddii uu shaqayn waayo, wuu socodsiin doonaa.

WatchDogT.me

:global scriptname "t.me"
:if ([:len [/system script job find script=$"scriptname"]] > 0) do={
:log info "$scriptname Already Running - killing old script before continuing"
:foreach counter in=[/system script job find script=$"scriptname"] do={
/system script job remove $counter
}
}
/system script run $scriptname

Hagaag, macmacaanka, qoraalka waxaa laga soo qaatay madasha Mikrotik.
Wuxuu mowduucyo muhiim ah ka soo diraa buugga-gacantayada.

Waxaan ku darnaa qoraalka si aan jadwal ugu sameyno oo aan sheegno inta udhaxeysa dib u bilaabashada 5-tii daqiqiba kasta, badal BotID iyo ChatID inteena gaarka ah.

Notify-log

:global lastTime
:global output
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;

:local LogGet [ :toarray [ /log find topics~"critical" || message~"login failure" || message~"[Ff]ailure" ] ] ;
:local LogtLineCount [ :len $LogGet ] ;
if ($LogtLineCount > 0) do={
   :local currentTime "$[ /log get [ :pick $LogGet ($LogtLineCount -1) ] time ]";
   :if ([:len $currentTime] = 10 ) do={
      :set currentTime [ :pick $currentTime 0 10 ];
   }
   :set output "$currentTime - $[/log get [ :pick $LogGet ($LogtLineCount-1) ] message ]";
   :if (([:len $lastTime] < 1) || (([:len $lastTime] > 0) && ($lastTime != $currentTime))) do={
      :set lastTime $currentTime ;
         :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$myChatID&text="$mtIdentity" :  $output") keep-result=no
   }
}

Waxaan helnaa natiijada:

Source: www.habr.com