Matsatsi a phomolo a monate ho bohle. Sehlooho sena se betere
Ka kakaretso, molao-motheo oa ts'ebetso ha o so fetohe, phapang feela ke hore hona joale e sebetsa hang-hang ntle le tieho.
Re kenya sengoloa ho Mikrotik, re fetole BotID le ChatID hore e be tsa rona mme re iketsetse kemiso ea eona. Beha paramethara ea "Nako ea ho Qala" ho qala (Matha sengoloa qalong.)
"Nako": 00:00:00
Ho seng joalo tsohle li joalo ka ha li ne li le joalo.
Telegram-v2
:delay 10
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;
:local chatId 0;
:local messageId 0;
:local parse do={
:local startLoc ([:find $content $variable -1] + [:len $variable] + 2);
:local commaLoc ([:find $content "," $startLoc] - 1 + 1);
:local braceLoc ([:find $content "}" $startLoc] - 1 + 1);
:local endLoc $commaLoc;
:local startSymbol [:pick $content $startLoc]
:if ($braceLoc != 0 and ($commaLoc = 0 or $braceLoc < $commaLoc)) do={
:set endLoc $braceLoc;
};
:if ($startSymbol = "{") do={
:set endLoc ($braceLoc + 1);
};
:if ($quotas = true) do={
:set startLoc ($startLoc + 1);
:set endLoc ($endLoc - 1);
}
:if ($endLoc < $startLoc) do={
:set endLoc ($startLoc + 1);
};
:local message [:pick $content $startLoc $endLoc]
#:log info $message;
:return $message;
}
:while ( true ) do={
:do {
#:log info "https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60";
:tool fetch url=("https://api.telegram.org/$botID/getUpdates?offset=$messageId&limit=1&allowed_updates=message&timeout=60") dst-path="getUpdates";
:local content [/file get [/file find name=getUpdates] contents] ;
#:log info $content;
:if ([:len $content] > 30) do={
:set messageId ([$parse content=$content variable="update_id"] + 1)
:local message [$parse content=$content variable="text" quotas=true]
:local chat [$parse content=$content variable="chat"]
:local chatId [$parse content=$chat variable="id"]
:if (($chatId = $myChatID) and ([/system script find name=$message] != "")) do={
:system script run $message;
} else={
:tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$chatId&text=$mtIdentity: Unknown command: $message") keep-result=no
}
}
} on-error={}
};
Ka mor'a lilemo tse 'maloa tsa tšebeliso, kokoana e ile ea fumanoa: ka mabaka a sa tsejoeng, Mikrotik e fokolang e emisa script, empa ho ba matla le ho feta e sebetsa ntle le ho emisa.
Bakeng sa merero ena, ke ile ka lahlela crutch ea WatchDog. Mona re fetola lebitso la script ho le bontšitsoeng ka holimo. 'me u behe nako ea ho qala bocha ho metsotso e 5. Metsotso e meng le e meng e 5 "balebeli" ba rona ba tla hlahloba sengoloa 'me haeba se sa sebetse, se tla se tsamaisa.
WatchDogT.me
:global scriptname "t.me"
:if ([:len [/system script job find script=$"scriptname"]] > 0) do={
:log info "$scriptname Already Running - killing old script before continuing"
:foreach counter in=[/system script job find script=$"scriptname"] do={
/system script job remove $counter
}
}
/system script run $scriptname
Ha e le hantle, bakeng sa lijo tse theolelang, sengoloa se nkiloe sebokeng sa Mikrotik.
E romella lihlooho tsa bohlokoa ho tloha ho log ho ea kariking ea rona.
Re eketsa sengoloa ho hlophisa le ho hlakisa nako ea ho qala bocha metsotso e meng le e meng e 5, fetola BotID le ChatID hore e be tsa rona.
Tsebisa-log
:global lastTime
:global output
:global mtIdentity [/system identity get name];
:global botID "botXXXXXXXXX:XXXXXXXXXXXXXXXXXXXXXXXXX" ;
:global myChatID "YYYYYY" ;
:local LogGet [ :toarray [ /log find topics~"critical" || message~"login failure" || message~"[Ff]ailure" ] ] ;
:local LogtLineCount [ :len $LogGet ] ;
if ($LogtLineCount > 0) do={
:local currentTime "$[ /log get [ :pick $LogGet ($LogtLineCount -1) ] time ]";
:if ([:len $currentTime] = 10 ) do={
:set currentTime [ :pick $currentTime 0 10 ];
}
:set output "$currentTime - $[/log get [ :pick $LogGet ($LogtLineCount-1) ] message ]";
:if (([:len $lastTime] < 1) || (([:len $lastTime] > 0) && ($lastTime != $currentTime))) do={
:set lastTime $currentTime ;
:tool fetch url=("https://api.telegram.org/$botID/sendmessage?chat_id=$myChatID&text="$mtIdentity" : $output") keep-result=no
}
}
Re fumana sephetho:
Source: www.habr.com