Grafana를 예로 들어 Yandex.Cloud에 분산 서비스 배포

안녕하세요 여러분! 저는 수업 과정의 일환으로 다음과 같은 국내 클라우드 플랫폼의 기능을 연구했습니다. 얀덱스.클라우드. 플랫폼은 실질적인 문제 해결을 위한 다양한 서비스를 제공합니다. 그러나 때로는 이러한 서비스를 기반으로 하는 상당히 광범위한 인프라를 갖춘 자체 클라우드 애플리케이션을 설정해야 하는 경우도 있습니다. 이 기사에서는 그러한 애플리케이션을 배포한 경험을 공유하고 싶습니다.

무엇을 받고 싶나요?

그라 파나 — 분석 문제를 해결하거나 시스템의 문제를 모니터링하기 위한 강력한 도구입니다. 기본 구성에서는 Grafana 웹 서버와 분석의 기반이 되는 데이터 세트가 있는 데이터베이스(ClickHouse, InfluxDB 등)가 있는 가상 머신입니다.

웹 서버가 포함된 가상 머신을 시작한 후 해당 호스트로 이동하여 아름다운 UI를 얻고, 추가 작업을 위한 소스로 데이터베이스를 지정하고, 대시보드와 그래프를 만들 수 있습니다.

기본 버전에는 한 가지 중요한 단점이 있습니다. 즉, 내결함성이 전혀 없습니다. 즉, 애플리케이션의 전체 기능은 하나의 가상 머신의 실행 가능성에 따라 달라집니다. 거부하거나 10명이 동시에 UI를 열면 문제가 발생합니다.

이 문제는 간단하게 해결할 수 있습니다. 웹 서버와 함께 동일한 가상 머신을 많이 배포하고 L3 밸런서 아래에 배치하기만 하면 됩니다. 그러나 여기서 모든 것이 그렇게 명확하지는 않습니다. Grafana는 사용자 설정(데이터베이스, 대시보드, 그래프 등에 대한 경로)을 가상 머신의 디스크에 직접 저장합니다. 따라서 UI에서 일부 설정을 변경하면 이러한 변경 사항은 밸런서가 보낸 가상 머신에만 반영됩니다. 이로 인해 애플리케이션 설정이 일관되지 않고 실행 및 사용 시 문제가 발생합니다.

여기서는 MySQL 또는 이와 동등한 데이터베이스와 같은 다른 데이터베이스가 구출됩니다. 우리는 Grafana에게 이 "예비" 데이터베이스에 사용자 설정을 저장해야 한다고 말합니다. 그 후에는 각 머신에서 이 데이터베이스에 대한 경로를 한 번 지정하고 가상 머신 중 하나에서 다른 모든 사용자 설정을 편집하면 충분합니다.

다음은 최종 애플리케이션 인프라의 다이어그램입니다.

손으로 들어올리는 법을 배우자

MySQL과 클릭하우스

버튼 클릭만으로 이러한 애플리케이션을 배포하기 전에 각 구성 요소를 처리하고 서로 통합하는 방법을 배워야 했습니다.

여기에서는 L3 밸런서, ClickHouse 및 MySQL을 관리형 서비스로 제공하는 Yandex.Cloud가 우리를 도와줄 것입니다. 사용자는 매개변수를 지정하고 플랫폼이 모든 것을 작동 순서대로 가져올 때까지 기다리기만 하면 됩니다.

등록하고 클라우드와 결제 계정을 만들었습니다. 그 후 클라우드로 가서 최소한의 설정으로 MySQL과 ClickHouse 클러스터를 설정했습니다. 활성화될 때까지 기다렸습니다.

또한 각 클러스터에 데이터베이스를 생성하고 로그인 및 비밀번호를 사용하여 데이터베이스에 대한 액세스를 구성해야 한다는 점을 기억해야 합니다. 여기서는 자세히 설명하지 않겠습니다. 인터페이스에서는 모든 것이 매우 명확합니다.

