ప్రోహోస్టర్ > బ్లాగ్ > పరిపాలన > ఇండస్ట్రియల్ నింజా అడుగుజాడల్లో: పాజిటివ్ హ్యాక్ డేస్ 9లో PLC ఎలా హ్యాక్ చేయబడింది

ఇండస్ట్రియల్ నింజా అడుగుజాడల్లో: పాజిటివ్ హ్యాక్ డేస్ 9లో PLC ఎలా హ్యాక్ చేయబడింది

ఇండస్ట్రియల్ నింజా అడుగుజాడల్లో: పాజిటివ్ హ్యాక్ డేస్ 9లో PLC ఎలా హ్యాక్ చేయబడింది

గత PHDays 9 వద్ద మేము గ్యాస్ పంపింగ్ ప్లాంట్‌ను హ్యాక్ చేయడానికి పోటీని నిర్వహించాము - పోటీ పారిశ్రామిక నింజా. ఒకే పారిశ్రామిక ప్రక్రియను అనుకరిస్తూ వేర్వేరు భద్రతా పారామితులతో (భద్రత లేదు, తక్కువ భద్రత, అధిక భద్రత) సైట్‌లో మూడు స్టాండ్‌లు ఉన్నాయి: ఒత్తిడిలో ఉన్న గాలిని బెలూన్‌లోకి పంప్ చేయబడింది (తర్వాత విడుదల చేయబడింది).

వివిధ భద్రతా పారామితులు ఉన్నప్పటికీ, స్టాండ్‌ల హార్డ్‌వేర్ కూర్పు ఒకే విధంగా ఉంటుంది: సిమెన్స్ సిమాటిక్ PLC S7-300 సిరీస్; అత్యవసర ప్రతి ద్రవ్యోల్బణం బటన్ మరియు ఒత్తిడిని కొలిచే పరికరం (PLC డిజిటల్ ఇన్‌పుట్‌లకు (DI) కనెక్ట్ చేయబడింది); గాలి యొక్క ద్రవ్యోల్బణం మరియు ప్రతి ద్రవ్యోల్బణం కోసం పనిచేసే కవాటాలు (PLC (DO) యొక్క డిజిటల్ అవుట్‌పుట్‌లకు కనెక్ట్ చేయబడ్డాయి) - దిగువ బొమ్మను చూడండి.

ఇండస్ట్రియల్ నింజా అడుగుజాడల్లో: పాజిటివ్ హ్యాక్ డేస్ 9లో PLC ఎలా హ్యాక్ చేయబడింది

PLC, ఒత్తిడి రీడింగ్‌లను బట్టి మరియు దాని ప్రోగ్రామ్‌కు అనుగుణంగా, బంతిని తగ్గించడానికి లేదా పెంచడానికి నిర్ణయం తీసుకుంది (సంబంధిత కవాటాలను తెరిచి మూసివేయబడింది). అయితే, అన్ని స్టాండ్‌లు మాన్యువల్ కంట్రోల్ మోడ్‌ను కలిగి ఉన్నాయి, ఇది ఎటువంటి పరిమితులు లేకుండా కవాటాల స్థితులను నియంత్రించడం సాధ్యం చేసింది.

ఈ మోడ్‌ను ప్రారంభించే సంక్లిష్టతలో స్టాండ్‌లు విభిన్నంగా ఉన్నాయి: అసురక్షిత స్టాండ్‌లో దీన్ని చేయడం చాలా సులభం మరియు హై సెక్యూరిటీ స్టాండ్‌లో తదనుగుణంగా మరింత కష్టం.

ఆరు సమస్యలలో ఐదు రెండు రోజుల్లో పరిష్కరించబడ్డాయి; మొదటి స్థానంలో పాల్గొనే వ్యక్తి 233 పాయింట్లను సంపాదించాడు (అతను పోటీకి సిద్ధమవుతున్న ఒక వారం గడిపాడు). ముగ్గురు విజేతలు: నేను స్థానం - a1exdandy, II - Rubikoid, III - Ze.

అయితే, PHDays సమయంలో, పాల్గొనేవారిలో ఎవరూ మూడు స్టాండ్‌లను అధిగమించలేకపోయారు, కాబట్టి మేము ఆన్‌లైన్ పోటీని నిర్వహించాలని నిర్ణయించుకున్నాము మరియు జూన్ ప్రారంభంలో అత్యంత కష్టమైన పనిని ప్రచురించాము. పాల్గొనేవారు ఒక నెలలోపు పనిని పూర్తి చేయాలి, జెండాను కనుగొని, పరిష్కారాన్ని వివరంగా మరియు ఆసక్తికరమైన రీతిలో వివరించాలి.

