Godiya ga marubucin blog ga rahotonsa
Gabatarwar
An rubuta wannan bayanin ne bayan taron kuma ya kunshi takaitaccen rahoton da na bayar. Lamarin ya faru ne a watan Yuni a St. Petersburg. Ganin cewa ina aiki da shinge daga wurin taron, ba zan iya taimakawa ba sai dai halartar wannan taron. A cikin 2016 da 2017, na saurari rahotannin taro, kuma a wannan shekara na ba da gabatarwa. Da fari dai, wani batu mai ban sha'awa (ga alama a gare ni) ya bayyana, wanda muke tasowa da shi , na biyu kuma, bayan dogon nazari game da dokokin Tarayyar Rasha game da manufofin takunkumi, a ma'aikatar da nake aiki, kamar yadda lasisi biyu suka bayyana. .
Kafin in ci gaba da batun jawabina, zan so in lura da kyakkyawan tsarin taron. Shafin ziyarar taron yana amfani da hoton Cathedral na Kazan. Cathedral na daya daga cikin manyan abubuwan jan hankali na St. Petersburg kuma a bayyane yake a fili daga zauren da taron ya gudana.
A ƙofar Jami'ar Tattalin Arziki ta Jihar St. A lokacin rajista, an ba da ƙananan abubuwan tunawa (abin wasan yara - karu mai walƙiya, alkalami, lambobi tare da alamun Wolfram). Abincin rana da hutun kofi kuma an haɗa su cikin jadawalin taron. Na riga na lura game da kofi mai daɗi da pies a bangon ƙungiyar - masu dafa abinci suna da kyau. Tare da wannan ɓangaren gabatarwa, Ina so in jaddada cewa taron da kansa, tsarinsa da wurinsa sun riga sun kawo motsin rai mai kyau.
Rahoton da ni da Kirill Belov suka shirya ana kiransa "Amfani da Wolfram Mathematica don magance matsalolin da aka yi amfani da su a fannin ilimin lissafi. Spectral analysis of seismic data ko "inda tsoffin koguna ke gudana." Abubuwan da ke cikin rahoton sun ƙunshi sassa biyu: na farko, amfani da algorithms da ake samu a ciki don nazarin bayanan geophysical, kuma na biyu, wannan shine yadda ake sanya bayanan geophysical cikin Wolfram Mathematica.
Binciken Seismic
Da farko kuna buƙatar yin ɗan gajeren balaguron balaguro zuwa geophysics. Geophysics kimiyyar kimiyya ce da ke nazarin abubuwan da ke jikin duwatsu. To, tun da duwatsu suna da kaddarorin daban-daban: lantarki, Magnetic, na roba, akwai hanyoyin da suka dace na geophysics: bincike na lantarki, bincike na maganadisu, binciken girgizar kasa ... A cikin mahallin wannan labarin, za mu tattauna kawai binciken binciken girgizar kasa daki-daki. Binciken girgizar ƙasa shine babbar hanyar neman mai da iskar gas. Hanyar ta dogara ne akan tashin hankali na rawar jiki na roba da kuma rikodi na gaba na amsa daga duwatsun da ke haɗa yankin binciken. Vibrations suna jin daɗi a ƙasa (tare da dynamite ko tushen girgizar girgizar da ba ta fashe ba) ko a cikin teku (tare da bindigogin iska). Jijjiga na roba yana yaduwa ta cikin babban dutsen, ana jujjuya su kuma ana nunawa a iyakoki na yadudduka tare da kaddarorin daban-daban. Raƙuman raƙuman ruwa suna komawa sama kuma ana yin rikodin su ta hanyar geophones akan ƙasa (yawanci na'urorin lantarki dangane da motsin maganadisu da aka dakatar a cikin nada) ko wayoyin ruwa a cikin teku (bisa tasirin piezoelectric). A lokacin isowar raƙuman ruwa, wanda zai iya yin hukunci a zurfin yadudduka na geological.
Kayan aikin jan jirgin ruwan Seismic
Bindigan iska yana zuga jijjiga na roba
Raƙuman ruwan raƙuman ruwa suna ratsa ta cikin babban dutsen kuma ana yin rikodin su ta hanyar hydrophones
Jirgin bincike na binciken Geophysical "Ivan Gubkin" a mashigin kusa da gadar Blagoveshchensky a St.
Samfurin siginar girgizar ƙasa
Duwatsu suna da kaddarorin jiki daban-daban. Don binciken girgizar ƙasa, kaddarorin roba suna da mahimmanci da farko - saurin yaduwa na girgizar ƙarfi da yawa. Idan yadudduka biyu suna da kaddarorin iri ɗaya ko makamantan su, to, kalaman "ba zai lura" iyakar tsakanin su ba. Idan saurin igiyoyin ruwa a cikin yadudduka sun bambanta, to, tunani zai faru a iyakar yadudduka. Babban bambanci a cikin kaddarorin, mafi tsananin tunani. Za a ƙayyade ƙarfinsa ta hanyar ma'aunin tunani (rc):
inda ρ shine girman dutsen, ν shine saurin igiyar ruwa, 1 da 2 suna nuna manyan yadudduka na sama da ƙasa.
Ɗaya daga cikin mafi sauƙi kuma mafi yawan amfani da siginar siginar girgizar ƙasa shine ƙirar juzu'i, lokacin da aka wakilta alamar girgizar ƙasa a sakamakon jujjuyawar jeri na ƙididdige ƙididdiga tare da bugun bugun jini:
ku (t) - alamar girgizar ƙasa, i.e. duk abin da aka yi rikodin ta hanyar hydrophone ko geophone yayin ƙayyadadden lokacin rikodi, w (t) - siginar da bindigar iska ta haifar, n (t) - bazuwar amo.
Bari mu lissafta alamar girgizar ƙasa ta roba a matsayin misali. Za mu yi amfani da bugun bugun Ricker, wanda aka yi amfani da shi sosai wajen binciken girgizar ƙasa, azaman siginar farko.
length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]Farkon girgizar ƙasa
Za mu saita iyakoki biyu a zurfin 300 ms da 600 ms, kuma ƙididdigar ƙira za su zama lambobin bazuwar.
rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]Jeri na tunani coefficients
Bari mu lissafta kuma mu nuna alamar girgizar ƙasa. Tun da ƙididdigar tunani suna da alamomi daban-daban, muna samun madaidaicin tunani guda biyu akan alamar girgizar ƙasa.
traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]Waƙa da aka kwaikwayi
Don wannan misali, wajibi ne a yi ajiyar wuri - a gaskiya, an ƙayyade zurfin yadudduka, ba shakka, a cikin mita, kuma lissafin alamar girgizar kasa yana faruwa don yankin lokaci. Zai zama mafi daidai don saita zurfin cikin mita kuma ƙididdige lokutan isowa da sanin saurin da ke cikin yadudduka. A wannan yanayin, nan da nan na saita yadudduka a kan lokaci axis.
Idan muka yi magana game da binciken filin, sa'an nan a sakamakon irin wannan lura da wani adadi mai yawa na irin wannan jerin lokaci (seismic burbushi) da aka rubuta. Misali, a lokacin da ake nazarin wani wuri mai tsawon kilomita 25 da fadin kilomita 15, inda sakamakon aiki, kowane tambari yana nuna tantanin halitta mai girman mita 25x25 (irin wannan tantanin halitta ana kiransa bin), tsarin bayanan karshe zai ƙunshi alamun 600000. Tare da samfurin lokaci na 1 ms da lokacin rikodi na 5 seconds, fayil ɗin bayanan ƙarshe zai kasance fiye da 11 GB, kuma ƙarar ainihin kayan "raw" na iya zama ɗaruruwan gigabytes.
Yadda ake aiki da su ?
Kunshin
Ci gaban kunshin ya fara a bangon VK na ƙungiyar tallafi na masu magana da harshen Rashanci. Godiya ga martanin da al'umma suka bayar, an sami mafita cikin sauri. Kuma a sakamakon haka, ya girma ya zama babban ci gaba. Daidaitawa Har ma an yi masa alama da masu daidaitawa. A halin yanzu, kunshin yana goyan bayan aiki tare da nau'ikan bayanai masu zuwa waɗanda ake amfani da su sosai a cikin masana'antar ƙasa:
- shigo da bayanan taswira a cikin tsarin ZMAP da IRAP
- shigo da ma'auni a cikin rijiyoyin tsarin LAS
- shigarwa da fitarwa na seismic fayiloli format
Don shigar da kunshin, dole ne ku bi umarnin kan shafin zazzagewa na kunshin da aka taru, watau. aiwatar da code na gaba a kowace :
If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
"https://wolfr.am/FiQ5oFih",
FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]Bayan haka za a shigar da kunshin a cikin babban fayil ɗin tsoho, hanyar da za a iya samun ta kamar haka:
FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]A matsayin misali, za mu nuna manyan iyawar kunshin. Ana yin kiran bisa ga al'ada don fakiti a cikin Yaren Wolfram:
Get["GeologyIO`"]An haɓaka kunshin ta amfani da . Wannan yana ba ku damar rakiyar babban aikin kunshin tare da takaddun shaida, wanda dangane da tsarin gabatarwa bai bambanta da takaddun Wolfram Mathematica kanta ba, kuma don samar da fakitin tare da fayilolin gwaji don sanin farko.
Irin wannan fayil ɗin, musamman, shine fayil ɗin "Marmousi.segy" - wannan sigar roba ce ta sashin yanki, wanda Cibiyar Man Fetur ta Faransa ta haɓaka. Yin amfani da wannan ƙirar, masu haɓakawa suna gwada nasu algorithms don ƙirar filin igiyar ruwa, sarrafa bayanai, jujjuya yanayin girgizar ƙasa, da sauransu. Samfurin Marmousi da kansa ana adana shi a cikin ma'ajiya daga inda aka sauke kunshin kanta. Domin samun fayil ɗin, gudanar da code mai zuwa:
If[Not[FileExistsQ["Marmousi.segy"]],
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]Sakamakon shigo da - SEGYData abu
Tsarin SEGY ya ƙunshi adana bayanai daban-daban game da abubuwan lura. Na farko, waɗannan maganganun rubutu ne. Wannan ya haɗa da bayanai game da wurin aikin, sunayen kamfanonin da suka yi ma'auni, da dai sauransu. A cikin yanayinmu, ana kiran wannan taken ta buƙatu tare da maɓallin TextHeader. Ga takaitaccen rubutun rubutun:
Short[marmousi["TextHeader"]]"An samar da saitin bayanan Marmousi a Cibiyar ... saurin gudu na 1500 m / s kuma iyakar 5500 m / s)"
Kuna iya nuna ainihin ƙirar yanayin ƙasa ta hanyar samun dama ga alamun girgizar ƙasa ta amfani da maɓallin "trace" (ɗayan fasalin fakitin shine makullin ba su da hankali):
ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]Model Marmousi
A halin yanzu, kunshin yana ba ku damar loda bayanai a cikin sassa daga manyan fayiloli, yana ba ku damar aiwatar da fayiloli waɗanda girmansu zai iya kaiwa dubun gigabytes. Ayyukan fakitin kuma sun haɗa da ayyuka don fitar da bayanai zuwa .segy da wani ɓangare na haɗe zuwa ƙarshen fayil ɗin.
Na dabam, yana da daraja a lura da ayyuka na kunshin lokacin aiki tare da hadadden tsarin fayilolin .segy. Tunda yana ba ku damar samun dama ga alamun kowane mutum da kan kai ta amfani da maɓalli da fihirisa, har ma don canza su sannan ku rubuta su zuwa fayil. Yawancin bayanan fasaha na aiwatar da GeologyIO sun wuce iyakar wannan labarin kuma tabbas sun cancanci bayanin daban.
Mahimmancin bincike na gani a cikin binciken girgizar ƙasa
Ikon shigo da bayanan girgizar ƙasa cikin Wolfram Mathematica yana ba ku damar amfani da ginanniyar aikin sarrafa sigina don bayanan gwaji. Tun da kowane alamar girgizar ƙasa tana wakiltar jerin lokaci, ɗayan manyan kayan aikin nazarin su shine bincike na gani. Daga cikin abubuwan da ake buqata don nazarin adadin mitar bayanan seismic, zamu iya suna, alal misali, masu zuwa:
- Nau'in raƙuman ruwa daban-daban suna da alaƙa da nau'ikan mitar daban-daban. Wannan yana ba ku damar haskaka raƙuman ruwa masu amfani da kuma kawar da tsangwama.
- Kaddarorin dutse kamar porosity da jikewa na iya shafar mitar abun da ke ciki. Wannan yana ba da damar gano duwatsu tare da mafi kyawun kaddarorin.
- Yadudduka masu kauri daban-daban suna haifar da anomalies a cikin jeri daban-daban.
Batu na uku shi ne babba a cikin mahallin wannan labarin. A ƙasa akwai guntun lambar don ƙididdige alamun girgizar ƙasa a cikin yanayin Layer mai bambance-bambancen kauri - ƙirar ƙira. Ana nazarin wannan ƙirar a al'adance a cikin binciken girgizar ƙasa don tantance tasirin tsangwama lokacin da raƙuman ruwa da ke fitowa daga yadudduka da yawa suka mamaye juna.
nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]Samfurin samuwar tsunkule
Gudun kalaman da ke cikin ƙugiya shine 4500 m/s, a waje da 4000 m/s, kuma yawancin ana ɗauka ya zama 2200 g/cm³ akai-akai. Don irin wannan ƙirar, muna ƙididdige ƙididdigar ƙididdiga da alamun girgizar ƙasa.
rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]Alamun girgizar ƙasa don ƙirar wedge
Jerin alamun girgizar ƙasa da aka nuna a wannan adadi ana kiransa sashin girgizar ƙasa. Kamar yadda kake gani, fassararsa kuma za'a iya aiwatar da shi a kan matakin fahimta, tun da lissafi na raƙuman ruwa da aka nuna a fili ya dace da samfurin da aka ƙayyade a baya. Idan kayi nazarin alamun daki-daki, za ku lura cewa alamun daga 1 zuwa kusan 30 ba su bambanta ba - tunani daga rufin da aka samu da kuma daga kasa ba su mamaye juna ba. Fara daga alamar 31st, tunani ya fara tsoma baki. Kuma, ko da yake a cikin samfurin, ƙididdiga na tunani ba sa canzawa a kwance - alamun girgizar kasa suna canza ƙarfin su yayin da kauri na samuwar ya canza.
Bari mu yi la'akari da amplitude na tunani daga babba iyaka na samuwar. Fara daga hanyar 60th, ƙarfin tunani ya fara karuwa kuma a hanyar 70th ya zama mafi girma. Wannan shi ne yadda tsangwama na raƙuman ruwa daga rufin da kasan yadudduka ke bayyana kansa, wanda ke haifar da wasu abubuwa masu mahimmanci a cikin rikodin girgizar kasa.
ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]Graph na amplitude na kalaman da aka nuna daga saman gefen wedge
Yana da ma'ana cewa lokacin da siginar ta kasance ƙasa-ƙasa, tsangwama yana fara bayyana a manyan kauri, kuma a cikin yanayin sigina mai girma, tsangwama yana faruwa a ƙananan kauri. Snippet lambar mai zuwa yana ƙirƙirar sigina tare da mitoci na 35 Hz, 55 Hz da 85 Hz.
waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]Saitin siginar tushe tare da mitoci na 35 Hz, 55Hz, 85Hz
Ta hanyar ƙididdige alamun girgizar ƙasa da ƙirƙira jadawalai na girman girman igiyoyin igiyar ruwa, za mu iya ganin cewa ga mitoci daban-daban ana ganin anomaly a nau'ikan kauri daban-daban.
tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];
lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]Zane-zane na amplitudes na kalaman da aka nuna daga saman gefen ƙugiya don mitoci daban-daban
Damar yanke hukunci game da kaurin samuwar daga sakamakon binciken girgizar ƙasa yana da matuƙar amfani, domin ɗaya daga cikin manyan ayyuka a cikin aikin haƙon mai shine tantance abubuwan da suka fi dacewa don shimfida rijiya (watau wuraren da aka kafa rijiya). kauri). Bugu da ƙari, a cikin sashin ilimin ƙasa za a iya samun abubuwa waɗanda asalinsu ya haifar da canji mai mahimmanci a cikin kauri na samuwar. Wannan ya sa bincike na gani ya zama ingantaccen kayan aiki don nazarin su. A kashi na gaba na labarin za mu yi la'akari da irin waɗannan abubuwan ƙasa dalla-dalla.
Bayanan gwaji. A ina kuka samo su kuma me kuke nema a cikinsu?
Abubuwan da aka bincika a cikin labarin an samo su ne a Yammacin Siberiya. Yankin, kamar yadda kowa ba tare da togiya ba tabbas ya sani, shi ne yankin da ake hako mai a kasarmu. Active ci gaba na adibas ya fara a cikin yankin a cikin 60s na karshe karni. Babban hanyar neman ma'ajiyar mai ita ce binciken girgizar kasa. Yana da ban sha'awa a kalli hotunan tauraron dan adam na wannan yanki. A ƙaramin ma'auni, zaku iya lura da ɗimbin fadama da tafkuna; ta hanyar faɗaɗa taswira, zaku iya ganin wuraren hako rijiyoyin cluster, kuma ta hanyar faɗaɗa taswira zuwa iyaka, zaku iya bambanta share bayanan bayanan tare da seismic. an gudanar da abubuwan lura.
Hoton tauraron dan adam taswirar Yandex - yankin birnin Noyabrsk
Cibiyar sadarwa na rijiyoyin rijiyoyin a daya daga cikin filayen
Duwatsu masu ɗauke da mai na Yammacin Siberiya suna faruwa a cikin zurfin zurfin zurfin - daga 1 km zuwa 5 km. An kafa babban adadin duwatsun da ke ɗauke da mai a zamanin Jurassic da Cretaceous. Jurassic zamani tabbas sananne ne ga mutane da yawa daga fim ɗin suna iri ɗaya. ya bambanta sosai da na zamani. Encyclopedia Britannica yana da jeri na paleomaps waɗanda ke siffanta kowane zamanin ilimin halitta.
Gabatarwa
Lokacin Jurassic
Lura cewa a zamanin Jurassic, yankin yammacin Siberiya ya kasance bakin tekun teku (ƙasar da koguna da ruwa mai zurfi). Tun da yanayin yana da dadi, zamu iya ɗauka cewa yanayin yanayin lokacin ya kasance kamar haka:
Jurassic Siberia
A cikin wannan hoton, abin da ke da mahimmanci a gare mu ba shine dabbobi da tsuntsaye ba, amma siffar kogin a bango. Kogin dai abu ne na kasa da muka tsaya a baya. Gaskiyar ita ce, ayyukan koguna na ba da damar rarrabuwar yashi da kyau, wanda zai zama tafki na mai. Wadannan tafkunan na iya samun siffa mai ban mamaki, hadadden tsari (kamar gadon kogi) kuma suna da kauri mai canzawa - kusa da bankunan kauri kadan ne, amma kusa da tsakiyar tashar ko kuma a wurare masu nisa yana karuwa. Don haka, kogunan da aka kafa a cikin Jurassic yanzu suna cikin zurfin kusan kilomita uku kuma sune abin neman tafkunan mai.
Bayanan gwaji. Gudanarwa da gani
Nan da nan bari mu yi ajiyar wuri game da abubuwan girgizar ƙasa da aka nuna a cikin labarin - saboda gaskiyar cewa adadin bayanan da aka yi amfani da shi don bincike yana da mahimmanci - kawai guntu na ainihin saitin alamun girgizar ƙasa yana cikin rubutun labarin. Wannan zai ba kowa damar sake yin lissafin da ke sama.
Lokacin aiki tare da bayanan girgizar ƙasa, masanin ilimin geophysici yawanci yana amfani da software na musamman (akwai shugabannin masana'antu da yawa waɗanda ake amfani da su sosai, misali Petrel ko Paradigm), wanda ke ba ku damar bincika nau'ikan bayanai daban-daban kuma yana da ingantacciyar hanyar hoto. Duk da dacewa, waɗannan nau'ikan software ma suna da nasu kurakurai - alal misali, aiwatar da algorithms na zamani a cikin tsayayyen juzu'i yana ɗaukar lokaci mai yawa, kuma yuwuwar yin lissafin sarrafa kansa yawanci yana iyakance. A cikin irin wannan yanayi, yana da matukar dacewa don amfani da tsarin lissafin kwamfuta da manyan harsunan shirye-shirye, waɗanda ke ba da damar yin amfani da tushe mai fa'ida na algorithmic kuma, a lokaci guda, ɗaukar abubuwa da yawa na yau da kullun. Wannan ita ce ƙa'idar da ake amfani da ita don aiki tare da bayanan girgizar ƙasa a Wolfram Mathematica. Ba daidai ba ne a rubuta ayyuka masu wadata don aiki mai hulɗa tare da bayanai - yana da mahimmanci don tabbatar da saukewa daga tsarin da aka yarda da shi gabaɗaya, yin amfani da algorithms da ake so zuwa gare su da loda su zuwa tsarin waje.
Bayan tsarin da aka tsara, za mu loda ainihin bayanan girgizar ƙasa kuma mu nuna su a ciki :
Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]Bayanan da aka zazzage da shigo da su ta wannan hanya sune hanyoyin da aka rubuta akan yanki mai nisan kilomita 10 zuwa 5. Idan an sami bayanan ta hanyar binciken yanayin girgizar ƙasa mai girma uku (ba a rubuta raƙuman ruwa tare da bayanan bayanan geophysical ɗaya ba, amma a duk faɗin yanki a lokaci ɗaya), yana yiwuwa a sami cubes na bayanan girgizar ƙasa. Waɗannan abubuwa ne masu girma uku, sassan a tsaye da a kwance waɗanda ke ba da damar cikakken nazarin yanayin yanayin ƙasa. A cikin misalin da aka yi la'akari, muna hulɗa da bayanai masu girma uku. Za mu iya samun wasu bayanai daga taken rubutu, kamar haka
StringPartition[seismic3DSEGY["textheader"], 80] // TableFormC 1 WANNAN FILE DEMO NE DON GWAJIN KASHIN GEOLOGYIO
C 2
C 3
C 4
C 5 SUNAN MAI AMFANI: MAI AMFANI DA WOLFRAM
C 6 SUNAN BINCIKE: WANI WUTA A SIBERIA
C 7 FILE TYPE 3D SEISMIC VOLUME
C 8
C 9
C10 Z kewayon: 2200M FARKO 2400M
Wannan saitin bayanai zai ishe mu don nuna manyan matakan bincike na bayanai. Alamun da ke cikin fayil ɗin ana yin rikodin su a jere kuma kowannensu yana kama da wani abu kamar wannan adadi - wannan shine rarraba amplitudes na raƙuman ruwa da aka nuna tare da axis na tsaye (zurfin axis).
ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2,
PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
LabelStyle -> Directive[Black, Italic], PlotRange -> All,
Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]Ɗaya daga cikin abubuwan da ke faruwa a ɓangaren girgizar ƙasa
Sanin adadin alamun da ke cikin kowane bangare na yankin da aka yi nazari, za ku iya samar da tsarin bayanai mai girma uku kuma ku nuna shi ta amfani da aikin Image3D[]
traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1; (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1; (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]Hoton 3D na kubu mai bayanan girgizar kasa. (A tsaye axis - zurfin)
Idan fasalin yanayin ƙasa na ban sha'awa ya haifar da matsanancin yanayi na girgizar ƙasa, to ana iya amfani da kayan aikin gani tare da nuna gaskiya. Wuraren "marasa mahimmanci" na rikodin za a iya sanya su ganuwa, barin abubuwan da ba a iya gani ba kawai. A Wolfram Mathematica ana iya yin wannan ta amfani da shi и .
data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]},
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]Hoton cube na Seismic ta amfani da Opacity[] da ayyukan Raster3D[].
Kamar yadda yake a cikin misali na roba, akan sassan asali na cube mutum zai iya gano wasu iyakokin geological (yadudduka) tare da sauƙi mai sauƙi.
Babban kayan aikin bincike na gani shine sauyin Fourier. Tare da taimakonsa, zaku iya ƙididdige girman bakan-mita na kowane alama ko rukuni na alamu. Koyaya, bayan canja wurin bayanai zuwa yankin mitar, bayanai sun ɓace game da wane lokuta (karanta a wane zurfin) mitar ta canza. Domin samun damar gano canje-canjen sigina akan lokaci (zurfin) axis, ana amfani da canjin Fourier mai taga da bacewar igiyar ruwa. Wannan labarin yana amfani da bazuwar igiyar ruwa. An fara amfani da fasahar nazarin wavelet sosai a cikin binciken girgizar ƙasa a cikin 90s. Ana ɗaukar fa'idar akan canjin Fourier mai taga a matsayin mafi kyawun ƙudurin lokaci.
Yin amfani da guntun lambar mai zuwa, zaku iya lalata ɗaya daga cikin alamun girgizar ƙasa zuwa sassa ɗaya:
cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]Rushewar alama cikin abubuwan da aka gyara
Don tantance yadda ake rarraba makamashin tunani a lokutan isowa daban-daban, ana amfani da scalograms (mai kama da spectrogram). A matsayinka na mai mulki, a aikace babu buƙatar nazarin duk abubuwan da aka gyara. Yawanci, ƙananan, tsakiya da manyan abubuwan haɗin mitoci an zaɓi.
freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]Scalogram. Sakamakon aiki
Harshen Wolfram yana amfani da aikin don sauya igiyar igiyar ruwa . Kuma za a yi amfani da wannan aikin zuwa ga dukkan saitin burbushi ta hanyar amfani da aikin . Anan ya kamata a lura da ɗayan ƙarfin Wolfram Mathematica - ikon yin amfani da daidaituwa . A cikin misalin da ke sama, babu buƙatar daidaitawa - ƙarar bayanai ba ta da girma, amma lokacin aiki tare da bayanan gwaji da ke dauke da daruruwan dubban alamu, wannan wajibi ne.
tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}]; Bayan amfani da aikin Sabbin saitin bayanai sun bayyana daidai da zaɓaɓɓun mitoci. A cikin misalin da ke sama, waɗannan mitoci sune: 38Hz, 33Hz, 27Hz. Mafi sau da yawa ana gudanar da zaɓin mitoci bisa ga gwaji - suna samun taswira masu tasiri don haɗuwa da mitar daban-daban kuma zaɓi mafi yawan bayanai daga mahangar masanin ilimin ƙasa.
Idan kuna buƙatar raba sakamakon tare da abokan aiki ko samar da su ga abokin ciniki, zaku iya amfani da aikin SEGYExport[] na fakitin GeologyIO
outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];Tare da uku daga cikin waɗannan cubes (ƙananan mitar, tsaka-tsaki, da manyan abubuwan haɓakawa), ana amfani da haɗakarwar RGB yawanci don ganin bayanan tare. Kowane bangare an sanya masa launi - ja, kore, blue. A Wolfram Mathematica ana iya yin wannan ta amfani da aikin .
Sakamakon shine hotuna waɗanda za a iya yin fassarar yanayin ƙasa. Matsakaicin da aka rubuta akan sashe yana ba da damar zazzage tashoshi na paleochannel, waɗanda suka fi dacewa su zama tafki kuma suna ɗauke da ajiyar mai. Binciken da bincike na analogues na zamani na irin wannan tsarin kogin yana ba mu damar ƙayyade sassan mafi mahimmanci na ma'ana. Tashoshin da kansu suna da kauri mai kauri na dutsen yashi da aka ware kuma suna da kyau tafki na mai. Wuraren da ke waje da abubuwan da ba a sani ba na "lace" sun yi kama da wuraren ajiyar ambaliyar ruwa na zamani. Duwatsun dutsen yumbu ne ke wakilta manyan wuraren ajiyar ambaliya kuma hakowa cikin waɗannan yankuna ba zai yi tasiri ba.
RGB yanki na cube data. A cikin tsakiya (dan kadan zuwa hagu na tsakiya) za ku iya gano kogin da ke da ma'ana.
RGB yanki na cube data. A gefen hagu za ku iya gano kogin da ke da ma'ana.
A wasu lokuta, ingancin bayanan girgizar ƙasa yana ba da damar bayyana hotuna masu mahimmanci. Wannan ya dogara da tsarin aikin filin, kayan aikin da ake amfani da su ta hanyar rage yawan amo. A irin waɗannan lokuta, ba kawai gaɓoɓin tsarin kogin ba ne ake iya gani ba, har ma da faɗuwar koguna na paleo.
Haɗin RGB na sassa uku na cube data seismic (yanke a kwance). Zurfin kusan kilomita 2.
Hoton tauraron dan adam na Volga River kusa da Saratov
ƙarshe
Wolfram Mathematica na iya nazarin bayanan girgizar ƙasa da magance matsalolin da ake amfani da su da suka shafi neman ma'adanai, kuma kunshin GeologyIO yana sa wannan tsari ya fi dacewa. Tsarin bayanan girgizar ƙasa shine irin ta yin amfani da ginanniyar hanyoyin don haɓaka ƙididdiga (, ,…) yana da inganci kuma yana ba ku damar sarrafa bayanai masu yawa. Ya zuwa babba, ana sauƙaƙe wannan ta hanyar fasalulluka na ajiyar bayanai na fakitin GeologyIO. Af, ana iya amfani da kunshin ba kawai a fagen binciken da aka yi amfani da shi ba. Ana amfani da kusan nau'ikan bayanai iri ɗaya a cikin radar da ke shiga ƙasa. Idan kuna da shawarwari kan yadda ake haɓaka sakamakon, waɗanne algorithms bincike na siginar daga Wolfram Mathematica arsenal sun dace da irin waɗannan bayanan, ko kuma idan kuna da wasu sharhi masu mahimmanci, don Allah bar sharhi.
source: www.habr.com