Tebur na lokaci-lokaci akan ilimin kwamfuta na makaranta

(Katunan sarrafawa)
(An sadaukar da shi ga Shekarar Ƙasa ta Duniya na Tebur na Abubuwan Abubuwan Sinadarai)
(An yi sabbin abubuwan karawa a ranar 8 ga Afrilu, 2019. Jerin abubuwan da aka karawa nan da nan yana ƙasa da yanke)

(Mendeleev fure, Source)

Na tuna mun wuce agwagi. Waɗannan darussa uku ne a lokaci ɗaya: labarin ƙasa, kimiyyar halitta da Rashanci. A cikin darasin kimiyya, an yi nazarin agwagwa a matsayin agwagi, wane fuka-fuki, da wace ƙafafu, yadda yake iyo, da dai sauransu. A cikin darasi na labarin kasa, an yi nazarin duck guda ɗaya a matsayin mazaunin duniya: ya zama dole a nuna akan taswira inda yake zaune da kuma inda ba ya. A cikin Rashanci, Serafima Petrovna ya koya mana mu rubuta "u-t-k-a" kuma karanta wani abu game da ducks daga Brem. A wucewa, ta sanar da mu cewa a Jamus duck ne kamar haka, kuma a Faransa kamar haka. Ina tsammanin an kira shi "hanyar hadaddun" a lokacin. Gabaɗaya, komai ya fito “a wucewa.”

Veniamin Kaverin, Shugabannin biyu

A cikin abin da aka ambata a sama, Veniamin Kaverin da ƙwarewa ya nuna gazawar hanyar koyarwa mai rikitarwa, duk da haka, a wasu lokuta (wataƙila ba kasafai ba) abubuwa na wannan hanyar sun dace. Ɗaya daga cikin irin wannan yanayin shine tebur na lokaci-lokaci na DI Mendeleev a cikin darussan kimiyyar kwamfuta na makaranta. Ayyukan sarrafa kansa na software na ayyuka na yau da kullun tare da tebur na lokaci-lokaci a bayyane yake ga yaran makaranta waɗanda suka fara nazarin sinadarai, kuma sun kasu kashi-kashi cikin ayyukan sinadarai da yawa. A lokaci guda kuma, a cikin tsarin ilimin kimiyyar kwamfuta, wannan aikin yana ba mu damar nunawa a cikin tsari mai sauƙi na hanyar sarrafa katunan, wanda za'a iya danganta shi da shirye-shiryen zane, wanda aka fahimta a cikin ma'anar kalmar kamar shirye-shirye ta amfani da abubuwa masu hoto.

(Afrilu 8, 2019 ƙarin an yi:
Ƙara 1: Yadda Ƙididdigar Chemistry ke Aiki
Shafi 2: misalan ayyuka don tacewa)

Bari mu fara da ainihin aiki. A cikin mafi sauƙi, ya kamata a nuna tebur na lokaci-lokaci akan allon a cikin sigar taga, inda a cikin kowane tantanin halitta za a sami sinadari na sinadarai: H - hydrogen, He - helium, da dai sauransu. Idan siginan linzamin kwamfuta yana nuni zuwa tantanin halitta, to, ana nuna nau'in siginar da lambarsa a wani fili na musamman akan sigar mu. Idan mai amfani ya danna LMB, to za a nuna nadi da lambar wannan zaɓin a wani filin sigar.

Ana iya magance matsalar ta amfani da kowane harshe na duniya. Za mu ɗauki tsohuwar Delpi-7 mai sauƙi, wanda kusan kowa ke fahimta. Amma kafin shirye-shirye a cikin PL, bari mu zana hotuna biyu, misali, a cikin Photoshop. Da farko, bari mu zana Tebur na lokaci-lokaci a cikin fom ɗin da muke son gani a cikin shirin. Ajiye sakamakon a cikin fayil mai hoto tebur01.bmp.

Don zane na biyu muna amfani da na farko. Za mu cika sel ɗin tebur bi da bi, share su daga duk zane-zane, tare da launuka na musamman a cikin ƙirar launi na RGB. R da G koyaushe za su kasance 0, da B=1 don hydrogen, 2 don helium, da sauransu. Wannan zane zai zama katin sarrafa mu, wanda za mu adana a cikin fayil mai suna. tebur2.bmp.