명백하지 않은 세부 사항은 이러한 데이터베이스에 내결함성을 보장하는 많은 호스트가 있다는 것입니다. 그러나 Grafana에는 작동하는 각 데이터베이스에 대해 정확히 하나의 호스트가 필요합니다. 긴 독서 선적 서류 비치 구름이 나에게 결정을 내려주었다. 종의 숙주인 것으로 밝혀졌습니다. c-<cluster_id>.rw.mdb.yandexcloud.net 해당 ID를 가진 클러스터의 현재 활성 마스터 호스트에 매핑됩니다. 이것이 우리가 Grafana에게 줄 것입니다.

웹 서버

이제 웹 서버에 달려 있습니다. Linux를 사용하여 일반 가상 머신을 생성하고 여기에 Grafana를 수동으로 구성해 보겠습니다.

SSH를 통해 연결하고 필요한 패키지를 설치해 보겠습니다.

sudo apt-get install -y apt-transport-https software-properties-common wget
wget -q -O - https://packages.grafana.com/gpg.key | sudo apt-key add -
sudo add-apt-repository "deb https://packages.grafana.com/enterprise/deb stable main"
sudo apt-get update
sudo apt-get install -y grafana-enterprise 

그런 다음 systemctl에서 Grafana를 실행하고 ClickHouse 작업을 위한 플러그인을 설치해 보겠습니다(예, 기본 패키지에는 제공되지 않습니다).

sudo systemctl start grafana-server
sudo systemctl enable grafana-server
sudo grafana-cli plugins install vertamedia-clickhouse-datasource

그 다음은 간단한 명령으로 끝입니다

sudo service grafana-server start

웹 서버를 시작하겠습니다. 이제 브라우저에 가상 머신의 외부 IP 주소를 입력하고 포트 3000을 지정하면 아름다운 그래픽 UI를 볼 수 있습니다.

그러나 서두르지 마십시오. Grafana를 설정하기 전에 설정을 저장할 MySQL 경로를 알려주어야 합니다.

Grafana 웹 서버의 전체 구성은 파일에 있습니다. /etc/grafana/grafana.ini. 필수 줄은 다음과 같습니다.

;url =

호스트를 MySQL 클러스터로 설정했습니다. 동일한 파일에는 위 그림의 Grafana에 액세스하기 위한 로그인 및 비밀번호가 포함되어 있으며 기본적으로 둘 다 동일합니다. admin.

sed 명령을 사용할 수 있습니다.

sudo sed -i "s#.*;url =.*#url = mysql://${MYSQL_USERNAME}:${MYSQL_PASSWORD}@${MYSQL_CLUSTER_URI}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_user =.*#admin_user = ${GRAFANA_USERNAME}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_password =.*#admin_password = ${GRAFANA_PASSWORD}#" /etc/grafana/grafana.ini

이제 웹 서버를 다시 시작할 시간입니다!

sudo service grafana-server restart

이제 Grafana UI에서 ClickHouse를 데이터 소스로 지정하겠습니다.

다음 설정을 사용하여 작업 구성을 달성할 수 있었습니다.

URL로 지정했습니다 https://c-<cluster_id>.rw.mdb.yandexcloud.net:8443

모두! CH 및 MySQL에 연결된 웹 서버가 있는 작동하는 가상 머신이 하나 있습니다. 이미 ClickHouse에 데이터 세트를 업로드하고 대시보드를 구축할 수 있습니다. 그러나 우리는 아직 목표를 달성하지 못했고 본격적인 인프라를 구축하지 못했습니다.

포장 기계

Yandex.Cloud를 사용하면 기존 가상 머신의 디스크 이미지를 생성하고 이를 기반으로 서로 동일한 머신 수를 생성할 수 있습니다. 이것이 바로 우리가 사용할 것입니다. 이미지를 편리하게 조립하려면 도구를 사용하세요. 포장 기계 HashiCorp에서. 이미지 조립 지침이 포함된 json 파일을 입력으로 사용합니다.

json 파일은 빌더와 프로비저너라는 두 개의 블록으로 구성됩니다. 첫 번째 블록은 이미지 자체의 매개변수를 엔터티로 설명하고, 두 번째 블록은 필요한 콘텐츠를 채우는 지침을 설명합니다.

빌더

