Taing do ùghdar a’ bhlog airson an aithris aige
Ro-ràdh
Chaidh an nota seo a sgrìobhadh an dèidh na co-labhairt agus tha geàrr-chunntas ann den aithisg a thug mi seachad. Thachair an tachartas san Ògmhios ann an St Petersburg. Leis gu bheil mi ag obair bloc bho làrach na co-labhairt, cha b’ urrainn dhomh cuideachadh ach a bhith an làthair aig an tachartas seo. Ann an 2016 agus 2017, dh'èist mi ri aithisgean co-labhairt, agus am-bliadhna thug mi seachad taisbeanadh. An toiseach, tha cuspair inntinneach (tha e coltach riumsa) air nochdadh, leis a bheil sinn a’ leasachadh , agus san dàrna àite, às deidh sgrùdadh fada air reachdas Caidreachas na Ruis a thaobh poileasaidh smachd-bhannan, aig an iomairt far a bheil mi ag obair, nochd suas ri dà chead .
Mus gluais mi air adhart gu cuspair na h-òraid agam, bu mhath leam mothachadh a thoirt air eagrachadh math an tachartais. Bidh duilleag tadhail na co-labhairt a 'cleachdadh ìomhaigh de Chathair-eaglais Kazan. Tha a 'chathair-eaglais mar aon de na prìomh àiteachan tarraingeach ann an St Petersburg agus tha e ri fhaicinn gu soilleir bhon talla anns an deach a' cho-labhairt a chumail.
Aig an t-slighe a-steach gu Oilthigh Eaconamach Stàite St Petersburg, choinnich luchd-cuideachaidh bho na h-oileanaich ri com-pàirtichean - cha do leig iad leotha a dhol air chall. Rè clàradh, chaidh cuimhneachain beaga a thoirt seachad (dèideag - spìc frasach, peann, stiogairean le samhlaidhean Wolfram). Bha biadh-bidhe agus cofaidh air an gabhail a-steach ann an clàr na co-labhairt cuideachd. Thug mi fa-near mu thràth mu chofaidh is paidhean blasta air balla na buidhne - tha na còcairean sgoinneil. Leis a’ phàirt tòiseachaidh seo, bu mhath leam a dhaingneachadh gu bheil an tachartas fhèin, a chruth agus a shuidheachadh mu thràth a’ toirt deagh fhaireachdainnean.
Canar “A’ cleachdadh Wolfram Mathematica gus fuasgladh fhaighinn air duilgheadasan ann an geo-fiosaigs gnìomhaichte an aithisg a chaidh ullachadh leam fhìn agus Kirill Belov. Mion-sgrùdadh speactram air dàta seismic no “far an robh seann aibhnichean a’ ruith. ” Tha susbaint na h-aithisge a’ còmhdach dà phàirt: an toiseach, cleachdadh algoirmean a tha rim faighinn ann an airson mion-sgrùdadh dàta geo-fhiosaigeach, agus san dàrna h-àite, seo mar a chuireas tu dàta geo-fhiosaigeach ann an Wolfram Mathematica.
Rannsachadh seismeach
An toiseach feumaidh tu turas goirid a dhèanamh gu geo-fhiosaig. Is e geo-fhiosaig an saidheans a bhios a’ sgrùdadh feartan fiosaigeach chreagan. Uill, leis gu bheil feartan eadar-dhealaichte aig creagan: dealanach, magnetach, elastagach, tha dòighean geo-fiosaig co-fhreagarrach ann: lorg dealain, lorg magnetach, lorg seismeach ... Ann an co-theacsa an artaigil seo, cha bhith sinn a’ bruidhinn ach air lorgaireachd seismeach. Is e sgrùdadh seismic am prìomh dhòigh air ola is gas a lorg. Tha an dòigh seo stèidhichte air a bhith a’ dùsgadh crithean elastagach agus a’ clàradh freagairt nan creagan a tha a’ dèanamh suas an raon sgrùdaidh às deidh sin. Tha crith-thalmhainn air bhioran air tìr (le stòran crathaidh dynamite no neo-spreadhaidh de chreathadh elastagach) no aig muir (le gunnaichean adhair). Bidh crith-thalmhainn elastagach a’ sgaoileadh tro mhullach na creige, gan ath-bhualadh agus a’ nochdadh aig crìochan sreathan le feartan eadar-dhealaichte. Bidh tonnan meòrachail a ’tilleadh chun uachdar agus air an clàradh le geophones air tìr (mar as trice innealan electrodynamic stèidhichte air gluasad magnet crochte ann an coil) no hydrophones sa mhuir (stèidhichte air a’ bhuaidh piezoelectric). Mun àm a thig na tuinn, faodaidh duine breithneachadh a dhèanamh air doimhneachd sreathan geòlais.
Uidheam tarraing soitheach seismic
Bidh an gunna èadhair a’ togail crith elastagach
Bidh na tonnan a’ dol tro mhullach na creige agus air an clàradh le hydrophones
Soitheach sgrùdaidh suirbhidh geo-fhiosaigeach "Ivan Gubkin" aig a 'chidhe faisg air Drochaid Blagoveshchensky ann an St.
Modail chomharran seismic
Tha feartan corporra eadar-dhealaichte aig creagan. Airson sgrùdadh seismic, tha feartan elastagach gu sònraichte cudromach - astar iomadachadh crith elastagach agus dùmhlachd. Ma tha na h-aon fheartan no feartan co-chosmhail aig dà shreath, cha toir an tonn “mothachadh” don chrìoch eatorra. Ma tha astar nan tonn anns na sreathan eadar-dhealaichte, thig meòrachadh aig crìoch nan sreathan. Mar as motha an eadar-dhealachadh ann an togalaichean, is ann as dian a bhios am meòrachadh. Bidh an dian aige air a dhearbhadh leis a’ cho-èifeachd meòrachaidh (rc):
far a bheil ρ an dùmhlachd creige, is e ν astar na tuinn, tha 1 agus 2 a’ comharrachadh na sreathan àrda is ìosal.
Is e aon de na modalan comharran seismic as sìmplidh agus as trice a chleachdar am modail convolution, nuair a tha an lorg seismic clàraichte air a riochdachadh mar thoradh air sreath de cho-èifeachdan meòrachaidh le buille sgrùdaidh:
far a bheil s(t) - lorg seismic, i.e. a h-uile càil a chaidh a chlàradh le hydrophone no geophone aig àm clàraidh stèidhichte, w(t) - an comharra a ghineadh leis a’ ghunna adhair, n(t) - fuaim air thuaiream.
Leig dhuinn cunntas a dhèanamh air lorg seismic synthetigeach mar eisimpleir. Cleachdaidh sinn an Ricker Pulse, air a chleachdadh gu farsaing ann an sgrùdadh seismic, mar a’ chiad chomharra.
length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]Spreagadh seismic tùsail
Suidhichidh sinn dà chrìoch aig doimhneachd 300 ms agus 600 ms, agus bidh na co-èifeachdan meòrachaidh nan àireamhan air thuaiream
rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]Sreath de cho-èifeachdan meòrachaidh
Feuch an dèan sinn àireamhachadh agus taisbeanadh an lorg seismic. Leis gu bheil comharran eadar-dhealaichte aig na co-èifeachdan meòrachaidh, gheibh sinn dà mheòrachadh mu seach air an lorg seismic.
traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]Slighe samhlaichte
Airson an eisimpleir seo, feumar glèidheadh - ann an da-rìribh, tha doimhneachd nan sreathan air a dhearbhadh, gu dearbh, ann am meatairean, agus tha àireamhachadh an lorg seismic a ’tachairt airson an raon ùine. Bhiodh e na bu cheart an doimhneachd a shuidheachadh ann am meatairean agus obrachadh a-mach na h-amannan ruighinn le fios air na luaths anns na sreathan. Anns a 'chùis seo, chuir mi na sreathan air an axis ùine sa bhad.
Ma tha sinn a 'bruidhinn mu dheidhinn rannsachadh làraich, an uairsin mar thoradh air na beachdan sin tha àireamh mhòr de shreathan ùine coltach (lorgan seismic) air an clàradh. Mar eisimpleir, nuair a bhios tu a’ sgrùdadh làrach 25 km a dh’ fhaid agus 15 km de leud, far a bheil, mar thoradh air an obair, a’ comharrachadh cealla le tomhas 25x25 meatairean (canar biona ri cealla mar sin), bidh 600000 lorg anns an raon dàta mu dheireadh. Le ùine samplachaidh de 1 ms agus ùine clàraidh de 5 diogan, bidh am faidhle dàta mu dheireadh nas motha na 11 GB, agus faodaidh meud an stuth “amh” tùsail a bhith ceudan de gigabytes.
Ciamar a bhith ag obair còmhla riutha ?
Pasgan
Thòisich leasachadh a 'phacaid air balla VK a 'bhuidheann taic Ruiseanach. Taing do fhreagairtean na coimhearsnachd, chaidh fuasgladh a lorg gu math luath. Agus mar thoradh air an sin, dh'fhàs e gu bhith na fhìor leasachadh. Co-fhreagairt Bha e eadhon air a chomharrachadh le modaireatairean. An-dràsta, tha am pasgan a’ toirt taic do bhith ag obair leis na seòrsaichean dàta a leanas a thathas a’ cleachdadh gu gnìomhach ann an gnìomhachas geòlais:
- toirt a-steach dàta mapa ann an cruthan ZMAP agus IRAP
- toirt a-steach tomhais ann an tobraichean cruth LAS
- cuir a-steach agus toradh cruth faidhlichean seismic
Gus am pasgan a stàladh, feumaidh tu leantainn ris an stiùireadh air duilleag luchdaich sìos a’ phacaid cruinnichte, i.e. cuir an gnìomh a’ chòd a leanas ann an gin :
If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
"https://wolfr.am/FiQ5oFih",
FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]Às deidh sin thèid am pasgan a chuir a-steach sa phasgan bunaiteach, agus gheibhear an t-slighe gu mar a leanas:
FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]Mar eisimpleir, seallaidh sinn prìomh chomasan a’ phacaid. Bithear a’ gairm gu traidiseanta airson pacaidean ann an Cànan Wolfram:
Get["GeologyIO`"]Tha am pasgan air a leasachadh le bhith a’ cleachdadh . Leigidh seo leat a dhol còmhla ri prìomh ghnìomhachd a ’phacaid le sgrìobhainnean, nach eil a thaobh cruth taisbeanaidh eadar-dhealaichte bho sgrìobhainnean Wolfram Mathematica fhèin, agus faidhlichean deuchainn a thoirt don phacaid airson a’ chiad neach-eòlais.
Is e faidhle mar seo, gu sònraichte, am faidhle “Marmousi.segy” - is e seo modal synthetigeach de roinn geòlais, a chaidh a leasachadh le Institiùd Petroleum na Frainge. A’ cleachdadh a’ mhodail seo, bidh luchd-leasachaidh a’ dèanamh deuchainn air na h-algorithms aca fhèin airson modaladh raointean tonn, giollachd dàta, tionndadh lorg seismic, msaa. Tha am modail Marmousi fhèin air a stòradh anns an stòr far an deach am pasgan fhèin a luchdachadh sìos. Gus am faidhle fhaighinn, ruith an còd a leanas:
If[Not[FileExistsQ["Marmousi.segy"]],
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]Toradh ion-phortadh - nì SEGYData
Tha cruth SEGY a’ toirt a-steach stòradh diofar fiosrachaidh mu bheachdan. An toiseach, is iad sin beachdan teacsa. Tha seo a’ toirt a-steach fiosrachadh mu shuidheachadh na h-obrach, ainmean nan companaidhean a rinn na tomhais, msaa. Anns a ’chùis againn, tha an bann-cinn seo air a ghairm le iarrtas leis an iuchair TextHeader. Seo ceann-cinn teacsa nas giorra:
Short[marmousi["TextHeader"]]“Chaidh an seata dàta Marmousi a chruthachadh aig an Institiud ... an astar as ìsle de 1500 m / s agus suas ri 5500 m / s)”
Faodaidh tu am fìor mhodail geòlais a thaisbeanadh le bhith a’ faighinn cothrom air na lorgan seismic a’ cleachdadh an iuchair “lorgan” (is e aon de fheartan a’ phacaid gu bheil na h-iuchraichean neo-mhothachail air cùisean):
ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]Modail Marmousi
An-dràsta, leigidh am pasgan leat dàta a luchdachadh ann am pàirtean bho fhaidhlichean mòra, ga dhèanamh comasach faidhlichean a phròiseasadh aig a bheil meud a ruigeas deichean de gigabytes. Tha gnìomhan a’ phacaid cuideachd a’ toirt a-steach gnìomhan airson às-mhalairt dàta gu .segy agus gu ìre a’ cur ri deireadh an fhaidhle.
Air leth, is fhiach toirt fa-near gnìomhachd a ’phacaid nuair a bhios tu ag obair le structar iom-fhillte .segy faidhlichean. Leis gu bheil e a ’toirt cothrom dhut chan ann a-mhàin faighinn gu lorgan agus cinn-cinn fa leth a’ cleachdadh iuchraichean agus clàran-amais, ach cuideachd an atharrachadh agus an sgrìobhadh gu faidhle. Tha mòran de na mion-fhiosrachadh teicnigeach mu bhuileachadh GeologyIO taobh a-muigh raon an artaigil seo agus is dòcha gu bheil iad airidh air tuairisgeul air leth.
Co-cheangailte ri mion-sgrùdadh spectral ann an sgrùdadh seismic
Leigidh an comas dàta seismic a thoirt a-steach gu Wolfram Mathematica dhut comas giullachd chomharran togte a chleachdadh airson dàta deuchainneach. Leis gu bheil gach lorg seismic a’ riochdachadh sreath ùine, is e mion-sgrùdadh speurail aon de na prìomh innealan airson an sgrùdadh. Am measg nan ro-ghoireasan airson mion-sgrùdadh air tricead co-dhèanamh dàta seismic, faodaidh sinn ainmeachadh, mar eisimpleir, na leanas:
- Tha diofar sheòrsaichean tonnan air an comharrachadh le diofar cho-dhèanamh tricead. Leigidh seo leat tonnan feumail a shoilleireachadh agus tonnan eadar-theachd a chumail fodha.
- Faodaidh feartan creige leithid porosity agus sùghaidh buaidh a thoirt air co-dhèanamh tricead. Tha seo ga dhèanamh comasach creagan leis na feartan as fheàrr aithneachadh.
- Bidh sreathan le diofar thiugh ag adhbhrachadh neo-riaghailteachdan ann an diofar raointean tricead.
Is e an treas puing am prìomh fhear ann an co-theacsa an artaigil seo. Gu h-ìosal tha criomag de chòd airson a bhith a 'cunntadh comharran seismic ann an cùis còmhdach le diofar thiugh - modail pìos. Tha am modail seo gu traidiseanta air a sgrùdadh ann an sgrùdadh seismic gus mion-sgrùdadh a dhèanamh air buaidhean eadar-theachd nuair a thèid tonnan a chithear bho iomadh sreathan a chuir thairis air a chèile.
nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]Modail de chruthachadh pinch-out
Is e astar na tonn taobh a-staigh na pìos 4500 m / s, taobh a-muigh na pìos 4000 m / s, agus thathas a’ gabhail ris gu bheil an dùmhlachd seasmhach 2200 g / cm³. Airson a leithid de mhodail, bidh sinn a 'cunntadh co-èifeachdan meòrachaidh agus comharran seismic.
rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]Lorgan seismic airson a’ mhodail wedge
Canar earrann seismic ris an t-sreath de lorgan seismic a chithear san fhigear seo. Mar a chì thu, faodar a mhìneachadh a dhèanamh cuideachd aig ìre intuitive, leis gu bheil geoimeatraidh nan tonnan a tha air an nochdadh gu soilleir a ’freagairt ris a’ mhodail a chaidh a shònrachadh na bu thràithe. Ma nì thu sgrùdadh nas mionaidiche air na lorgan, chì thu nach eil comharran bho 1 gu timcheall air 30 eadar-dhealaichte - chan eil am meòrachadh bho mhullach an cruthachadh agus bhon bhonn a ’dol thairis air a chèile. A 'tòiseachadh bhon 31mh lorg, tha na faileasan a' tòiseachadh a 'cur bacadh air. Agus, ged a tha e sa mhodail, chan eil na co-èifeachdan meòrachaidh ag atharrachadh gu còmhnard - bidh na comharran seismic ag atharrachadh an dian mar a bhios tiugh an cruthachaidh ag atharrachadh.
Beachdaichidh sinn air meud meòrachaidh bho chrìoch àrd an cruthachadh. A 'tòiseachadh bhon 60mh slighe, tha dian a' mheòrachadh a 'tòiseachadh a' dol am meud agus aig an t-slighe 70mh bidh e nas àirde. Seo mar a tha eadar-theachd tonnan bho mhullach is bonn nan sreathan ga nochdadh fhèin, a’ leantainn ann an cuid de chùisean gu neo-riaghailteachdan mòra anns a’ chlàr seismic.
ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]Graf de leud na tonn a tha air a nochdadh bho oir àrd na pìos
Tha e loidsigeach nuair a tha an comharra tricead nas ìsle, gu bheil eadar-theachd a’ tòiseachadh a ’nochdadh aig tiugh cruthachaidh mòr, agus a thaobh comharra àrd-tricead, bidh casg a’ tachairt aig tiugh nas lugha. Tha an criomag còd a leanas a’ cruthachadh comharra le triceadan 35 Hz, 55 Hz agus 85 Hz.
waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]Seata de chomharran stòr le triceadan 35 Hz, 55Hz, 85Hz
Le bhith ag obrachadh a-mach lorgan seismic agus a’ dealbhadh ghrafaichean de leudachan tonn ri fhaicinn, chì sinn gu bheilear a’ faicinn neo-riaghailteachd aig diofar thigheadan cruthachaidh airson diofar triceadan.
tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];
lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]Grafan de leudan na tonn a tha air a nochdadh bho oir àrd na pìos airson diofar triceadan
Tha an comas co-dhùnaidhean a dhèanamh mu thiugh an cruthachadh bho thoraidhean seismic amharc air leth feumail, oir is e aon de na prìomh ghnìomhan ann an sgrùdadh ola measadh a dhèanamh air na puingean as gealltanach airson tobar a chuir sìos (ie, na raointean sin far a bheil an cruthachadh. nas tiugh). A bharrachd air an sin, anns an roinn eòlas-eòlais dh’fhaodadh gum bi nithean aig a bheil genesis ag adhbhrachadh atharrachadh geur ann an tiugh an cruthachadh. Tha seo a’ fàgail mion-sgrùdadh speactram na inneal èifeachdach airson an sgrùdadh. Anns an ath phàirt den artaigil beachdaichidh sinn ann am barrachd mionaideachd air nithean geòlais mar sin.
Dàta deuchainneach. Càite an d’ fhuair thu iad agus dè a choimheadas tu annta?
Chaidh na stuthan a chaidh a sgrùdadh san artaigil fhaighinn ann an Siberia an Iar. Is e an roinn, mar a tha fios aig a h-uile duine gun eisgeachd, am prìomh roinn cinneasachaidh ola san dùthaich againn. Thòisich leasachadh gnìomhach air tasgaidhean anns an sgìre anns na 60an den linn mu dheireadh. Is e sgrùdadh seismic am prìomh dhòigh air tasgaidhean ola a lorg. Tha e inntinneach coimhead air ìomhaighean saideal den sgìre seo. Aig ìre bheag, chì thu àireamh mhòr de bhoglaich is lochan; le bhith a’ leudachadh a’ mhapa, chì thu làraich drileadh tobar cnuasachaidh, agus le bhith a’ leudachadh a’ mhapa chun ìre as ìsle, faodaidh tu cuideachd eadar-dhealachadh a dhèanamh air fuadaichean nam pròifilean air a bheil seismic. chaidh seallaidhean a dhèanamh.
Ìomhaigh saideal de mhapaichean Yandex - sgìre baile-mòr Noyabrsk
Lìonra de phlocan tobair aig aon de na raointean
Tha creagan ola Siberia an Iar a 'nochdadh ann an raon farsaing de dhoimhneachd - bho 1 km gu 5 km. Chaidh am prìomh àireamh de chreagan anns an robh ola a chruthachadh anns na h-amannan Iurasaig agus Cretaceous. Is dòcha gu bheil mòran eòlach air an àm Jurassic bhon fhilm den aon ainm. bha e gu math eadar-dhealaichte bhon fhear ùr-nodha. Tha sreath de phalaomaps anns an Encyclopedia Britannica a tha a’ comharrachadh gach linn heological.
An làthair
àm Jurassic
Thoir an aire, ann an amannan Jurassic, gur e oirthir mara a bh’ ann an sgìre Siberia an Iar (fearann air a dhol thairis le aibhnichean agus muir eu-domhainn). Leis gu robh an aimsir comhfhurtail, faodaidh sinn gabhail ris gu robh cruth-tìre àbhaisteach aig an àm sin a’ coimhead mar seo:
Jurassic Siberia
Anns an dealbh seo, chan e na beathaichean agus na h-eòin cho mòr an rud a tha cudromach dhuinn, ach ìomhaigh na h-aibhne air a’ chùl. Is e an abhainn an aon rud geòlais ris an do stad sinn na bu thràithe. Is e an fhìrinn gu bheil gnìomhachd aibhnichean a 'leigeil le clachan-gainmhich a tha air an deagh rèiteachadh cruinneachadh, a bhios an uairsin na stòras ola. Faodaidh cumadh neònach, iom-fhillte a bhith aig na stòran-tasgaidh sin (mar leabaidh aibhne) agus tha tiugh caochlaideach aca - faisg air na bruaichean tha an tighead beag, ach nas fhaisge air meadhan an t-sianail no ann an ceàrnaidhean lùbach bidh e ag àrdachadh. Mar sin, tha na h-aibhnichean a chaidh a chruthachadh anns an Jurassic a-nis aig doimhneachd timcheall air trì cilemeatairean agus tha iad nan adhbhar airson rannsachadh airson stòran-ola.
Dàta deuchainneach. Giullachd agus lèirsinn
Nì sinn cinnteach sa bhad mu na stuthan seismic a chithear san artaigil - air sgàth gu bheil an ìre de dhàta a chaidh a chleachdadh airson an anailis cudromach - chan eil ach criomag den t-seata tùsail de lorgan seismic air a ghabhail a-steach ann an teacsa an artaigil. Leigidh seo le neach sam bith an àireamhachadh gu h-àrd ath-riochdachadh.
Nuair a bhios tu ag obair le dàta seismic, bidh geo-fhiosaig mar as trice a’ cleachdadh bathar-bog sònraichte (tha grunn stiùirichean gnìomhachais ann a tha na leasachaidhean air an cleachdadh gu gnìomhach, mar eisimpleir Petrel no Paradigm), a leigeas leat diofar sheòrsaichean dàta a sgrùdadh agus aig a bheil eadar-aghaidh grafaigeach goireasach. A dh 'aindeoin a h-uile goireas, tha na duilgheadasan aca cuideachd - mar eisimpleir, bidh buileachadh algorithms ùr-nodha ann an dreachan seasmhach a' toirt mòran ùine, agus mar as trice chan eil mòran chothroman ann airson àireamhachadh fèin-ghluasadach. Ann an suidheachadh mar sin, bidh e gu math goireasach siostaman matamataigeach coimpiutaireachd agus cànanan prògramadh àrd-ìre a chleachdadh, a leigeas le bunait farsaing algorithmach a chleachdadh agus, aig an aon àm, a bhith a ’gabhail os làimh mòran de chleachdadh àbhaisteach. Is e seo am prionnsapal a thathar a’ cleachdadh airson obrachadh le dàta seismic ann am Wolfram Mathematica. Chan eil e iomchaidh comas-gnìomh beairteach a sgrìobhadh airson obair eadar-ghnìomhach le dàta - tha e nas cudromaiche dèanamh cinnteach gu bheil iad air an luchdachadh bho chruth ris an gabhar san fharsaingeachd, a’ cur an sàs na h-algorithms a tha thu ag iarraidh agus gan luchdachadh suas air ais gu cruth a-muigh.
Às deidh an sgeama a chaidh a mholadh, luchdaichidh sinn an dàta seismic tùsail agus seallaidh sinn a-steach iad :
Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]Is e an dàta a chaidh a luchdachadh sìos agus a thoirt a-steach san dòigh seo na slighean a chaidh a chlàradh air sgìre a tha a’ tomhas 10 le 5 cilemeatair. Ma gheibhear an dàta le bhith a ‘cleachdadh modh sgrùdaidh seismic trì-thaobhach (tha tonnan air an clàradh chan ann air pròifilean geo-fhiosaigeach fa leth, ach thairis air an raon gu lèir aig an aon àm), bidh e comasach ciùban dàta seismeach fhaighinn. Is iad sin nithean trì-thaobhach, le earrannan dìreach agus còmhnard dhiubh a’ ceadachadh sgrùdadh mionaideach air an àrainneachd geòlais. Anns an eisimpleir air a bheilear a’ beachdachadh, tha sinn a’ dèiligeadh ri dàta trì-thaobhach. Gheibh sinn beagan fiosrachaidh bhon cheann teacsa, mar seo
StringPartition[seismic3DSEGY["textheader"], 80] // TableFormC 1 IS E SEO FILE DEMO AIRSON TESTAL PACKAGE GEOLOGYIO
C 2
C 3
C 4
C 5 Ceann-latha AINM CLEACHDADH: CLEACHDADH WOLFRAM
C 6 AINM AN T-SOISGEIL: AIR A BHEIL ANN AN SIBRIA
C 7 FILE TYPE 3D SEISMIC LUACHMHOR
C 8
C 9
RAON C10 Z: A 'CHIAD 2200M LAST 2400M
Bidh an seata dàta seo gu leòr dhuinn na prìomh ìrean de mhion-sgrùdadh dàta a thaisbeanadh. Tha na comharran san fhaidhle air an clàradh ann an òrdugh agus tha gach fear dhiubh a’ coimhead rudeigin mar an fhigear a leanas - is e seo cuairteachadh meudan tonnan meòrachail air an axis dhìreach (axis doimhneachd).
ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2,
PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
LabelStyle -> Directive[Black, Italic], PlotRange -> All,
Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]Aon de na lorgan earrann seismic
Le fios cia mheud lorg a tha suidhichte anns gach taobh den raon sgrùdaidh, faodaidh tu raon dàta trì-thaobhach a ghineadh agus a thaisbeanadh a’ cleachdadh gnìomh Image3D []
traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1; (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1; (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]Ìomhaigh XNUMXD de chiùb dàta seismic. (Ais dhìreach - doimhneachd)
Ma tha na feartan geòlais inntinneach a ‘cruthachadh neo-riaghailteachdan seismic dian, faodar innealan lèirsinn le follaiseachd a chleachdadh. Faodar raointean “neo-chudromach” den chlàradh a dhèanamh do-fhaicsinneach, a’ fàgail dìreach neo-riaghailteachdan rim faicinn. Ann am Wolfram Mathematica faodar seo a dhèanamh le bhith a’ cleachdadh и .
data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]},
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]Ìomhaigh ciùb dàta seismic a’ cleachdadh gnìomhan Opacity[] agus Raster3D[]
Mar a tha san eisimpleir synthetigeach, air earrannan den chiùb tùsail faodaidh aon crìochan geòlais (sreathan) a chomharrachadh le faochadh caochlaideach.
Is e am prìomh inneal airson mion-sgrùdadh speactra an cruth-atharrachadh Fourier. Le a chuideachadh, faodaidh tu measadh a dhèanamh air an speactram tricead amplitude de gach lorg no buidheann de lorgan. Ach, às deidh an dàta a ghluasad chun raon tricead, thèid fiosrachadh a chall mu na h-amannan (leugh dè an doimhneachd) a bhios tricead ag atharrachadh. Gus a bhith comasach air atharrachaidhean comharran a shuidheachadh gu h-ionadail air an axis ùine (doimhneachd), thathas a’ cleachdadh cruth-atharrachadh Fourier le uinneag agus lobhadh tonn-tonn. Bidh an artaigil seo a’ cleachdadh lobhadh tonn. Thòisich teicneòlas anailis Wavelet air a chleachdadh gu gnìomhach ann an sgrùdadh seismic anns na 90n. Thathas den bheachd gur e am buannachd thairis air cruth-atharrachadh uinneig Fourier fuasgladh ùine nas fheàrr.
Le bhith a’ cleachdadh a’ chriomag còd a leanas, faodaidh tu aon de na lorgan seismic a bhriseadh sìos gu pàirtean fa leth:
cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]A 'lobhadh lorg gu co-phàirtean
Gus measadh a dhèanamh air mar a tha an lùth meòrachaidh air a chuairteachadh aig diofar amannan ruighinn nan tonn, thathas a’ cleachdadh scalograman (co-chosmhail ri spectrogram). Mar riaghailt, ann an cleachdadh chan eil feum air mion-sgrùdadh a h-uile co-phàirtean. Mar as trice, bidh co-phàirtean tricead ìosal, meadhanach agus àrd air an taghadh.
freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]Sgalogram. Toradh gnìomh
Bidh Cànan Wolfram a’ cleachdadh a’ ghnìomh airson cruth-atharrachadh tonnan . Agus thèid an gnìomh seo a chuir an sàs anns an t-seata iomlan de lorgan a ’cleachdadh a’ ghnìomh . An seo is fhiach toirt fa-near aon de na neartan aig Wolfram Mathematica - an comas co-shìnteadh a chleachdadh . Anns an eisimpleir gu h-àrd, chan eil feum air co-shìnte - chan eil an àireamh de dhàta mòr, ach nuair a bhios tu ag obair le seataichean dàta deuchainneach anns a bheil ceudan de mhìltean de lorgan, tha seo riatanach.
tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}]; Às deidh an gnìomh a chuir an sàs Bidh seataichean dàta ùra a’ nochdadh a rèir nan triceadan taghte. Anns an eisimpleir gu h-àrd, is iad na triceadan sin: 38Hz, 33Hz, 27Hz. Mar as trice bidh an roghainn tricead air a dhèanamh air bunait deuchainn - bidh iad a ’faighinn mhapaichean èifeachdach airson measgachadh tricead eadar-dhealaichte agus a’ taghadh am fear as fiosrachail bho shealladh geòlaiche.
Ma dh’ fheumas tu na toraidhean a cho-roinn le co-obraichean no an toirt don neach-ceannach, faodaidh tu an gnìomh SEGYExport[] den phasgan GeologyIO a chleachdadh
outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];Le trì de na ciùban sin (co-phàirtean tricead ìosal, meadhan-tricead, agus àrd-tricead), bidh measgachadh RGB mar as trice air a chleachdadh gus an dàta fhaicinn còmhla. Tha a dath fhèin aig gach pàirt - dearg, uaine, gorm. Ann am Wolfram Mathematica faodar seo a dhèanamh leis a’ ghnìomh .
Is e an toradh ìomhaighean às an urrainnear mìneachadh geòlais a dhèanamh. Tha na lùban a tha air an clàradh air an earrann ga dhèanamh comasach paleochannels a mhìneachadh, a tha nas buailtiche a bhith nan stòran-tasgaidh agus anns a bheil stòrasan ola. Tha sgrùdadh agus sgrùdadh analogues ùr-nodha de shiostam aibhne mar sin a’ toirt cothrom dhuinn na pàirtean as gealltanach de na lùban a dhearbhadh. Tha na seanalan fhèin air an comharrachadh le sreathan tiugh de chlach-ghainmhich air an deagh sheòrsachadh agus tha iad nan stòras math airson ola. Tha raointean taobh a-muigh an neo-riaghailteachdan "lace" coltach ri tasgaidhean raon-tuiltean an latha an-diugh. Tha tasgaidhean raon-tuile sa mhòr-chuid air an riochdachadh le creagan crèadha agus bidh drileadh a-steach do na sònaichean sin neo-èifeachdach.
Sliseag RGB den chiùb dàta. Anns a 'mheadhan (beagan air taobh clì an ionaid) faodaidh tu lorg a dhèanamh air an abhainn lùbach.
Sliseag RGB den chiùb dàta. Air an taobh chlì chì thu an abhainn lùbach.
Ann an cuid de chùisean, tha càileachd dàta seismic a ‘ceadachadh ìomhaighean gu math nas soilleire. Tha seo an urra ris an dòigh-obrach obair làraich, an uidheamachd a bhios an algairim lughdachadh fuaim a’ cleachdadh. Ann an leithid de shuidheachaidhean, chan e a-mhàin gu bheil pìosan de shiostaman aibhne rim faicinn, ach cuideachd aibhnichean paleo leudaichte gu lèir.
Measgachadh RGB de thrì phàirtean de chiùb dàta seismic (sliseag chòmhnard). Doimhneachd timcheall air 2 km.
Ìomhaigh saideal den Volga Abhainn faisg air Saratov
co-dhùnadh
Leigidh Wolfram Mathematica leat dàta seismic a mhion-sgrùdadh agus fuasgladh fhaighinn air duilgheadasan gnìomhaichte co-cheangailte ri sgrùdadh mèinnearachd, agus tha pasgan GeologyIO a’ dèanamh a ’phròiseas seo nas goireasaiche. Tha structar dàta seismic mar sin a’ cleachdadh dhòighean togte gus àireamhachadh a luathachadh (, ,…) gu math èifeachdach agus leigidh e leat tòrr dàta a phròiseasadh. Gu ìre mhòr, tha seo air a dhèanamh comasach le feartan stòraidh dàta pasgan GeologyIO. Air an t-slighe, faodar am pasgan a chleachdadh chan ann a-mhàin ann an raon sgrùdadh seismic gnìomhaichte. Bithear a’ cleachdadh cha mhòr na h-aon sheòrsan dàta ann an radar a tha a’ dol a-steach don talamh agus seismology. fàg beachd.
Source: www.habr.com