An kammala matakin farko na shirye-shiryen hoto a Photoshop. Bari mu matsa zuwa shirye-shiryen GUI mai hoto a cikin Delpi-7 IDE. Don yin wannan, buɗe sabon aikin, inda a kan babban tsari muka sanya maɓallin tattaunawa (teburDlg), wanda aiki tare da tebur zai faru. Na gaba muna aiki tare da fom teburDlg.

Sanya bangaren aji akan fom TIMage... Mun samu Image1. Lura cewa gabaɗaya, don manyan ayyuka, ana samar da sunayen fom ta atomatik Hoton Ninda N zai iya kaiwa dozin da yawa ko fiye - wannan ba shine mafi kyawun salon shirye-shiryen ba, kuma yakamata a ba da sunaye masu ma'ana. Amma a cikin ɗan aikin mu, a ina N ba zai wuce 2 ba, zaka iya barin shi kamar yadda aka haifar.

Zuwa dukiya Hoto1.Hoto loda fayil ɗin tebur01.bmp. Mun halitta Image2 kuma ku loda katin sarrafa mu a can tebur2.bmp. A wannan yanayin, muna sanya fayil ɗin ƙarami kuma marar ganuwa ga mai amfani, kamar yadda aka nuna a cikin ƙananan hagu na tsari. Muna ƙara ƙarin abubuwan sarrafawa, wanda manufarsa a bayyane yake. An kammala mataki na biyu na shirye-shiryen GUI mai hoto a cikin Delpi-7 IDE.

Bari mu matsa zuwa mataki na uku - lambar rubutu a cikin Delpi-7 IDE. Tsarin ya ƙunshi masu gudanar da taron guda biyar kawai: ƙirƙirar tsari (Ƙirƙiri Form), motsin siginan kwamfuta Image1 (Hoton MouseMove), danna LMB akan tantanin halitta (Hoto1 Dannada kuma fita tattaunawa ta amfani da OK buttons (OKBtnClick) ko soke (CancelBtnClick). Ana samar da kawunan waɗannan masu sarrafa su ta daidaitaccen hanya ta amfani da IDE.

Lambar tushen Module:

unit tableUnit;
// Периодическая таблица химических элементов Д.И.Менделеева
//
// third112
// https://habr.com/ru/users/third112/
//
// Оглавление
// 1) создание формы
// 2) работа с таблицей: указание и выбор
// 3) выход из диалога

interface

uses Windows, SysUtils, Classes, Graphics, Forms, Controls, StdCtrls, 
  Buttons, ExtCtrls;

const
 size = 104; // число элементов
 
type
 TtableDlg = class(TForm)
    OKBtn: TButton;
    CancelBtn: TButton;
    Bevel1: TBevel;
    Image1: TImage;  //таблица химических элементов
    Label1: TLabel;
    Image2: TImage;  //управляющая карта
    Label2: TLabel;
    Edit1: TEdit;
    procedure FormCreate(Sender: TObject); // создание формы
    procedure Image1MouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);                        // указание клетки
    procedure Image1Click(Sender: TObject); // выбор клетки
    procedure OKBtnClick(Sender: TObject);  // OK
    procedure CancelBtnClick(Sender: TObject); // Cancel
  private
    { Private declarations }
    TableSymbols : array [1..size] of string [2]; // массив обозначений элементов
  public
    { Public declarations }
    selectedElement : string; // выбранный элемент
    currNo : integer;         // текущий номер элемента
  end;

var
  tableDlg: TtableDlg;

implementation

{$R *.dfm}

const
PeriodicTableStr1=
'HHeLiBeBCNOFNeNaMgAlSiPSClArKCaScTiVCrMnFeCoNiCuZnGaGeAsSeBrKrRbSrYZrNbMoTcRuRhPdAgCdInSnSbTeIXeCsBaLa';
PeriodicTableStr2='CePrNdPmSmEuGdTbDyHoErTmYbLu';
PeriodicTableStr3='HfTaWReOsIrPtAuHgTlPbBiPoAtRnFrRaAc';
PeriodicTableStr4='ThPaUNpPuAmCmBkCfEsFmMdNoLrKu ';