{
"builders": [
    {
      "type": "yandex",
      "endpoint": "{{user `endpoint`}}",
      "folder_id": "<folder_id>",
      "subnet_id": "{{user `subnet_id`}}",
      "zone": "{{user `zone`}}",
      "labels": {},
      "use_ipv4_nat": true,
      "use_internal_ip": false,
      "service_account_key_file": "<service_account_key_file>",
      "image_name": "grafana-{{timestamp}}",
      "image_family": "grafana",
      "image_labels": {},
      "image_description": "GRAFANA",
      "source_image_family": "ubuntu-1804-lts",
      "disk_size_gb": 3,
      "disk_type": "network-hdd",
      "ssh_username": "ubuntu"
    }
  ],
...
}

이 템플릿에서는 이미지를 생성하려는 클라우드 섹션의 식별자와 이 섹션에서 이전에 생성된 서비스 계정의 키가 포함된 파일 경로를 설정해야 합니다. 해당 섹션에서 파일 형식으로 서비스 계정 및 키를 생성하는 방법에 대해 자세히 알아볼 수 있습니다. 선적 서류 비치.

이 구성은 디스크 이미지가 플랫폼을 기반으로 구축됨을 나타냅니다. ubuntu-1804-lts, 이미지 계열의 적절한 사용자 섹션에 배치 GRAFANA 이름으로 grafana-{{timestamp}}.

제공자

이제 구성의 더 흥미로운 부분이 나옵니다. 가상 머신의 상태를 디스크 이미지로 고정하기 전에 가상 머신에서 수행해야 하는 일련의 작업을 설명합니다.

{
...,
"provisioners": [
    {
            "type": "shell",
            "pause_before": "5s",
            "scripts": [
                "prepare-ctg.sh"
            ]
        },
    {
            "type": "file",
            "source": "setup.sh",
            "destination": "/opt/grafana/setup.sh"
        },
        {
            "type": "shell",
        "execute_command": "sudo {{ .Vars }} bash '{{ .Path }}'",
            "pause_before": "5s",
            "scripts": [
                "install-packages.sh",
                "grafana-setup.sh",
                "run-setup-at-reboot.sh"
        ]
        }
  ]
}

여기서 모든 작업은 3단계로 나뉩니다. 첫 번째 단계에서는 보조 디렉터리를 생성하는 간단한 스크립트가 실행됩니다.

준비-ctg.sh:

#!/bin/bash
sudo mkdir -p /opt/grafana
sudo chown -R ubuntu:ubuntu /opt/grafana

다음 단계에서는 가상 머신을 시작한 후 즉시 실행해야 하는 스크립트를 이 디렉터리에 배치합니다. 이 스크립트는 Grafana 구성에 등록해야 하는 사용자 변수를 넣고 웹 서버를 다시 시작합니다.

setup.sh:

#!/bin/bash
CLUSTER_ID="<cluster_id>"
USERNAME="<username>"
PASSWORD="<password>"
sudo sed -i "s#.*;url =.*#url = mysql://${USERNAME}:${PASSWORD}@c-${CLUSTER_ID}.rw.mdb.yandexcloud.net#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_user =.*#admin_user = ${USERNAME}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_password =.*#admin_password = ${PASSWORD}#" /etc/grafana/grafana.ini
sudo service grafana-server restart

그 후에 해야 할 일이 3가지 남았습니다.
1) 패키지 설치
2) systemctl에서 Grafana를 실행하고 ClickHouse 플러그인을 설치합니다.
3) 가상 머신을 켠 직후 setup.sh 스크립트를 실행 대기열에 넣습니다.

설치 패키지.sh:

#!/bin/bash
sudo systemd-run --property='After=apt-daily.service apt-daily-upgrade.service' --wait /bin/true
sudo apt-get install -y apt-transport-https
sudo apt-get install -y software-properties-common wget
wget -q -O - https://packages.grafana.com/gpg.key | sudo apt-key add -
sudo add-apt-repository "deb https://packages.grafana.com/enterprise/deb stable main"
sudo apt-get update
sudo apt-get install -y grafana-enterprise 

grafana-setup.sh:

#!/bin/bash
sudo systemctl start grafana-server
sudo systemctl enable grafana-server
sudo grafana-cli plugins install vertamedia-clickhouse-datasource

