Пуппет је систем за управљање конфигурацијом. Користи се за довођење домаћина у жељено стање и одржавање овог стања.

Са Пуппет-ом радим више од пет година. Овај текст је у суштини преведена и преуређена компилација кључних тачака из званичне документације, која ће почетницима омогућити да брзо схвате суштину Пуппет-а.

Основне информације

Оперативни систем Пуппет-а је клијент-сервер, иако такође подржава рад без сервера са ограниченом функционалношћу.

Користи се модел рада повлачења: подразумевано, једном на сваких пола сата, клијенти контактирају сервер ради конфигурације и примењују је. Ако сте радили са Ансибле-ом, онда они користе другачији пусх модел: администратор покреће процес примене конфигурације, сами клијенти неће применити ништа.

Током мрежне комуникације користи се двосмерна ТЛС енкрипција: сервер и клијент имају своје приватне кључеве и одговарајуће сертификате. Обично сервер издаје сертификате за клијенте, али у принципу је могуће користити екстерни ЦА.

Упознавање са манифестима

У луткарској терминологији на сервер за лутке повезати чворови (чворови). Написана је конфигурација за чворове у манифестима у посебном програмском језику – Пуппет ДСЛ.

Пуппет ДСЛ је декларативни језик. Описује жељено стање чвора у облику декларација појединачних ресурса, на пример:

• Датотека постоји и има специфичан садржај.
• Пакет је инсталиран.
• Служба је почела.

Ресурси могу бити међусобно повезани:

• Постоје зависности, оне утичу на редослед коришћења ресурса.
  На пример, „прво инсталирајте пакет, затим уредите конфигурациону датотеку, а затим покрените услугу.“
• Постоје обавештења - ако се ресурс променио, он шаље обавештења ресурсима који су на њега претплаћени.
  На пример, ако се конфигурациона датотека промени, можете аутоматски поново покренути услугу.

Поред тога, Пуппет ДСЛ има функције и варијабле, као и условне изјаве и селекторе. Подржани су и различити шаблонски механизми - ЕПП и ЕРБ.

Пуппет је написан у Руби-у, тако да су многи конструкти и термини преузети одатле. Руби вам омогућава да проширите Пуппет - додајте сложену логику, нове врсте ресурса, функције.

Док је Пуппет покренут, манифести за сваки одређени чвор на серверу се компајлирају у директоријум. Директоријум је листа ресурса и њихових односа након израчунавања вредности функција, променљивих и проширења условних исказа.

Синтакса и стил кода

Ево делова званичне документације који ће вам помоћи да разумете синтаксу ако наведени примери нису довољни:

• Синтакса различитих језичких конструкција.
• Синтакса ресурса.
• Синтакса за описивање чворова.

Ево примера како манифест изгледа:

# Комментарии пишутся, как и много где, после решётки.
#
# Описание конфигурации ноды начинается с ключевого слова node,
# за которым следует селектор ноды — хостнейм (с доменом или без)
# или регулярное выражение для хостнеймов, или ключевое слово default.
#
# После этого в фигурных скобках описывается собственно конфигурация ноды.
#
# Одна и та же нода может попасть под несколько селекторов. Про приоритет
# селекторов написано в статье про синтаксис описания нод.
node 'hostname', 'f.q.d.n', /regexp/ {
  # Конфигурация по сути является перечислением ресурсов и их параметров.
  #
  # У каждого ресурса есть тип и название.
  #
  # Внимание: не может быть двух ресурсов одного типа с одинаковыми названиями!
  #
  # Описание ресурса начинается с его типа. Тип пишется в нижнем регистре.
  # Про разные типы ресурсов написано ниже.
  #
  # После типа в фигурных скобках пишется название ресурса, потом двоеточие,
  # дальше идёт опциональное перечисление параметров ресурса и их значений.
  # Значения параметров указываются через т.н. hash rocket (=>).
  resource { 'title':
    param1 => value1,
    param2 => value2,
    param3 => value3,
  }
}

Увлачење и преломи линија нису обавезни део манифеста, али постоји препорука стиле гуиде. резиме:

• Увлачења са два размака, табулатори се не користе.
• Коврџаве заграде су раздвојене размаком;
• Зарези иза сваког параметра, укључујући и последњи. Сваки параметар је у посебном реду. Изузетак је направљен за случај без параметара и једног параметра: можете писати у једном реду и без зареза (тј. resource { 'title': } и resource { 'title': param => value }).
• Стрелице на параметрима треба да буду на истом нивоу.
• Испред њих су исписане стрелице односа ресурса.

Локација датотека на паппетсерверу

За даље објашњење, представићу концепт „коренског директоријума“. Основни директоријум је директоријум који садржи конфигурацију лутке за одређени чвор.

Основни директоријум варира у зависности од верзије Пуппет-а и окружења које се користи. Окружење су независни скупови конфигурација који се чувају у засебним директоријумима. Обично се користи у комбинацији са гит-ом, у ком случају се окружења креирају из гит грана. Сходно томе, сваки чвор се налази у једном или другом окружењу. Ово се може конфигурисати на самом чвору или у ЕНЦ-у, о чему ћу говорити у следећем чланку.

• У трећој верзији („стара лутка“) основни директоријум је био /etc/puppet. Употреба окружења је опциона - на пример, не користимо их са старим Пуппет-ом. Ако се користе окружења, обично се чувају /etc/puppet/environments, основни директоријум ће бити директоријум окружења. Ако се окружења не користе, основни директоријум ће бити основни директоријум.
• Почевши од четврте верзије („нова лутка“), употреба окружења је постала обавезна, а основни директоријум је премештен у /etc/puppetlabs/code. Сходно томе, окружења се чувају у /etc/puppetlabs/code/environments, основни директоријум је директоријум окружења.

