జియోఫిజిక్స్‌లో వోల్‌ఫ్రామ్ మ్యాథమెటికా

బ్లాగు రచయితకు ధన్యవాదాలు అంటోన్ ఎకిమెంకో అతని నివేదిక కోసం

పరిచయం

సదస్సు నేపథ్యంలో ఈ నోట్ రాశారు వోల్ఫ్రామ్ రష్యన్ టెక్నాలజీ కాన్ఫరెన్స్ మరియు నేను ఇచ్చిన నివేదిక యొక్క సారాంశాన్ని కలిగి ఉంది. సెయింట్ పీటర్స్‌బర్గ్‌లో జూన్‌లో ఈ కార్యక్రమం జరిగింది. నేను కాన్ఫరెన్స్ సైట్ నుండి బ్లాక్‌గా పని చేస్తున్నందున, నేను ఈ ఈవెంట్‌కు హాజరు కాకుండా ఉండలేకపోయాను. 2016 మరియు 2017లో, నేను కాన్ఫరెన్స్ రిపోర్టులను విన్నాను మరియు ఈ సంవత్సరం నేను ప్రెజెంటేషన్ ఇచ్చాను. మొదట, ఒక ఆసక్తికరమైన (నాకు అనిపిస్తోంది) అంశం కనిపించింది, దానితో మేము అభివృద్ధి చేస్తున్నాము కిరిల్ బెలోవ్, మరియు రెండవది, ఆంక్షల విధానానికి సంబంధించి రష్యన్ ఫెడరేషన్ యొక్క చట్టాన్ని సుదీర్ఘ అధ్యయనం చేసిన తర్వాత, నేను పనిచేసే సంస్థలో, రెండు లైసెన్సులు కనిపించాయి. వోల్ఫ్రామ్ మ్యాథమెటికా.

నా ప్రసంగం యొక్క అంశానికి వెళ్లే ముందు, ఈవెంట్ యొక్క మంచి సంస్థను నేను గమనించాలనుకుంటున్నాను. సమావేశం యొక్క సందర్శన పేజీ కజాన్ కేథడ్రల్ చిత్రాన్ని ఉపయోగిస్తుంది. సెయింట్ పీటర్స్‌బర్గ్ యొక్క ప్రధాన ఆకర్షణలలో కేథడ్రల్ ఒకటి మరియు సమావేశం జరిగిన హాల్ నుండి చాలా స్పష్టంగా కనిపిస్తుంది.

సెయింట్ పీటర్స్‌బర్గ్ స్టేట్ ఎకనామిక్ యూనివర్శిటీ ప్రవేశద్వారం వద్ద, పాల్గొనేవారిని విద్యార్థుల నుండి సహాయకులు కలుసుకున్నారు - వారు వారిని కోల్పోవడానికి అనుమతించలేదు. రిజిస్ట్రేషన్ సమయంలో, చిన్న స్మారక చిహ్నాలు ఇవ్వబడ్డాయి (ఒక బొమ్మ - ఒక ఫ్లాషింగ్ స్పైక్, ఒక పెన్, వోల్ఫ్రామ్ చిహ్నాలతో స్టిక్కర్లు). కాన్ఫరెన్స్ షెడ్యూల్‌లో లంచ్ మరియు కాఫీ బ్రేక్‌లు కూడా చేర్చబడ్డాయి. సమూహం యొక్క గోడపై రుచికరమైన కాఫీ మరియు పైస్ గురించి నేను ఇప్పటికే గుర్తించాను - చెఫ్‌లు గొప్పవి. ఈ పరిచయ భాగంతో, ఈవెంట్, దాని ఆకృతి మరియు స్థానం ఇప్పటికే సానుకూల భావోద్వేగాలను తెస్తున్నాయని నేను నొక్కి చెప్పాలనుకుంటున్నాను.

నేను మరియు కిరిల్ బెలోవ్ రూపొందించిన నివేదికను “అనువర్తిత జియోఫిజిక్స్‌లో సమస్యలను పరిష్కరించడానికి వోల్ఫ్రామ్ మ్యాథమెటికాను ఉపయోగించడం. భూకంప డేటా యొక్క వర్ణపట విశ్లేషణ లేదా "పురాతన నదులు ఎక్కడ ప్రవహిస్తున్నాయి." నివేదిక యొక్క కంటెంట్ రెండు భాగాలను కవర్ చేస్తుంది: ముందుగా, అందుబాటులో ఉన్న అల్గారిథమ్‌ల ఉపయోగం వోల్ఫ్రామ్ మ్యాథమెటికా జియోఫిజికల్ డేటాను విశ్లేషించడం కోసం, మరియు రెండవది, వోల్ఫ్రామ్ మ్యాథమెటికాలో జియోఫిజికల్ డేటాను ఎలా ఉంచాలి.

భూకంప అన్వేషణ

మొదట మీరు జియోఫిజిక్స్‌లో చిన్న విహారయాత్ర చేయాలి. జియోఫిజిక్స్ అనేది రాళ్ల భౌతిక లక్షణాలను అధ్యయనం చేసే శాస్త్రం. బాగా, రాళ్ళు వేర్వేరు లక్షణాలను కలిగి ఉంటాయి కాబట్టి: ఎలక్ట్రికల్, మాగ్నెటిక్, సాగే, జియోఫిజిక్స్ యొక్క సంబంధిత పద్ధతులు ఉన్నాయి: ఎలక్ట్రికల్ ప్రాస్పెక్టింగ్, మాగ్నెటిక్ ప్రోస్పెక్టింగ్, సీస్మిక్ ప్రోస్పెక్టింగ్... ఈ ఆర్టికల్ సందర్భంలో, మేము భూకంప ప్రాస్పెక్టింగ్ గురించి మరింత వివరంగా చర్చిస్తాము. చమురు మరియు వాయువు కోసం శోధించే ప్రధాన పద్ధతి భూకంప అన్వేషణ. ఈ పద్ధతి సాగే ప్రకంపనల యొక్క ఉత్తేజితం మరియు అధ్యయన ప్రాంతాన్ని కంపోజ్ చేసే రాళ్ల నుండి ప్రతిస్పందన యొక్క తదుపరి రికార్డింగ్‌పై ఆధారపడి ఉంటుంది. కంపనాలు భూమిపై (డైనమైట్ లేదా సాగే ప్రకంపనల యొక్క నాన్-పేలుడు వైబ్రేషన్ మూలాలతో) లేదా సముద్రంలో (ఎయిర్ గన్‌లతో) ఉత్తేజితమవుతాయి. సాగే కంపనాలు రాతి ద్రవ్యరాశి ద్వారా వ్యాపిస్తాయి, వివిధ లక్షణాలతో పొరల సరిహద్దుల వద్ద వక్రీభవనం మరియు ప్రతిబింబిస్తాయి. ప్రతిబింబించే తరంగాలు ఉపరితలంపైకి తిరిగి వస్తాయి మరియు భూమిపై జియోఫోన్‌లు (సాధారణంగా కాయిల్‌లో సస్పెండ్ చేయబడిన అయస్కాంతం యొక్క కదలిక ఆధారంగా ఎలక్ట్రోడైనమిక్ పరికరాలు) లేదా సముద్రంలో హైడ్రోఫోన్‌లు (పైజోఎలెక్ట్రిక్ ప్రభావం ఆధారంగా) ద్వారా రికార్డ్ చేయబడతాయి. తరంగాలు వచ్చే సమయానికి, భౌగోళిక పొరల లోతులను అంచనా వేయవచ్చు.