실행-설정-at-reboot.sh:

#!/bin/bash
chmod +x /opt/grafana/setup.sh
cat > /etc/cron.d/first-boot <<EOF
PATH=/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin:/usr/games:/usr/local/games
@reboot root /bin/bash /opt/grafana/setup.sh > /var/log/yc-setup.log 2>&1
EOF
chmod +x /etc/cron.d/first-boot;

이제 남은 것은 Packer를 실행하고 출력 이미지를 지정된 섹션에 배치하는 것입니다. 가상 머신을 생성할 때 이를 부팅 디스크로 선택할 수 있으며 실행 후 미리 만들어진 Grafana 웹 서버를 받게 됩니다.

인스턴스 그룹 및 밸런서

동일한 Grafana 웹 서버를 여러 개 생성할 수 있는 디스크 이미지가 있으면 인스턴스 그룹을 생성할 수 있습니다. Yandex.Cloud 플랫폼에서 이 용어는 동일한 특성을 가진 가상 머신의 결합을 나타냅니다. 인스턴스 그룹을 생성할 때 이 그룹에 있는 모든 머신의 프로토타입이 구성되고 그룹 자체의 특성(예: 활성 머신의 최소 및 최대 수)이 구성됩니다. 현재 숫자가 이러한 기준을 충족하지 않으면 인스턴스 그룹 자체가 불필요한 머신을 제거하거나 자체 이미지에 새 머신을 생성합니다.

작업의 일환으로 이전에 생성된 디스크 이미지에서 생성될 웹 서버의 인스턴스 그룹을 생성합니다.

정말 놀라운 점은 마지막 인스턴스 그룹 설정입니다. Load Balancer와 통합된 대상 그룹은 몇 개의 버튼을 클릭하여 이 그룹의 가상 머신 위에 L3 밸런서를 구성하는 데 도움이 됩니다.

밸런서를 설정할 때 두 가지 중요한 사항을 구현했습니다.

1. 밸런서가 포트 80에서 사용자 트래픽을 허용하고 이를 정확히 Grafana가 있는 가상 머신의 포트 3000으로 리디렉션하도록 했습니다.
2. 포트 3000에 핑을 보내 머신의 실행 가능성을 확인하도록 설정했습니다.

미니 요약

마지막으로 원하는 애플리케이션 인프라를 수동으로 배포할 수 있었고 이제 탄력성이 뛰어난 Grafana 서비스를 갖게 되었습니다. 데이터 세트를 로드하려면 ClickHouse 클러스터의 호스트와 애플리케이션의 진입점인 밸런서의 IP 주소만 알면 됩니다.

승리처럼 보일까요? 응, 승리야. 하지만 뭔가 여전히 혼란스럽습니다. 위의 전체 프로세스에는 수동 단계가 많이 필요하고 확장성이 전혀 없으므로 가능하면 자동화하고 싶습니다. 이것이 다음 섹션에서 다루어질 내용입니다.

Terraform 통합

우리는 HashiCorp의 도구를 다시 사용할 것입니다. 테라 폼. 사용자가 전달한 여러 변수를 기반으로 버튼 클릭만으로 전체 애플리케이션 인프라를 배포하는 데 도움이 됩니다. 다양한 사용자의 다양한 섹션에서 여러 번 실행할 수 있는 레시피를 작성해 보겠습니다.

Terraform을 사용하는 모든 작업은 구성 파일(*.tf) 및 이를 기반으로 인프라를 구축합니다.

변수들

파일 맨 처음에는 향후 인프라가 배포될 위치와 방법을 결정하는 변수가 포함됩니다.

variable "oauth_token" {
    type = string
    default = "<oauth-token>"
}
variable "cloud_id" {
    type = string
    default = "<cloud-id>"
}
variable "folder_id" {
    type = string
    default = "<folder_id>"
}
variable "service_account_id" {
    type = string
    default = "<service_account_id>"
}
variable "image_id" {
    type = string
    default = "<image_id>"
}
variable "username" {
    type = string
    default = "<username>"
}
variable "password" {
    type = string
    default = "<password>"
}
variable "dbname" {
    type = string
    default = "<dbname>"
}
variable "public_key_path" {
    type = string
    default = "<path to ssh public key>"
}

