Salamat sa tagsulat sa blog para sa iyang report
Pasiuna
Kini nga nota gisulat pagkahuman sa komperensya ug naglangkob sa usa ka summary sa report nga akong gihatag. Ang kalihokan nahitabo sa Hunyo sa St. Petersburg. Naghunahuna nga nagtrabaho ako usa ka bloke gikan sa site sa komperensya, dili nako malikayan nga motambong niini nga kalihokan. Sa 2016 ug 2017, naminaw ko sa mga report sa komperensya, ug karong tuiga mihatag ko og presentasyon. Una, usa ka makapaikag (para kanako) nga hilisgutan ang nagpakita, nga among gipalambo , ug ikaduha, human sa dugay nga pagtuon sa lehislasyon sa Russian Federation bahin sa polisiya sa mga silot, sa negosyo diin ako nagtrabaho, kutob sa duha ka mga lisensya ang nagpakita .
Sa dili pa mopadayon sa hilisgutan sa akong pakigpulong, gusto nakong timan-an ang maayong pagkahan-ay sa kalihokan. Ang panid sa pagbisita sa komperensya naggamit usa ka imahe sa Kazan Cathedral. Ang katedral mao ang usa sa mga nag-unang atraksyon sa St. Petersburg ug tin-aw kaayo nga makita gikan sa hawanan diin ang komperensya nahitabo.
Sa entrada sa St. Petersburg State Economic University, ang mga partisipante gisugat sa mga katabang gikan sa mga estudyante - wala nila sila tugoti nga mawala. Atol sa pagparehistro, gihatag ang gagmay nga mga souvenir (usa ka dulaan - usa ka flashing spike, usa ka pen, mga sticker nga adunay mga simbolo sa Wolfram). Ang paniudto ug mga pagpahulay sa kape gilakip usab sa iskedyul sa komperensya. Namatikdan na nako ang bahin sa lamian nga kape ug pie sa dingding sa grupo - maayo ang mga chef. Uban niining pasiuna nga bahin, gusto nakong ipasiugda nga ang panghitabo mismo, ang pormat ug lokasyon niini nagdala na ug positibo nga mga emosyon.
Ang taho nga giandam nako ug ni Kirill Belov gitawag nga "Paggamit sa Wolfram Mathematica aron masulbad ang mga problema sa gigamit nga geophysics. Spectral analysis sa seismic data o "diin ang karaang mga suba midagayday." Ang sulud sa taho naglangkob sa duha ka bahin: una, ang paggamit sa mga algorithm nga magamit sa alang sa pag-analisar sa geophysical data, ug ikaduha, kini mao ang paagi sa pagbutang geophysical data ngadto sa Wolfram Mathematica.
Seismic eksplorasyon
Una kinahanglan nimo nga maghimo usa ka mubo nga ekskursiyon sa geophysics. Ang geophysics mao ang siyensiya nga nagtuon sa pisikal nga mga kabtangan sa mga bato. Aw, tungod kay ang mga bato adunay lain-laing mga kabtangan: electrical, magnetic, pagkamaunat-unat, adunay katugbang nga mga pamaagi sa geophysics: electrical prospecting, magnetic prospecting, seismic prospecting... Sa konteksto niini nga artikulo, kita lamang sa paghisgot sa seismic prospecting sa mas detalyado. Ang seismic exploration mao ang nag-unang pamaagi sa pagpangita sa lana ug gas. Ang pamaagi gibase sa paghinam-hinam sa pagkamaunat-unat nga mga pagkurog ug sa sunod nga pagrekord sa tubag gikan sa mga bato nga naglangkob sa lugar nga gitun-an. Ang mga vibration naghinam-hinam sa yuta (nga adunay dinamita o dili explosive nga mga tinubdan sa vibration sa pagkamaunat-unat nga mga vibrations) o sa dagat (nga adunay mga air gun). Ang pagkamaunat-unat nga mga vibrations mokaylap pinaagi sa bato mass, nga refracted ug nagpakita sa mga utlanan sa mga sapaw sa lain-laing mga kabtangan. Ang gipabanaag nga mga balud mobalik sa ibabaw ug girekord sa mga geophone sa yuta (kasagaran mga electrodynamic nga aparato base sa paglihok sa usa ka magnet nga gisuspinde sa usa ka coil) o mga hydrophone sa dagat (base sa piezoelectric nga epekto). Sa panahon sa pag-abot sa mga balod, ang usa makahukom sa giladmon sa geological layer.
Mga kagamitan sa pagguyod sa barko sa seismic
Ang air gun nagpukaw sa pagkamaunat-unat nga mga vibrations
Ang mga balud moagi sa bato nga masa ug girekord sa mga hydrophone
Geophysical survey research vessel "Ivan Gubkin" sa pier duol sa Blagoveshchensky Bridge sa St.
Modelo sa seismic signal
Ang mga bato adunay lainlaing pisikal nga mga kabtangan. Alang sa eksplorasyon sa seismic, ang pagkamaunat-unat nga mga kabtangan ang panguna nga hinungdanon - ang katulin sa pagpadaghan sa pagkamaunat-unat nga mga vibrations ug density. Kung ang duha ka mga layer adunay parehas o parehas nga mga kabtangan, nan ang balud "dili makamatikod" sa utlanan tali kanila. Kung ang katulin sa balud sa mga lut-od magkalainlain, unya ang pagpamalandong mahitabo sa utlanan sa mga lut-od. Kon mas dako ang kalainan sa mga kabtangan, mas grabe ang pagpamalandong. Ang intensity niini matino pinaagi sa reflectance coefficient (rc):
diin ang Ο mao ang densidad sa bato, Ξ½ ang gikusgon sa balud, ang 1 ug 2 nagpakita sa ibabaw ug ubos nga mga lut-od.
Usa sa pinakasimple ug kasagarang gigamit nga seismic signal models mao ang convolution model, kung ang natala nga seismic trace girepresentahan isip resulta sa convolution sa usa ka sequence of reflection coefficients nga adunay probing pulse:
diin s(t) - pagsubay sa seismic, i.e. tanan nga narekord sa usa ka hydrophone o geophone sa usa ka piho nga oras sa pagrekord, w(t) - ang signal nga gihimo sa air gun, n(t) - random nga kasaba.
Atong kuwentahon ang usa ka sintetikong seismic trace isip pananglitan. Atong gamiton ang Ricker pulse, kaylap nga gigamit sa seismic exploration, isip inisyal nga signal.
length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]Inisyal nga seismic impulse
Magbutang kami og duha ka mga utlanan sa giladmon nga 300 ms ug 600 ms, ug ang mga koepisyent sa pagpamalandong mahimong random nga mga numero.
rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]Pagkasunod-sunod sa mga coefficient sa pagpamalandong
Atong kuwentahon ug ipakita ang seismic trace. Tungod kay ang mga reflector coefficient adunay lain-laing mga timailhan, kita makakuha og duha ka alternating reflection sa seismic trace.
traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]Gi-simulate nga track
Alang sa kini nga pananglitan, kinahanglan nga maghimo usa ka reserbasyon - sa tinuud, ang giladmon sa mga lut-od gitino, siyempre, sa mga metro, ug ang pagkalkula sa pagsubay sa seismic mahitabo alang sa domain sa oras. Mas husto nga ibutang ang giladmon sa mga metro ug kuwentahon ang mga oras sa pag-abot nga nahibal-an ang mga katulin sa mga layer. Sa kini nga kaso, gibutang dayon nako ang mga layer sa axis sa oras.
Kung maghisgot kita bahin sa panukiduki sa kapatagan, ingon usa ka sangputanan sa ingon nga mga obserbasyon, daghang mga parehas nga serye sa oras (seismic traces) ang natala. Pananglitan, kung magtuon sa usa ka site nga 25 km ang gitas-on ug 15 km ang gilapdon, diin, ingon usa ka sangputanan sa pagtrabaho, ang matag pagsubay nagpaila sa usa ka cell nga adunay sukod nga 25x25 metros (ang ingon nga cell gitawag nga bin), ang katapusan nga array sa datos adunay 600000 nga mga pagsubay. Uban sa usa ka sampling nga oras sa 1 ms ug usa ka oras sa pagrekord sa 5 segundos, ang katapusan nga data file mahimong labaw pa sa 11 GB, ug ang gidaghanon sa orihinal nga "hilaw" nga materyal mahimong gatusan ka gigabytes.
Unsaon pagtrabaho uban kanila ?
Pakete
Ang pag-uswag sa pakete nagsugod sa VK nga bungbong sa grupo sa suporta nga nagsultig Ruso. Salamat sa mga tubag sa komunidad, dali nga nakit-an ang solusyon. Ug ingon nga resulta, kini mitubo ngadto sa usa ka seryoso nga kalamboan. Katugbang Gimarkahan pa kini sa mga moderator. Sa pagkakaron, ang package nagsuporta sa pagtrabaho sa mosunod nga mga tipo sa datos nga aktibong gigamit sa geological nga industriya:
- import sa data sa mapa sa ZMAP ug IRAP format
- import sa mga sukod sa LAS format atabay
- input ug output sa seismic files format
Aron ma-install ang package, kinahanglan nimo nga sundon ang mga panudlo sa panid sa pag-download sa gipundok nga pakete, i.e. ipatuman ang mosunod nga code sa bisan unsa :
If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
"https://wolfr.am/FiQ5oFih",
FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]Pagkahuman nga ang package ma-install sa default folder, ang agianan diin makuha ang mosunod:
FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]Isip usa ka pananglitan, among ipakita ang mga nag-unang kapabilidad sa package. Ang tawag kay tradisyonal nga gihimo para sa mga pakete sa Wolfram Language:
Get["GeologyIO`"]Ang pakete gipalambo gamit ang . Kini nagtugot kanimo sa pag-uban sa mga nag-unang gamit sa package uban sa dokumentasyon, nga sa mga termino sa presentasyon format dili lahi gikan sa dokumentasyon sa Wolfram Mathematica sa iyang kaugalingon, ug sa paghatag sa package sa pagsulay files alang sa unang kaila.
Ang ingon nga file, sa partikular, mao ang file nga "Marmousi.segy" - kini usa ka sintetikong modelo sa usa ka seksyon sa geological, nga gimugna sa French Petroleum Institute. Gamit kini nga modelo, gisulayan sa mga developer ang ilang kaugalingon nga mga algorithm alang sa pagmodelo sa natad sa balud, pagproseso sa datos, pagbag-o sa pagsubay sa seismic, ug uban pa. Ang modelo sa Marmousi mismo gitipigan sa repositoryo kung diin ang package mismo na-download. Aron makuha ang file, pagdagan ang mosunod nga code:
If[Not[FileExistsQ["Marmousi.segy"]],
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]Resulta sa import - butang nga SEGYData
Ang SEGY nga pormat naglakip sa pagtipig sa nagkalain-laing impormasyon mahitungod sa mga obserbasyon. Una, kini ang mga komento sa teksto. Naglakip kini sa kasayuran bahin sa lokasyon sa trabaho, mga ngalan sa mga kompanya nga naghimo sa mga pagsukod, ug uban pa. Sa among kaso, kini nga header gitawag pinaagi sa usa ka hangyo nga adunay yawe sa TextHeader. Ania ang usa ka pinamubo nga ulohan sa teksto:
Short[marmousi["TextHeader"]]"Ang Marmousi data set namugna sa Institute ...nimum velocity nga 1500 m/s ug maximum nga 5500 m/s)"
Mahimo nimong ipakita ang aktuwal nga geological nga modelo pinaagi sa pag-access sa mga seismic traces gamit ang "traces" key (usa sa mga feature sa package mao nga ang mga yawe kay case-insensitive):
ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]Model nga Marmousi
Sa pagkakaron, ang package usab nagtugot kanimo sa pag-load sa datos sa mga bahin gikan sa dagkong mga file, nga nagpaposible sa pagproseso sa mga file kansang gidak-on mahimong moabot sa napulo ka gigabytes. Ang mga gimbuhaton sa package naglakip usab sa mga gimbuhaton alang sa pag-eksport sa datos ngadto sa .segy ug partially apending sa katapusan sa file.
Tagsa-tagsa, kini mao ang bili noting sa pagpaandar sa package sa diha nga nagtrabaho uban sa komplikado nga gambalay sa .segy files. Tungod kay kini nagtugot kanimo dili lamang sa pag-access sa mga indibidwal nga mga pagsubay ug mga ulohan gamit ang mga yawe ug mga indeks, apan usab sa pag-usab niini ug unya isulat kini sa usa ka file. Daghan sa mga teknikal nga detalye sa pagpatuman sa GeologyIO kay lapas pa sa kasangkaran niini nga artikulo ug lagmit angayan ug bulag nga deskripsyon.
Kalambigitan sa spectral analysis sa seismic exploration
Ang abilidad sa pag-import sa seismic data ngadto sa Wolfram Mathematica nagtugot kanimo sa paggamit sa built-in nga signal processing functionality alang sa experimental data. Tungod kay ang matag seismic trace nagrepresentar sa usa ka serye sa panahon, usa sa mga nag-unang himan sa pagtuon niini mao ang spectral analysis. Lakip sa mga kinahanglanon alang sa pag-analisar sa frequency nga komposisyon sa seismic data, mahimo natong hinganlan, pananglitan, ang mosunod:
- Ang lain-laing mga matang sa mga balud gihulagway pinaagi sa lain-laing frequency komposisyon. Kini nagtugot kanimo sa pag-highlight sa mapuslanon nga mga balud ug pagsumpo sa mga interference wave.
- Ang mga kabtangan sa bato sama sa porosity ug saturation mahimong makaapekto sa komposisyon sa frequency. Kini nagpaposible sa pag-ila sa mga bato nga adunay labing maayo nga mga kabtangan.
- Ang mga lut-od nga adunay lainlaing gibag-on hinungdan sa mga anomaliya sa lainlaing mga sakup sa frequency.
Ang ikatulo nga punto mao ang panguna sa konteksto niini nga artikulo. Sa ubos usa ka tipik sa code alang sa pagkalkula sa mga pagsubay sa seismic sa kaso sa usa ka layer nga adunay lainlaing gibag-on - usa ka modelo sa wedge. Kini nga modelo tradisyonal nga gitun-an sa seismic exploration aron analisahon ang interference effects kung ang mga balud nga makita gikan sa daghang mga layer gipatong sa usag usa.
nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]Modelo sa usa ka pinch-out formation
Ang gikusgon sa balud sa sulod sa wedge mao ang 4500 m/s, sa gawas sa wedge 4000 m/s, ug ang densidad gituohan nga kanunay nga 2200 g/cmΒ³. Alang sa ingon nga modelo, among gikalkulo ang mga koepisyent sa pagpamalandong ug mga pagsubay sa seismic.
rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]Mga pagsubay sa seismic alang sa modelo sa wedge
Ang han-ay sa seismic traces nga gipakita niini nga numero gitawag og seismic section. Sama sa imong nakita, ang interpretasyon niini mahimo usab nga himuon sa usa ka intuitive nga lebel, tungod kay ang geometry sa gipakita nga mga balud tin-aw nga katumbas sa modelo nga gitakda sa sayo pa. Kung imong analisahon ang mga pagsubay sa mas detalyado, imong mamatikdan nga ang mga pagsubay gikan sa 1 ngadto sa gibana-bana nga 30 wala magkalahi - ang pagpamalandong gikan sa atop sa pagporma ug gikan sa ubos dili magsapaw sa usag usa. Sugod sa ika-31 nga pagsubay, ang mga pagpamalandong nagsugod sa pagpanghilabot. Ug, bisan pa sa modelo, ang mga koepisyent sa pagpamalandong wala magbag-o nga pinahigda - ang mga pagsubay sa seismic nagbag-o sa ilang kakusog samtang nagbag-o ang gibag-on sa pagporma.
Atong tagdon ang amplitude sa pagpamalandong gikan sa ibabaw nga utlanan sa pagporma. Sugod gikan sa ika-60 nga ruta, ang intensity sa pagpamalandong nagsugod sa pagdugang ug sa ika-70 nga ruta kini mahimong labing kataas. Kini ang paagi nga ang pagpanghilabot sa mga balud gikan sa atop ug sa ilawom sa mga lut-od nagpakita sa kaugalingon, nga nagdala sa pipila ka mga kaso sa hinungdanon nga mga anomaliya sa rekord sa seismic.
ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]Graph sa amplitude sa gipakita nga balud gikan sa ibabaw nga ngilit sa wedge
Makataronganon nga kung ang signal mas ubos nga frequency, ang interference magsugod sa pagpakita sa dagkong mga gibag-on sa pormasyon, ug sa kaso sa usa ka high-frequency nga signal, ang interference mahitabo sa mas gagmay nga mga gibag-on. Ang mosunod nga code snippet nagmugna og signal nga adunay frequency nga 35 Hz, 55 Hz ug 85 Hz.
waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]Usa ka hugpong sa mga tinubdan nga signal nga adunay mga frequency nga 35 Hz, 55Hz, 85Hz
Pinaagi sa pagkuwenta sa mga seismic traces ug pagplano sa mga graph sa reflected wave amplitudes, atong makita nga para sa lain-laing frequency usa ka anomaliya ang makita sa lain-laing gibag-on sa formation.
tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];
lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]Mga graph sa mga amplitude sa gipakita nga balud gikan sa ibabaw nga ngilit sa wedge alang sa lainlaing mga frequency
Ang katakus sa paghimo og mga konklusyon bahin sa gibag-on sa pagporma gikan sa mga resulta sa mga obserbasyon sa seismic labi ka mapuslanon, tungod kay ang usa sa mga nag-unang tahas sa eksplorasyon sa lana mao ang pagtimbang-timbang sa labing maayong mga punto alang sa pagbutang sa usa ka atabay (ie, kadtong mga lugar diin ang pagporma mao ang mas baga). Dugang pa, sa seksyon sa geological mahimong adunay mga butang kansang genesis hinungdan sa usa ka mahait nga pagbag-o sa gibag-on sa pagporma. Kini naghimo sa spectral analysis nga usa ka epektibo nga himan sa pagtuon niini. Sa sunod nga bahin sa artikulo atong hisgotan ang maong geolohikong mga butang sa mas detalyado.
Eksperimental nga datos. Asa nimo sila gikuha ug unsay pangitaon niini?
Ang mga materyal nga gisusi sa artikulo nakuha sa Western Siberia. Ang rehiyon, ingon nga nahibal-an sa tanan nga walaβy eksepsiyon, mao ang nag-unang rehiyon nga naghimo og lana sa atong nasud. Ang aktibo nga pag-uswag sa mga deposito nagsugod sa rehiyon sa 60s sa miaging siglo. Ang nag-unang pamaagi sa pagpangita sa mga deposito sa lana mao ang seismic exploration. Makapainteres nga tan-awon ang mga satellite nga mga imahe sa kini nga teritoryo. Sa gamay nga sukod, mahimo nimong matikdan ang daghang mga kalamakan ug mga lanaw; pinaagi sa pagpalapad sa mapa, makita nimo ang mga lugar nga pag-drill sa cluster well, ug pinaagi sa pagpadako sa mapa hangtod sa limitasyon, mahimo usab nimo mailhan ang mga paghawan sa mga profile diin ang seismic obserbasyon gihimo.
Satellite nga hulagway sa Yandex nga mga mapa - Noyabrsk city area
Usa ka network sa mga well pad sa usa sa mga uma
Ang mga bato nga nagdala sa lana sa Western Siberia mahitabo sa usa ka halapad nga giladmon - gikan sa 1 km hangtod sa 5 km. Ang panguna nga gidaghanon sa mga bato nga adunay sulud nga lana naporma sa mga panahon sa Jurassic ug Cretaceous. Ang panahon sa Jurassic lagmit nahibal-an sa kadaghanan gikan sa pelikula nga parehas nga ngalan. lahi kaayo gikan sa moderno. Ang Encyclopedia Britannica adunay usa ka serye sa mga paleomaps nga nagpaila sa matag helogical nga panahon.
Karon
Jurassic nga panahon
Palihug timan-i nga sa panahon sa Jurassic, ang teritoryo sa Western Siberia kay usa ka baybayon sa dagat (yuta nga gitabok sa mga suba ug usa ka mabaw nga dagat). Tungod kay komportable ang klima, mahimo natong hunahunaon nga ang usa ka tipikal nga talan-awon nianang panahona ingon niini:
Jurassic Siberia
Niini nga hulagway, ang importante kanato dili ang mga mananap ug mga langgam, kondili ang larawan sa suba sa luyo. Ang suba mao ra ang geological nga butang nga among gihunongan kaniadto. Ang kamatuoran mao nga ang kalihokan sa mga suba nagtugot sa maayong pagkahan-ay nga mga sandstone nga matigom, nga unya mahimong reservoir sa lana. Kini nga mga reservoir mahimo nga adunay usa ka talagsaon, komplikado nga porma (sama sa usa ka sapa sa sapa) ug kini adunay lainlain nga gibag-on - duol sa mga bangko gamay ra ang gibag-on, apan mas duol sa sentro sa agianan o sa mga lugar nga liko-liko kini nagdugang. Busa, ang mga suba nga naporma sa Jurassic anaa na sa giladmon nga mga tulo ka kilometro ug maoy tumong sa pagpangita sa mga reservoir sa lana.
Eksperimental nga datos. Pagproseso ug paghanduraw
Himoon dayon nato ang usa ka reserbasyon mahitungod sa mga materyales sa seismic nga gipakita sa artikulo - tungod sa kamatuoran nga ang gidaghanon sa datos nga gigamit alang sa pagtuki mahinungdanon - usa lamang ka tipik sa orihinal nga hugpong sa mga seismic traces ang gilakip sa teksto sa artikulo. Kini magtugot sa bisan kinsa sa pagkopya sa mga kalkulasyon sa ibabaw.
Kung nagtrabaho uban ang seismic data, ang usa ka geophysicist kasagaran naggamit sa espesyal nga software (adunay daghang mga lider sa industriya kansang mga pag-uswag aktibo nga gigamit, pananglitan Petrel o Paradigm), nga nagtugot kanimo sa pag-analisar sa lainlaing mga lahi sa datos ug adunay usa ka kombenyente nga graphical interface. Bisan pa sa tanan nga kasayon, kini nga mga matang sa software adunay mga kakulangan usab - pananglitan, ang pagpatuman sa mga modernong algorithm sa mga stable nga bersyon nanginahanglan daghang oras, ug ang mga posibilidad sa pag-automate sa mga kalkulasyon kasagaran limitado. Sa ingon nga sitwasyon, kini mahimong sayon ββββkaayo nga gamiton ang mga sistema sa matematika sa kompyuter ug mga high-level nga programming language, nga nagtugot sa paggamit sa usa ka lapad nga base sa algorithm ug, sa samang higayon, naghimo sa daghang rutina. Kini ang prinsipyo nga gigamit sa pagtrabaho sa seismic data sa Wolfram Mathematica. Dili angay nga isulat ang daghang gamit alang sa interactive nga trabaho nga adunay data - mas hinungdanon nga masiguro ang pagkarga gikan sa usa ka kasagarang gidawat nga format, pagpadapat sa gusto nga mga algorithm sa kanila ug i-upload kini balik sa usa ka eksternal nga format.
Pagsunod sa gisugyot nga laraw, among ikarga ang orihinal nga datos sa seismic ug ipakita kini :
Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]Ang datos nga gi-download ug gi-import niining paagiha mao ang mga ruta nga natala sa usa ka lugar nga may sukod nga 10 por 5 ka kilometro. Kung ang datos makuha gamit ang three-dimensional nga seismic survey nga pamaagi (ang mga balud girekord dili subay sa indibidwal nga geophysical profiles, apan sa tibuok nga lugar dungan), mahimong posible nga makakuha og seismic data cubes. Kini ang tulo-ka-dimensyon nga mga butang, bertikal ug pinahigda nga mga seksyon nga nagtugot sa usa ka detalyado nga pagtuon sa geological nga palibot. Sa pananglitan nga gikonsiderar, nag-atubang kami sa tulo-ka-dimensional nga datos. Makakuha kita og pipila ka impormasyon gikan sa ulohan sa teksto, sama niini
StringPartition[seismic3DSEGY["textheader"], 80] // TableFormC 1 KINI ANG DEMO FILE PARA SA GEOLOGYIO PACKAGE TEST
C 2
C 3
C 4
C 5 PETSA NGA NGALAN SA USER: WOLFRAM USER
C 6 SURVEY NGA NGALAN: ASA SA SIBERIA
C 7 FILE TYPE 3D SEISMIC VOLUME
C 8
C 9
C10 Z RANGE: UNANG 2200M KATAPUSAN 2400M
Kini nga set sa datos igo na alang kanamo aron ipakita ang mga nag-unang yugto sa pagtuki sa datos. Ang mga pagsubay sa file girekord nga sunud-sunod ug ang matag usa kanila sama sa mosunud nga numero - kini ang pag-apod-apod sa mga amplitude sa gipakita nga mga balud ubay sa bertikal nga axis (depth axis).
ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2,
PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
LabelStyle -> Directive[Black, Italic], PlotRange -> All,
Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]Usa sa mga pagsubay sa seismic section
Nahibal-an kung pila ka mga pagsubay ang nahimutang sa matag direksyon sa gitun-an nga lugar, mahimo kang makamugna og usa ka three-dimensional data array ug ipakita kini gamit ang Image3D [] function.
traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*ΠΊΠΎΠΎΡΠ΄ΠΈΠ½Π°ΡΠ° Π₯ Π½Π°ΡΠ°Π»Π° ΠΈ ΠΊΠΎΠ½ΡΠ° ΡΡΡΠΌΠΊΠΈ ΠΈ ΡΠ°Π³ ΡΡΠ°ΡΡ*)
startXL=1165;EndXL=1615;stepXL=2; (*ΠΊΠΎΠΎΡΠ΄ΠΈΠ½Π°ΡΠ° Y Π½Π°ΡΠ°Π»Π° ΠΈ ΠΊΠΎΠ½ΡΠ° ΡΡΡΠΌΠΊΠΈ ΠΈ ΡΠ°Π³ ΡΡΠ°ΡΡ*)
numIL=(EndIL-startIL)/stepIL+1; (*ΠΊΠΎΠ»ΠΈΡΠ΅ΡΡΠ²ΠΎ ΡΡΠ°ΡΡ ΠΏΠΎ ΠΎΠΈΡ Π₯*)
numXL=(EndXL-startXL)/stepIL+1; (*ΠΊΠΎΠ»ΠΈΡΠ΅ΡΡΠ²ΠΎ ΡΡΠ°ΡΡ ΠΏΠΎ ΠΎΠΈΡ Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]XNUMXD nga hulagway sa usa ka seismic data cube. (Vertical axis - giladmon)
Kung ang geological nga mga bahin sa interes makamugna og grabe nga seismic anomalies, nan ang visualization tools nga adunay transparency mahimong magamit. Ang "dili importante" nga mga dapit sa pagrekord mahimong dili makita, nga magbilin lamang sa mga anomaliya nga makita. Sa Wolfram Mathematica mahimo kini gamit ΠΈ .
data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]},
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]Seismic data cube image gamit ang Opacity [] ug Raster3D [] functions
Sama sa sintetikong pananglitan, sa mga seksiyon sa orihinal nga cube ang usa makaila sa pipila ka geological boundaries (layers) nga may variable relief.
Ang nag-unang himan alang sa spectral analysis mao ang Fourier transform. Uban sa tabang niini, mahimo nimong susihon ang amplitude-frequency spectrum sa matag pagsubay o grupo sa mga pagsubay. Bisan pa, pagkahuman sa pagbalhin sa datos sa frequency domain, nawala ang kasayuran kung unsang orasa (basaha kung unsa ang giladmon) ang pagbag-o sa frequency. Aron ma-localize ang mga pagbag-o sa signal sa oras (depth) axis, gigamit ang windowed Fourier transform ug wavelet decomposition. Kini nga artikulo naggamit sa wavelet decomposition. Ang teknolohiya sa pagtuki sa wavelet nagsugod nga aktibong gigamit sa eksplorasyon sa seismic sa dekada 90. Ang bentaha sa windowed Fourier nga pagbag-o giisip nga mas maayo nga resolusyon sa oras.
Gamit ang mosunud nga tipik sa code, mahimo nimong madunot ang usa sa mga pagsubay sa seismic sa mga indibidwal nga sangkap:
cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]Pagkadunot sa usa ka pagsubay ngadto sa mga sangkap
Aron masusi kung giunsa ang pag-apod-apod sa enerhiya sa pagpamalandong sa lainlaing mga oras sa pag-abot sa balud, gigamit ang mga scalograms (kaamgid sa usa ka spectrogram). Ingon sa usa ka lagda, sa praktis dili kinahanglan nga analisahon ang tanan nga mga sangkap. Kasagaran, ang ubos, tunga-tunga ug taas nga frequency nga mga sangkap gipili.
freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]Scalogram. Resulta sa function
Ang Wolfram Language naggamit sa function alang sa pagbag-o sa wavelet . Ug ang paggamit niini nga function sa tibuuk nga set sa mga pagsubay himuon gamit ang function . Dinhi angay nga matikdan ang usa sa mga kalig-on sa Wolfram Mathematica - ang abilidad sa paggamit sa parallelization . Sa panig-ingnan sa ibabaw, wala'y kinahanglan alang sa parallelization - ang gidaghanon sa datos dili dako, apan sa diha nga nagtrabaho uban sa mga eksperimento data set nga naglangkob sa gatusan ka libo nga mga pagsubay, kini mao ang usa ka kinahanglanon.
tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}]; Human sa paggamit sa function Ang mga bag-ong set sa datos makita nga katumbas sa gipili nga mga frequency. Sa pananglitan sa ibabaw, kini nga mga frequency mao ang: 38Hz, 33Hz, 27Hz. Ang pagpili sa mga frequency sagad nga gihimo pinasukad sa pagsulay - nakakuha sila epektibo nga mga mapa alang sa lainlaing mga kombinasyon sa frequency ug gipili ang labing kasayuran gikan sa punto sa pagtan-aw sa usa ka geologist.
Kung kinahanglan nimo nga ipaambit ang mga resulta sa mga kauban o ihatag kini sa kustomer, mahimo nimong gamiton ang SEGYExport [] function sa GeologyIO package
outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];Uban sa tulo niini nga mga cubes (low-frequency, mid-frequency, ug high-frequency nga mga component), ang RGB blending kasagarang gigamit sa paghanduraw sa data nga magkauban. Ang matag sangkap gi-assign sa kaugalingon nga kolor - pula, berde, asul. Sa Wolfram Mathematica mahimo kini gamit ang function .
Ang resulta mao ang mga hulagway diin mahimo ang geological interpretation. Ang mga meander nga natala sa seksyon nagpaposible sa pagdelineate sa mga paleochannel, nga mas lagmit nga mga reservoir ug adunay mga reserba sa lana. Ang pagpangita ug pagtuki sa modernong mga analogue sa ingon nga sistema sa suba nagtugot kanato sa pagtino sa labing maayong mga bahin sa meanders. Ang mga agianan mismo gihulagway sa baga nga mga lut-od sa maayong pagkahan-ay nga sandstone ug usa ka maayong reservoir alang sa lana. Ang mga lugar sa gawas sa mga anomaliya sa "lace" susama sa modernong mga deposito sa baha. Ang mga deposito sa Floodplain kasagarang girepresentahan sa lapok nga mga bato ug ang pag-drill niini nga mga sona dili epektibo.
RGB nga hiwa sa data cube. Sa tunga (gamay sa wala sa sentro) masubay nimo ang naglikoliko nga suba.
RGB nga hiwa sa data cube. Sa wala nga bahin masubay nimo ang naglikoliko nga suba.
Sa pipila ka mga kaso, ang kalidad sa seismic data nagtugot alang sa labi ka klaro nga mga imahe. Kini nag-agad sa field work methodology, ang mga ekipo nga gigamit sa noise reduction algorithm. Sa ingon nga mga kaso, dili lamang mga tipik sa mga sistema sa suba ang makita, apan usab ang tibuuk nga gipalapdan nga mga suba sa paleo.
RGB nga pagsagol sa tulo ka sangkap sa usa ka seismic data cube (horizontal slice). Gibana-bana nga 2 km ang giladmon.
Satellite nga hulagway sa Volga River duol sa Saratov
konklusyon
Gitugotan ka ni Wolfram Mathematica sa pag-analisar sa datos sa seismic ug pagsulbad sa mga problema nga may kalabotan sa eksplorasyon sa mineral, ug ang pakete nga GeologyIO naghimo niini nga proseso nga labi ka dali. Ang istruktura sa datos sa seismic mao ang paggamit sa mga built-in nga pamaagi aron mapadali ang mga kalkulasyon (, ,β¦) episyente kaayo ug nagtugot kanimo sa pagproseso sa daghang mga datos. Sa usa ka dako nga gidak-on, kini gipadali sa mga bahin sa pagtipig sa datos sa pakete sa GeologyIO. Pinaagi sa dalan, ang pakete mahimong magamit dili lamang sa natad sa gipadapat nga seismic exploration. Halos parehas nga mga tipo sa datos ang gigamit sa ground penetrating radar ug seismology. Kung naa kay mga sugyot kung giunsa pagpauswag ang resulta, kung unsang mga algorithm sa pag-analisa sa signal gikan sa arsenal sa Wolfram Mathematica ang magamit sa ingon nga datos, o kung adunay ka pagsaway, palihug ibilin ang usa ka komentaryo.
Source: www.habr.com