Gnuplot 5.0. Spiderplot med 4 axlar på egen hand

När jag arbetade med datavisualisering för artikeln uppstod behovet av att ha 4 axlar med positiva etiketter på alla.

Som med andra diagram i artikeln beslutade jag mig för att använda gnuplot. Först tog jag en titt på den officiella webbplatsen där det finns många exempel. Jag blev mycket glad när jag hittade den nödvändiga exempel (lite fint arbete här och där, tänkte jag).

Jag kopierade snabbt koden, körde den. Fick ett fel. Jag undersökte. Det visade sig att jag hade en gammal version av gnuplot (Version 5.0 patchlevel 3 last modified 2016-02-21) och den kan inte göra så.

Med vetskap om gnuplots flexibilitet började jag söka på nätet och stötte på några passande exempel på stackoverflow (Double x-axis on a spider plot with Gnuplot och How to Create a Spider Plot in Gnuplot?) och github (gnuplot-radarchart). De blev min utgångspunkt.

Därefter ledde mina manipulationer med kommandon till följande:

0) Stäng av gränser

unset border

1) Skapa 4 nollinjer - 2 huvudsakliga och 2 ytterligare:

set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis

Några ord om nollinjer i dokumentationen. Denna operation gör det möjligt att centrera axlarna i diagrammet. De ytterligare behövs för att visa positiva tickar.

2) Ställ in visning av tickarna på axlarna:

max = 1.5 # För flexibilitet
min = -max
set xtics  axis  0,.5,max in scale 0.5,0.25 mirror norotate  autojustify offset 0.35
set ytics  axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify            

Med tickarna på axlarna är inställningarna lite fler.
axis — där tickarna kommer att placeras, på axeln eller (border — på gränsen).
För axeln x, som går åt höger 0,.5,max. Det första talet är startpunkten, det andra är steget, det tredje är slutpunkten. För den första från 0, och för de andra från 0.5, så att nollorna inte stör i origo.

Blandning av nollor i origo.
Alla intervall *tics är inställda som 0,.5,max
Utan offset 0.35 för xtics

Inställning scale 0.5,0.25 mirror lägger till markeringar på axeln. Om man leker med siffrorna, kommer storleken på dem att förändras.
Jag introducerar också variablerna max, min, med hjälp av vilka jag styr gränserna för diagrammets axlar.
Ytterligare information om inställning av tickar kan hittas i dokumentationen i avsnittet Xtics.

3) Ställ in axlarnas intervall:

set xrange  [ min : max ] 
set yrange  [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]

Här bör man notera att 2 axlar börjar räkna från min i ökande och 2 axlar — från max i minskande.
Ytterligare information i avsnittet Xrange.

4) Vi namnger axlarna och placerar dem vackert:

set label "H_1" at  0,       max center offset char  2, 0
set label "H_2" at  max+0.1, 0   center offset char -1, 1
set label "H_3" at  0,       min center offset char -2, 0
set label "H_4" at  min,     0   center offset char  0, 1

5) Vi formar indata
Varje diagram får två kolumner. Radnumret är axelnummret, den femte raden används för att stänga konturen. Udda kolumn är koordinaten x, jämn — y. Eftersom alla punkter ligger på axlarna, så är en av paret (x, y) alltid lika med noll.
Trots att alla 4 axlar är positiva, flyttas vissa data artificiellt till den negativa halvan eftersom de ligger på huvudaxlarna x och y.

 0  1  0     1.21
 1  0  1.21  0   
 0 -1  0    -1.06
-1  0 -1.19  0   
 0  1  0     1.21 #Dublett av första punkten

Resultat

Fullständig kod

#!/usr/bin/gnuplot -persist
#файл в кодировке cp1251 чтоб русские буквы отображались в eps

set encoding cp1251
set terminal postscript eps enhanced monochrome size 5cm,5cm
set output "./img/eps/fig2.eps"

unset border
set key at -2, 1.5 font 'LiberationSerif, 23' 
set key left top samplen 4.5

set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis

max = 1.5
min = -max

set xtics  axis  0,.5,max in scale 0.5,0.25 mirror norotate  autojustify offset 0.35 font 'LiberationSerif, 20
set ytics  axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate  autojustify             font 'LiberationSerif, 20

set xrange  [ min : max ]
set yrange  [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]

set label "H_1" at  0,       max center offset char  2, 0   font 'LiberationSerif, 23'
set label "H_2" at  max+0.1, 0   center offset char -1, 1   font 'LiberationSerif, 23'
set label "H_3" at  0,       min center offset char -2, 0   font 'LiberationSerif, 23'
set label "H_4" at  min,     0   center offset char  0, 1   font 'LiberationSerif, 23'

set style line 1 linetype 1 pointtype 7 linewidth 3 linecolor black
set style line 2 linetype 2 pointtype 7 linewidth 3 linecolor black

plot 'data.csv' using  1:2 title "1" w lp ls 1 ,
     'data.csv' using  3:4 title "2" w lp ls 2

Källa: habr.com