// создание формы  ==================================================

procedure TtableDlg.FormCreate(Sender: TObject);
// создание формы
var
  s : string;
  i,j : integer;
begin
  currNo := 0;
// инициализация массива обозначений элементов:
  s := PeriodicTableStr1+ PeriodicTableStr2+PeriodicTableStr3+PeriodicTableStr4;
  j := 1;
  for i :=1 to size do
   begin
     TableSymbols [i] := s[j];
     inc (j);
     if s [j] in ['a'..'z'] then
      begin
        TableSymbols [i] := TableSymbols [i]+ s [j];
        inc (j);
      end; // if s [j] in
   end; // for i :=1
end; // FormCreate ____________________________________________________

// работа с таблицей: указание и выбор =========================================

procedure TtableDlg.Image1MouseMove(Sender: TObject; Shift: TShiftState;
  X, Y: Integer);
// указание клетки
var
  sl : integer;
begin
  sl := GetBValue(Image2.Canvas.Pixels [x,y]);
  if sl in [1..size] then
   begin
    Label1.Caption := intToStr (sl)+ ' '+TableSymbols [sl];
    currNo := sl;
   end
  else
    Label1.Caption := 'Select element:';
end; // Image1MouseMove   ____________________________________________________

procedure TtableDlg.Image1Click(Sender: TObject);
begin
  if currNo <> 0 then
   begin
    selectedElement := TableSymbols [currNo];
    Label2.Caption := intToStr (currNo)+ ' '+selectedElement+ ' selected';
    Edit1.Text := selectedElement;
   end;
end; // Image1Click  ____________________________________________________

// выход из диалога  ==================================================

procedure TtableDlg.OKBtnClick(Sender: TObject);
begin
    selectedElement := Edit1.Text;
    hide;
end;  // OKBtnClick ____________________________________________________

procedure TtableDlg.CancelBtnClick(Sender: TObject);
begin
  hide;
end;  // CancelBtnClick ____________________________________________________

end.

A cikin sigar mu, mun ɗauki tebur na abubuwa 104 (constant size). Babu shakka ana iya ƙara wannan girman. Ana rubuta sunayen abubuwa (alamomin sinadarai) zuwa tsararru Alamomin Tebur. Koyaya, saboda dalilai na ƙaƙƙarfan lambar tushe, yana da kyau a rubuta jerin waɗannan bayanan a cikin nau'ikan kirtani akai-akai. Lokaci-lokaciTableStr1..., Lokaci-lokaciTableStr4ta yadda idan aka samar da fom din, shirin da kansa ya watsa wadannan sunayen a cikin abubuwan da ke cikin tsarin. Kowane nau'in nadi ya ƙunshi haruffan Latin ɗaya ko biyu, tare da harafin farko ya zama babba kuma na biyu (idan akwai) ƙananan haruffa. Ana aiwatar da wannan sauƙi mai sauƙi lokacin loda tsararru. Don haka, za a iya rubuta jerin abubuwan sanarwa a taƙaice ba tare da sarari ba. Karɓar jeri zuwa sassa huɗu (constant Lokaci-lokaciTableStr1..., Lokaci-lokaciTableStr4) saboda la'akari da sauƙin karanta lambar tushe, saboda Layin da ya yi tsayi da yawa ba zai dace da allon gaba ɗaya ba.

Lokacin da siginan linzamin kwamfuta ya motsa akan Image1 mai kulawa Hoton MouseMove wannan taron yana ƙayyade ƙimar ɓangaren launin shuɗi na pixel katin sarrafawa Image2 don daidaitawar siginan kwamfuta na yanzu. Ta hanyar gini Image2 wannan ƙimar tana daidai da lambar kashi idan siginan kwamfuta yana cikin tantanin halitta; sifili idan a kan iyaka, da 255 a wasu lokuta. Sauran ayyukan da shirin ya yi ba su da mahimmanci kuma baya buƙatar bayani.