భూకంప నాళం టోయింగ్ పరికరాలు


ఎయిర్ గన్ సాగే ప్రకంపనలను ఉత్తేజపరుస్తుంది


తరంగాలు రాక్ మాస్ గుండా వెళతాయి మరియు హైడ్రోఫోన్‌ల ద్వారా రికార్డ్ చేయబడతాయి


సెయింట్ పీటర్స్‌బర్గ్‌లోని బ్లాగోవెష్‌చెంస్కీ బ్రిడ్జ్ సమీపంలోని పీర్ వద్ద జియోఫిజికల్ సర్వే పరిశోధన నౌక "ఇవాన్ గుబ్కిన్"

సీస్మిక్ సిగ్నల్ మోడల్

రాళ్ళు వివిధ భౌతిక లక్షణాలను కలిగి ఉంటాయి. భూకంప అన్వేషణ కోసం, సాగే లక్షణాలు ప్రధానంగా ముఖ్యమైనవి - సాగే కంపనాలు మరియు సాంద్రత యొక్క ప్రచారం వేగం. రెండు పొరలు ఒకే లేదా సారూప్య లక్షణాలను కలిగి ఉంటే, అల వాటి మధ్య సరిహద్దును "గమనించదు". పొరలలో తరంగ వేగం భిన్నంగా ఉంటే, పొరల సరిహద్దులో ప్రతిబింబం ఏర్పడుతుంది. లక్షణాలలో ఎక్కువ వ్యత్యాసం, ప్రతిబింబం మరింత తీవ్రంగా ఉంటుంది. దీని తీవ్రత ప్రతిబింబ గుణకం (rc) ద్వారా నిర్ణయించబడుతుంది:

ఇక్కడ ρ అనేది రాతి సాంద్రత, ν అనేది తరంగ వేగం, 1 మరియు 2 ఎగువ మరియు దిగువ పొరలను సూచిస్తాయి.

సరళమైన మరియు అత్యంత తరచుగా ఉపయోగించే భూకంప సంకేత నమూనాలలో ఒకటి కన్వల్యూషన్ మోడల్, నమోదు చేయబడిన భూకంప జాడను ప్రోబింగ్ పల్స్‌తో ప్రతిబింబ గుణకాల శ్రేణి యొక్క కన్వల్యూషన్ ఫలితంగా సూచించబడుతుంది:

ఎక్కడ s(t) - భూకంప జాడ, అనగా. స్థిరమైన రికార్డింగ్ సమయంలో హైడ్రోఫోన్ లేదా జియోఫోన్ ద్వారా రికార్డ్ చేయబడిన ప్రతిదీ, w(t) - ఎయిర్ గన్ ద్వారా ఉత్పత్తి చేయబడిన సిగ్నల్, n(t) - యాదృచ్ఛిక శబ్దం.

సింథటిక్ సీస్మిక్ ట్రేస్‌ను ఉదాహరణగా లెక్కిద్దాం. మేము భూకంప అన్వేషణలో విస్తృతంగా ఉపయోగించే రికర్ పల్స్‌ను ప్రారంభ సంకేతంగా ఉపయోగిస్తాము.

length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]

ప్రారంభ భూకంప ప్రేరణ


మేము 300 ms మరియు 600 ms లోతులో రెండు సరిహద్దులను సెట్ చేస్తాము మరియు ప్రతిబింబ గుణకాలు యాదృచ్ఛిక సంఖ్యలుగా ఉంటాయి

rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]

ప్రతిబింబ గుణకాల క్రమం


భూకంప జాడను లెక్కించి ప్రదర్శిస్తాము. ప్రతిబింబ గుణకాలు వేర్వేరు సంకేతాలను కలిగి ఉన్నందున, మేము భూకంప జాడపై రెండు ప్రత్యామ్నాయ ప్రతిబింబాలను పొందుతాము.

traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]

అనుకరణ ట్రాక్


ఈ ఉదాహరణ కోసం, రిజర్వేషన్ చేయడం అవసరం - వాస్తవానికి, పొరల లోతు నిర్ణయించబడుతుంది, వాస్తవానికి, మీటర్లలో, మరియు భూకంప ట్రేస్ యొక్క గణన సమయ డొమైన్ కోసం జరుగుతుంది. లోతులను మీటర్లలో సెట్ చేయడం మరియు పొరలలోని వేగాలను తెలుసుకొని రాక సమయాలను లెక్కించడం మరింత సరైనది. ఈ సందర్భంలో, నేను వెంటనే సమయ అక్షంపై పొరలను సెట్ చేసాను.

మేము క్షేత్ర పరిశోధన గురించి మాట్లాడినట్లయితే, అటువంటి పరిశీలనల ఫలితంగా భారీ సంఖ్యలో సారూప్య సమయ శ్రేణి (భూకంప జాడలు) నమోదు చేయబడతాయి. ఉదాహరణకు, 25 కిమీ పొడవు మరియు 15 కిమీ వెడల్పు ఉన్న సైట్‌ను అధ్యయనం చేస్తున్నప్పుడు, పని ఫలితంగా, ప్రతి ట్రేస్ 25x25 మీటర్ల కొలిచే సెల్‌ను వర్గీకరిస్తుంది (అటువంటి సెల్‌ను బిన్ అంటారు), చివరి డేటా శ్రేణిలో 600000 ట్రేస్‌లు ఉంటాయి. నమూనా సమయం 1 ms మరియు 5 సెకన్ల రికార్డింగ్ సమయంతో, తుది డేటా ఫైల్ 11 GB కంటే ఎక్కువగా ఉంటుంది మరియు అసలు “ముడి” పదార్థం యొక్క వాల్యూమ్ వందల గిగాబైట్‌లు కావచ్చు.