Мора постојати поддиректоријум у основном директоријуму manifests, који садржи један или више манифеста који описују чворове. Поред тога, требало би да постоји поддиректоријум modules, који садржи модуле. Рећи ћу вам који су модули мало касније. Поред тога, стари Пуппет може имати и поддиректоријум files, који садржи различите датотеке које копирамо у чворове. У новом Пуппет-у, све датотеке су смештене у модуле.

Датотеке манифеста имају екстензију .pp.

Пар борбених примера

Опис чвора и ресурса на њему

На чвору server1.testdomain датотека мора бити креирана /etc/issue са садржајем Debian GNU/Linux n l. Датотека мора бити власништво корисника и групе root, права приступа морају бити 644.

Пишемо манифест:

node 'server1.testdomain' {   # блок конфигурации, относящийся к ноде server1.testdomain
    file { '/etc/issue':   # описываем файл /etc/issue
        ensure  => present,   # этот файл должен существовать
        content => 'Debian GNU/Linux n l',   # у него должно быть такое содержимое
        owner   => root,   # пользователь-владелец
        group   => root,   # группа-владелец
        mode    => '0644',   # права на файл. Они заданы в виде строки (в кавычках), потому что иначе число с 0 в начале будет воспринято как записанное в восьмеричной системе, и всё пойдёт не так, как задумано
    }
}

Односи између ресурса на чвору

На чвору server2.testdomain нгинк мора бити покренут и радити са претходно припремљеном конфигурацијом.

Хајде да разложимо проблем:

• Пакет треба да се инсталира nginx.
• Неопходно је да се конфигурационе датотеке копирају са сервера.
• Услуга треба да ради nginx.
• Ако се конфигурација ажурира, сервис се мора поново покренути.

Пишемо манифест:

node 'server2.testdomain' {   # блок конфигурации, относящийся к ноде server2.testdomain
    package { 'nginx':   # описываем пакет nginx
        ensure => installed,   # он должен быть установлен
    }
  # Прямая стрелка (->) говорит о том, что ресурс ниже должен
  # создаваться после ресурса, описанного выше.
  # Такие зависимости транзитивны.
    -> file { '/etc/nginx':   # описываем файл /etc/nginx
        ensure  => directory,   # это должна быть директория
        source  => 'puppet:///modules/example/nginx-conf',   # её содержимое нужно брать с паппет-сервера по указанному адресу
        recurse => true,   # копировать файлы рекурсивно
        purge   => true,   # нужно удалять лишние файлы (те, которых нет в источнике)
        force   => true,   # удалять лишние директории
    }
  # Волнистая стрелка (~>) говорит о том, что ресурс ниже должен
  # подписаться на изменения ресурса, описанного выше.
  # Волнистая стрелка включает в себя прямую (->).
    ~> service { 'nginx':   # описываем сервис nginx
        ensure => running,   # он должен быть запущен
        enable => true,   # его нужно запускать автоматически при старте системы
    }
  # Когда ресурс типа service получает уведомление,
  # соответствующий сервис перезапускается.
}

Да би ово функционисало, потребна вам је отприлике следећа локација датотеке на серверу лутке:

/etc/puppetlabs/code/environments/production/ # (это для нового Паппета, для старого корневой директорией будет /etc/puppet)
├── manifests/
│   └── site.pp
└── modules/
    └── example/
        └── files/
            └── nginx-conf/
                ├── nginx.conf
                ├── mime.types
                └── conf.d/
                    └── some.conf

Типови ресурса

Комплетну листу подржаних типова ресурса можете пронаћи овде у документацији, овде ћу описати пет основних типова, који су у мојој пракси довољни за решавање већине проблема.

фајл

Управља датотекама, директоријумима, симболичким везама, њиховим садржајем и правима приступа.

Параметри:

• назив ресурса — путања до датотеке (опционо)
• пут — путања до датотеке (ако није наведена у називу)
• обезбедити - тип датотеке:
  • absent - избришите датотеку
  • present — мора постојати датотека било које врсте (ако не постоји, биће креирана обична датотека)
  • file - обичан фајл
  • directory - именик
  • link - симболична веза
• садржина — садржај датотеке (погодан само за обичне датотеке, не може се користити заједно са извор или мета)
• извор — везу до путање са које желите да копирате садржај датотеке (не може се користити заједно са садржина или мета). Може се навести као УРИ са шемом puppet: (тада ће се користити датотеке са сервера лутака) и са шемом http: (Надам се да је јасно шта ће се догодити у овом случају), па чак и са дијаграмом file: или као апсолутна путања без шеме (онда ће се користити датотека из локалног ФС-а на чвору)
• мета — где симболска веза треба да показује (не може се користити заједно са садржина или извор)
• власник — корисник који треба да поседује датотеку
• група — група којој датотека треба да припада
• начин — дозволе датотеке (као стринг)
• рецурсе - омогућава рекурзивну обраду директоријума
• чистка - омогућава брисање датотека које нису описане у Пуппет-у
• силом - омогућава брисање директоријума који нису описани у Пуппет-у

пакет

Инсталира и уклања пакете. Може да обрађује обавештења - поново инсталира пакет ако је параметар наведен реинсталл_он_рефресх.

Параметри:

