Једноставно надгледање ДФС репликације у Заббик-у

Увод

Са прилично великом и дистрибуираном инфраструктуром која користи ДФС као јединствену тачку приступа подацима и ДФСР за репликацију података између центара података и сервера филијала, поставља се питање праћења статуса ове репликације.
Игром случаја, скоро одмах након што смо почели да користимо ДФСР, почели смо да имплементирамо Заббик са циљем да заменимо постојећи зоо разним алатима и доведемо надзор инфраструктуре у информативнији, потпунији и логичнији облик. Причаћемо о коришћењу Заббик-а за праћење ДФС репликације.

Пре свега, морамо да одлучимо које податке о ДФС репликацији треба да добијемо да бисмо пратили њен статус. Најрелевантнији индикатор је заостатак. Садржи датотеке које нису синхронизоване са другим члановима групе за репликацију. Можете видети његову величину помоћу услужног програма дфсрдиаг, инсталиран са улогом ДФСР. У нормалном стању репликације, величина заостатка би требало да се приближи нули. Сходно томе, велики број датотека у заостатку указује на проблеме са репликацијом.

Сада о практичној страни питања.

Да бисмо пратили величину заосталих предмета преко Заббик агента, требаће нам:

• Скрипта која ће анализирати излаз дфсрдиаг да Заббик-у обезбеди коначне вредности величине заосталих предмета,
• Скрипта која ће одредити колико група за репликацију има на серверу, које фасцикле реплицирају и који други сервери су укључени у њих (не желимо да све ово уносимо ручно у Заббик за сваки сервер, зар не?),
• Додавање ових скрипти као УсерПараметер у конфигурацију Заббик агента за накнадно позивање са сервера за надгледање,
• Покретање услуге Заббик агента као корисника који има права да чита заостале ствари,
• Шаблон за Заббик, у којем ће бити конфигурисано откривање група, обрада примљених података и издавање упозорења о њима.

Парсер скрипти

Да бих написао парсер, изабрао сам ВБС као најуниверзалнији језик присутан у свим верзијама Виндовс Сервера. Логика скрипте је једноставна: преко командне линије прима име групе за репликацију, реплицирану фасциклу и имена сервера за слање и примање. Ови параметри се затим прослеђују на дфсрдиаг, и у зависности од свог излаза производи:
Број датотека - ако се прими порука о присуству датотека у заостатку,
0 — ако је примљена порука о одсуству датотека у заостатку („Нема заостатака“),
-1 - ако је примљена порука о грешци дфсрдиаг приликом извршавања захтева („[ГРЕШКА]“).

гет-Бацклог.вбс

strReplicationGroup=WScript.Arguments.Item(0)
strReplicatedFolder=WScript.Arguments.Item(1)
strSending=WScript.Arguments.Item(2)
strReceiving=WScript.Arguments.Item(3)