Baya ga dabarun shirye-shirye masu salo da aka ambata a sama, yana da kyau a lura da salon sharhi. A taƙaice, lambar da aka tattauna tana da ƙanƙanta kuma mai sauƙi wanda ba a yi kama da sharhi ba musamman. Duk da haka, an ƙara su don dalilai na hanya - gajeriyar lambar tana ba mu damar yin wasu ƙararraki gaba ɗaya a sarari. A cikin lambar da aka gabatar an ayyana aji ɗaya (TtableDlg). Ana iya musanya hanyoyin wannan ajin kuma wannan ba zai shafi aikin shirin ta kowace hanya ba, amma yana iya shafar iya karanta shi. Misali, yi tunanin tsarin:

OKBtnClick, Image1MouseMove, FormCreate, Image1Click, CancelBtnClick.

Wataƙila ba za a iya ganewa sosai ba, amma zai zama ɗan wahala a karanta da fahimta. Idan babu biyar, amma sau goma fiye da hanyoyi a cikin sashin aiwatar suna da tsari daban-daban fiye da a cikin kwatancin ajin, to hargitsin zai karu ne kawai. Saboda haka, ko da yake yana da wuya a tabbatar da gaske kuma yana iya yiwuwa ma ba zai yiwu ba, mutum na iya fatan cewa gabatar da ƙarin tsari zai inganta karanta lambar. Ana sauƙaƙe wannan ƙarin umarni ta hanyar haɗakarwa ta hankali ta hanyoyi da yawa waɗanda ke yin ayyuka masu alaƙa. Ya kamata a ba kowace ƙungiya take, misali:

// работа с таблицей: указание и выбор

Ya kamata a kwafi waɗannan taken zuwa farkon tsarin kuma a tsara su azaman tebur na abun ciki. A wasu lokuta na dogayen kayayyaki, irin waɗannan allunan abubuwan suna ba da ƙarin zaɓuɓɓukan kewayawa. Hakazalika, a cikin dogon jiki na hanya ɗaya, hanya ko aiki, yana da daraja, da farko, alamar ƙarshen wannan jiki:

end; // FormCreate

kuma, na biyu, a cikin maganganun reshe tare da maƙallan shirye-shiryen farawa - ƙarshe, yi alama bayanin da sashin rufewa ke nuni da:

      end; // if s [j] in
   end; // for i :=1
end; // FormCreate

Don haskaka taken rukuni da ƙarshen jikunan hanya, zaku iya ƙara layin da suka fi tsayi fiye da yawancin maganganun kuma sun ƙunshi, misali, haruffan "=" da "_", bi da bi.
Har ila yau, muna buƙatar yin ajiyar wuri: misalinmu yana da sauƙi. Kuma lokacin da lambar hanyar ba ta dace akan allo ɗaya ba, yana iya zama da wahala a fahimci ƙarshen jere guda shida don yin canje-canjen code. A wasu tsofaffin masu tarawa, alal misali, Pascal 8000 don OS IBM 360/370, an buga ginshiƙin sabis kamar wannan a hagu a cikin jeri.

B5
…
E5

Wannan yana nufin cewa ɓangarorin rufewa akan layi E5 yayi daidai da baka na buɗe akan layi B5.

Tabbas salon shirye-shirye lamari ne mai cike da cece-kuce, don haka ya kamata a dauki ra'ayoyin da aka bayyana a nan a matsayin ba komai ba illa abinci don tunani. Yana iya zama da wahala ga ƙwararrun ƙwararrun shirye-shirye guda biyu waɗanda suka haɓaka kuma suka saba da salo daban-daban tsawon shekaru masu yawa na aiki, su cimma yarjejeniya. Wani al’amari ne na daban ga dalibin da ke koyon programming wanda har yanzu bai samu lokacin neman nasa salon ba. Ina ganin cewa a wannan yanayin ya kamata malami ya kamata a kalla ya isar wa dalibansa irin wannan sauki, amma ba a bayyane yake ba a gare su cewa nasarar shirin ya ta'allaka ne ga salon rubuta lambar tushe. Dalibin bazai bi tsarin da aka ba da shawarar ba, amma bari ya kalla yayi tunani game da buƙatar ayyukan "karin" don inganta ƙirar lambar tushe.

