ตรวจสอบเครื่องมือฟรี SQLIndexManager

ดังที่คุณทราบ ดัชนีมีบทบาทสำคัญใน DBMS ทำให้สามารถค้นหาบันทึกที่ต้องการได้อย่างรวดเร็ว ด้วยเหตุนี้การให้บริการอย่างทันท่วงทีจึงเป็นเรื่องสำคัญมาก มีการเขียนเนื้อหามากมายเกี่ยวกับการวิเคราะห์และการเพิ่มประสิทธิภาพ รวมถึงบนอินเทอร์เน็ต ตัวอย่างเช่น หัวข้อนี้เพิ่งได้รับการตรวจสอบใน สิ่งพิมพ์นี้.

มีวิธีแก้ไขปัญหาแบบชำระเงินและฟรีมากมายสำหรับสิ่งนี้ ตัวอย่างเช่นมีแบบสำเร็จรูป การตัดสินใจอิงตามวิธีการปรับดัชนีให้เหมาะสมที่สุด

ต่อไปเรามาดูยูทิลิตี้ฟรีกัน SQLIndexManagerประพันธ์โดย อลันเดนตัน.

ความแตกต่างทางเทคนิคหลักระหว่าง SQLIndexManager และอะนาล็อกอื่น ๆ จำนวนหนึ่งนั้นได้รับจากผู้เขียนเอง ที่นี่ и ที่นี่.

ในบทความนี้ เราจะมาดูโครงการและความสามารถในการปฏิบัติงานของโซลูชันซอฟต์แวร์นี้จากภายนอก

หารือเกี่ยวกับยูทิลิตี้นี้ ที่นี่.
เมื่อเวลาผ่านไป ความคิดเห็นและข้อบกพร่องส่วนใหญ่ได้รับการแก้ไข

ตอนนี้เรามาดูยูทิลิตี SQLIndexManager กันดีกว่า

แอปพลิเคชันเขียนด้วย C# .NET Framework 4.5 ใน Visual Studio 2017 และใช้ DevExpress สำหรับแบบฟอร์ม:

และมีลักษณะดังนี้:

คำขอทั้งหมดถูกสร้างขึ้นในไฟล์ต่อไปนี้:

1. ดัชนี
2. สอบถาม
3. QueryEngine
4. ข้อมูลเซิร์ฟเวอร์

เมื่อเชื่อมต่อกับฐานข้อมูลและส่งคำถามไปยัง DBMS แอปพลิเคชันจะถูกลงนามดังนี้:

ApplicationName=”SQLIndexManager”

เมื่อคุณเปิดแอปพลิเคชัน หน้าต่างโมดอลจะเปิดขึ้นเพื่อเพิ่มการเชื่อมต่อ:

ที่นี่ การโหลดรายการอินสแตนซ์ MS SQL Server ทั้งหมดที่เข้าถึงได้ผ่านเครือข่ายท้องถิ่นยังใช้งานไม่ได้

คุณยังสามารถเพิ่มการเชื่อมต่อโดยใช้ปุ่มซ้ายสุดบนเมนูหลัก:

ถัดไป แบบสอบถามต่อไปนี้ไปยัง DBMS จะถูกเปิดใช้งาน:

1. การรับข้อมูลเกี่ยวกับ DBMS

   SELECT ProductLevel  = SERVERPROPERTY('ProductLevel')
        , Edition       = SERVERPROPERTY('Edition')
        , ServerVersion = SERVERPROPERTY('ProductVersion')
        , IsSysAdmin    = CAST(IS_SRVROLEMEMBER('sysadmin') AS BIT)
   

2. รับรายการฐานข้อมูลพร้อมคุณสมบัติโดยย่อ

   SELECT DatabaseName = t.[name]
        , d.DataSize
        , DataUsedSize  = CAST(NULL AS BIGINT)
        , d.LogSize
        , LogUsedSize   = CAST(NULL AS BIGINT)
        , RecoveryModel = t.recovery_model_desc
        , LogReuseWait  = t.log_reuse_wait_desc
   FROM sys.databases t WITH(NOLOCK)
   LEFT JOIN (
       SELECT [database_id]
            , DataSize = SUM(CASE WHEN [type] = 0 THEN CAST(size AS BIGINT) END)
            , LogSize  = SUM(CASE WHEN [type] = 1 THEN CAST(size AS BIGINT) END)
       FROM sys.master_files WITH(NOLOCK)
       GROUP BY [database_id]
   ) d ON d.[database_id] = t.[database_id]
   WHERE t.[state] = 0
       AND t.[database_id] != 2
       AND ISNULL(HAS_DBACCESS(t.[name]), 1) = 1
   