• назив ресурса — назив пакета (опционо)
• име — назив пакета (ако није наведено у називу)
• Снабдевач — менаџер пакета за коришћење
• обезбедити — жељено стање паковања:
  • present, installed - било која верзија инсталирана
  • latest - инсталирана најновија верзија
  • absent - избрисан (apt-get remove)
  • purged — обрисано заједно са конфигурационим датотекама (apt-get purge)
  • held - верзија пакета је закључана (apt-mark hold)
  • любая другая строка — наведена верзија је инсталирана
• реинсталл_он_рефресх - ако true, онда ће по пријему обавештења пакет бити поново инсталиран. Корисно за дистрибуције засноване на извору, где може бити неопходна реконструкција пакета када се мењају параметри изградње. Уобичајено false.

сервис

Управља услугама. Може да обрађује обавештења - поново покреће услугу.

Параметри:

• назив ресурса — услуга којом се управља (опционо)
• име — услуга којом треба управљати (ако није наведено у називу)
• обезбедити — жељено стање услуге:
  • running - покренут
  • stopped - стао
• омогућити — контролише могућност покретања услуге:
  • true — аутоматско покретање је омогућено (systemctl enable)
  • mask - прерушен (systemctl mask)
  • false — аутоматско покретање је онемогућено (systemctl disable)
• покренути - команда за поновно покретање услуге
• статус — команда за проверу статуса сервиса
• хасрестарт — назначите да ли инитсцрипт сервиса подржава поновно покретање. Ако false а параметар је наведен покренути — користи се вредност овог параметра. Ако false и параметар покренути није наведено - услуга је заустављена и почела да се поново покреће (али системд користи команду systemctl restart).
• хасстатус — назначите да ли инитсцрипт сервиса подржава команду status. Ако false, тада се користи вредност параметра статус. Уобичајено true.

екец

Покреће екстерне команде. Ако не наведете параметре ствара, само ако, ако не или рефресхонли, команда ће бити покренута сваки пут када се покрене Пуппет. Може да обрађује обавештења - покреће команду.

Параметри:

• назив ресурса — команда која се извршава (опционо)
• команда — команда коју треба извршити (ако није наведена у називу)
• пут — путање у којима се тражи извршна датотека
• само ако — ако је команда наведена у овом параметру завршена са нултим повратним кодом, главна команда ће бити извршена
• ако не — ако је команда наведена у овом параметру завршена са повратним кодом који није нула, главна команда ће бити извршена
• ствара — ако датотека наведена у овом параметру не постоји, главна команда ће бити извршена
• рефресхонли - ако true, онда ће се команда покренути само када овај екец прими обавештење од других ресурса
• цвд — директоријум из којег треба покренути команду
• корисник — корисник од кога да се покрене команда
• Снабдевач - како покренути команду:
  • ПОСИКС — подређени процес се једноставно креира, обавезно наведите пут
  • граната - команда се покреће у љусци /bin/sh, можда није наведено пут, можете користити глобинг, цеви и друге карактеристике љуске. Обично се аутоматски детектује ако постоје посебни карактери (|, ;, &&, || и тако даље).

црон

Контролише цроњобс.

Параметри:

• назив ресурса - само нека врста идентификатора
• обезбедити — статус крунског посла:
  • present - креирати ако не постоји
  • absent - избрисати ако постоји
• команда - коју наредбу покренути
• околина — у ком окружењу треба покренути команду (листа променљивих окружења и њихових вредности преко =)
• корисник — од ког корисника да покренете команду
• минут, сат, радним даном, месец, месец дана — када покренути црон. Ако било који од ових атрибута није наведен, његова вредност у цронтаб-у ће бити *.

У Пуппет 6.0 црон као да уклоњен из кутије у пуппетсервер, тако да нема документације на општем сајту. Али је он је у кутији у пуппет-агент-у, тако да нема потребе да га засебно инсталирате. Можете видети документацију за то у документацији за пету верзију ПупетаИли на ГитХуб-у.

О ресурсима уопште

Захтеви за јединственост ресурса

Најчешћа грешка са којом се сусрећемо је Дупликат декларације. Ова грешка се јавља када се у директоријуму појављују два или више ресурса истог типа са истим именом.

Зато ћу поново писати: манифести за исти чвор не би требало да садрже ресурсе истог типа са истим насловом!

Понекад постоји потреба да се инсталирају пакети са истим именом, али са различитим менаџерима пакета. У овом случају морате користити параметар nameда бисте избегли грешку:

package { 'ruby-mysql':
  ensure   => installed,
  name     => 'mysql',
  provider => 'gem',
}
package { 'python-mysql':
  ensure   => installed,
  name     => 'mysql',
  provider => 'pip',
}

Други типови ресурса имају сличне опције како би се избегло дуплирање − name у сервис, command у екец, и тако даље.

Метапараметри

Сваки тип ресурса има неке посебне параметре, без обзира на његову природу.

Потпуна листа мета параметара у документацији Лутка.

Кратка листа:

• захтевати — овај параметар показује од којих ресурса зависи овај ресурс.
• пре - Овај параметар одређује који ресурси зависе од овог ресурса.
• претплатити се — овај параметар одређује са којих извора овај ресурс прима обавештења.
• нотифи — Овај параметар одређује који ресурси примају обавештења са овог ресурса.

Сви наведени метапараметри прихватају или једну везу до ресурса или низ веза у угластим заградама.

Везе ка ресурсима

Веза ресурса је једноставно помињање ресурса. Углавном се користе за означавање зависности. Упућивање на непостојећи ресурс ће изазвати грешку при компилацији.