వారితో ఎలా పని చేయాలి వోల్ఫ్రామ్ మ్యాథమెటికా?

ప్యాకేజీ జియాలజీIO

ప్యాకేజీ అభివృద్ధి ప్రారంభమైంది ప్రశ్న రష్యన్ మాట్లాడే మద్దతు సమూహం యొక్క VK గోడపై. సంఘం యొక్క ప్రతిస్పందనలకు ధన్యవాదాలు, చాలా త్వరగా పరిష్కారం కనుగొనబడింది. మరియు ఫలితంగా, ఇది తీవ్రమైన అభివృద్ధిగా మారింది. సంబంధిత వోల్ఫ్రామ్ కమ్యూనిటీ వాల్ పోస్ట్ ఇది మోడరేటర్‌లచే కూడా గుర్తించబడింది. ప్రస్తుతం, భౌగోళిక పరిశ్రమలో చురుకుగా ఉపయోగించే క్రింది డేటా రకాలతో పని చేయడానికి ప్యాకేజీ మద్దతు ఇస్తుంది:

1. ZMAP మరియు IRAP ఫార్మాట్లలో మ్యాప్ డేటా దిగుమతి
2. LAS ఫార్మాట్ బావులలో కొలతల దిగుమతి
3. సీస్మిక్ ఫైల్స్ ఫార్మాట్ యొక్క ఇన్‌పుట్ మరియు అవుట్‌పుట్ SEGY

ప్యాకేజీని ఇన్‌స్టాల్ చేయడానికి, మీరు సమావేశమైన ప్యాకేజీ యొక్క డౌన్‌లోడ్ పేజీలోని సూచనలను తప్పనిసరిగా అనుసరించాలి, అనగా. కింది కోడ్‌ను ఏదైనా అమలు చేయండి గణిత నోట్బుక్:

If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
    "https://wolfr.am/FiQ5oFih", 
    FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]

ప్యాకేజీ డిఫాల్ట్ ఫోల్డర్‌లో ఇన్‌స్టాల్ చేయబడిన తర్వాత, దాని మార్గం క్రింది విధంగా పొందవచ్చు:

FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]

ఉదాహరణగా, మేము ప్యాకేజీ యొక్క ప్రధాన సామర్థ్యాలను ప్రదర్శిస్తాము. వోల్ఫ్రామ్ భాషలోని ప్యాకేజీల కోసం కాల్ సాంప్రదాయకంగా చేయబడుతుంది:

Get["GeologyIO`"]

ప్యాకేజీని ఉపయోగించి అభివృద్ధి చేయబడింది వోల్ఫ్రామ్ వర్క్‌బెంచ్. ఇది డాక్యుమెంటేషన్‌తో ప్యాకేజీ యొక్క ప్రధాన కార్యాచరణతో పాటుగా మిమ్మల్ని అనుమతిస్తుంది, ఇది ప్రెజెంటేషన్ ఫార్మాట్ పరంగా Wolfram Mathematica యొక్క డాక్యుమెంటేషన్‌కు భిన్నంగా ఉండదు మరియు మొదటి పరిచయానికి టెస్ట్ ఫైల్‌లతో ప్యాకేజీని అందించడానికి.

అటువంటి ఫైల్, ప్రత్యేకించి, ఫైల్ “Marmousi.segy” - ఇది ఒక భౌగోళిక విభాగం యొక్క సింథటిక్ మోడల్, దీనిని ఫ్రెంచ్ పెట్రోలియం ఇన్స్టిట్యూట్ అభివృద్ధి చేసింది. ఈ మోడల్‌ని ఉపయోగించి, డెవలపర్‌లు వేవ్ ఫీల్డ్ మోడలింగ్, డేటా ప్రాసెసింగ్, సీస్మిక్ ట్రేస్ ఇన్‌వర్షన్ మొదలైన వాటి కోసం వారి స్వంత అల్గారిథమ్‌లను పరీక్షిస్తారు. Marmousi మోడల్ కూడా ప్యాకేజీ డౌన్‌లోడ్ చేయబడిన రిపోజిటరీలో నిల్వ చేయబడుతుంది. ఫైల్‌ను పొందడానికి, కింది కోడ్‌ను అమలు చేయండి:

If[Not[FileExistsQ["Marmousi.segy"]], 
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]

దిగుమతి ఫలితం - SEGYData ఆబ్జెక్ట్


SEGY ఫార్మాట్ పరిశీలనల గురించి వివిధ సమాచారాన్ని నిల్వ చేస్తుంది. మొదట, ఇవి టెక్స్ట్ వ్యాఖ్యలు. ఇది పని యొక్క స్థానం, కొలతలు చేసిన కంపెనీల పేర్లు మొదలైన వాటి గురించి సమాచారాన్ని కలిగి ఉంటుంది. మా సందర్భంలో, ఈ శీర్షిక TextHeader కీతో అభ్యర్థన ద్వారా పిలువబడుతుంది. ఇక్కడ సంక్షిప్త టెక్స్ట్ హెడర్ ఉంది:

Short[marmousi["TextHeader"]]

“మర్మోసి డేటా సెట్ ఇన్‌స్టిట్యూట్‌లో రూపొందించబడింది ...కనిష్ట వేగం 1500 మీ/సె మరియు గరిష్టంగా 5500 మీ/సె)”

మీరు "జాడలు" కీని ఉపయోగించి భూకంప జాడలను యాక్సెస్ చేయడం ద్వారా వాస్తవ భౌగోళిక నమూనాను ప్రదర్శించవచ్చు (ప్యాకేజీ యొక్క లక్షణాలలో ఒకటి కీలు కేస్-సెన్సిటివ్‌గా ఉంటాయి):

ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]

మోడల్ మార్మోసి