Set WshShell = CreateObject ("Wscript.shell")
Set objExec = WSHshell.Exec("dfsrdiag.exe Backlog /RGName:""" & strReplicationGroup & """ /RFName:""" & strReplicatedFolder & """ /SendingMember:" & strSending & " /ReceivingMember:" & strReceiving)
strResult = ""
Do While Not objExec.StdOut.AtEndOfStream
	strResult = strResult & objExec.StdOut.ReadLine() & "\"
Loop

If InStr(strResult, "No Backlog") > 0 then
	intBackLog = 0
ElseIf  InStr(strResult, "[ERROR]") > 0 Then
    intBackLog = -1
Else
	arrLines = Split(strResult, "\")
	arrResult = Split(arrLines(1), ":")
	intBackLog = arrResult(1)
End If

WScript.echo intBackLog

Дисцовери сцрипт

Да би Заббик одредио све групе репликације присутне на серверу и да би сазнао све параметре потребне за захтев (име фасцикле, имена суседних сервера), морамо, прво, да добијемо ове информације, а друго, да их представимо у формату разумљивом Заббик-у. Формат који алатка за откривање разуме изгледа овако:

        "data":[
                {
                        "{#GROUP}":"Share1",
                        "{#FOLDER}":"Folder1",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"Server2"}

...

                        "{#GROUP}":"ShareN",
                        "{#FOLDER}":"FolderN",
                        "{#SENDING}":"Server1",
                        "{#RECEIVING}":"ServerN"}]}

Најлакши начин да добијемо информације које нас занимају је преко ВМИ-а, извлачећи их из одговарајућих одељака ДфсрРеплицатионГроупЦонфиг. Као резултат тога, рођена је скрипта која генерише захтев за ВМИ и даје листу група, њихових фасцикли и сервера у потребном формату.

ДФСРДисцовери.вбс

dim strComputer, strLine, n, k, i

Set wshNetwork = WScript.CreateObject( "WScript.Network" )
strComputer = wshNetwork.ComputerName

Set oWMIService = GetObject("winmgmts:\" & strComputer & "rootMicrosoftDFS")
Set colRGroups = oWMIService.ExecQuery("SELECT * FROM DfsrReplicationGroupConfig")
wscript.echo "{"
wscript.echo "        ""data"":["
n=0
k=0
i=0
For Each oGroup in colRGroups
  n=n+1
  Set colRGFolders = oWMIService.ExecQuery("SELECT * FROM DfsrReplicatedFolderConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
  For Each oFolder in colRGFolders
    k=k+1
    Set colRGConnections = oWMIService.ExecQuery("SELECT * FROM DfsrConnectionConfig WHERE ReplicationGroupGUID='" & oGroup.ReplicationGroupGUID & "'")
    For Each oConnection in colRGConnections
      i=i+1
      binInbound = oConnection.Inbound
      strPartner = oConnection.PartnerName
      strRGName = oGroup.ReplicationGroupName
      strRFName = oFolder.ReplicatedFolderName
      If oConnection.Enabled = True and binInbound = False Then
        strSendingComputer = strComputer
        strReceivingComputer = strPartner
        strLine1="                {"    
        strLine2="                        ""{#GROUP}"":""" & strRGName & """," 
        strLine3="                        ""{#FOLDER}"":""" & strRFName & """," 
        strLine4="                        ""{#SENDING}"":""" & strSendingComputer & ""","                  
        if (n < colRGroups.Count) or (k < colRGFolders.count) or (i < colRGConnections.Count) then
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """},"
        else
          strLine5="                        ""{#RECEIVING}"":""" & strReceivingComputer & """}]}"       
        end if		
        wscript.echo strLine1
        wscript.echo strLine2
        wscript.echo strLine3
        wscript.echo strLine4
        wscript.echo strLine5	   
      End If
    Next
  Next
Next

Слажем се, скрипта можда не блиста елеганцијом кода и неке ствари у њој би се свакако могле поједноставити, али обавља своју главну функцију - пружа информације о параметрима група репликације у формату разумљивом Заббик-у.

Додавање скрипти у конфигурацију Заббик агента

Овде је све крајње једноставно. Додајте следеће редове на крај конфигурационе датотеке агента:

UserParameter=check_dfsr[*],cscript /nologo "C:Program FilesZabbix Agentget-Backlog.vbs" $1 $2 $3 $4
UserParameter=discovery_dfsr[*],cscript /nologo "C:Program FilesZabbix AgentDFSRDiscovery.vbs"

Наравно, путање прилагођавамо онима где имамо скрипте. Ставио сам их у исту фасциклу у којој је инсталиран агент.

Након што извршите измене, поново покрените услугу Заббик агента.

Промена корисника под којим се покреће услуга Заббик Агент

Да бисте добили информације преко дфсрдиаг, услужни програм мора бити покренут под налогом који има административна права и за слање и за пријем чланова групе за репликацију. Услуга Заббик агента, која подразумевано ради под системским налогом, неће моћи да изврши такав захтев. Направио сам посебан налог у домену, дао му административна права на неопходним серверима и конфигурисао услугу да ради под њим на овим серверима.

Можете ићи другим путем: јер дфсрдиаг, у ствари, ради кроз исти ВМИ, онда можете користити Опис, како налогу домена дати права да га користи без издавања административних права, али ако имамо много група за репликацију, онда ће издавање права свакој групи бити тешко. Међутим, у случају да желимо да надгледамо репликацију волумена доменског система на контролерима домена, ово може бити једина прихватљива опција, пошто давање администраторских права домена налогу услуге надгледања није добра идеја.

Шаблон за праћење

На основу података које сам добио, направио сам шаблон који:

• Покреће аутоматско откривање група репликације једном на сат,
• Проверава величину заосталих предмета за сваку групу сваких 5 минута,
• Садржи окидач који издаје упозорење када је величина заостатка за било коју групу већа од 100 током 30 минута. Окидач је описан као прототип који се аутоматски додаје откривеним групама,
• Прави графиконе величине заостатака за сваку групу репликације.

Можете преузети шаблон за Заббик 2.2 овде.

Укупан

Након увоза шаблона у Заббик и креирања налога са потребним правима, биће нам потребно само да копирамо скрипте на сервере датотека које желимо да надгледамо за ДФСР, додамо две линије у конфигурацију агента на њима и поново покренемо услугу Заббик агента , постављајући га да ради као жељени налог. За праћење ДФСР-а нису потребна никаква друга ручна подешавања.

Извор: ввв.хабр.цом