Komawa ga ainihin matsalarmu akan Tebur na lokaci-lokaci: ƙarin haɓakawa na iya tafiya ta hanyoyi daban-daban. Ɗaya daga cikin kwatance shine don tunani: lokacin da kake jujjuya siginan linzamin kwamfuta a kan tantanin halitta, taga bayanin yana bayyana mai ɗauke da ƙarin bayani akan takamaiman kashi. Ƙarin ci gaba shine tacewa. Alal misali, dangane da shigarwa, taga bayanin zai ƙunshi kawai: mafi mahimmancin bayanan jiki da na sinadarai, bayanai game da tarihin ganowa, bayani game da rarraba a yanayi, jerin abubuwan da suka fi muhimmanci (wanda ya hada da wannan kashi). physiological Properties, suna a cikin harshen waje, da dai sauransu e. Tunawa da Kaverin "duck" wanda wannan labarin ya fara, za mu iya cewa tare da wannan ci gaban da shirin za mu samu cikakken horo hadaddun a cikin halitta kimiyyar: ban da kwamfuta. kimiyya, kimiyyar lissafi da kuma sunadarai - ilmin halitta, tattalin arziki labarin kasa, tarihin kimiyya har ma da kasashen waje harsuna.

Amma rumbun adana bayanai na gida ba iyaka ba ne. Shirin a zahiri yana haɗawa da Intanet. Lokacin da ka zaɓi wani abu, hanyar haɗin yana kunna, kuma ana buɗe labarin Wikipedia game da wannan kashi a cikin taga mai binciken gidan yanar gizo. Wikipedia, kamar yadda kuka sani, ba tushe ne mai iko ba. Kuna iya saita hanyoyin haɗi zuwa tushe masu ƙarfi, misali, ilmin sinadarai, TSB, mujallu masu ƙima, yin oda a cikin injunan bincike don wannan kashi, da sauransu. Wannan. Dalibai za su iya kammala ayyuka masu sauƙi amma masu ma'ana akan DBMS da batutuwan Intanet.

Baya ga tambayoyi akan wani kashi ɗaya, zaku iya ƙirƙirar ayyuka waɗanda zasu, alal misali, yiwa sel alama a cikin tebur waɗanda suka dace da wasu sharuɗɗa tare da launuka daban-daban. Misali, karafa da wadanda ba karafa ba. Ko kuma sel waɗanda wata shukar sinadarai ke jefawa cikin ruwa.

Hakanan zaka iya aiwatar da ayyukan mai tsara littafin rubutu. Misali, nuna alama a cikin tebur abubuwan da ke cikin jarabawar. Sa'an nan kuma fito da abubuwan da ɗalibin ya yi nazari / maimaita su a shirye-shiryen jarrabawa.

Kuma a nan, alal misali, yana ɗaya daga cikin matsalolin ilimin kimiyyar makaranta:

An ba da 10 g na alli. Nawa ne ya kamata a sha hydrochloric acid don narkar da duk wannan alli?

Don magance wannan matsala, wajibi ne a rubuta chem. amsawa da sanya ma'aunin ƙididdiga a cikinsa, ƙididdige ma'aunin ƙwayoyin ƙwayoyin calcium carbonate da hydrogen chloride, sannan a shirya kuma ku warware rabon. Kalkuleta bisa tushen shirin mu na iya ƙididdigewa da warwarewa. Gaskiya ne, har yanzu za ku buƙaci la'akari da cewa dole ne a ɗauki acid ɗin cikin ma'ana kuma a cikin hankali mai ma'ana, amma wannan sinadari ne, ba kimiyyar kwamfuta ba.
Ƙara 1: Yadda Ƙididdigar Chemistry ke AikiBari mu bincika aikin kalkuleta ta amfani da misalin matsalar da ke sama na alli da "hodgepodge". Bari mu fara da martani:

CaCO3 + 2HCl = CaCl2 + H2O

Daga nan za mu ga cewa za mu buƙaci ma'aunin atom ɗin na abubuwa masu zuwa: calcium (Ca), carbon (C), oxygen (O), hydrogen (H) da chlorine (Cl). A cikin mafi sauƙi, za mu iya rubuta waɗannan ma'aunin nauyi a cikin tsararru mai girma ɗaya da aka ayyana azaman

AtomicMass : array [1..size] of real;