ప్రస్తుతం, ప్యాకేజీ పెద్ద ఫైల్‌ల నుండి భాగాలలో డేటాను లోడ్ చేయడానికి మిమ్మల్ని అనుమతిస్తుంది, దీని పరిమాణం పదుల గిగాబైట్‌లకు చేరుకోగల ఫైల్‌లను ప్రాసెస్ చేయడం సాధ్యపడుతుంది. ప్యాకేజీ యొక్క విధులు .segyకి డేటాను ఎగుమతి చేయడం మరియు ఫైల్ చివర పాక్షికంగా జోడించడం వంటి విధులను కూడా కలిగి ఉంటాయి.

విడిగా, .segy ఫైల్స్ యొక్క సంక్లిష్ట నిర్మాణంతో పని చేస్తున్నప్పుడు ప్యాకేజీ యొక్క కార్యాచరణను గుర్తించడం విలువ. కీలు మరియు సూచికలను ఉపయోగించి వ్యక్తిగత జాడలు మరియు శీర్షికలను యాక్సెస్ చేయడానికి మాత్రమే కాకుండా, వాటిని మార్చడానికి మరియు వాటిని ఫైల్‌కి వ్రాయడానికి కూడా ఇది మిమ్మల్ని అనుమతిస్తుంది కాబట్టి. GeologyIO యొక్క అమలు యొక్క అనేక సాంకేతిక వివరాలు ఈ కథనం యొక్క పరిధికి మించినవి మరియు బహుశా ప్రత్యేక వివరణకు అర్హులు.

భూకంప అన్వేషణలో స్పెక్ట్రల్ విశ్లేషణ యొక్క ఔచిత్యం

Wolfram Mathematicaలోకి భూకంప డేటాను దిగుమతి చేయగల సామర్థ్యం ప్రయోగాత్మక డేటా కోసం అంతర్నిర్మిత సిగ్నల్ ప్రాసెసింగ్ కార్యాచరణను ఉపయోగించడానికి మిమ్మల్ని అనుమతిస్తుంది. ప్రతి భూకంప జాడ ఒక సమయ శ్రేణిని సూచిస్తుంది కాబట్టి, వాటిని అధ్యయనం చేయడానికి ప్రధాన సాధనాల్లో ఒకటి స్పెక్ట్రల్ విశ్లేషణ. భూకంప డేటా యొక్క ఫ్రీక్వెన్సీ కూర్పును విశ్లేషించడానికి ముందస్తు అవసరాలలో, ఉదాహరణకు, మేము ఈ క్రింది వాటిని పేర్కొనవచ్చు:

1. వివిధ రకాలైన తరంగాలు విభిన్న పౌనఃపున్య కూర్పు ద్వారా వర్గీకరించబడతాయి. ఇది ఉపయోగకరమైన తరంగాలను హైలైట్ చేయడానికి మరియు జోక్యం తరంగాలను అణిచివేసేందుకు మిమ్మల్ని అనుమతిస్తుంది.
2. సచ్ఛిద్రత మరియు సంతృప్తత వంటి రాక్ లక్షణాలు ఫ్రీక్వెన్సీ కూర్పును ప్రభావితం చేయవచ్చు. ఇది ఉత్తమ లక్షణాలతో రాళ్లను గుర్తించడం సాధ్యపడుతుంది.
3. వేర్వేరు మందంతో పొరలు వేర్వేరు పౌనఃపున్య పరిధులలో క్రమరాహిత్యాలకు కారణమవుతాయి.

ఈ వ్యాస సందర్భంలో మూడవ అంశం ప్రధానమైనది. వివిధ మందం కలిగిన పొర విషయంలో భూకంప జాడలను లెక్కించడానికి క్రింద ఒక కోడ్ భాగం ఉంది - ఒక చీలిక మోడల్. ఈ నమూనా సాంప్రదాయకంగా అనేక పొరల నుండి ప్రతిబింబించే తరంగాలు ఒకదానిపై ఒకటి అతివ్యాప్తి చెందినప్పుడు జోక్యం ప్రభావాలను విశ్లేషించడానికి భూకంప అన్వేషణలో అధ్యయనం చేయబడుతుంది.

nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]

పించ్-అవుట్ నిర్మాణం యొక్క నమూనా


చీలిక లోపల తరంగ వేగం 4500 m/s, వెడ్జ్ వెలుపల 4000 m/s, మరియు సాంద్రత స్థిరంగా 2200 g/cm³గా భావించబడుతుంది. అటువంటి మోడల్ కోసం, మేము ప్రతిబింబ గుణకాలు మరియు భూకంప జాడలను లెక్కిస్తాము.

rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
	ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
		{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]

వెడ్జ్ మోడల్ కోసం భూకంప జాడలు


ఈ చిత్రంలో చూపిన భూకంప జాడల క్రమాన్ని భూకంప విభాగం అంటారు. మీరు చూడగలిగినట్లుగా, ప్రతిబింబించే తరంగాల జ్యామితి ముందుగా పేర్కొన్న మోడల్‌కు స్పష్టంగా అనుగుణంగా ఉన్నందున, దాని వివరణను సహజమైన స్థాయిలో కూడా నిర్వహించవచ్చు. మీరు జాడలను మరింత వివరంగా విశ్లేషిస్తే, 1 నుండి సుమారు 30 వరకు జాడలు భిన్నంగా ఉండవని మీరు గమనించవచ్చు - నిర్మాణం యొక్క పైకప్పు నుండి మరియు దిగువ నుండి ప్రతిబింబం ఒకదానికొకటి అతివ్యాప్తి చెందదు. 31 వ ట్రేస్ నుండి, ప్రతిబింబాలు జోక్యం చేసుకోవడం ప్రారంభిస్తాయి. మరియు, మోడల్‌లో, ప్రతిబింబ గుణకాలు అడ్డంగా మారనప్పటికీ - భూకంప జాడలు ఏర్పడే మందం మారినప్పుడు వాటి తీవ్రతను మారుస్తాయి.

నిర్మాణం యొక్క ఎగువ సరిహద్దు నుండి ప్రతిబింబం యొక్క వ్యాప్తిని పరిశీలిద్దాం. 60 వ మార్గం నుండి, ప్రతిబింబం యొక్క తీవ్రత పెరగడం ప్రారంభమవుతుంది మరియు 70 వ మార్గంలో అది గరిష్టంగా మారుతుంది. ఈ విధంగా పొరల పైకప్పు మరియు దిగువ నుండి తరంగాల జోక్యం వ్యక్తమవుతుంది, ఇది కొన్ని సందర్భాల్లో భూకంప రికార్డులో గణనీయమైన క్రమరాహిత్యాలకు దారితీస్తుంది.

ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]