కట్ క్రింద మేము నెలలో పంపిన వారి నుండి పనికి ఉత్తమ పరిష్కారం యొక్క విశ్లేషణను ప్రచురిస్తాము, ఇది డిజిటల్ సెక్యూరిటీ కంపెనీకి చెందిన అలెక్సీ కోవ్రిజ్నిఖ్ (a1exdandy) ద్వారా కనుగొనబడింది, అతను PHDays సమయంలో పోటీలో XNUMX వ స్థానంలో నిలిచాడు. క్రింద మేము మా వ్యాఖ్యలతో దాని వచనాన్ని ప్రదర్శిస్తాము.

ప్రారంభ విశ్లేషణ

కాబట్టి, టాస్క్ కింది ఫైల్‌లతో కూడిన ఆర్కైవ్‌ను కలిగి ఉంది:

  • block_upload_traffic.pcapng
  • DB100.బిన్
  • సూచనలు.txt

hints.txt ఫైల్ పనిని పరిష్కరించడానికి అవసరమైన సమాచారం మరియు సూచనలను కలిగి ఉంది. దాని కంటెంట్‌లు ఇక్కడ ఉన్నాయి:

  1. మీరు PlcSim నుండి Step7లోకి బ్లాక్‌లను లోడ్ చేయవచ్చని పెట్రోవిచ్ నిన్న నాకు చెప్పారు.
  2. సిమెన్స్ సిమాటిక్ S7-300 సిరీస్ PLC స్టాండ్‌లో ఉపయోగించబడింది.
  3. PlcSim అనేది సిమెన్స్ S7 PLCల కోసం ప్రోగ్రామ్‌లను అమలు చేయడానికి మరియు డీబగ్ చేయడానికి మిమ్మల్ని అనుమతించే PLC ఎమ్యులేటర్.

DB100.bin ఫైల్ DB100 PLC డేటా బ్లాక్‌ను కలిగి ఉన్నట్లు కనిపిస్తోంది: 00000000: 0100 0102 6e02 0401 0206 0100 0101 0102 ....n......... 00000010: 1002 0501 0202 2002 ..... ......... 0501: 0206 0100 0102 00000020 0102 7702 0401 0206a0100 ..w............. 0103: 0102 0 02 00000030 0501 0202 1602 ................ 0501: 0206 0100 0104 0102 00000040 7502 0401a0206 0100 u............ 0105: 0102 0 02 0501 00000050 0202 1602 0501............0206. 0100: 0106 0102 3402 4 00000060 0401 0206 0100 .........&..... 0107: 0102c2602 0501 0202 00000070 4 02 : 0501 0206 0100 0108 0102a3302 0401 3 00000080 ................ 0206: 0100 0109 0102 0a 02 0501 0202 1602 ....00000090. 0501a0206: 0100 010b 0102 3702 0401 0206 7 000000 ...".....F... 0b0100: 010 0102 2202c 0501 0202 4602 0501........ 000000........ .. 0c0206: 0100d 010 0102a3302 0401 0206 0100 3 000000 ................ 0d010: 0102 0e 02 0501d0202 1602 0501 0206 .... 000000e0: 0100 010 0102 6 02 0401 0206 0100 ........#...... 010f000000: 0 0102 1102 0501 0202 2302.....0501 ..... 0206: 0100 000000 0 0110 0102 3502 0401 0206 ......%......... 0100: 0111 0102 5 00000100 1202 0501.. 0202 2502. .....&. 0501: 0206 0100 0112c00000110 0102 3302 0401 ....L......

పేరు సూచించినట్లుగా, block_upload_traffic.pcapng ఫైల్ PLCకి బ్లాక్ అప్‌లోడ్ ట్రాఫిక్ యొక్క డంప్‌ను కలిగి ఉంది.

కాన్ఫరెన్స్ సమయంలో పోటీ సైట్ వద్ద ఈ ట్రాఫిక్ డంప్ పొందడం కొంచెం కష్టమని గమనించాలి. దీన్ని చేయడానికి, TeslaSCADA2 కోసం ప్రాజెక్ట్ ఫైల్ నుండి స్క్రిప్ట్‌ను అర్థం చేసుకోవడం అవసరం. దాని నుండి RC4ని ఉపయోగించి గుప్తీకరించిన డంప్ ఎక్కడ ఉందో మరియు దానిని డీక్రిప్ట్ చేయడానికి ఏ కీని ఉపయోగించాలో అర్థం చేసుకోవడం సాధ్యమైంది. సైట్‌లోని డేటా బ్లాక్‌ల డంప్‌లను S7 ప్రోటోకాల్ క్లయింట్ ఉపయోగించి పొందవచ్చు. దీని కోసం నేను Snap7 ప్యాకేజీ నుండి డెమో క్లయింట్‌ని ఉపయోగించాను.