Синтакса везе је следећа: тип ресурса са великим словом (ако име типа садржи дупле двотачке, онда се сваки део имена између две тачке пише великим словима), затим име ресурса у угластим заградама (велика и мала слова имена не мења!). Не би требало да буде размака у углатим заградама одмах иза назива типа.

Пример:

file { '/file1': ensure => present }
file { '/file2':
  ensure => directory,
  before => File['/file1'],
}
file { '/file3': ensure => absent }
File['/file1'] -> File['/file3']

Зависности и обавештења

Документација овде.

Као што је раније речено, једноставне зависности између ресурса су транзитивне. Узгред, будите пажљиви када додајете зависности - можете креирати цикличне зависности, што ће изазвати грешку у компилацији.

За разлику од зависности, обавештења нису транзитивна. За обавештења важе следећа правила:

• Ако ресурс прими обавештење, он се ажурира. Акције ажурирања зависе од типа ресурса − екец покреће команду, сервис поново покреће услугу, пакет поново инсталира пакет. Ако ресурс нема дефинисану акцију ажурирања, онда се ништа не дешава.
• Током једног покретања Пуппет-а, ресурс се ажурира највише једном. Ово је могуће јер обавештења укључују зависности, а графикон зависности не садржи циклусе.
• Ако Пуппет промени стање ресурса, ресурс шаље обавештења свим ресурсима који су претплаћени на њега.
• Ако се ресурс ажурира, он шаље обавештења свим ресурсима који су претплаћени на њега.

Руковање неодређеним параметрима

По правилу, ако неки параметар ресурса нема подразумевану вредност и овај параметар није наведен у манифесту, онда Пуппет неће променити ово својство за одговарајући ресурс на чвору. На пример, ако је ресурс типа фајл параметар није наведен owner, тада Пуппет неће променити власника одговарајуће датотеке.

Увод у класе, варијабле и дефиниције

Претпоставимо да имамо неколико чворова који имају исти део конфигурације, али постоје и разлике - иначе бисмо све то могли описати у једном блоку node {}. Наравно, можете једноставно копирати идентичне делове конфигурације, али генерално ово је лоше решење - конфигурација расте, а ако промените општи део конфигурације, мораћете да уређујете исту ствар на много места. У исто време, лако је погрешити, а генерално, принцип ДРИ (не понављај се) је измишљен с разлогом.

За решавање овог проблема постоји такав дизајн као класа.

Предавања

Класа је именовани блок попет кода. Класе су потребне за поновно коришћење кода.

Прво треба описати класу. Сам опис нигде не додаје никакве ресурсе. Класа је описана у манифестима:

# Описание класса начинается с ключевого слова class и его названия.
# Дальше идёт тело класса в фигурных скобках.
class example_class {
    ...
}

Након овога, класа се може користити:

# первый вариант использования — в стиле ресурса с типом class
class { 'example_class': }
# второй вариант использования — с помощью функции include
include example_class
# про отличие этих двух вариантов будет рассказано дальше

Пример из претходног задатка - преместимо инсталацију и конфигурацију нгинк-а у класу:

class nginx_example {
    package { 'nginx':
        ensure => installed,
    }
    -> file { '/etc/nginx':
        ensure => directory,
        source => 'puppet:///modules/example/nginx-conf',
        recure => true,
        purge  => true,
        force  => true,
    }
    ~> service { 'nginx':
        ensure => running,
        enable => true,
    }
}

node 'server2.testdomain' {
    include nginx_example
}

Променљиве

Класа из претходног примера уопште није флексибилна јер увек доноси исту нгинк конфигурацију. Хајде да направимо путању до конфигурационе променљиве, онда се ова класа може користити за инсталирање нгинк-а са било којом конфигурацијом.

То се може учинити користећи променљиве.

Пажња: променљиве у Пуппет-у су непроменљиве!

Поред тога, променљивој се може приступити тек након што је декларисана, иначе ће вредност променљиве бити undef.

Пример рада са променљивим:

# создание переменных
$variable = 'value'
$var2 = 1
$var3 = true
$var4 = undef
# использование переменных
$var5 = $var6
file { '/tmp/text': content => $variable }
# интерполяция переменных — раскрытие значения переменных в строках. Работает только в двойных кавычках!
$var6 = "Variable with name variable has value ${variable}"

Лутка има именских простора, а варијабле, сходно томе, имају област видљивости: Променљива са истим именом може бити дефинисана у различитим именским просторима. Приликом решавања вредности променљиве, променљива се претражује у тренутном именском простору, затим у затвореном именском простору и тако даље.

Примери именског простора:

• глобално - променљиве ван описа класе или чвора иду тамо;
• именски простор чвора у опису чвора;
• именски простор класе у опису класе.

Да бисте избегли двосмисленост приликом приступа променљивој, можете да наведете именски простор у имену променљиве:

# переменная без пространства имён
$var
# переменная в глобальном пространстве имён
$::var
# переменная в пространстве имён класса
$classname::var
$::classname::var

Хајде да се сложимо да пут до нгинк конфигурације лежи у променљивој $nginx_conf_source. Тада ће класа изгледати овако:

class nginx_example {
    package { 'nginx':
        ensure => installed,
    }
    -> file { '/etc/nginx':
        ensure => directory,
        source => $nginx_conf_source,   # здесь используем переменную вместо фиксированной строки
        recure => true,
        purge  => true,
        force  => true,
    }
    ~> service { 'nginx':
        ensure => running,
        enable => true,
    }
}