చీలిక ఎగువ అంచు నుండి ప్రతిబింబించే తరంగం యొక్క వ్యాప్తి యొక్క గ్రాఫ్


సిగ్నల్ తక్కువ-ఫ్రీక్వెన్సీగా ఉన్నప్పుడు, పెద్ద ఫార్మేషన్ మందం వద్ద జోక్యం కనిపించడం ప్రారంభమవుతుంది మరియు అధిక-ఫ్రీక్వెన్సీ సిగ్నల్ విషయంలో, చిన్న మందం వద్ద జోక్యం ఏర్పడుతుంది. కింది కోడ్ స్నిప్పెట్ 35 Hz, 55 Hz మరియు 85 Hz ఫ్రీక్వెన్సీలతో ఒక సిగ్నల్‌ను సృష్టిస్తుంది.

waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]

35 Hz, 55Hz, 85Hz పౌనఃపున్యాలతో సోర్స్ సిగ్నల్స్ సెట్


భూకంప జాడలను లెక్కించడం మరియు ప్రతిబింబించే తరంగ వ్యాప్తి యొక్క గ్రాఫ్‌లను ప్లాట్ చేయడం ద్వారా, వేర్వేరు పౌనఃపున్యాల కోసం వివిధ నిర్మాణ మందం వద్ద అసాధారణత గమనించవచ్చు.

tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];

lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];

Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]

వేర్వేరు పౌనఃపున్యాల కోసం చీలిక ఎగువ అంచు నుండి ప్రతిబింబించే తరంగం యొక్క వ్యాప్తి యొక్క గ్రాఫ్‌లు


భూకంప పరిశీలనల ఫలితాల నుండి ఏర్పడే మందం గురించి తీర్మానాలు చేయగల సామర్థ్యం చాలా ఉపయోగకరంగా ఉంటుంది, ఎందుకంటే చమురు అన్వేషణలో ప్రధాన పని ఏమిటంటే బావిని వేయడానికి అత్యంత ఆశాజనకమైన పాయింట్లను అంచనా వేయడం (అనగా, ఏర్పడిన ప్రాంతాలు. మందంగా). అదనంగా, భౌగోళిక విభాగంలో వస్తువులు ఉండవచ్చు, దీని పుట్టుక నిర్మాణం యొక్క మందంలో పదునైన మార్పుకు కారణమవుతుంది. ఇది స్పెక్ట్రల్ విశ్లేషణను వాటిని అధ్యయనం చేయడానికి సమర్థవంతమైన సాధనంగా చేస్తుంది. వ్యాసం యొక్క తదుపరి భాగంలో మేము అటువంటి భౌగోళిక వస్తువులను మరింత వివరంగా పరిశీలిస్తాము.

ప్రయోగాత్మక డేటా. మీరు వాటిని ఎక్కడ పొందారు మరియు వాటిలో ఏమి చూడాలి?

వ్యాసంలో విశ్లేషించబడిన పదార్థాలు పశ్చిమ సైబీరియాలో పొందబడ్డాయి. ఈ ప్రాంతం, మినహాయింపు లేకుండా అందరికీ తెలిసినట్లుగా, మన దేశంలో ప్రధాన చమురు ఉత్పత్తి ప్రాంతం. గత శతాబ్దపు 60వ దశకంలో ఈ ప్రాంతంలో డిపాజిట్ల క్రియాశీల అభివృద్ధి ప్రారంభమైంది. చమురు నిక్షేపాల కోసం శోధించే ప్రధాన పద్ధతి భూకంప అన్వేషణ. ఈ భూభాగం యొక్క ఉపగ్రహ చిత్రాలను చూడటం ఆసక్తికరంగా ఉంటుంది. చిన్న స్థాయిలో, మీరు భారీ సంఖ్యలో చిత్తడి నేలలు మరియు సరస్సులను గమనించవచ్చు; మ్యాప్‌ను విస్తరించడం ద్వారా, మీరు క్లస్టర్ వెల్ డ్రిల్లింగ్ సైట్‌లను చూడవచ్చు మరియు మ్యాప్‌ను పరిమితికి పెంచడం ద్వారా, మీరు భూకంపం ఉన్న ప్రొఫైల్‌ల క్లియరింగ్‌లను కూడా గుర్తించవచ్చు. పరిశీలనలు జరిగాయి.

Yandex పటాల ఉపగ్రహ చిత్రం - Noyabrsk నగర ప్రాంతం


ఫీల్డ్‌లలో ఒకదాని వద్ద బావి ప్యాడ్‌ల నెట్‌వర్క్


వెస్ట్రన్ సైబీరియా యొక్క చమురు-బేరింగ్ శిలలు విస్తృత శ్రేణి లోతులలో సంభవిస్తాయి - 1 కిమీ నుండి 5 కిమీ వరకు. జురాసిక్ మరియు క్రెటేషియస్ కాలంలో చమురు కలిగిన శిలల ప్రధాన పరిమాణం ఏర్పడింది. జురాసిక్ కాలం బహుశా అదే పేరుతో ఉన్న చిత్రం నుండి చాలా మందికి తెలుసు. జురాసిక్ వాతావరణం ఆధునిక దాని నుండి గణనీయంగా భిన్నంగా ఉంది. ఎన్‌సైక్లోపీడియా బ్రిటానికాలో ప్రతి హెలాజికల్ యుగాన్ని వివరించే పాలియోమాప్‌ల శ్రేణి ఉంది.

ప్రస్తుతం

జురాసిక్ కాలం


జురాసిక్ కాలంలో, పశ్చిమ సైబీరియా భూభాగం సముద్ర తీరం (నదులు మరియు నిస్సారమైన సముద్రం ద్వారా దాటిన భూమి) అని దయచేసి గమనించండి. వాతావరణం సౌకర్యవంతంగా ఉన్నందున, ఆ కాలపు సాధారణ ప్రకృతి దృశ్యం ఇలా ఉందని మనం భావించవచ్చు:

జురాసిక్ సైబీరియా