ట్రాఫిక్ డంప్ నుండి సిగ్నల్ ప్రాసెసింగ్ బ్లాక్‌లను సంగ్రహించడం

డంప్‌లోని కంటెంట్‌లను చూస్తే, ఇది OB1, FC1, FC2 మరియు FC3 అనే సిగ్నల్ ప్రాసెసింగ్ బ్లాక్‌లను కలిగి ఉందని మీరు అర్థం చేసుకోవచ్చు:

ఇండస్ట్రియల్ నింజా అడుగుజాడల్లో: పాజిటివ్ హ్యాక్ డేస్ 9లో PLC ఎలా హ్యాక్ చేయబడింది

ఈ బ్లాక్‌లను తొలగించాలి. మునుపు pcapng ఫార్మాట్ నుండి pcapకి ట్రాఫిక్‌ను మార్చిన తర్వాత, ఉదాహరణకు, కింది స్క్రిప్ట్‌తో ఇది చేయవచ్చు:

#!/usr/bin/env python2

import struct
from scapy.all import *

packets = rdpcap('block_upload_traffic.pcap')
s7_hdr_struct = '>BBHHHHBB'
s7_hdr_sz = struct.calcsize(s7_hdr_struct)
tpkt_cotp_sz = 7
names = iter(['OB1.bin', 'FC1.bin', 'FC2.bin', 'FC3.bin'])
buf = ''

for packet in packets:
    if packet.getlayer(IP).src == '10.0.102.11':
        tpkt_cotp_s7 = str(packet.getlayer(TCP).payload)
        if len(tpkt_cotp_s7) < tpkt_cotp_sz + s7_hdr_sz:
            continue
        s7 = tpkt_cotp_s7[tpkt_cotp_sz:]
        s7_hdr = s7[:s7_hdr_sz]
        param_sz = struct.unpack(s7_hdr_struct, s7_hdr)[4]
        s7_param = s7[12:12+param_sz]
        s7_data = s7[12+param_sz:]
        if s7_param in ('x1ex00', 'x1ex01'):  # upload
            buf += s7_data[4:]
        elif s7_param == 'x1f':
            with open(next(names), 'wb') as f:
                f.write(buf)
            buf = ''

ఫలిత బ్లాక్‌లను పరిశీలించిన తర్వాత, అవి ఎల్లప్పుడూ బైట్‌లు 70 70 (pp)తో ప్రారంభమవుతాయని మీరు గమనించవచ్చు. ఇప్పుడు మీరు వాటిని ఎలా విశ్లేషించాలో నేర్చుకోవాలి. దీని కోసం మీరు PlcSimని ఉపయోగించాలని అసైన్‌మెంట్ సూచన సూచిస్తుంది.

బ్లాక్‌ల నుండి మానవులు చదవగలిగే సూచనలను పొందడం

ముందుగా, S7-PlcSimని సిమాటిక్ మేనేజర్ సాఫ్ట్‌వేర్‌ని ఉపయోగించి పునరావృత సూచనలతో (= Q 0.0) అనేక బ్లాక్‌లను లోడ్ చేయడం ద్వారా మరియు ఎమ్యులేటర్‌లో పొందిన PLCని example.plc ఫైల్‌లో సేవ్ చేయడం ద్వారా ప్రోగ్రామ్ చేయడానికి ప్రయత్నిద్దాం. ఫైల్ యొక్క కంటెంట్‌లను చూడటం ద్వారా, మేము ముందుగా కనుగొన్న సంతకం 70 70 ద్వారా డౌన్‌లోడ్ చేయబడిన బ్లాక్‌ల ప్రారంభాన్ని మీరు సులభంగా నిర్ణయించవచ్చు. బ్లాక్‌ల ముందు, స్పష్టంగా, బ్లాక్ పరిమాణం 4-బైట్ లిటిల్-ఎండియన్ విలువగా వ్రాయబడింది.

ఇండస్ట్రియల్ నింజా అడుగుజాడల్లో: పాజిటివ్ హ్యాక్ డేస్ 9లో PLC ఎలా హ్యాక్ చేయబడింది