inda jigon tsararru yayi daidai da lambar kashi. Ƙari akan sarari kyauta na tsari teburDlg sanya filayen biyu. A cikin filin farko an fara rubuta cewa: "An ba da reagent na farko", a cikin na biyu - "Na biyu reagents shine nemo x". Bari mu nuna filayen reagent1, reagent2 bi da bi. Sauran ƙarin abubuwan da aka haɗa a cikin shirin za su fito fili daga misalin mai ƙididdigewa.

Muna buga akan madannai na kwamfuta: 10 g. Rubutun a filin reagent1 canje-canje: "An ba da reagent na farko 10 g." Yanzu mun shigar da dabarar wannan reagent, kuma kalkuleta zai lissafta kuma ya nuna nauyin kwayar halitta yayin shigar da shi.

Danna LMB akan tantanin halitta tare da alamar Ca. Rubutun a cikin filin reagent1 Canje-canje: "Na farko reagent Ca 40.078 da aka ba 10 g."

Danna LMB akan tantanin halitta mai alamar C. Rubutun a filin reagent1 Canje-canje: "Na farko reagent CaC 52.089 da aka ba 10 g." Wadancan. Kalkuleta ya haɗa ma'aunin atomic na alli da carbon.

Danna LMB akan tantanin halitta mai alamar O. Rubutun a filin reagent1 Canje-canje: "Na farko reagent CaCO 68.088 da aka ba 10 g." Kalkuleta ya ƙara nauyin atomic na iskar oxygen zuwa jimillar.

Danna LMB akan tantanin halitta mai alamar O. Rubutun a filin reagent1 Canje-canje: "Na farko reagent CaCO2 84.087 da aka ba 10 g." Kalkuleta ya sake ƙara nauyin atomic na iskar oxygen zuwa jimillar.

Danna LMB akan tantanin halitta mai alamar O. Rubutun a filin reagent1 Canje-canje: "Farkon reagent CaCO3 100.086 da aka ba 10 g." Kalkuleta ya sake ƙara nauyin atomic na iskar oxygen zuwa jimillar.

Danna Shigar akan madannai na kwamfutarku. An gama ƙaddamar da reagenti na farko kuma ya canza zuwa filin reagent2. Lura cewa a cikin wannan misali muna samar da ƙaramin siga. Idan ana so, zaku iya tsara nau'ikan nau'ikan nau'ikan nau'ikan nau'ikan nau'ikan nau'ikan zarra iri ɗaya cikin sauƙi, ta yadda, alal misali, ba dole ba ne ku danna sau bakwai a jere akan tantanin oxygen lokacin shigar da tsarin chromium (K2Cr2O7).

Danna LMB akan tantanin halitta mai alamar H. Rubutun a filin reagent2 canje-canje: "Reagent na biyu H 1.008 nemo x."

Danna LMB akan tantanin halitta tare da alamar Cl. Rubutun a cikin filin reagent2 Canje-canje: "Reagent na biyu HCl 36.458 nemo x." Kalkuleta ya haɗa ma'aunin atomic na hydrogen da chlorine. A cikin ma'auni na amsawa na sama, hydrogen chloride yana gaba da ma'auni na 2. Don haka, danna LMB akan filin. reagent2. Nauyin kwayoyin halitta ya ninka (sau uku idan an danna sau biyu, da sauransu). Rubutun a cikin filin reagent2 canje-canje: "Reagent na biyu 2HCl 72.916 sami x."

Danna Shigar akan madannai na kwamfutarku. An gama shigar da reagenti na biyu, kuma kalkuleta ya sami x daga madaidaicin

Abin da muke bukata ke nan mu samu.

Lura 1. Ma'anar sakamakon sakamakon: don rushewa 100.086 Da alli yana buƙatar 72.916 Da acid, kuma don narkar da gram 10 na alli kuna buƙatar x acid.

Lura 2. Tarin matsaloli iri ɗaya:

Khomchenko I. G., Tarin matsalolin da motsa jiki a cikin ilmin sunadarai 2009 (grades 8-11).
Khomchenko G. P., Khomchenko I. G., Tarin matsaloli a cikin ilmin sunadarai ga masu neman zuwa jami'o'i, 2019.

Lura 3. Don sauƙaƙe aikin, zaku iya sauƙaƙe shigar da dabarar a cikin sigar farko kuma kawai ƙara alamar kashi zuwa ƙarshen layin dabara. Sa'an nan dabarar calcium carbonate zai zama:
CaCOOO
Amma da wuya malamin ilmin sunadarai ya so irin wannan rikodin. Ba shi da wahala a shigar da daidai - don yin wannan kuna buƙatar ƙara tsararru:

formula : array [1..size] of integer;

inda ma'auni shine adadin sinadari, kuma ƙimar wannan ma'aunin shine adadin atom (da farko an sake saita duk abubuwan da ke cikin tsararru zuwa sifili). Ya kamata a yi la'akari da tsarin da aka rubuta atom a cikin tsari, kamar yadda aka yi a cikin ilmin sunadarai. Misali, mutane kaɗan ne za su so O3CaC ko dai. Bari mu matsar da alhakin zuwa ga mai amfani. Yin tsararru:

 formulaOrder : array [1..size] of integer; // можно взять покороче

inda muka rubuta adadin sinadarai gwargwadon ma'aunin bayyanarsa a cikin dabarar. Ƙara zarra kurNo cikin dabara:

if formula [currNo]=0 then //этот атом встретился первый раз
 begin
 orderIndex := orderIndex+1;//в начале ввода формулы orderIndex=0
 formulaOrder [orderIndex] :=  currNo;
 end;
formula [currNo]:=formula [currNo]+1;

Rubuta dabarar zuwa layi:

s := ''; // пустая строка для формулы
for i:=1 to  orderIndex do // для всех хим.символов в формуле 
 begin
 s:=s+TableSymbols [ formulaOrder[i]];// добавляем хим.символ
 if formula [formulaOrder[i]]<>1 then //добавляем кол-во атомов
  s:=s+ intToStr(formula [formulaOrder[i]]);
 end;

Lura 4. Yana da ma'ana don samar da ikon shigar da dabarar reagent a madadin madannai. A wannan yanayin, kuna buƙatar aiwatar da fassarori mai sauƙi.

Yana da kyau a lura cewa:

A yau, akwai nau'ikan nau'ikan tebur da yawa, kuma masana kimiyya koyaushe suna ba da sabbin zaɓuɓɓuka. (Wikipedia)

Dalibai za su iya nuna hazakarsu ta wannan hanyar ta aiwatar da ɗaya daga cikin zaɓin da aka riga aka tsara ko ƙoƙarin yin nasu na asali. Yana iya zama kamar wannan ita ce hanya mafi ƙarancin amfani ga darussan kimiyyar kwamfuta. Koyaya, a cikin nau'in Tebur na lokaci-lokaci da aka aiwatar a cikin wannan labarin, wasu ɗalibai ƙila ba za su ga fa'idodin katunan sarrafawa akan madadin mafita ta amfani da maɓalli na yau da kullun ba. TButton. Siffar karkace na tebur (inda sel ke da siffofi daban-daban) zai fi nuna fa'idodin da aka gabatar a nan.

(Madadin tsarin abubuwa na Theodore Benfey, Source)

Bari kuma mu ƙara da cewa adadin shirye-shiryen kwamfuta da ake da su a halin yanzu don Tebur na lokaci-lokaci an bayyana su a cikin kwanan nan da aka buga akan Habré labarin.

Shafi 2: misalan ayyuka don tacewaYin amfani da masu tacewa zaku iya warwarewa, misali, ayyuka masu zuwa:

1) Zaɓi a cikin tebur duk abubuwan da aka sani a Tsakiyar Tsakiya.

2) Gano duk abubuwan da aka sani a lokacin da aka gano Dokar Lokaci.

3) Gano wasu abubuwa guda bakwai da masana kimiyyar kimiyyar lissafi ke la'akari da karafa.

4) Zaɓi duk abubuwan da ke cikin yanayin gas a ƙarƙashin yanayin al'ada (n.s.).

5) Zaɓi duk abubuwan da ke cikin yanayin ruwa a no.

6) Zaɓi duk abubuwan da ke cikin ƙaƙƙarfan yanayi a no.

7) Zaɓi duk abubuwan da za'a iya fallasa su cikin iska na dogon lokaci ba tare da canje-canje masu gani ba a yanayin al'ada.

8) Zaɓi duk karafa da ke narkewa a cikin hydrochloric acid.

9) Zaɓi duk karafa da ke narkewa a cikin sulfuric acid a no.