ఈ చిత్రంలో, మనకు ముఖ్యమైనది జంతువులు మరియు పక్షులు కాదు, కానీ నేపథ్యంలో నది యొక్క చిత్రం. నది మనం ఇంతకు ముందు ఆగిపోయిన అదే భౌగోళిక వస్తువు. వాస్తవం ఏమిటంటే, నదుల కార్యకలాపాలు బాగా క్రమబద్ధీకరించబడిన ఇసుకరాళ్ళు పేరుకుపోవడానికి అనుమతిస్తుంది, ఇది చమురు కోసం రిజర్వాయర్ అవుతుంది. ఈ జలాశయాలు వికారమైన, సంక్లిష్టమైన ఆకారాన్ని (నదీ మంచం వంటివి) కలిగి ఉంటాయి మరియు అవి వేరియబుల్ మందాన్ని కలిగి ఉంటాయి - ఒడ్డు దగ్గర మందం చిన్నది, కానీ ఛానెల్ మధ్యలో లేదా మెండర్ ప్రాంతాలలో అది పెరుగుతుంది. కాబట్టి, జురాసిక్‌లో ఏర్పడిన నదులు ఇప్పుడు మూడు కిలోమీటర్ల లోతులో ఉన్నాయి మరియు చమురు రిజర్వాయర్‌ల కోసం అన్వేషణ వస్తువుగా ఉన్నాయి.

ప్రయోగాత్మక డేటా. ప్రాసెసింగ్ మరియు విజువలైజేషన్

వ్యాసంలో చూపిన భూకంప పదార్థాలకు సంబంధించి వెంటనే రిజర్వేషన్ చేద్దాం - విశ్లేషణ కోసం ఉపయోగించిన డేటా మొత్తం ముఖ్యమైనది కాబట్టి - అసలు భూకంప జాడల యొక్క ఒక భాగం మాత్రమే వ్యాసం యొక్క వచనంలో చేర్చబడింది. ఇది పై గణనలను ఎవరైనా పునరుత్పత్తి చేయడానికి అనుమతిస్తుంది.

భూకంప డేటాతో పని చేస్తున్నప్పుడు, జియోఫిజిసిస్ట్ సాధారణంగా ప్రత్యేకమైన సాఫ్ట్‌వేర్‌ను ఉపయోగిస్తాడు (అనేక మంది పరిశ్రమ నాయకులు అభివృద్ధిని చురుకుగా ఉపయోగిస్తున్నారు, ఉదాహరణకు పెట్రెల్ లేదా పారాడిగ్మ్), ఇది వివిధ రకాల డేటాను విశ్లేషించడానికి మిమ్మల్ని అనుమతిస్తుంది మరియు అనుకూలమైన గ్రాఫికల్ ఇంటర్‌ఫేస్‌ను కలిగి ఉంటుంది. అన్ని సౌలభ్యం ఉన్నప్పటికీ, ఈ రకమైన సాఫ్ట్‌వేర్‌లు కూడా వాటి లోపాలను కలిగి ఉన్నాయి - ఉదాహరణకు, స్థిరమైన సంస్కరణల్లో ఆధునిక అల్గోరిథంల అమలు చాలా సమయం పడుతుంది మరియు గణనలను ఆటోమేట్ చేసే అవకాశాలు సాధారణంగా పరిమితం. అటువంటి పరిస్థితిలో, కంప్యూటర్ మ్యాథమెటిక్స్ సిస్టమ్స్ మరియు హై-లెవల్ ప్రోగ్రామింగ్ లాంగ్వేజ్‌లను ఉపయోగించడం చాలా సౌకర్యవంతంగా ఉంటుంది, ఇది విస్తృత అల్గోరిథమిక్ బేస్‌ను ఉపయోగించడాన్ని అనుమతిస్తుంది మరియు అదే సమయంలో చాలా రొటీన్‌ను తీసుకుంటుంది. ఇది వోల్‌ఫ్రామ్ మ్యాథమెటికాలో భూకంప డేటాతో పని చేయడానికి ఉపయోగించే సూత్రం. డేటాతో ఇంటరాక్టివ్ వర్క్ కోసం రిచ్ ఫంక్షనాలిటీని రాయడం సరికాదు - సాధారణంగా ఆమోదించబడిన ఫార్మాట్ నుండి లోడ్ అవుతుందని నిర్ధారించుకోవడం, వాటికి కావలసిన అల్గారిథమ్‌లను వర్తింపజేయడం మరియు వాటిని తిరిగి బాహ్య ఆకృతికి అప్‌లోడ్ చేయడం చాలా ముఖ్యం.

ప్రతిపాదిత పథకాన్ని అనుసరించి, మేము అసలు భూకంప డేటాను లోడ్ చేస్తాము మరియు వాటిని ప్రదర్శిస్తాము వోల్ఫ్రామ్ మ్యాథమెటికా:

Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]

ఈ విధంగా డౌన్‌లోడ్ చేయబడిన మరియు దిగుమతి చేయబడిన డేటా 10 నుండి 5 కిలోమీటర్ల విస్తీర్ణంలో నమోదు చేయబడిన మార్గాలు. త్రిమితీయ భూకంప సర్వే పద్ధతిని ఉపయోగించి డేటాను పొందినట్లయితే (తరంగాలు వ్యక్తిగత జియోఫిజికల్ ప్రొఫైల్‌ల వెంట కాకుండా మొత్తం ప్రాంతంపై ఏకకాలంలో నమోదు చేయబడతాయి), భూకంప డేటా క్యూబ్‌లను పొందడం సాధ్యమవుతుంది. ఇవి త్రిమితీయ వస్తువులు, నిలువు మరియు క్షితిజ సమాంతర విభాగాలు భౌగోళిక పర్యావరణం యొక్క వివరణాత్మక అధ్యయనాన్ని అనుమతిస్తుంది. పరిగణించబడిన ఉదాహరణలో, మేము త్రిమితీయ డేటాతో వ్యవహరిస్తున్నాము. మేము టెక్స్ట్ హెడర్ నుండి కొంత సమాచారాన్ని పొందవచ్చు

StringPartition[seismic3DSEGY["textheader"], 80] // TableForm

సి 1 ఇది జియోలజీయో ప్యాకేజీ పరీక్ష కోసం డెమో ఫైల్
C 2
C 3
C 4
C 5 తేదీ వినియోగదారు పేరు: WOLFRAM వినియోగదారు
సి 6 సర్వే పేరు: సైబీరియాలో ఎక్కడో
C 7 ఫైల్ టైప్ 3D సీస్మిక్ వాల్యూమ్
C 8
C 9
C10 Z పరిధి: మొదటి 2200M చివరి 2400M