node 'server2.testdomain' {
    $nginx_conf_source = 'puppet:///modules/example/nginx-conf'
    include nginx_example
}

Међутим, дати пример је лош јер постоји нека „тајна сазнања“ да се негде унутар класе користи променљива са таквим и таквим именом. Много је исправније ово знање учинити општим – класе могу имати параметре.

Параметри класе су променљиве у именском простору класе, наведене су у заглављу класе и могу се користити као обичне променљиве у телу класе. Вредности параметара су наведене када се класа користи у манифесту.

Параметар се може поставити на подразумевану вредност. Ако параметар нема подразумевану вредност и вредност није подешена када се користи, то ће изазвати грешку при компилацији.

Параметризујмо класу из горњег примера и додајмо два параметра: први, обавезан, је путања до конфигурације, а други, опциони, је назив пакета са нгинк-ом (у Дебиан-у, на пример, постоје пакети nginx, nginx-light, nginx-full).

# переменные описываются сразу после имени класса в круглых скобках
class nginx_example (
  $conf_source,
  $package_name = 'nginx-light', # параметр со значением по умолчанию
) {
  package { $package_name:
    ensure => installed,
  }
  -> file { '/etc/nginx':
    ensure  => directory,
    source  => $conf_source,
    recurse => true,
    purge   => true,
    force   => true,
  }
  ~> service { 'nginx':
    ensure => running,
    enable => true,
  }
}

node 'server2.testdomain' {
  # если мы хотим задать параметры класса, функция include не подойдёт* — нужно использовать resource-style declaration
  # *на самом деле подойдёт, но про это расскажу в следующей серии. Ключевое слово "Hiera".
  class { 'nginx_example':
    conf_source => 'puppet:///modules/example/nginx-conf',   # задаём параметры класса точно так же, как параметры для других ресурсов
  }
}

У Пуппет-у се куцају променљиве. Једи много типова података. Типови података се обично користе за валидацију вредности параметара прослеђених класама и дефиницијама. Ако се прослеђени параметар не подудара са наведеним типом, појавиће се грешка при компилацији.

Тип се пише непосредно испред имена параметра:

class example (
  String $param1,
  Integer $param2,
  Array $param3,
  Hash $param4,
  Hash[String, String] $param5,
) {
  ...
}

Класе: укључују назив класе у односу на цласс{'цласснаме':}

Свака класа је ресурс типа класа. Као и код било које друге врсте ресурса, не могу постојати две инстанце исте класе на истом чвору.

Ако покушате да додате класу истом чвору два пута користећи class { 'classname':} (без разлике, са различитим или идентичним параметрима), доћи ће до грешке у компилацији. Али ако користите класу у стилу ресурса, можете одмах експлицитно да подесите све њене параметре у манифесту.

Међутим, ако користите include, онда се класа може додати колико год пута желите. Чињеница је да include је идемпотентна функција која проверава да ли је класа додата у директоријум. Ако класа није у директоријуму, додаје је, а ако већ постоји, не ради ништа. Али у случају употребе include Не можете подесити параметре класе током декларације класе - сви потребни параметри морају бити постављени у екстерном извору података - Хиера или ЕНЦ. О њима ћемо говорити у следећем чланку.

Дефинише

Као што је речено у претходном блоку, иста класа не може бити присутна на чвору више од једном. Међутим, у неким случајевима морате бити у могућности да користите исти блок кода са различитим параметрима на истом чвору. Другим речима, постоји потреба за сопственим типом ресурса.

На пример, да бисмо инсталирали ПХП модул, у Авито-у радимо следеће:

1. Инсталирајте пакет са овим модулом.
2. Хајде да направимо конфигурациону датотеку за овај модул.
3. Креирамо симболичку везу до конфигурације за пхп-фпм.
4. Креирамо симболичку везу до конфигурације за пхп цли.

У таквим случајевима, дизајн као нпр дефинисати (дефинисати, дефинисани тип, дефинисани тип ресурса). Дефине је сличан класи, али постоје разлике: прво, сваки Дефине је тип ресурса, а не ресурс; друго, свака дефиниција има имплицитни параметар $title, где иде име ресурса када је декларисано. Као иу случају класа, дефиниција се прво мора описати, након чега се може користити.

Поједностављени пример са модулом за ПХП:

define php74::module (
  $php_module_name = $title,
  $php_package_name = "php7.4-${title}",
  $version = 'installed',
  $priority = '20',
  $data = "extension=${title}.son",
  $php_module_path = '/etc/php/7.4/mods-available',
) {
  package { $php_package_name:
    ensure          => $version,
    install_options => ['-o', 'DPkg::NoTriggers=true'],  # триггеры дебиановских php-пакетов сами создают симлинки и перезапускают сервис php-fpm - нам это не нужно, так как и симлинками, и сервисом мы управляем с помощью Puppet
  }
  -> file { "${php_module_path}/${php_module_name}.ini":
    ensure  => $ensure,
    content => $data,
  }
  file { "/etc/php/7.4/cli/conf.d/${priority}-${php_module_name}.ini":
    ensure  => link,
    target  => "${php_module_path}/${php_module_name}.ini",
  }
  file { "/etc/php/7.4/fpm/conf.d/${priority}-${php_module_name}.ini":
    ensure  => link,
    target  => "${php_module_path}/${php_module_name}.ini",
  }
}

node server3.testdomain {
  php74::module { 'sqlite3': }
  php74::module { 'amqp': php_package_name => 'php-amqp' }
  php74::module { 'msgpack': priority => '10' }
}