10) Zaɓi duk karafa da ke narkewa a cikin sulfuric acid lokacin zafi.

11) Zaɓi duk karafa da ke narkewa a cikin nitric acid.

12) Ware duk wasu karafa da ke yin tashin hankali da ruwa a yanayin yanayi.

13) Zaɓi duk karafa.

14) Gano abubuwan da suka yadu a yanayi.

15) Gano abubuwan da aka samo a cikin yanayi a cikin 'yanci.

16) Gano abubuwan da suke taka muhimmiyar rawa a jikin mutum da dabba.

17) Zaɓi abubuwan da ake amfani da su a cikin rayuwar yau da kullum (a cikin kyauta ko a hade).

18) Gano abubuwan da suka fi haɗari don aiki tare da buƙatar matakan musamman da kayan kariya.

19) Gano abubuwan da, a cikin kyauta ko a cikin nau'i na mahadi, haifar da babbar barazana ga muhalli.

20) Zabi karafa masu daraja.

21) Gano abubuwan da suka fi karafa tsada.

Bayanan kula

1) Yana da ma'ana don samar da tacewa da yawa. Misali, idan kun kunna tacewa don magance matsala ta 1 (duk abubuwan da aka sani a Tsakiyar Tsakiya) da 20 (ƙarfe masu daraja), to za a haskaka sel masu ƙarfe masu daraja da aka sani a tsakiyar zamanai (misali, ta launi) ( misali, palladium ba za a haskaka , bude a 1803).

2) Yana da ma'ana don tabbatar da cewa filtata da yawa suna aiki a cikin irin wannan yanayin cewa kowane tacewa yana zaɓar sel masu launinsa, amma ba ya cire zaɓin wani tace gaba ɗaya (bangaren tantanin halitta a launi ɗaya, sashi a wani). Sa'an nan kuma, a cikin misalin da ya gabata, za a iya ganin abubuwan da ke cikin tsaka-tsakin saitin da aka gano a tsakiyar zamanai da karafa masu daraja, da kuma abubuwan da ke cikin na farko kawai kuma na biyu kawai. Wadancan. karafa masu daraja da ba a san su ba a tsakiyar zamanai, da abubuwan da aka sani a tsakiyar zamanai amma ba karafa masu daraja ba.

3) Yana da ma'ana bayan amfani da tacewa don tabbatar da yiwuwar sauran aiki tare da sakamakon da aka samu. Misali, bayan da aka zaɓa abubuwan da aka sani a Tsakiyar Tsakiyar Zamani, mai amfani yana danna LMB akan abin da aka zaɓa kuma an ɗauke shi zuwa labarin Wikipedia game da wannan kashi.

4) Yana da ma'ana don samar wa mai amfani da ikon cire zaɓi ta danna LMB akan tantanin tebur da aka zaɓa. Misali, don cire abubuwan da aka riga aka gani.

5) Yana da ma'ana don tabbatar da cewa an adana jerin sel da aka zaɓa a cikin fayil kuma an ɗora irin wannan fayil ɗin tare da zaɓin sel ta atomatik. Wannan zai ba mai amfani damar yin hutu daga aiki.

Mun yi amfani da taswirar da aka ƙayyade, amma akwai ayyuka masu mahimmanci da yawa inda za a iya amfani da taswirar sarrafawa masu ƙarfi waɗanda ke canzawa yayin da shirin ke gudana. Misali zai zama editan jadawali, wanda mai amfani yana amfani da linzamin kwamfuta don nuna matsayi na tsaye a cikin taga kuma ya zana gefuna tsakanin su. Don share juzu'i ko gefen, dole ne mai amfani ya nuna shi. Amma idan yana da sauƙi a nuna gefen gefen da aka yi masa alama da da'irar, to zai fi wuya a nuna gefen da aka zana tare da sirara. Taswirar sarrafawa za ta taimaka a nan, inda tudu da gefuna suka mamaye unguwanni masu faɗi fiye da adadi da ake gani.

Tambaya mai ban sha'awa mai ban sha'awa da ke da alaƙa da wannan hanyar horo mai rikitarwa ita ce: shin wannan hanyar za ta iya zama da amfani wajen horar da AI?

source: www.habr.com