డేటా విశ్లేషణ యొక్క ప్రధాన దశలను ప్రదర్శించడానికి మాకు ఈ డేటా సెట్ సరిపోతుంది. ఫైల్‌లోని జాడలు వరుసగా రికార్డ్ చేయబడతాయి మరియు వాటిలో ప్రతి ఒక్కటి క్రింది బొమ్మ వలె కనిపిస్తుంది - ఇది నిలువు అక్షం (లోతు అక్షం) వెంట ప్రతిబింబించే తరంగాల వ్యాప్తి యొక్క పంపిణీ.

ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2, 
 PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
 LabelStyle -> Directive[Black, Italic], PlotRange -> All, 
 Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]

భూకంప విభాగం జాడలలో ఒకటి


అధ్యయనం చేయబడిన ప్రాంతం యొక్క ప్రతి దిశలో ఎన్ని జాడలు ఉన్నాయో తెలుసుకోవడం, మీరు త్రిమితీయ డేటా శ్రేణిని రూపొందించవచ్చు మరియు Image3D[] ఫంక్షన్‌ని ఉపయోగించి దాన్ని ప్రదర్శించవచ్చు.

traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1;   (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1;   (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]

భూకంప డేటా క్యూబ్ యొక్క XNUMXD చిత్రం. (నిలువు అక్షం - లోతు)


ఆసక్తి యొక్క భౌగోళిక లక్షణాలు తీవ్రమైన భూకంప క్రమరాహిత్యాలను సృష్టిస్తే, పారదర్శకతతో కూడిన విజువలైజేషన్ సాధనాలను ఉపయోగించవచ్చు. రికార్డింగ్ యొక్క "అప్రముఖ" ప్రాంతాలు కనిపించకుండా చేయవచ్చు, క్రమరాహిత్యాలు మాత్రమే కనిపిస్తాయి. Wolfram Mathematicaలో దీనిని ఉపయోగించి చేయవచ్చు అస్పష్టత[] и Raster3D[].

data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]}, 
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]

అస్పష్టత[] మరియు రాస్టర్3డి[] ఫంక్షన్‌లను ఉపయోగించి సీస్మిక్ డేటా క్యూబ్ ఇమేజ్

సింథటిక్ ఉదాహరణలో వలె, అసలు క్యూబ్ యొక్క విభాగాలపై వేరియబుల్ రిలీఫ్‌తో కొన్ని భౌగోళిక సరిహద్దులను (పొరలు) గుర్తించవచ్చు.

స్పెక్ట్రల్ విశ్లేషణకు ప్రధాన సాధనం ఫోరియర్ పరివర్తన. దాని సహాయంతో, మీరు ప్రతి ట్రేస్ లేదా జాడల సమూహం యొక్క వ్యాప్తి-ఫ్రీక్వెన్సీ స్పెక్ట్రంను అంచనా వేయవచ్చు. అయితే, డేటాను ఫ్రీక్వెన్సీ డొమైన్‌కు బదిలీ చేసిన తర్వాత, ఫ్రీక్వెన్సీ మార్పులు ఏ సమయంలో (ఏ లోతుల్లో చదవండి) అనే దాని గురించి సమాచారం పోతుంది. సమయ (లోతు) అక్షంపై సిగ్నల్ మార్పులను స్థానికీకరించడానికి, విండోడ్ ఫోరియర్ రూపాంతరం మరియు వేవ్‌లెట్ కుళ్ళిపోవడం ఉపయోగించబడుతుంది. ఈ వ్యాసం వేవ్‌లెట్ కుళ్ళిపోవడాన్ని ఉపయోగిస్తుంది. వేవ్లెట్ విశ్లేషణ సాంకేతికత 90లలో భూకంప అన్వేషణలో చురుకుగా ఉపయోగించడం ప్రారంభమైంది. విండోడ్ ఫోరియర్ ట్రాన్స్‌ఫార్మ్‌పై ఉన్న ప్రయోజనం మెరుగైన టైమ్ రిజల్యూషన్‌గా పరిగణించబడుతుంది.

కింది కోడ్ భాగాన్ని ఉపయోగించి, మీరు భూకంప జాడలలో ఒకదానిని వ్యక్తిగత భాగాలుగా విడదీయవచ్చు:

cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]

భాగాలుగా ట్రేస్ యొక్క కుళ్ళిపోవడం


వివిధ వేవ్ రాక సమయాల్లో ప్రతిబింబ శక్తి ఎలా పంపిణీ చేయబడుతుందో అంచనా వేయడానికి, స్కాలోగ్రామ్‌లు (స్పెక్ట్రోగ్రామ్‌కి సారూప్యంగా) ఉపయోగించబడతాయి. నియమం ప్రకారం, ఆచరణలో అన్ని భాగాలను విశ్లేషించాల్సిన అవసరం లేదు. సాధారణంగా, తక్కువ, మధ్య మరియు అధిక ఫ్రీక్వెన్సీ భాగాలు ఎంపిక చేయబడతాయి.

freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]

స్కాలోగ్రామ్. ఫంక్షన్ ఫలితం WaveletScalogram[]


వోల్‌ఫ్రామ్ లాంగ్వేజ్ వేవ్‌లెట్ ట్రాన్స్‌ఫర్మేషన్ కోసం ఫంక్షన్‌ను ఉపయోగిస్తుంది నిరంతర వేవ్లెట్ ట్రాన్స్‌ఫార్మ్[]. మరియు మొత్తం జాడల సెట్‌కు ఈ ఫంక్షన్ యొక్క అప్లికేషన్ ఫంక్షన్‌ని ఉపయోగించి నిర్వహించబడుతుంది పట్టిక[]. ఇక్కడ వోల్ఫ్రామ్ మ్యాథమెటికా యొక్క బలాలలో ఒకదానిని గమనించడం విలువ - సమాంతరీకరణను ఉపయోగించగల సామర్థ్యం సమాంతర పట్టిక[]. పై ఉదాహరణలో, సమాంతరీకరణ అవసరం లేదు - డేటా పరిమాణం పెద్దది కాదు, కానీ వందల వేల ట్రేస్‌లను కలిగి ఉన్న ప్రయోగాత్మక డేటా సెట్‌లతో పని చేస్తున్నప్పుడు, ఇది అవసరం.

tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}]; 