전체 애플리케이션 배포 프로세스는 디스크 이미지를 구축하고 이러한 변수를 설정하는 것으로 요약됩니다. 그들이 무엇을 담당하는지 설명하겠습니다.

oauth_token — 클라우드에 액세스하기 위한 토큰입니다. 다음으로 얻을 수 있습니다. 링크.
cloud_id — 애플리케이션을 배포할 클라우드 식별자
폴더 아이디 — 애플리케이션을 배포할 섹션 식별자
service_account_id — 클라우드의 해당 섹션에 있는 서비스 계정 식별자.
이미지_ID — Packer를 사용하여 얻은 디스크 이미지의 식별자
사용자 이름 и 암호 — 데이터베이스와 Grafana 웹 서버에 모두 액세스하기 위한 사용자 이름과 비밀번호
데이터베이스 이름 — CH 및 MySQL 클러스터 내부의 데이터베이스 이름
공개_키_경로 — 이름으로 연결하는 데 사용할 수 있는 공개 SSH 키가 있는 파일 경로 ubuntu 웹 서버가 있는 가상 머신에

제공업체 설정

이제 Terraform 공급자(이 경우 Yandex)를 구성해야 합니다.

provider "yandex" {
  token     = var.oauth_token
  cloud_id  = var.cloud_id
  folder_id = var.folder_id
  zone      = "ru-central1-a"
}

여기서는 위에서 정의한 변수를 사용하고 있음을 알 수 있습니다.

네트워크 및 클러스터

이제 우리는 인프라 요소가 통신하고 XNUMX개의 서브넷(각 지역에 하나씩)과 CH 및 MySQL 클러스터를 키우는 네트워크를 생성할 것입니다.

resource "yandex_vpc_network" "grafana_network" {}

resource "yandex_vpc_subnet" "subnet_a" {
  zone           = "ru-central1-a"
  network_id     = yandex_vpc_network.grafana_network.id
  v4_cidr_blocks = ["10.1.0.0/24"]
}

resource "yandex_vpc_subnet" "subnet_b" {
  zone           = "ru-central1-b"
  network_id     = yandex_vpc_network.grafana_network.id
  v4_cidr_blocks = ["10.2.0.0/24"]
}

resource "yandex_vpc_subnet" "subnet_c" {
  zone           = "ru-central1-c"
  network_id     = yandex_vpc_network.grafana_network.id
  v4_cidr_blocks = ["10.3.0.0/24"]
}

resource "yandex_mdb_clickhouse_cluster" "ch_cluster" {
  name        = "grafana-clickhouse"
  environment = "PRODUCTION"
  network_id  = yandex_vpc_network.grafana_network.id

  clickhouse {
    resources {
      resource_preset_id = "s2.micro"
      disk_type_id       = "network-ssd"
      disk_size          = 16
    }
  }

  zookeeper {
    resources {
      resource_preset_id = "s2.micro"
      disk_type_id       = "network-ssd"
      disk_size          = 10
    }
  }

  database {
    name = var.dbname
  }

  user {
    name     = var.username
    password = var.password
    permission {
      database_name = var.dbname
    }
  }

  host {
    type      = "CLICKHOUSE"
    zone      = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.subnet_a.id
  }

  host {
    type      = "CLICKHOUSE"
    zone      = "ru-central1-b"
    subnet_id = yandex_vpc_subnet.subnet_b.id
  }

  host {
    type      = "CLICKHOUSE"
    zone      = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.subnet_c.id
  }

  host {
    type      = "ZOOKEEPER"
    zone      = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.subnet_a.id
  }

  host {
    type      = "ZOOKEEPER"
    zone      = "ru-central1-b"
    subnet_id = yandex_vpc_subnet.subnet_b.id
  }

  host {
    type      = "ZOOKEEPER"
    zone      = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.subnet_c.id
  }
}