మేము plc ఫైల్‌ల నిర్మాణం గురించి సమాచారాన్ని స్వీకరించిన తర్వాత, PLC S7 ప్రోగ్రామ్‌లను చదవడానికి క్రింది కార్యాచరణ ప్రణాళిక కనిపించింది:

  1. సిమాటిక్ మేనేజర్‌ని ఉపయోగించి, మేము డంప్ నుండి అందుకున్న మాదిరిగానే S7-PlcSimలో బ్లాక్ నిర్మాణాన్ని సృష్టిస్తాము. బ్లాక్ పరిమాణాలు తప్పనిసరిగా సరిపోలాలి (అవసరమైన సూచనల సంఖ్యతో బ్లాక్‌లను పూరించడం ద్వారా ఇది సాధించబడుతుంది) మరియు వాటి ఐడెంటిఫైయర్‌లు (OB1, FC1, FC2, FC3).
  2. PLCని ఫైల్‌కి సేవ్ చేయండి.
  3. మేము ఫలితంగా ఫైల్‌లోని బ్లాక్‌ల కంటెంట్‌లను ట్రాఫిక్ డంప్ నుండి బ్లాక్‌లతో భర్తీ చేస్తాము. బ్లాక్‌ల ప్రారంభం సంతకం ద్వారా నిర్ణయించబడుతుంది.
  4. మేము ఫలిత ఫైల్‌ను S7-PlcSim లోకి లోడ్ చేస్తాము మరియు సిమాటిక్ మేనేజర్‌లోని బ్లాక్‌ల కంటెంట్‌లను చూస్తాము.

బ్లాక్‌లను భర్తీ చేయవచ్చు, ఉదాహరణకు, కింది కోడ్‌తో:

with open('original.plc', 'rb') as f:
    plc = f.read()
blocks = []
for fname in ['OB1.bin', 'FC1.bin', 'FC2.bin', 'FC3.bin']:
    with open(fname, 'rb') as f:
        blocks.append(f.read())

i = plc.find(b'pp')
for block in blocks:
    plc = plc[:i] + block + plc[i+len(block):]
    i = plc.find(b'pp', i + 1)

with open('target.plc', 'wb') as f:
    f.write(plc)

అలెక్సీ బహుశా మరింత కష్టతరమైన, కానీ ఇప్పటికీ సరైన మార్గాన్ని తీసుకున్నాడు. పాల్గొనేవారు NetToPlcSim ప్రోగ్రామ్‌ను ఉపయోగిస్తారని మేము ఊహించాము, తద్వారా PlcSim నెట్‌వర్క్ ద్వారా కమ్యూనికేట్ చేయగలదు, Snap7 ద్వారా PlcSimకు బ్లాక్‌లను అప్‌లోడ్ చేసి, అభివృద్ధి వాతావరణాన్ని ఉపయోగించి PlcSim నుండి ప్రాజెక్ట్‌గా ఈ బ్లాక్‌లను డౌన్‌లోడ్ చేసుకోవచ్చు.

ఫలితంగా ఫైల్‌ని S7-PlcSimలో తెరవడం ద్వారా, మీరు సిమాటిక్ మేనేజర్‌ని ఉపయోగించి ఓవర్‌రైట్ చేసిన బ్లాక్‌లను చదవవచ్చు. ప్రధాన పరికర నియంత్రణ విధులు బ్లాక్ FC1లో నమోదు చేయబడ్డాయి. ప్రత్యేకించి గమనించదగినది #TEMP0 వేరియబుల్, ఇది ఆన్ చేసినప్పుడు M2.2 మరియు M2.3 బిట్ మెమరీ విలువల ఆధారంగా PLC నియంత్రణను మాన్యువల్ మోడ్‌కు సెట్ చేసినట్లు కనిపిస్తుంది. #TEMP0 విలువ ఫంక్షన్ FC3 ద్వారా సెట్ చేయబడింది.

ఇండస్ట్రియల్ నింజా అడుగుజాడల్లో: పాజిటివ్ హ్యాక్ డేస్ 9లో PLC ఎలా హ్యాక్ చేయబడింది

సమస్యను పరిష్కరించడానికి, మీరు FC3 ఫంక్షన్‌ను విశ్లేషించి, ఏమి చేయాలో అర్థం చేసుకోవాలి, తద్వారా ఇది లాజికల్‌గా వస్తుంది.