ఫంక్షన్‌ను వర్తింపజేసిన తర్వాత నిరంతర వేవ్లెట్ ట్రాన్స్‌ఫార్మ్[] ఎంచుకున్న పౌనఃపున్యాలకు అనుగుణంగా కొత్త డేటా సెట్‌లు కనిపిస్తాయి. పై ఉదాహరణలో, ఈ ఫ్రీక్వెన్సీలు: 38Hz, 33Hz, 27Hz. పౌనఃపున్యాల ఎంపిక చాలా తరచుగా పరీక్ష ఆధారంగా నిర్వహించబడుతుంది - అవి వివిధ పౌనఃపున్య కలయికల కోసం సమర్థవంతమైన మ్యాప్‌లను పొందుతాయి మరియు భూవిజ్ఞాన శాస్త్రజ్ఞుడి దృక్కోణం నుండి అత్యంత సమాచారంగా ఎంపిక చేసుకుంటాయి.

మీరు ఫలితాలను సహోద్యోగులతో పంచుకోవాలనుకుంటే లేదా వాటిని కస్టమర్‌కు అందించాలనుకుంటే, మీరు జియాలజీIO ప్యాకేజీ యొక్క SEGYExport[] ఫంక్షన్‌ని ఉపయోగించవచ్చు

outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];

వీటిలో మూడు క్యూబ్‌లతో (తక్కువ-ఫ్రీక్వెన్సీ, మిడ్-ఫ్రీక్వెన్సీ మరియు హై-ఫ్రీక్వెన్సీ కాంపోనెంట్‌లు), RGB బ్లెండింగ్ సాధారణంగా డేటాను కలిసి దృశ్యమానం చేయడానికి ఉపయోగించబడుతుంది. ఎరుపు, ఆకుపచ్చ, నీలం - ప్రతి భాగం దాని స్వంత రంగు కేటాయించబడుతుంది. Wolfram Mathematicaలో ఇది ఫంక్షన్‌ని ఉపయోగించి చేయవచ్చు కలర్‌కాంబైన్[].

ఫలితంగా భౌగోళిక వివరణను తయారు చేయగల చిత్రాలు. విభాగంలో నమోదు చేయబడిన మెండర్‌లు రిజర్వాయర్‌లు మరియు చమురు నిల్వలను కలిగి ఉండే అవకాశం ఉన్న పాలియోచానెల్‌లను వివరించడం సాధ్యపడుతుంది. అటువంటి నది వ్యవస్థ యొక్క ఆధునిక అనలాగ్ల శోధన మరియు విశ్లేషణ మెండర్ల యొక్క అత్యంత ఆశాజనక భాగాలను గుర్తించడానికి మాకు అనుమతిస్తుంది. ఛానెల్‌లు బాగా క్రమబద్ధీకరించబడిన ఇసుకరాయి యొక్క మందపాటి పొరల ద్వారా వర్గీకరించబడతాయి మరియు చమురు కోసం మంచి రిజర్వాయర్. "లేస్" క్రమరాహిత్యాల వెలుపల ఉన్న ప్రాంతాలు ఆధునిక వరద మైదానాల నిక్షేపాలను పోలి ఉంటాయి. వరద మైదానం నిక్షేపాలు ప్రధానంగా బంకమట్టి శిలలచే సూచించబడతాయి మరియు ఈ మండలాల్లోకి డ్రిల్లింగ్ అసమర్థంగా ఉంటుంది.

డేటా క్యూబ్ యొక్క RGB స్లైస్. మధ్యలో (మధ్యకు కొంచెం ఎడమవైపు) మీరు వణుకుతున్న నదిని గుర్తించవచ్చు.

డేటా క్యూబ్ యొక్క RGB స్లైస్. ఎడమ వైపున మీరు వంకరగా ఉన్న నదిని గుర్తించవచ్చు.


కొన్ని సందర్భాల్లో, భూకంప డేటా నాణ్యత గణనీయంగా స్పష్టమైన చిత్రాలను అనుమతిస్తుంది. ఇది ఫీల్డ్ వర్క్ మెథడాలజీపై ఆధారపడి ఉంటుంది, శబ్దం తగ్గింపు అల్గోరిథం ఉపయోగించే పరికరాలు. అటువంటి సందర్భాలలో, నదీ వ్యవస్థల శకలాలు మాత్రమే కనిపిస్తాయి, కానీ మొత్తం విస్తరించిన పాలియో-నదులు కూడా కనిపిస్తాయి.

సీస్మిక్ డేటా క్యూబ్ (క్షితిజ సమాంతర స్లైస్) యొక్క మూడు భాగాల RGB మిక్సింగ్. లోతు సుమారు 2 కి.మీ.

సరతోవ్ సమీపంలోని వోల్గా నది యొక్క ఉపగ్రహ చిత్రం

తీర్మానం

Wolfram Mathematica భూకంప డేటాను విశ్లేషించడానికి మరియు ఖనిజ అన్వేషణకు సంబంధించిన అనువర్తిత సమస్యలను పరిష్కరించడానికి మిమ్మల్ని అనుమతిస్తుంది మరియు GeologyIO ప్యాకేజీ ఈ ప్రక్రియను మరింత సౌకర్యవంతంగా చేస్తుంది. భూకంప డేటా యొక్క నిర్మాణం గణనలను వేగవంతం చేయడానికి అంతర్నిర్మిత పద్ధతులను ఉపయోగించడం (సమాంతర పట్టిక[], ParallelDo[],...) చాలా సమర్థవంతమైనది మరియు పెద్ద మొత్తంలో డేటాను ప్రాసెస్ చేయడానికి మిమ్మల్ని అనుమతిస్తుంది. చాలా వరకు, ఇది GeologyIO ప్యాకేజీ యొక్క డేటా నిల్వ లక్షణాల ద్వారా సులభతరం చేయబడింది. మార్గం ద్వారా, ప్యాకేజీ అనువర్తిత భూకంప అన్వేషణ రంగంలో మాత్రమే ఉపయోగించబడుతుంది. గ్రౌండ్ పెనెట్రేటింగ్ రాడార్ మరియు సిస్మోలజీలో దాదాపు ఒకే రకమైన డేటా ఉపయోగించబడుతుంది. ఫలితాన్ని ఎలా మెరుగుపరచాలనే దానిపై మీకు సూచనలు ఉంటే, Wolfram Mathematica ఆర్సెనల్ నుండి సిగ్నల్ విశ్లేషణ అల్గారిథమ్‌లు అటువంటి డేటాకు వర్తిస్తాయి లేదా మీకు ఏవైనా క్లిష్టమైన వ్యాఖ్యలు ఉంటే, దయచేసి అభిప్రాయము ఇవ్వగలరు.

మూలం: www.habr.com