resource "yandex_mdb_mysql_cluster" "mysql_cluster" {
  name        = "grafana_mysql"
  environment = "PRODUCTION"
  network_id  = yandex_vpc_network.grafana_network.id
  version     = "8.0"

  resources {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 16
  }

  database {
    name = var.dbname
  }

  user {
    name     = var.username
    password = var.password
    permission {
      database_name = var.dbname
      roles         = ["ALL"]
    }
  }

  host {
    zone      = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.subnet_a.id
  }
  host {
    zone      = "ru-central1-b"
    subnet_id = yandex_vpc_subnet.subnet_b.id
  }
  host {
    zone      = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.subnet_c.id
  }
}

보시다시피, 두 클러스터 각각은 세 개의 가용성 영역에 배치되어 내결함성이 매우 뛰어납니다.

웹 서버

우리는 같은 정신으로 계속할 수 있을 것 같았지만 난관에 봉착했습니다. 그 전에는 먼저 MySQL 클러스터를 생성한 후에야 해당 ID를 알고 필요한 구성이 포함된 디스크 이미지를 수집하여 클러스터에 대한 호스트를 지정했습니다. 그러나 이제 이미지 빌드 시를 포함하여 Terraform을 시작하기 전에는 클러스터 ID를 알 수 없습니다. 따라서 나는 다음과 같은 조치를 취해야했습니다. 장난.

Amazon의 메타데이터 서비스를 사용하여 일부 매개변수를 가상 머신에 전달하고 이를 수락하고 처리합니다. 시작 후 사용자가 Terraform 파일에 지정한 MySQL 클러스터 호스트 및 사용자 이름-비밀번호 뒤의 메타데이터로 이동하려면 머신이 필요합니다. 파일 내용을 살짝 바꿔보자 setup.sh, 가상 머신이 켜질 때 실행됩니다.

setup.sh:

#!/bin/bash
CLUSTER_URI="$(curl -H 'Metadata-Flavor:Google' http://169.254.169.254/computeMetadata/v1/instance/attributes/mysql_cluster_uri)"
USERNAME="$(curl -H 'Metadata-Flavor:Google' http://169.254.169.254/computeMetadata/v1/instance/attributes/username)"
PASSWORD="$(curl -H 'Metadata-Flavor:Google' http://169.254.169.254/computeMetadata/v1/instance/attributes/password)"
sudo sed -i "s#.*;url =.*#url = mysql://${USERNAME}:${PASSWORD}@${CLUSTER_URI}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_user =.*#admin_user = ${USERNAME}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_password =.*#admin_password = ${PASSWORD}#" /etc/grafana/grafana.ini
sudo service grafana-server restart

인스턴스 그룹 및 밸런서

새 디스크 이미지를 다시 빌드한 후 마침내 Terraform용 파일을 추가할 수 있습니다.

기존 디스크 이미지를 사용하려고 한다고 지정해 보겠습니다.

data "yandex_compute_image" "grafana_image" {
  image_id = var.image_id
}

이제 인스턴스 그룹을 만들어 보겠습니다.

resource "yandex_compute_instance_group" "grafana_group" {
  name               = "grafana-group"
  folder_id          = var.folder_id
  service_account_id = var.service_account_id
  instance_template {
    platform_id = "standard-v1"
    resources {
      memory = 1
      cores  = 1
    }
    boot_disk {
      mode = "READ_WRITE"
      initialize_params {
        image_id = data.yandex_compute_image.grafana_image.id
        size     = 4
      }
    }
    network_interface {
      network_id = yandex_vpc_network.grafana_network.id
      subnet_ids = [yandex_vpc_subnet.subnet_a.id, yandex_vpc_subnet.subnet_b.id, yandex_vpc_subnet.subnet_c.id]
      nat = "true"
    }
    metadata = {
      mysql_cluster_uri = "c-${yandex_mdb_mysql_cluster.mysql_cluster.id}.rw.mdb.yandexcloud.net:3306/${var.dbname}"
      username = var.username
      password = var.password
      ssh-keys = "ubuntu:${file("${var.public_key_path}")}"
    }
    network_settings {
      type = "STANDARD"
    }
  }

  scale_policy {
    fixed_scale {
      size = 6
    }
  }

  allocation_policy {
    zones = ["ru-central1-a", "ru-central1-b", "ru-central1-c"]
  }

  deploy_policy {
    max_unavailable = 2
    max_creating    = 2
    max_expansion   = 2
    max_deleting    = 2
  }

  load_balancer {
    target_group_name = "grafana-target-group"
  }
}