Најлакши начин да ухватите грешку Дуплицате децларатион је у Дефине. Ово се дешава ако дефиниција има ресурс са константним именом, а постоје две или више инстанци ове дефиниције на неком чвору.

Лако се заштитити од овога: сви ресурси унутар дефиниције морају имати назив у зависности од тога $title. Алтернатива је идемпотентно додавање ресурса, у најједноставнијем случају, довољно је преместити ресурсе заједничке за све инстанце дефиниције у посебну класу и укључити ову класу у дефиницију - функцију; include идемпотентан.

Постоје и други начини да се постигне идемпотенција приликом додавања ресурса, наиме коришћење функција defined и ensure_resources, али о томе ћу вам рећи у следећој епизоди.

Зависности и обавештења за класе и дефиниције

Класе и дефиниције додају следећа правила руковању зависностима и обавештењима:

• зависност од класе/дефине додаје зависности од свих ресурса класе/дефине;
• зависност класе/дефинисања додаје зависности свим ресурсима класе/дефинисања;
• цласс/дефине нотификација обавештава све ресурсе класе/дефине;
• цласс/дефине претплата се претплаћује на све ресурсе класе/дефине.

Условни искази и селектори

Документација овде.

if

Овде је једноставно:

if ВЫРАЖЕНИЕ1 {
  ...
} elsif ВЫРАЖЕНИЕ2 {
  ...
} else {
  ...
}

ако не

осим ако је ако је обрнуто: блок кода ће бити извршен ако је израз лажан.

unless ВЫРАЖЕНИЕ {
  ...
}

случај

Ни ту нема ништа компликовано. Можете користити регуларне вредности (низове, бројеве, итд.), регуларне изразе и типове података као вредности.

case ВЫРАЖЕНИЕ {
  ЗНАЧЕНИЕ1: { ... }
  ЗНАЧЕНИЕ2, ЗНАЧЕНИЕ3: { ... }
  default: { ... }
}

Селектори

Селектор је језичка конструкција слична case, али уместо да изврши блок кода, враћа вредност.

$var = $othervar ? { 'val1' => 1, 'val2' => 2, default => 3 }

Модули

Када је конфигурација мала, лако се може држати у једном манифесту. Али што више конфигурација описујемо, што више класа и чворова има у манифесту, он расте и постаје незгодан за рад.

Поред тога, постоји проблем поновне употребе кода – када је сав код у једном манифесту, тешко је поделити овај код са другима. Да би решио ова два проблема, Пуппет има ентитет који се зове модули.

Модули - ово су скупови класа, дефиниција и других луткарских ентитета смештених у посебан директоријум. Другим речима, модул је независан део луткарске логике. На пример, може постојати модул за рад са нгинк-ом, и он ће садржати оно и само оно што је потребно за рад са нгинк-ом, или може постојати модул за рад са ПХП-ом и тако даље.

Модули су верзионисани, а такође су подржане зависности модула један од другог. Постоји отворено спремиште модула - Пуппет Форге.

На луткарском серверу, модули се налазе у поддиректоријуму модули основног директоријума. Унутар сваког модула постоји стандардна шема директоријума - манифести, датотеке, шаблони, либ итд.

Структура датотеке у модулу

Корен модула може да садржи следеће директоријуме са описним именима:

• manifests - садржи манифесте
• files - садржи датотеке
• templates - садржи шаблоне
• lib — садржи Руби код

Ово није потпуна листа директоријума и датотека, али је за сада довољна за овај чланак.

Имена ресурса и имена датотека у модулу

Документација овде.

Ресурси (класе, дефиниције) у модулу се не могу именовати како год желите. Поред тога, постоји директна кореспонденција између имена ресурса и имена датотеке у којој ће Пуппет тражити опис тог ресурса. Ако прекршите правила именовања, онда Пуппет једноставно неће пронаћи опис ресурса и добићете грешку у компилацији.

Правила су једноставна:

• Сви ресурси у модулу морају бити у именском простору модула. Ако се модул позове foo, онда би сви ресурси у њему требали бити именовани foo::<anything>, или само foo.
• Ресурс са именом модула мора бити у датотеци init.pp.
• За друге ресурсе, шема именовања датотека је следећа:
  • префикс са именом модула се одбацује
  • све двотачке, ако их има, замењују се косим цртама
  • додатак је додат .pp

Показаћу на примеру. Рецимо да пишем модул nginx. Садржи следеће ресурсе:

• класа nginx описано у манифесту init.pp;
• класа nginx::service описано у манифесту service.pp;
• дефинисати nginx::server описано у манифесту server.pp;
• дефинисати nginx::server::location описано у манифесту server/location.pp.

шаблони

Сигурно и сами знате шта су шаблони, нећу их овде детаљно описивати. Али оставићу то за сваки случај линк ка Википедији.

Како користити шаблоне: Значење шаблона се може проширити помоћу функције template, који је прослеђен путањом до шаблона. За ресурсе типа фајл користи се заједно са параметром content. На пример, овако:

file { '/tmp/example': content => template('modulename/templatename.erb')

Виев патх <modulename>/<filename> подразумева фајл <rootdir>/modules/<modulename>/templates/<filename>.

Поред тога, постоји функција inline_template — прима текст шаблона као унос, а не име датотеке.

У оквиру шаблона, можете користити све варијабле Пуппет у тренутном опсегу.

Пуппет подржава шаблоне у ЕРБ и ЕПП формату:

• ЕПП документација.
• ЕРБ документација.

Укратко о ЕРБ-у

Контролне структуре:

• <%= ВЫРАЖЕНИЕ %> — убаците вредност израза
• <% ВЫРАЖЕНИЕ %> — израчунати вредност израза (без уметања). Условне изјаве (иф) и петље (свака) обично иду овде.
• <%# КОММЕНТАРИЙ %>

Изрази у ЕРБ-у су написани у Руби-у (ЕРБ је заправо Ембеддед Руби).

Да бисте приступили променљивим из манифеста, потребно је да додате @ на име променљиве. Да бисте уклонили прелом реда који се појављује након контролне конструкције, потребно је да користите ознаку за затварање -%>.

Пример коришћења шаблона

Рецимо да пишем модул за контролу ЗооКеепер-а. Класа одговорна за креирање конфигурације изгледа отприлике овако:

class zookeeper::configure (
  Array[String] $nodes,
  Integer $port_client,
  Integer $port_quorum,
  Integer $port_leader,
  Hash[String, Any] $properties,
  String $datadir,
) {
  file { '/etc/zookeeper/conf/zoo.cfg':
    ensure  => present,
    content => template('zookeeper/zoo.cfg.erb'),
  }
}

И одговарајући шаблон zoo.cfg.erb - Тако:

<% if @nodes.length > 0 -%>
<% @nodes.each do |node, id| -%>
server.<%= id %>=<%= node %>:<%= @port_leader %>:<%= @port_quorum %>;<%= @port_client %>
<% end -%>
<% end -%>

dataDir=<%= @datadir %>

<% @properties.each do |k, v| -%>
<%= k %>=<%= v %>
<% end -%>

Чињенице и уграђене варијабле

Често одређени део конфигурације зависи од тога шта се тренутно дешава на чвору. На пример, у зависности од тога шта је Дебиан издање, потребно је да инсталирате једну или другу верзију пакета. Све ово можете надгледати ручно, преписивањем манифеста ако се чворови промене. Али ово није озбиљан приступ, аутоматизација је много боља.

Да би добио информације о чворовима, Пуппет има механизам који се зове чињенице. чињенице - ово је информација о чвору, доступна у манифестима у облику обичних променљивих у глобалном простору имена. На пример, име хоста, верзија оперативног система, архитектура процесора, листа корисника, листа мрежних интерфејса и њихових адреса и још много тога. Чињенице су доступне у манифестима и шаблонима као регуларне варијабле.

Пример рада са чињеницама:

notify { "Running OS ${facts['os']['name']} version ${facts['os']['release']['full']}": }
# ресурс типа notify просто выводит сообщение в лог

Формално гледано, чињеница има име (стринг) и вредност (доступни су различити типови: низови, низови, речници). Једи скуп уграђених чињеница. Такође можете написати своје. Описани су сакупљачи чињеница као функције у Руби-у, или како извршне датотеке. Чињенице се такође могу представити у облику текстуалне датотеке са подацима на чворовима.

Током рада, марионетски агент прво копира све доступне сакупљаче чињеница са сервера папета у чвор, након чега их покреће и шаље прикупљене чињенице серверу; Након тога, сервер почиње са састављањем каталога.

Чињенице у облику извршних датотека

Такве чињенице су смештене у модуле у именику facts.d. Наравно, датотеке морају бити извршне. Када се покрећу, морају да излазе информације у стандардни излаз у ИАМЛ или формату кључ=вредност.

Не заборавите да се чињенице односе на све чворове које контролише попет сервер на који је ваш модул распоређен. Стога, у скрипти, водите рачуна да проверите да ли систем има све програме и датотеке неопходне да ваша чињеница функционише.

#!/bin/sh
echo "testfact=success"

#!/bin/sh
echo '{"testyamlfact":"success"}'

Руби фацтс

Такве чињенице су смештене у модуле у именику lib/facter.

# всё начинается с вызова функции Facter.add с именем факта и блоком кода
Facter.add('ladvd') do
# в блоках confine описываются условия применимости факта — код внутри блока должен вернуть true, иначе значение факта не вычисляется и не возвращается
  confine do
    Facter::Core::Execution.which('ladvdc') # проверим, что в PATH есть такой исполняемый файл
  end
  confine do
    File.socket?('/var/run/ladvd.sock') # проверим, что есть такой UNIX-domain socket
  end
# в блоке setcode происходит собственно вычисление значения факта
  setcode do
    hash = {}
    if (out = Facter::Core::Execution.execute('ladvdc -b'))
      out.split.each do |l|
        line = l.split('=')
        next if line.length != 2
        name, value = line
        hash[name.strip.downcase.tr(' ', '_')] = value.strip.chomp(''').reverse.chomp(''').reverse
      end
    end
    hash  # значение последнего выражения в блоке setcode является значением факта
  end
end

Текст чињенице

Такве чињенице се постављају на чворове у директоријуму /etc/facter/facts.d у старом Луткару или /etc/puppetlabs/facts.d у новом Лутку.

examplefact=examplevalue

---
examplefact2: examplevalue2
anotherfact: anothervalue

Долазак до чињеница

Постоје два начина да се приступи чињеницама:

• кроз речник $facts: $facts['fqdn'];
• користећи име чињенице као име променљиве: $fqdn.

Најбоље је користити речник $facts, или још боље, назначите глобални простор имена ($::facts).

Ево релевантног одељка документације.

Уграђене варијабле

Осим чињеница, постоји и неке варијабле, доступно у глобалном именском простору.

• поуздане чињенице — променљиве које су преузете из клијентовог сертификата (пошто се сертификат обично издаје на серверу за попет, агент не може само да узме и промени свој сертификат, па су променљиве „поверљиве“): назив сертификата, назив сертификата хост и домен, екстензије из сертификата.
• чињенице о серверу —променљиве које се односе на информације о серверу—верзија, име, ИП адреса сервера, окружење.
• агентске чињенице — променљиве које додаје директно агент-пуппет, а не фактор — назив сертификата, верзија агента, верзија лутке.
• мастер променљиве - Паппетмастер варијабле (сиц!). То је отприлике исто као у чињенице о серверу, плус вредности конфигурационих параметара су доступне.
• променљиве компајлера — променљиве компајлера које се разликују у сваком опсегу: назив тренутног модула и назив модула у коме се приступило тренутном објекту. Могу се користити, на пример, за проверу да се ваши приватни часови не користе директно из других модула.

Додатак 1: како покренути и отклонити све ово?

Чланак је садржао много примера луткарског кода, али нам уопште није рекао како да покренемо овај код. Па, исправљам се.

За покретање Пуппет-а довољан је агент, али у већини случајева ће вам требати и сервер.

Агенте

Барем од верзије 5, пакети пуппет-агент из званично складиште Пуппетлабс-а садрже све зависности (рубин и одговарајуће драгуље), тако да нема потешкоћа са инсталацијом (говорим о дистрибуцијама заснованим на Дебиан-у - не користимо дистрибуције засноване на РПМ-у).

У најједноставнијем случају, да бисте користили конфигурацију лутке, довољно је покренути агента у режиму без сервера: под условом да је код лутке копиран у чвор, покрените puppet apply <путь к манифесту>:

atikhonov@atikhonov ~/puppet-test $ cat helloworld.pp 
node default {
    notify { 'Hello world!': }
}
atikhonov@atikhonov ~/puppet-test $ puppet apply helloworld.pp 
Notice: Compiled catalog for atikhonov.localdomain in environment production in 0.01 seconds
Notice: Hello world!
Notice: /Stage[main]/Main/Node[default]/Notify[Hello world!]/message: defined 'message' as 'Hello world!'
Notice: Applied catalog in 0.01 seconds

Боље је, наравно, подесити сервер и покренути агенте на чворовима у демонском режиму - тада ће једном на сваких пола сата применити конфигурацију преузету са сервера.

Можете имитирати пусх модел рада - идите на чвор који вас занима и почните sudo puppet agent -t. Кључ -t (--test) заправо укључује неколико опција које се могу појединачно омогућити. Ове опције укључују следеће:

• не покрећу се у демонском режиму (подразумевано агент почиње у демонском режиму);
• искључите се након примене каталога (подразумевано, агент ће наставити да ради и примењује конфигурацију једном на сваких пола сата);
• написати детаљан дневник рада;
• прикажи промене у датотекама.

Агент има режим рада без промена - можете га користити када нисте сигурни да сте написали исправну конфигурацију и желите да проверите шта ће тачно агент променити током рада. Овај режим је омогућен параметром --noop на командној линији: sudo puppet agent -t --noop.

Поред тога, можете омогућити дневник отклањања грешака у раду - у њему лутка пише о свим радњама које обавља: ​​о ресурсу који тренутно обрађује, о параметрима овог ресурса, о томе које програме покреће. Наравно, ово је параметар --debug.

Сервер

У овом чланку нећу разматрати комплетну поставку паппетсервера и постављање кода на њега, само ћу рећи да постоји потпуно функционална верзија сервера која не захтева додатну конфигурацију за рад са малим бројем; чворови (рецимо, до сто). Већи број чворова ће захтевати подешавање - по подразумеваној вредности, пуппетсервер покреће не више од четири радника, за веће перформансе морате повећати њихов број и не заборавите да повећате ограничења меморије, иначе ће сервер већину времена сакупљати смеће.

Примена кода - ако вам је потребна брзо и лако, погледајте (на р10к)[https://github.com/puppetlabs/r10k], за мале инсталације би требало да буде сасвим довољно.

Додатак 2: Смернице за кодирање

1. Поставите сву логику у класе и дефиниције.
2. Држите класе и дефиниције у модулима, а не у манифестима који описују чворове.
3. Користите чињенице.
4. Не правите иф-ове на основу имена хостова.
5. Слободно додајте параметре за класе и дефиниције – ово је боље од имплицитне логике скривене у телу класе/дефине.

Објаснићу зашто препоручујем да то урадите у следећем чланку.

Закључак

Завршимо са уводом. У следећем чланку ћу вам рећи о Хиери, ЕНЦ-у и ПуппетДБ-у.

Само регистровани корисници могу учествовати у анкети. Пријавите се, Добродошао си.

Заправо, материјала има много више – могу да пишем чланке о следећим темама, гласам о ономе о чему би вас занимало да прочитате:

• 100%Напредне луткарске конструкције – неко срање следећег нивоа: петље, мапирање и други ламбда изрази, сакупљачи ресурса, извезени ресурси и комуникација међу хостовима преко Пуппет-а, ознака, добављача, апстрактних типова података.13
• 100%„Ја сам мамин админ“ или како смо се ми у Авито-у спријатељили са неколико сервера за пупке различитих верзија и, у принципу, део о администрирању попет сервера.7
• 100%Како пишемо луткарски код: инструментација, документација, тестирање, ЦИ/ЦД.18

22 корисника је гласало. 9 корисника је било уздржано.

Извор: ввв.хабр.цом