หลังจากรันสคริปต์ข้างต้น หน้าต่างจะปรากฏขึ้นพร้อมข้อมูลโดยย่อเกี่ยวกับฐานข้อมูลของอินสแตนซ์ที่เลือกของ MS SQL Server:

เป็นที่น่าสังเกตว่าข้อมูลเพิ่มเติมจะแสดงตามสิทธิ์ ถ้ามี ดูแลระบบจากนั้นคุณสามารถเลือกข้อมูลจากมุมมองได้ sys.master_files. หากไม่มีสิทธิ์ดังกล่าว ข้อมูลก็จะถูกส่งกลับน้อยลงเพื่อไม่ให้คำขอช้าลง

ที่นี่คุณจะต้องเลือกฐานข้อมูลที่สนใจและคลิกที่ปุ่ม "ตกลง"

ถัดไป สคริปต์ต่อไปนี้จะถูกดำเนินการสำหรับแต่ละฐานข้อมูลที่เลือกเพื่อวิเคราะห์สถานะของดัชนี:

การวิเคราะห์สถานะดัชนี

declare @Fragmentation float=15;
declare @MinIndexSize bigint=768;
declare @MaxIndexSize bigint=1048576;
declare @PreDescribeSize bigint=32768;
SET NOCOUNT ON
SET ARITHABORT ON
SET NUMERIC_ROUNDABORT OFF
IF OBJECT_ID('tempdb.dbo.#AllocationUnits') IS NOT NULL
DROP TABLE #AllocationUnits
CREATE TABLE #AllocationUnits (
ContainerID   BIGINT PRIMARY KEY
, ReservedPages BIGINT NOT NULL
, UsedPages     BIGINT NOT NULL
)
INSERT INTO #AllocationUnits (ContainerID, ReservedPages, UsedPages)
SELECT [container_id]
, SUM([total_pages])
, SUM([used_pages])
FROM sys.allocation_units WITH(NOLOCK)
GROUP BY [container_id]
HAVING SUM([total_pages]) BETWEEN @MinIndexSize AND @MaxIndexSize
IF OBJECT_ID('tempdb.dbo.#ExcludeList') IS NOT NULL
DROP TABLE #ExcludeList
CREATE TABLE #ExcludeList (ID INT PRIMARY KEY)
INSERT INTO #ExcludeList
SELECT [object_id]
FROM sys.objects WITH(NOLOCK)
WHERE [type] IN ('V', 'U')
AND ( [is_ms_shipped] = 1 )
IF OBJECT_ID('tempdb.dbo.#Partitions') IS NOT NULL
DROP TABLE #Partitions
SELECT [object_id]
, [index_id]
, [partition_id]
, [partition_number]
, [rows]
, [data_compression]
INTO #Partitions
FROM sys.partitions WITH(NOLOCK)
WHERE [object_id] > 255
AND [rows] > 0
AND [object_id] NOT IN (SELECT * FROM #ExcludeList)
IF OBJECT_ID('tempdb.dbo.#Indexes') IS NOT NULL
DROP TABLE #Indexes
CREATE TABLE #Indexes (
ObjectID         INT NOT NULL
, IndexID          INT NOT NULL
, IndexName        SYSNAME NULL
, PagesCount       BIGINT NOT NULL
, UnusedPagesCount BIGINT NOT NULL
, PartitionNumber  INT NOT NULL
, RowsCount        BIGINT NOT NULL
, IndexType        TINYINT NOT NULL
, IsAllowPageLocks BIT NOT NULL
, DataSpaceID      INT NOT NULL
, DataCompression  TINYINT NOT NULL
, IsUnique         BIT NOT NULL
, IsPK             BIT NOT NULL
, FillFactorValue  INT NOT NULL
, IsFiltered       BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Indexes
SELECT ObjectID         = i.[object_id]
, IndexID          = i.index_id
, IndexName        = i.[name]
, PagesCount       = a.ReservedPages
, UnusedPagesCount = CASE WHEN ABS(a.ReservedPages - a.UsedPages) > 32 THEN a.ReservedPages - a.UsedPages ELSE 0 END
, PartitionNumber  = p.[partition_number]
, RowsCount        = ISNULL(p.[rows], 0)
, IndexType        = i.[type]
, IsAllowPageLocks = i.[allow_page_locks]
, DataSpaceID      = i.[data_space_id]
, DataCompression  = p.[data_compression]
, IsUnique         = i.[is_unique]
, IsPK             = i.[is_primary_key]
, FillFactorValue  = i.[fill_factor]
, IsFiltered       = i.[has_filter]
FROM #AllocationUnits a
JOIN #Partitions p ON a.ContainerID = p.[partition_id]
JOIN sys.indexes i WITH(NOLOCK) ON i.[object_id] = p.[object_id] AND p.[index_id] = i.[index_id] 
WHERE i.[type] IN (0, 1, 2, 5, 6)
AND i.[object_id] > 255
DECLARE @files TABLE (ID INT PRIMARY KEY)
INSERT INTO @files
SELECT DISTINCT [data_space_id]
FROM sys.database_files WITH(NOLOCK)
WHERE [state] != 0
AND [type] = 0
IF @@ROWCOUNT > 0 BEGIN
DELETE FROM i
FROM #Indexes i
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
WHERE ISNULL(dds.[data_space_id], i.DataSpaceID) IN (SELECT * FROM @files)
END
DECLARE @DBID   INT
, @DBNAME SYSNAME
SET @DBNAME = DB_NAME()
SELECT @DBID = [database_id]
FROM sys.databases WITH(NOLOCK)
WHERE [name] = @DBNAME
IF OBJECT_ID('tempdb.dbo.#Fragmentation') IS NOT NULL
DROP TABLE #Fragmentation
CREATE TABLE #Fragmentation (
ObjectID         INT NOT NULL
, IndexID          INT NOT NULL
, PartitionNumber  INT NOT NULL
, Fragmentation    FLOAT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, PartitionNumber)
)
INSERT INTO #Fragmentation (ObjectID, IndexID, PartitionNumber, Fragmentation)
SELECT i.ObjectID
, i.IndexID
, i.PartitionNumber
, r.[avg_fragmentation_in_percent]
FROM #Indexes i
CROSS APPLY sys.dm_db_index_physical_stats(@DBID, i.ObjectID, i.IndexID, i.PartitionNumber, 'LIMITED') r
WHERE i.PagesCount <= @PreDescribeSize
AND r.[index_level] = 0
AND r.[alloc_unit_type_desc] = 'IN_ROW_DATA'
AND i.IndexType IN (0, 1, 2)
IF OBJECT_ID('tempdb.dbo.#Columns') IS NOT NULL
DROP TABLE #Columns
CREATE TABLE #Columns (
ObjectID     INT NOT NULL
, ColumnID     INT NOT NULL
, ColumnName   SYSNAME NULL
, SystemTypeID TINYINT NULL
, IsSparse     BIT
, IsColumnSet  BIT
, MaxLen       INT
, PRIMARY KEY (ObjectID, ColumnID)
)
INSERT INTO #Columns
SELECT ObjectID     = [object_id]
, ColumnID     = [column_id]
, ColumnName   = [name]
, SystemTypeID = [system_type_id]
, IsSparse     = [is_sparse]
, IsColumnSet  = [is_column_set]
, MaxLen       = [max_length]
FROM sys.columns WITH(NOLOCK)
WHERE [object_id] IN (SELECT DISTINCT i.ObjectID FROM #Indexes i)
IF OBJECT_ID('tempdb.dbo.#IndexColumns') IS NOT NULL
DROP TABLE #IndexColumns
CREATE TABLE #IndexColumns (
ObjectID   INT NOT NULL
, IndexID    INT NOT NULL
, OrderID    INT NOT NULL
, ColumnID   INT NOT NULL
, IsIncluded BIT NOT NULL
, PRIMARY KEY (ObjectID, IndexID, ColumnID)
)
INSERT INTO #IndexColumns
SELECT ObjectID   = [object_id]
, IndexID    = [index_id]
, OrderID    = CASE WHEN [is_included_column] = 0 THEN [key_ordinal] ELSE [index_column_id] END
, ColumnID   = [column_id]
, IsIncluded = ISNULL([is_included_column], 0)
FROM sys.index_columns ic WITH(NOLOCK)
WHERE EXISTS(
SELECT *
FROM #Indexes i
WHERE i.ObjectID = ic.[object_id]
AND i.IndexID = ic.[index_id]
AND i.IndexType IN (1, 2)
)
IF OBJECT_ID('tempdb.dbo.#Lob') IS NOT NULL
DROP TABLE #Lob
CREATE TABLE #Lob (
ObjectID    INT NOT NULL
, IndexID     INT NOT NULL
, IsLobLegacy BIT
, IsLob       BIT
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #Lob (ObjectID, IndexID, IsLobLegacy, IsLob)
SELECT c.ObjectID
, IndexID     = ISNULL(i.IndexID, 1)
, IsLobLegacy = MAX(CASE WHEN c.SystemTypeID IN (34, 35, 99) THEN 1 END)
, IsLob       = 0
FROM #Columns c
LEFT JOIN #IndexColumns i ON c.ObjectID = i.ObjectID AND c.ColumnID = i.ColumnID
WHERE c.SystemTypeID IN (34, 35, 99)
GROUP BY c.ObjectID
, i.IndexID
IF OBJECT_ID('tempdb.dbo.#Sparse') IS NOT NULL
DROP TABLE #Sparse
CREATE TABLE #Sparse (ObjectID INT PRIMARY KEY)
INSERT INTO #Sparse
SELECT DISTINCT ObjectID
FROM #Columns
WHERE IsSparse = 1
OR IsColumnSet = 1
IF OBJECT_ID('tempdb.dbo.#AggColumns') IS NOT NULL
DROP TABLE #AggColumns
CREATE TABLE #AggColumns (
ObjectID        INT NOT NULL
, IndexID         INT NOT NULL
, IndexColumns    NVARCHAR(MAX)
, IncludedColumns NVARCHAR(MAX)
, PRIMARY KEY (ObjectID, IndexID)
)
INSERT INTO #AggColumns
SELECT t.ObjectID
, t.IndexID
, IndexColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 0
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
, IncludedColumns = STUFF((
SELECT ', [' + c.ColumnName + ']'
FROM #IndexColumns i
JOIN #Columns c ON i.ObjectID = c.ObjectID AND i.ColumnID = c.ColumnID
WHERE i.ObjectID = t.ObjectID
AND i.IndexID = t.IndexID
AND i.IsIncluded = 1
ORDER BY i.OrderID
FOR XML PATH(''), TYPE).value('(./text())[1]', 'NVARCHAR(MAX)'), 1, 2, '')
FROM (
SELECT DISTINCT ObjectID, IndexID
FROM #Indexes
WHERE IndexType IN (1, 2)
) t
SELECT i.ObjectID
, i.IndexID
, i.IndexName
, ObjectName       = o.[name]
, SchemaName       = s.[name]
, i.PagesCount
, i.UnusedPagesCount
, i.PartitionNumber
, i.RowsCount
, i.IndexType
, i.IsAllowPageLocks
, u.TotalWrites
, u.TotalReads
, u.TotalSeeks
, u.TotalScans
, u.TotalLookups
, u.LastUsage
, i.DataCompression
, f.Fragmentation
, IndexStats       = STATS_DATE(i.ObjectID, i.IndexID)
, IsLobLegacy      = ISNULL(lob.IsLobLegacy, 0)
, IsLob            = ISNULL(lob.IsLob, 0)
, IsSparse         = CAST(CASE WHEN p.ObjectID IS NULL THEN 0 ELSE 1 END AS BIT)
, IsPartitioned    = CAST(CASE WHEN dds.[data_space_id] IS NOT NULL THEN 1 ELSE 0 END AS BIT)
, FileGroupName    = fg.[name]
, i.IsUnique
, i.IsPK
, i.FillFactorValue
, i.IsFiltered
, a.IndexColumns
, a.IncludedColumns
FROM #Indexes i
JOIN sys.objects o WITH(NOLOCK) ON o.[object_id] = i.ObjectID
JOIN sys.schemas s WITH(NOLOCK) ON s.[schema_id] = o.[schema_id]
LEFT JOIN #AggColumns a ON a.ObjectID = i.ObjectID AND a.IndexID = i.IndexID
LEFT JOIN #Sparse p ON p.ObjectID = i.ObjectID
LEFT JOIN #Fragmentation f ON f.ObjectID = i.ObjectID AND f.IndexID = i.IndexID AND f.PartitionNumber = i.PartitionNumber
LEFT JOIN (
SELECT ObjectID      = [object_id]
, IndexID       = [index_id]
, TotalWrites   = NULLIF([user_updates], 0)
, TotalReads    = NULLIF([user_seeks] + [user_scans] + [user_lookups], 0)
, TotalSeeks    = NULLIF([user_seeks], 0)
, TotalScans    = NULLIF([user_scans], 0)
, TotalLookups  = NULLIF([user_lookups], 0)
, LastUsage     = (
SELECT MAX(dt)
FROM (
VALUES ([last_user_seek])
, ([last_user_scan])
, ([last_user_lookup])
, ([last_user_update])
) t(dt)
)
FROM sys.dm_db_index_usage_stats WITH(NOLOCK)
WHERE [database_id] = @DBID
) u ON i.ObjectID = u.ObjectID AND i.IndexID = u.IndexID
LEFT JOIN #Lob lob ON lob.ObjectID = i.ObjectID AND lob.IndexID = i.IndexID
LEFT JOIN sys.destination_data_spaces dds WITH(NOLOCK) ON i.DataSpaceID = dds.[partition_scheme_id] AND i.PartitionNumber = dds.[destination_id]
JOIN sys.filegroups fg WITH(NOLOCK) ON ISNULL(dds.[data_space_id], i.DataSpaceID) = fg.[data_space_id] 
WHERE o.[type] IN ('V', 'U')
AND (
f.Fragmentation >= @Fragmentation
OR
i.PagesCount > @PreDescribeSize
OR
i.IndexType IN (5, 6)
)