పోటీ సైట్‌లోని తక్కువ సెక్యూరిటీ స్టాండ్‌లోని PLC సిగ్నల్ ప్రాసెసింగ్ బ్లాక్‌లు ఇదే విధంగా అమర్చబడ్డాయి, అయితే #TEMP0 వేరియబుల్ విలువను సెట్ చేయడానికి, DB1 బ్లాక్‌లో నా నింజా మార్గంలో లైన్‌ను వ్రాస్తే సరిపోతుంది. బ్లాక్‌లో విలువను తనిఖీ చేయడం సూటిగా ఉంటుంది మరియు బ్లాక్ ప్రోగ్రామింగ్ లాంగ్వేజ్ గురించి లోతైన జ్ఞానం అవసరం లేదు. సహజంగానే, హై సెక్యూరిటీ స్థాయిలో, మాన్యువల్ నియంత్రణను సాధించడం చాలా కష్టంగా ఉంటుంది మరియు STL భాష యొక్క చిక్కులను అర్థం చేసుకోవడం అవసరం (S7 PLCని ప్రోగ్రామ్ చేయడానికి మార్గాలలో ఒకటి).

రివర్స్ బ్లాక్ FC3

STL ప్రాతినిధ్యంలో FC3 బ్లాక్ యొక్క కంటెంట్‌లు:

      L     B#16#0
      T     #TEMP13
      T     #TEMP15
      L     P#DBX 0.0
      T     #TEMP4
      CLR   
      =     #TEMP14
M015: L     #TEMP4
      LAR1  
      OPN   DB   100
      L     DBLG
      TAR1  
      <=D   
      JC    M016
      L     DW#16#0
      T     #TEMP0
      L     #TEMP6
      L     W#16#0
      <>I   
      JC    M00d
      L     P#DBX 0.0
      LAR1  
