Nigbati o ba n ṣiṣẹ lori iworan data fun nkan kan, o di pataki lati ni awọn aake 4 pẹlu awọn aami rere lori gbogbo.
Gẹgẹbi pẹlu awọn aworan miiran ninu nkan naa, Mo pinnu lati lo gbuplot. Ni akọkọ, Mo wo oju opo wẹẹbu osise, nibiti ọpọlọpọ awọn apẹẹrẹ wa. Inu mi dun nigbati mo ri eyi ti o tọ (Emi yoo ṣiṣẹ pẹlu faili kan diẹ ati pe yoo dara, Mo ro).
Mo yara daakọ koodu naa ati ṣiṣe rẹ. Mo gba aṣiṣe. Mo n ro ero rẹ. O wa ni pe Mo ni gnuplot atijọ kan (Version 5.0 patchlevel 3 last modified 2016-02-21) kò sì lè ṣe bẹ́ẹ̀.
Ni mimọ nipa irọrun ti gnuplot, Mo bẹrẹ si ṣawari Wẹẹbu Wẹẹbu Agbaye ati pe Mo wa ọpọlọpọ awọn apẹẹrẹ ti o dara lori ṣiṣan ṣiṣan ( и ) ati github (). Wọn di aaye ibẹrẹ.
Pẹlupẹlu, awọn ifọwọyi mi pẹlu awọn aṣẹ naa yori si atẹle yii:
0) Pa
unset border
1) Ṣẹda awọn laini odo mẹrin - akọkọ 4 ati afikun 2:
set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis
Awọn ọrọ diẹ nipa awọn laini odo ni . Išišẹ yii ngbanilaaye lati mu awọn aake wa si aarin aworan naa. Ati awọn afikun ni a nilo lati ṣafihan awọn ami rere lori wọn.
2) Ṣeto ifihan awọn ami si awọn aake:
max = 1.5 # Для гибкости
min = -max
set xtics axis 0,.5,max in scale 0.5,0.25 mirror norotate autojustify offset 0.35
set ytics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify
Pẹlu awọn ami lori awọn aake nibẹ ni awọn eto diẹ diẹ sii.
axis - nibiti awọn ami yoo wa, lori ipo tabi (aala - lori aala).
Fun asulu x, eyi ti o lọ si ọtun 0,.5,max. Nọmba akọkọ jẹ ibẹrẹ kika, ekeji ni igbesẹ, ẹkẹta ni ipari kika. Fun igba akọkọ lati 0, ati fun awọn iyokù lati 0.5, ki awọn odo ko ba dabaru pẹlu awọn Oti.
Dapọ awọn odo ni ile-iṣẹ ipoidojuko.
Gbogbo awọn aaye arin *tics tunto bi 0,.5,max
Laisi offset 0.35 fun xtics
Ṣe akanṣe scale 0.5,0.25 mirror afikun notches si awọn ipo. Ti o ba ṣiṣẹ pẹlu awọn nọmba, iwọn wọn yoo yipada.
Mo tun tẹ awọn oniyipada max, min, pẹlu iranlọwọ ti eyi ti mo šakoso awọn aala ti awonya aake.
Alaye ni afikun lori eto awọn ami ni a le rii ninu iwe ni apakan .
3) Ṣeto awọn sakani axis:
set xrange [ min : max ]
set yrange [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]
O yẹ ki o ṣe akiyesi nibi pe awọn aake 2 bẹrẹ lati min fun magnification ati 2 ãke - pẹlu max lati dinku.
Alaye ni afikun ni apakan .
4) Fun awọn orukọ awọn aake ki o si fi wọn si ni ẹwa:
set label "H_1" at 0, max center offset char 2, 0
set label "H_2" at max+0.1, 0 center offset char -1, 1
set label "H_3" at 0, min center offset char -2, 0
set label "H_4" at min, 0 center offset char 0, 1
5) Ṣiṣe data titẹ sii
Aworan kọọkan ni awọn ọwọn 2. Nọmba laini - nọmba asopo, laini karun lati tii lupu naa. Odd iwe - ipoidojuko x, ani- y. Nitori otitọ pe gbogbo awọn aaye wa lori awọn aake, lẹhinna lati bata (x, y) ọkan nigbagbogbo odo.
Paapaa botilẹjẹpe gbogbo awọn aake 4 jẹ rere, diẹ ninu awọn data ni a ti gbe lọna atọwọdọwọ si idaji odi nitori pe o wa lori awọn aake akọkọ. x и y.
0 1 0 1.21
1 0 1.21 0
0 -1 0 -1.06
-1 0 -1.19 0
0 1 0 1.21 #Дубликат первой точки
Esi
Kikun koodu
#!/usr/bin/gnuplot -persist
#файл в кодировке cp1251 чтоб русские буквы отображались в eps
set encoding cp1251
set terminal postscript eps enhanced monochrome size 5cm,5cm
set output "./img/eps/fig2.eps"
unset border
set key at -2, 1.5 font 'LiberationSerif, 23'
set key left top samplen 4.5
set xzeroaxis
set yzeroaxis
set x2zeroaxis
set y2zeroaxis
max = 1.5
min = -max
set xtics axis 0,.5,max in scale 0.5,0.25 mirror norotate autojustify offset 0.35 font 'LiberationSerif, 20
set ytics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify font 'LiberationSerif, 20
set x2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify font 'LiberationSerif, 20
set y2tics axis .5,.5,max in scale 0.5,0.25 mirror norotate autojustify font 'LiberationSerif, 20
set xrange [ min : max ]
set yrange [ min : max ]
set x2range [ max : min ]
set y2range [ max : min ]
set label "H_1" at 0, max center offset char 2, 0 font 'LiberationSerif, 23'
set label "H_2" at max+0.1, 0 center offset char -1, 1 font 'LiberationSerif, 23'
set label "H_3" at 0, min center offset char -2, 0 font 'LiberationSerif, 23'
set label "H_4" at min, 0 center offset char 0, 1 font 'LiberationSerif, 23'
set style line 1 linetype 1 pointtype 7 linewidth 3 linecolor black
set style line 2 linetype 2 pointtype 7 linewidth 3 linecolor black
plot 'data.csv' using 1:2 title "1" w lp ls 1 ,
'data.csv' using 3:4 title "2" w lp ls 2
orisun: www.habr.com
