Aktivizimi në distancë i skripteve Mikrotik nga Telegram v 2.0

Gëzuar festën e vonuar të gjithëve. Kjo temë është më e mirë version i asaj që kam shkruar në vitin 2016 këtu.

Në përgjithësi, parimi i funksionimit nuk ka ndryshuar, ndryshimi i vetëm është se tani funksionon menjëherë pa vonesë.

Ne ngarkojmë skriptin në Mikrotik, ndryshojmë BotID dhe ChatID në tonat dhe krijojmë një orar për të. Cakto parametrin "Ora e fillimit" në nisje (ekzekuto skriptin në fillim.)
"Interval": 00:00:00
Përndryshe gjithçka është ashtu siç ishte.

Telegram-v2

:delay 10
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;
:local chatId 0;
:local messageId 0;


:local parse do={
  :local startLoc ([:find $content $variable -1] + [:len $variable] + 2);
  :local commaLoc ([:find $content "," $startLoc] - 1 + 1);
  :local braceLoc ([:find $content "}" $startLoc] - 1 + 1);
  :local endLoc $commaLoc;
  :local startSymbol [:pick $content $startLoc]
  :if ($braceLoc != 0 and ($commaLoc = 0 or $braceLoc < $commaLoc)) do={
    :set endLoc $braceLoc;
  };
  :if ($startSymbol = "{") do={
    :set endLoc ($braceLoc + 1);
  };
  :if ($quotas = true) do={
    :set startLoc ($startLoc + 1);
    :set endLoc ($endLoc - 1);
  }
  :if ($endLoc < $startLoc) do={
    :set endLoc ($startLoc + 1);
  };
  :local message [:pick $content $startLoc $endLoc]
  #:log info $message;
  :return $message;
}


:while ( true ) do={
  :do {
    #:log info "https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60";
    :tool fetch url=("https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60") dst-path="getUpdates";
    :local content [/file get [/file find name=getUpdates] contents] ;
    #:log info $content;
    :if ([:len $content] > 30) do={
      :set messageId ([$parse content=$content variable="update_id"] + 1)
      :local message [$parse content=$content variable="text" quotas=true]
      :local chat [$parse content=$content variable="chat"]
      :local chatId [$parse content=$chat variable="id"]      
      
      :if (($chatId = $myChatID) and ([/system script find name=$message] != "")) do={
        :system script run $message;
      } else={
        :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$chatId&text=$mtIdentity: Unknown command: $message") keep-result=no
      }
    }
  } on-error={}
};

Pas nja dy vitesh përdorimi, u zbulua një gabim: për ndonjë arsye të panjohur, Mikrotik i dobët ndalon skenarin, por në ato më të fuqishme funksionon pa u ndalur.

Për këto qëllime, hodha patericën WatchDog. Këtu ne ndryshojmë emrin e skenarit në atë të treguar më sipër. dhe vendoseni intervalin e rifillimit në 5 minuta. Çdo 5 minuta "watchdog" ynë do të kontrollojë skenarin dhe nëse nuk funksionon, do ta ekzekutojë atë.

WatchDogT.me

:global scriptname "t.me"
:if ([:len [/system script job find script=$"scriptname"]] > 0) do={
:log info "$scriptname Already Running - killing old script before continuing"
:foreach counter in=[/system script job find script=$"scriptname"] do={
/system script job remove $counter
}
}
/system script run $scriptname

Epo, për ëmbëlsirë, skenari është marrë nga forumi i Mikrotik.
Dërgon tema të rëndësishme nga regjistri në shportën tonë.

Ne shtojmë skriptin për të planifikuar dhe specifikojmë intervalin e rifillimit çdo 5 minuta, ndryshojmë BotID dhe ChatID në tonat.

Njoftim-log

:global lastTime
:global output
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;

:local LogGet [ :toarray [ /log find topics~"critical" || message~"login failure" || message~"[Ff]ailure" ] ] ;
:local LogtLineCount [ :len $LogGet ] ;
if ($LogtLineCount > 0) do={
   :local currentTime "$[ /log get [ :pick $LogGet ($LogtLineCount -1) ] time ]";
   :if ([:len $currentTime] = 10 ) do={
      :set currentTime [ :pick $currentTime 0 10 ];
   }
   :set output "$currentTime - $[/log get [ :pick $LogGet ($LogtLineCount-1) ] message ]";
   :if (([:len $lastTime] < 1) || (([:len $lastTime] > 0) && ($lastTime != $currentTime))) do={
      :set lastTime $currentTime ;
         :tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$myChatID&text="$mtIdentity" :  $output") keep-result=no
   }
}

Ne marrim rezultatin:

Burimi: www.habr.com