M00d: L     B [AR1,P#0.0]
      T     #TEMP5
      L     W#16#1
      ==I   
      JC    M007
      L     #TEMP5
      L     W#16#2
      ==I   
      JC    M008
      L     #TEMP5
      L     W#16#3
      ==I   
      JC    M00f
      L     #TEMP5
      L     W#16#4
      ==I   
      JC    M00e
      L     #TEMP5
      L     W#16#5
      ==I   
      JC    M011
      L     #TEMP5
      L     W#16#6
      ==I   
      JC    M012
      JU    M010
M007: +AR1  P#1.0
      L     P#DBX 0.0
      LAR2  
      L     B [AR1,P#0.0]
      L     C#8
      *I    
      +AR2  
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M003
      JU    M001
      JU    M002
      JU    M004
M003: JU    M005
M001: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP0
      JU    M006
M002: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP1
      JU    M006
M004: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #TEMP2
      JU    M006
M00f: +AR1  P#1.0
      L     B [AR1,P#0.0]
      L     C#8
      *I    
      T     #TEMP11
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      TAR1  #TEMP4
      OPN   DB   101
      L     P#DBX 0.0
      LAR1  
      L     #TEMP11
      +AR1  
      LAR2  #TEMP9
      L     B [AR2,P#0.0]
      T     B [AR1,P#0.0]
      L     #TEMP4
      LAR1  
      JU    M006
M008: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP3
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M009
      JU    M00b
      JU    M00a
      JU    M00c
M009: JU    M005
M00b: L     #TEMP3
      T     #TEMP0
      JU    M006
M00a: L     #TEMP3
      T     #TEMP1
      JU    M006
M00c: L     #TEMP3
      T     #TEMP2
      JU    M006
M00e: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      AW    
      INVI  
      T     #TEMP12
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      OW    
      L     #TEMP12
      AW    
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #TEMP0
      L     MB   101
      T     #TEMP1
      L     MB   102
      T     #TEMP2
      L     #TEMP4
      LAR1  
      JU    M006
M011: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      -I    
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #TEMP0
      L     MB   101
      T     #TEMP1
      L     MB   102
      T     #TEMP2
      L     #TEMP4
      LAR1  
      JU    M006
M012: L     #TEMP15
      INC   1
      T     #TEMP15
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10
      TAR1  #TEMP4
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      ==I   
      JCN   M013
      JU    M014
M013: L     P#DBX 0.0
      LAR1  
      T     #TEMP4
      L     B#16#0
      T     #TEMP6
      JU    M006
M014: L     #TEMP4
      LAR1  
      L     #TEMP13
      L     L#1
      +I    
      T     #TEMP13
      JU    M006
M006: L     #TEMP0
      T     MB   100
      L     #TEMP1
      T     MB   101
      L     #TEMP2
      T     MB   102
      +AR1  P#1.0
      L     #TEMP6
      +     1
      T     #TEMP6
      JU    M005
M010: L     P#DBX 0.0
      LAR1  
      L     0
      T     #TEMP6
      TAR1  #TEMP4
M005: TAR1  #TEMP4
      CLR   
      =     #TEMP16
      L     #TEMP13
      L     L#20
      ==I   
      S     #TEMP16
      L     #TEMP15
      ==I   
      A     #TEMP16
      JC    M017
      L     #TEMP13
      L     L#20
      <I    
      S     #TEMP16
      L     #TEMP15
      ==I   
      A     #TEMP16
      JC    M018
      JU    M019
M017: SET   
      =     #TEMP14
      JU    M016
M018: CLR   
      =     #TEMP14
      JU    M016
M019: CLR   
      O     #TEMP14
      =     #RET_VAL
      JU    M015
M016: CLR   
      O     #TEMP14
      =     #RET_VAL

కోడ్ చాలా పొడవుగా ఉంది మరియు STL గురించి తెలియని వారికి సంక్లిష్టంగా అనిపించవచ్చు. ఈ కథనం యొక్క ఫ్రేమ్‌వర్క్‌లో ప్రతి సూచనను విశ్లేషించడంలో అర్థం లేదు; STL భాష యొక్క వివరణాత్మక సూచనలు మరియు సామర్థ్యాలను సంబంధిత మాన్యువల్‌లో చూడవచ్చు: S7-300 మరియు S7-400 ప్రోగ్రామింగ్ కోసం స్టేట్‌మెంట్ జాబితా (STL).. ఇక్కడ నేను ప్రాసెస్ చేసిన తర్వాత అదే కోడ్‌ని ప్రదర్శిస్తాను - లేబుల్‌లు మరియు వేరియబుల్స్ పేరు మార్చడం మరియు ఆపరేషన్ అల్గోరిథం మరియు కొన్ని STL భాషా నిర్మాణాలను వివరించే వ్యాఖ్యలను జోడించడం. సందేహాస్పద బ్లాక్ DB100 బ్లాక్‌లో ఉన్న కొంత బైట్‌కోడ్‌ను అమలు చేసే వర్చువల్ మెషీన్‌ను కలిగి ఉందని నేను వెంటనే గమనించాను, దానిలోని విషయాలు మనకు తెలుసు. వర్చువల్ మెషీన్ సూచనలు 1 బైట్ ఆపరేటింగ్ కోడ్ మరియు బైట్‌ల ఆర్గ్యుమెంట్‌లను కలిగి ఉంటాయి, ప్రతి ఆర్గ్యుమెంట్‌కు ఒక బైట్. పరిగణించబడిన అన్ని సూచనలకు రెండు వాదనలు ఉన్నాయి; నేను వాటి విలువలను వ్యాఖ్యలలో X మరియు Yగా పేర్కొన్నాను.

ప్రాసెస్ చేసిన తర్వాత కోడ్] 

# Инициализация различных переменных
      L     B#16#0
      T     #CHECK_N        # Счетчик успешно пройденных проверок
      T     #COUNTER_N      # Счетчик общего количества проверок
      L     P#DBX 0.0
      T     #POINTER        # Указатель на текущую инструкцию
      CLR   
      =     #PRE_RET_VAL

# Основной цикл работы интерпретатора байт-кода
LOOP: L     #POINTER
      LAR1  
      OPN   DB   100
      L     DBLG
      TAR1  
      <=D                   # Проверка выхода указателя за пределы программы
      JC    FINISH
      L     DW#16#0
      T     #REG0
      L     #TEMP6
      L     W#16#0
      <>I   
      JC    M00d
      L     P#DBX 0.0
      LAR1  

# Конструкция switch - case для обработки различных опкодов
M00d: L     B [AR1,P#0.0]
      T     #OPCODE
      L     W#16#1
      ==I   
      JC    OPCODE_1
      L     #OPCODE
      L     W#16#2
      ==I   
      JC    OPCODE_2
      L     #OPCODE
      L     W#16#3
      ==I   
      JC    OPCODE_3
      L     #OPCODE
      L     W#16#4
      ==I   
      JC    OPCODE_4
      L     #OPCODE
      L     W#16#5
      ==I   
      JC    OPCODE_5
      L     #OPCODE
      L     W#16#6
      ==I   
      JC    OPCODE_6
      JU    OPCODE_OTHER

# Обработчик опкода 01: загрузка значения из DB101[X] в регистр Y
# OP01(X, Y): REG[Y] = DB101[X]
OPCODE_1: +AR1  P#1.0
      L     P#DBX 0.0
      LAR2  
      L     B [AR1,P#0.0]   # Загрузка аргумента X (индекс в DB101)
      L     C#8
      *I    
      +AR2  
      +AR1  P#1.0
      L     B [AR1,P#0.0]   # Загрузка аргумента Y (индекс регистра)
      JL    M003            # Аналог switch - case на основе значения Y
      JU    M001            # для выбора необходимого регистра для записи.
      JU    M002            # Подобные конструкции используются и в других
      JU    M004            # операциях ниже для аналогичных целей
M003: JU    LOOPEND
M001: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG0           # Запись значения DB101[X] в REG[0]
      JU    PRE_LOOPEND
M002: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG1           # Запись значения DB101[X] в REG[1]
      JU    PRE_LOOPEND
M004: OPN   DB   101
      L     B [AR2,P#0.0]
      T     #REG2           # Запись значения DB101[X] в REG[2]
      JU    PRE_LOOPEND

# Обработчик опкода 02: загрузка значения X в регистр Y
# OP02(X, Y): REG[Y] = X
OPCODE_2: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP3
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      JL    M009
      JU    M00b
      JU    M00a
      JU    M00c
M009: JU    LOOPEND
M00b: L     #TEMP3
      T     #REG0
      JU    PRE_LOOPEND
M00a: L     #TEMP3
      T     #REG1
      JU    PRE_LOOPEND
M00c: L     #TEMP3
      T     #REG2
      JU    PRE_LOOPEND

# Опкод 03 не используется в программе, поэтому пропустим его
...

# Обработчик опкода 04: сравнение регистров X и Y
# OP04(X, Y): REG[0] = 0; REG[X] = (REG[X] == REG[Y])
OPCODE_4: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7          # первый аргумент - X
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          # REG[X]
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9          # REG[X]
      LAR2  #TEMP10         # REG[Y]
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      AW    
      INVI  
      T     #TEMP12         # ~(REG[Y] & REG[X])
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      OW    
      L     #TEMP12
      AW                    # (~(REG[Y] & REG[X])) & (REG[Y] | REG[X]) - аналог проверки на равенство
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #REG0
      L     MB   101
      T     #REG1
      L     MB   102
      T     #REG2
      L     #POINTER
      LAR1  
      JU    PRE_LOOPEND

# Обработчик опкода 05: вычитание регистра Y из X
# OP05(X, Y): REG[0] = 0; REG[X] = REG[X] - REG[Y]
OPCODE_5: +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          # REG[X]
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9
      LAR2  #TEMP10
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      -I                    # ACCU1 = ACCU2 - ACCU1, REG[X] - REG[Y]
      T     B [AR1,P#0.0]
      L     DW#16#0
      T     #REG0
      L     MB   101
      T     #REG1
      L     MB   102
      T     #REG2
      L     #POINTER
      LAR1  
      JU    PRE_LOOPEND

# Обработчик опкода 06: инкремент #CHECK_N при равенстве регистров X и Y
# OP06(X, Y): #CHECK_N += (1 if REG[X] == REG[Y] else 0)
OPCODE_6: L     #COUNTER_N
      INC   1
      T     #COUNTER_N
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP7          #  REG[X]     
      L     P#M 100.0
      LAR2  
      L     #TEMP7
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP9          #  REG[X]  
      +AR1  P#1.0
      L     B [AR1,P#0.0]
      T     #TEMP8
      L     P#M 100.0
      LAR2  
      L     #TEMP8
      L     C#8
      *I    
      +AR2  
      TAR2  #TEMP10         # REG[Y]
      TAR1  #POINTER
      LAR1  #TEMP9          # REG[Y]
      LAR2  #TEMP10         # REG[X]
      L     B [AR1,P#0.0]
      L     B [AR2,P#0.0]
      ==I   
      JCN   M013
      JU    M014
M013: L     P#DBX 0.0
      LAR1  
      T     #POINTER
      L     B#16#0
      T     #TEMP6
      JU    PRE_LOOPEND
M014: L     #POINTER
      LAR1  
# Инкремент значения #CHECK_N
      L     #CHECK_N
      L     L#1
      +I    
      T     #CHECK_N
      JU    PRE_LOOPEND

PRE_LOOPEND: L     #REG0
      T     MB   100
      L     #REG1
      T     MB   101
      L     #REG2
      T     MB   102
      +AR1  P#1.0
      L     #TEMP6
      +     1
      T     #TEMP6
      JU    LOOPEND

OPCODE_OTHER: L     P#DBX 0.0
      LAR1  
      L     0
      T     #TEMP6
      TAR1  #POINTER

LOOPEND: TAR1  #POINTER
      CLR   
      =     #TEMP16
      L     #CHECK_N
      L     L#20
      ==I   
      S     #TEMP16
      L     #COUNTER_N
      ==I   
      A     #TEMP16
# Все проверки пройдены, если #CHECK_N == #COUNTER_N == 20
      JC    GOOD
      L     #CHECK_N
      L     L#20
      <I    
      S     #TEMP16
      L     #COUNTER_N
      ==I   
      A     #TEMP16
      JC    FAIL
      JU    M019
GOOD: SET   
      =     #PRE_RET_VAL
      JU    FINISH
FAIL: CLR   
      =     #PRE_RET_VAL
      JU    FINISH
M019: CLR   
      O     #PRE_RET_VAL
      =     #RET_VAL
      JU    LOOP
FINISH: CLR   
      O     #PRE_RET_VAL
      =     #RET_VAL

వర్చువల్ మెషీన్ సూచనల గురించి ఒక ఆలోచన వచ్చిన తర్వాత, DB100 బ్లాక్‌లో బైట్‌కోడ్‌ను అన్వయించడానికి ఒక చిన్న డిస్‌అసెంబ్లర్‌ను వ్రాద్దాం:

import string
alph = string.ascii_letters + string.digits

with open('DB100.bin', 'rb') as f:
    m = f.read()

pc = 0

while pc < len(m):
    op = m[pc]
    if op == 1:
        print('R{} = DB101[{}]'.format(m[pc + 2], m[pc + 1]))
        pc += 3
    elif op == 2:
        c = chr(m[pc + 1])
        c = c if c in alph else '?'
        print('R{} = {:02x} ({})'.format(m[pc + 2], m[pc + 1], c))
        pc += 3
    elif op == 4:
        print('R0 = 0; R{} = (R{} == R{})'.format(
            m[pc + 1], m[pc + 1], m[pc + 2]))
        pc += 3
    elif op == 5:
        print('R0 = 0; R{} = R{} - R{}'.format(
            m[pc + 1], m[pc + 1], m[pc + 2]))
        pc += 3
    elif op == 6:
        print('CHECK (R{} == R{})n'.format(
            m[pc + 1], m[pc + 2]))
        pc += 3
    else:
        print('unk opcode {}'.format(op))
        break

ఫలితంగా, మేము క్రింది వర్చువల్ మెషీన్ కోడ్‌ను పొందుతాము:

వర్చువల్ మెషిన్ కోడ్

R1 = DB101[0]
R2 = 6e (n)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[1]
R2 = 10 (?)
R0 = 0; R1 = R1 - R2
R2 = 20 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[2]
R2 = 77 (w)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[3]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[4]
R2 = 75 (u)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[5]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[6]
R2 = 34 (4)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[7]
R2 = 26 (?)
R0 = 0; R1 = R1 - R2
R2 = 4c (L)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[8]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[9]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[10]
R2 = 37 (7)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[11]
R2 = 22 (?)
R0 = 0; R1 = R1 - R2
R2 = 46 (F)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[12]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[13]
R2 = 0a (?)
R0 = 0; R1 = R1 - R2
R2 = 16 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[14]
R2 = 6d (m)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[15]
R2 = 11 (?)
R0 = 0; R1 = R1 - R2
R2 = 23 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[16]
R2 = 35 (5)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[17]
R2 = 12 (?)
R0 = 0; R1 = R1 - R2
R2 = 25 (?)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

R1 = DB101[18]
R2 = 33 (3)
R0 = 0; R1 = (R1 == R2)
CHECK (R1 == R0)

R1 = DB101[19]
R2 = 26 (?)
R0 = 0; R1 = R1 - R2
R2 = 4c (L)
R0 = 0; R1 = R1 - R2
CHECK (R1 == R0)

మీరు చూడగలిగినట్లుగా, ఈ ప్రోగ్రామ్ ఒక నిర్దిష్ట విలువకు సమానత్వం కోసం DB101 నుండి ప్రతి అక్షరాన్ని తనిఖీ చేస్తుంది. అన్ని తనిఖీలను పాస్ చేయడానికి చివరి పంక్తి: n0w u 4r3 7h3 m4573r. ఈ లైన్ DB101 బ్లాక్‌లో ఉంచబడితే, మాన్యువల్ PLC నియంత్రణ సక్రియం చేయబడుతుంది మరియు బెలూన్‌ను పేల్చడం లేదా తగ్గించడం సాధ్యమవుతుంది.


అంతే! అలెక్సీ పారిశ్రామిక నింజాకు తగిన ఉన్నత స్థాయి జ్ఞానాన్ని ప్రదర్శించారు :) మేము విజేతకు చిరస్మరణీయ బహుమతులు పంపాము. పాల్గొనే వారందరికీ చాలా ధన్యవాదాలు!

మూలం: www.habr.com

ఒక వ్యాఖ్యను జోడించండి