ดังที่เห็นได้จากแบบสอบถาม ตารางชั่วคราวถูกใช้ค่อนข้างบ่อย สิ่งนี้ทำเพื่อไม่ให้มีการคอมไพล์ซ้ำ และในกรณีของโครงร่างขนาดใหญ่ แผนสามารถสร้างขึ้นพร้อมกันได้เมื่อแทรกข้อมูล เนื่องจากการแทรกตัวแปรตารางสามารถทำได้ในเธรดเดียวเท่านั้น

หลังจากรันสคริปต์ข้างต้นแล้ว หน้าต่างที่มีตารางดัชนีจะปรากฏขึ้น:

คุณยังสามารถแสดงข้อมูลรายละเอียดอื่นๆ ได้ที่นี่ เช่น:

1. ฐานข้อมูล
2. จำนวนส่วน
3. วันที่และเวลาของการโทรครั้งล่าสุด
4. การอัด
5. กลุ่มไฟล์

เป็นต้น
ตัวลำโพงสามารถปรับแต่งได้:

ในเซลล์ของคอลัมน์ Fix คุณสามารถเลือกการดำเนินการที่จะดำเนินการระหว่างการปรับให้เหมาะสมได้ นอกจากนี้ เมื่อการสแกนเสร็จสิ้น ระบบจะเลือกการดำเนินการเริ่มต้นตามการตั้งค่าที่เลือก:

คุณต้องเลือกดัชนีที่ต้องการสำหรับการประมวลผล

เมื่อใช้เมนูหลัก คุณสามารถบันทึกสคริปต์ได้ (ปุ่มเดียวกันนี้จะเริ่มกระบวนการเพิ่มประสิทธิภาพดัชนีเอง):

และบันทึกตารางในรูปแบบต่างๆ (ปุ่มเดียวกันนี้ช่วยให้คุณสามารถเปิดการตั้งค่าโดยละเอียดสำหรับการวิเคราะห์และเพิ่มประสิทธิภาพดัชนี):

คุณยังสามารถอัปเดตข้อมูลได้โดยคลิกที่ปุ่มที่สามทางด้านซ้ายในเมนูหลักถัดจากแว่นขยาย

ปุ่มพร้อมแว่นขยายช่วยให้คุณเลือกฐานข้อมูลที่ต้องการเพื่อประกอบการพิจารณา

ขณะนี้ยังไม่มีระบบช่วยเหลือที่ครอบคลุม ดังนั้นให้กดปุ่ม “?” จะทำให้หน้าต่างโมดอลปรากฏขึ้นซึ่งมีข้อมูลพื้นฐานเกี่ยวกับผลิตภัณฑ์ซอฟต์แวร์:

นอกเหนือจากทุกสิ่งที่อธิบายไว้ข้างต้นแล้ว เมนูหลักยังมีแถบค้นหา:

เมื่อเริ่มต้นกระบวนการเพิ่มประสิทธิภาพดัชนี:

คุณยังสามารถดูบันทึกการดำเนินการที่ดำเนินการที่ด้านล่างของหน้าต่าง:

ในหน้าต่างการตั้งค่าโดยละเอียดสำหรับการวิเคราะห์ดัชนีและการเพิ่มประสิทธิภาพ คุณสามารถกำหนดค่าตัวเลือกที่ละเอียดยิ่งขึ้นได้:

คำขอสำหรับการสมัคร:

1. ทำให้สามารถเลือกอัปเดตสถิติได้ไม่เพียงแต่สำหรับดัชนีเท่านั้นและในรูปแบบต่างๆ (อัปเดตทั้งหมดหรือบางส่วน)
2. ทำให้ไม่เพียงแต่สามารถเลือกฐานข้อมูลเท่านั้น แต่ยังรวมถึงเซิร์ฟเวอร์ที่แตกต่างกันด้วย (ซึ่งสะดวกมากเมื่อมี MS SQL Server หลายอินสแตนซ์)
3. เพื่อความยืดหยุ่นในการใช้งานที่มากขึ้น ขอแนะนำให้รวมคำสั่งในไลบรารีและส่งออกไปยังคำสั่ง PowerShell ดังตัวอย่างต่อไปนี้:
4. dbatools.io/commands
5. ทำให้สามารถบันทึกและเปลี่ยนแปลงการตั้งค่าส่วนบุคคลสำหรับทั้งแอปพลิเคชันและหากจำเป็นสำหรับแต่ละอินสแตนซ์ของ MS SQL Server และแต่ละฐานข้อมูล
6. จากจุดที่ 2 และ 4 เป็นไปตามที่คุณต้องการสร้างกลุ่มตามฐานข้อมูลและกลุ่มตามอินสแตนซ์ MS SQL Server ซึ่งการตั้งค่าเหมือนกัน
7. ค้นหาดัชนีที่ซ้ำกัน (สมบูรณ์และไม่สมบูรณ์ซึ่งแตกต่างกันเล็กน้อยหรือแตกต่างกันเฉพาะในคอลัมน์ที่รวมไว้)
8. เนื่องจาก SQLIndexManager ใช้สำหรับ MS SQL Server DBMS เท่านั้น จึงจำเป็นต้องสะท้อนสิ่งนี้ในชื่อ เช่น ดังนี้: SQLIndexManager สำหรับ MS SQL Server
9. ย้ายส่วนที่ไม่ใช่ GUI ทั้งหมดของแอปพลิเคชันไปยังโมดูลแยกกัน และเขียนใหม่ใน .NET Core 2.1

ในขณะที่เขียนความปรารถนาข้อ 6 กำลังได้รับการพัฒนาอย่างแข็งขันและมีการสนับสนุนอยู่แล้วในรูปแบบของการค้นหารายการที่ซ้ำกันทั้งหมดและคล้ายกัน:

แหล่งที่มา

• วิธีการหาค่าดัชนีชี้วัดแบบปรับตัวให้เหมาะสม
• ยูทิลิตี้ SQLIndexManager
• ภาพรวมทางเทคนิคโดยย่อของยูทิลิตี้ SQLIndexManager
• การอภิปรายเกี่ยวกับยูทิลิตี้ SQLIndexManager
• SQL Index Manager – เครื่องมือ GUI ฟรีสำหรับการบำรุงรักษาดัชนีบน SQL Server และ Azure
• การวิเคราะห์และการเพิ่มประสิทธิภาพดัชนีเซิร์ฟเวอร์ SQL

ที่มา: will.com