메타데이터에 이를 어떻게 전달했는지 주목할 필요가 있습니다. cluster_uri, username и password. 가상 머신이 시작 시 꺼내서 Grafana 구성에 넣는 것은 바로 이러한 것입니다.

그것은 밸런서에게 달려 있습니다.

resource "yandex_lb_network_load_balancer" "grafana_balancer" {
  name = "grafana-balancer"

  listener {
    name = "grafana-listener"
    port = 80
    target_port = 3000
    external_address_spec {
      ip_version = "ipv4"
    }
  }

  attached_target_group {
    target_group_id = yandex_compute_instance_group.grafana_group.load_balancer.0.target_group_id

    healthcheck {
      name = "healthcheck"
      tcp_options {
        port = 3000
      }
    }
  }
}

약간의 설탕

조금 남았습니다. 인프라가 배포된 후에는 Grafana UI로 이동하여 CH 클러스터(아직 ID를 가져와야 함)를 데이터 원본으로 수동으로 추가해야 합니다. 그러나 Terraform은 클러스터 ID를 알고 있습니다. 그 문제를 해결하는 일을 그에게 맡기자.

새로운 공급자인 Grafana를 추가하고 그녀에게 밸런서의 IP 주소를 호스트로 제공하겠습니다. Terraform이 해당 밸런서가 결정하는 머신에서 수행하는 모든 변경 사항은 MySQL에서 증가하므로 다른 모든 머신에서도 커집니다.

provider "grafana" {
  url  = "http://${[for s in yandex_lb_network_load_balancer.grafana_balancer.listener: s.external_address_spec.0.address].0}"
  auth = "${var.username}:${var.password}"
}

resource "grafana_data_source" "ch_data_source" {
  type          = "vertamedia-clickhouse-datasource"
  name          = "grafana"
  url           = "https://c-${yandex_mdb_clickhouse_cluster.ch_cluster.id}.rw.mdb.yandexcloud.net:8443"
  basic_auth_enabled = "true"
  basic_auth_username = var.username
  basic_auth_password = var.password
  is_default = "true"
  access_mode = "proxy"
}

머리를 빗자

ClickHouse 클러스터의 밸런서 IP 주소와 호스트를 표시해 보겠습니다.

output "grafana_balancer_ip_address" {
  value = [for s in yandex_lb_network_load_balancer.grafana_balancer.listener: s.external_address_spec.0.address].0
}

output "clickhouse_cluster_host" {
  value = "https://c-${yandex_mdb_clickhouse_cluster.ch_cluster.id}.rw.mdb.yandexcloud.net:8443"
}

실행할 수 있습니다

모두! 구성 파일이 준비되었으며 변수를 설정하여 Terraform에 위에서 설명한 모든 내용을 발생시키도록 지시할 수 있습니다. 전체 과정은 약 15분 정도 걸렸습니다.
마지막에는 다음과 같은 아름다운 메시지를 볼 수 있습니다.

Apply complete! Resources: 9 added, 0 changed, 0 destroyed.
Outputs:

clickhouse_cluster_host = https://c-c9q14ipa2ngadqsbp2iq.rw.mdb.yandexcloud.net:8443
grafana_balancer_ip_address = 130.193.50.25

그리고 클라우드에서는 강화된 인프라의 요소가 표시됩니다.

합계하다

이제 Grafana를 예로 사용하여 각자는 Yandex.Cloud 플랫폼에서 광범위한 클라우드 아키텍처로 애플리케이션을 배포할 수 있습니다. Packer 및 Terraform과 같은 HashiCorp의 유용한 도구가 이 작업에 도움이 될 수 있습니다. 누군가가 이 글을 유용하게 여기기를 바랍니다 :)

PS 아래에는 이 기사에서 제공한 단편인 Packer 및 Terraform에 대한 기성 레시피를 찾을 수 있는 저장소에 대한 링크를 첨부하겠습니다.

저장소

출처 : habr.com