Spas ji bo nivîskarê blogê ji bo rapora xwe
Pîrozbahiyê
Ev not di çarçoveya konferansê de hatiye nivîsandin û kurteya rapora ku min daye dihewîne. Bûyer di meha Hezîranê de li St. Ji ber ku ez ji malpera konferansê dûr dixebitim, ez nikarim beşdarî vê bûyerê bibim. Di salên 2016 û 2017an de min li raporên konferansê guhdarî kir, îsal jî min pêşkêşiyek kir. Pêşîn, mijarek balkêş (ji min re xuya dike) derketiye, ku em pê re pêşde diçin , û ya duyemîn jî, piştî lêkolînek dirêj li ser qanûnên Federasyona Rûsyayê di derbarê siyaseta cezayan de, li pargîdaniya ku ez lê dixebitim, bi qasî du destûr xuya bûn. .
Beriya ku ez derbasî mijara axaftina xwe bibim, dixwazim balê bikişînim ser organîzekirina baş a çalakiyê. Di rûpela serdana konferansê de wêneyek Katedrala Kazan bikar tîne. Katedral yek ji seyrangehên sereke yên St.
Li ber deriyê Zanîngeha Aborî ya Dewletê ya St. Di dema qeydkirinê de, bîranînên piçûk hatin dayîn (lîstokek - çîpek dibiriqe, pênûs, çîpên bi sembolên Wolfram). Di bernameya konferansê de navberên firavîn û qehweyê jî cih girtin. Min berê li ser qehwe û pîvazên xweş ên li ser dîwarê komê destnîşan kir - şef mezin in. Bi vê beşa destpêkê, ez dixwazim balê bikşînim ser wê yekê ku bûyer bi xwe, format û cihê wê jixwe hestên erênî bi xwe re tîne.
Rapora ku ji aliyê min û Kirill Belov ve hatiye amadekirin bi navê “Bikaranîna Wolfram Mathematica ji bo çareserkirina pirsgirêkên di jeofîzîka sepandî de. Analîza spektral ya daneyên erdhejê an "ku çemên kevnar diherikin." Naveroka raporê du beşan digire: Ya yekem, karanîna algorîtmayên ku di nav de hene ji bo analîzkirina daneyên jeofîzîkî, û ya duyemîn jî, ev e ku meriv çawa daneyên jeofîzîkî têxe Wolfram Mathematica.
Lêgerîna erdhejê
Pêşî hûn hewce ne ku rêwîtiyek kurt li jeofîzîkê bikin. Jeofizîk zanista ku taybetiyên fizîkî yên zinaran lêkolîn dike ye. Belê, ji ber ku kevir xwedî taybetmendiyên cûda ne: elektrîk, magnetîkî, elastîk, rêbazên jeofizîkê yên têkildar hene: lêgerîna elektrîkê, lêgerîna magnetîkî, lêgerîna erdhejê... Di çarçoveya vê gotarê de, em ê tenê bi berfirehî li ser lêgerîna erdhejê nîqaş bikin. Lêgerîna erdhejê rêbaza sereke ya lêgerîna neft û gazê ye. Rêbaz li ser heyecana lerizînên elastîk û dûv re tomarkirina bersivê ji zinarên ku qada lêkolînê pêk tînin, pêk tê. Lerizîn li bejahiyê (bi dînamîtan an jêderkên lerizînê yên ne-teqandî yên lerizînên elastîk) an li deryayê (bi çekên hewayê) bi heyecan in. Lerizînên elastîk di nav girseya zinaran de belav dibin, li sînorên qatên xwedî taybetmendiyên cihêreng vediqetin û xuyang dibin. Pêlên reflekskirî vedigerin ser rûyê erdê û ji hêla jeofonên li ser bejahiyê ve têne tomar kirin (bi gelemperî amûrên elektrodînamîk ên ku li ser tevgera magnetek ku di kulikê de sekinîne) an hîdrofonên di deryayê de (li ser bingeha bandora piezoelektrîkî) têne tomar kirin. Di dema hatina pêlan de, mirov dikare kûrahiya qatên jeolojîk dadbar bike.
Amûrên kişandina keştiya sîsmîk
Çeka hewayê vibrasyonên elastîk heyecan dike
Pêl di nav girseya zinaran re derbas dibin û bi hîdrofonan têne tomarkirin
Keştiya lêkolînê ya lêkolîna jeofizîkî "Ivan Gubkin" li keleka nêzîkî Pira Blagoveshchensky li St.
Modela sînyala erdhejê
Kevir xwedî taybetmendiyên fizîkî yên cihê ne. Ji bo lêgerîna erdhejê, taybetmendiyên elastîk di serî de girîng in - leza belavbûna lerzîn û tîrêjê. Ger du qat xwedan taybetmendiyên heman an jî mîna hev bin, wê hingê pêl "dê nabîne" sînorê di navbera wan de. Ger leza pêlan di qatan de ji hev cuda bin, wê hingê refleks dê li sînorê qatan çêbibe. Cûdahiya di taybetmendiyan de çi qas mezin be, refleks ew qas xurtir dibe. Zêdebûna wê dê ji hêla rêjeya refleksê (rc) ve were destnîşankirin:
ku ρ tîrêjiya kevir e, ν leza pêlê ye, 1 û 2 qatên jorîn û jêrîn nîşan didin.
Yek ji wan modelên sînyala erdhejê ya herî hêsan û ku pir caran tê bikar anîn modela tevlihevkirinê ye, dema ku şopa erdhejê ya tomarkirî wekî encama berhevkirina rêzek hevrêzên refleksê bi nebza lêkolînê re tê destnîşan kirin:
ku s (t) - şopa erdhejê, yanî. her tiştê ku ji hêla hîdrofon an jeofonê ve di demek tomarkirinê de hatî tomar kirin, w(t) - sînyala ku ji hêla çeka hewayê ve hatî çêkirin, n(t) - dengê random.
Werin em wekî mînak şopa erdhejê ya sentetîk hesab bikin. Em ê pêla Rickerê, ku bi berfirehî di keşfkirina erdhejê de tê bikar anîn, wekî nîşana destpêkê bikar bînin.
length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]Hêza erdhejê ya destpêkê
Em ê du sînoran li kûrahiyên 300 ms û 600 ms deynin, û hevrêzên refleksê dê jimareyên rasthatî bin.
rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]Rêzeya hevberên refleksê
Werin em şopa erdhejê hesab bikin û nîşan bidin. Ji ber ku hevberên refleksê xwedî nîşanên cihê ne, em li ser şopa erdhejê du refleksên guherbar distînin.
traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]track simulated
Ji bo vê nimûneyê, pêdivî ye ku rezervek were çêkirin - di rastiyê de, kûrahiya qatan, bê guman, bi metreyan tê destnîşankirin, û hesabkirina şopa erdhejê ji bo qada demê pêk tê. Dê rasttir be ku meriv kûrahiyan bi metreyan verast bike û demên gihîştinê bi zanîna leza di qatan de bihesibîne. Di vê rewşê de, min tavilê qatan li ser eksê demê danî.
Ger em li ser lêkolîna zeviyê biaxivin, wê hingê di encama çavdêriyên weha de hejmareke mezin ji rêzikên demkî yên wekhev (şopên erdhejê) têne tomar kirin. Mînakî, dema lêkolîna cîhek 25 km dirêj û 15 km fireh e, ku, di encama xebatê de, her şopek şaneyek bi pîvana 25x25 metre (şaneyek weha jê re tê gotin, binav dike), di rêza daneya paşîn de dê 600000 şop hebin. Digel dema nimûneyê 1 ms û dema tomarkirinê 5 çirkeyan, pelê daneya paşîn dê ji 11 GB zêdetir be, û qebareya materyalê "xav" a orîjînal dikare bi sedan gigabayt be.
Meriv çawa bi wan re dixebite ?
Pakêt
Pêşxistina pakêtê dest pê kir li ser dîwarê VK ya koma piştevaniya rûsî-axêv. Bi saya bersivên civakê, çareseriyek pir zû hat dîtin. Û di encamê de, ew di pêşveçûnek cidî de mezin bû. Gorî Ji hêla moderatoran ve jî hate nîşankirin. Heya nuha, pakêt piştgirî dide xebata bi celebên daneya jêrîn ên ku di pîşesaziya jeolojîk de bi rengek çalak têne bikar anîn:
- îtxalkirina daneyên nexşeyê di formatên ZMAP û IRAP de
- îtxalkirina pîvandinê di bîrên formata LAS de
- têketin û derketina formata pelên erdhejê
Ji bo sazkirina pakêtê, divê hûn rêwerzên li ser rûpela dakêşanê ya pakêta berhevkirî bişopînin, ango. koda jêrîn di her yekê de bicîh bikin :
If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
"https://wolfr.am/FiQ5oFih",
FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]Piştî ku pakêt dê di peldanka xwerû de were saz kirin, riya ku dikare bi vî rengî were bidestxistin:
FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]Wekî nimûne, em ê kapasîteyên sereke yên pakêtê nîşan bidin. Bang bi kevneşopî ji bo pakêtên bi Zimanê Wolfram tê kirin:
Get["GeologyIO`"]Pakêt bi kar tê pêşxistin . Ev dihêle hûn fonksiyona sereke ya pakêtê bi belgekirinê re, ku di warê forma pêşkêşkirinê de ji belgeya Wolfram Mathematica bixwe cûda nabe, û ji bo nasîna yekem pakêtê bi pelên testê re peyda bikin.
Pelek wusa, bi taybetî, pelê "Marmousi.segy" e - ev modelek sentetîk a beşa jeolojîk e, ku ji hêla Enstîtuya Petrolê ya Frensî ve hatî pêşve xistin. Bi karanîna vê modelê, pêşdebiran algorîtmayên xwe ji bo modela qada pêlê, hilanîna daneyê, veguheztina şopa erdhejê, hwd ceribandin. Modela Marmousi bixwe di depoya ku pakêt bixwe lê hatî daxistin de tê hilanîn. Ji bo ku hûn pelê bistînin, koda jêrîn bicîh bikin:
If[Not[FileExistsQ["Marmousi.segy"]],
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]Encama import - Tişta SEGYData
Forma SEGY di derbarê çavdêriyan de agahdariya cihêreng hilîne. Ya yekem, ev şîroveyên nivîsê ne. Di nav de agahdariya li ser cîhê xebatê, navên pargîdaniyên ku pîvandin pêk anîne, hwd. Di rewşa me de, ev sernav ji hêla daxwazek bi bişkojka TextHeader ve tê gazî kirin. Li vir sernavek nivîsê ya kurtkirî heye:
Short[marmousi["TextHeader"]]"Daneyên Marmousi li Enstîtuyê hate çêkirin ... leza herî kêm 1500 m / s û herî zêde 5500 m / s)"
Hûn dikarin modela erdnasî ya rastîn bi gihandina şopên erdhejê bi karanîna mifteya "şopan" nîşan bidin (yek ji taybetmendiyên pakêtê ev e ku kilît ne-hesas in):
ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]Model Marmousi
Heya nuha, pakêt di heman demê de dihêle hûn daneyan ji pelên mezin di beşan de bar bikin, ku ev gengaz dike ku pelên ku mezinahiya wan bigihîje bi dehan gigabyte bişopîne. Fonksiyonên pakêtê di heman demê de fonksiyonên hinardekirina daneyan ji bo .segy û bi qismî lêvekirina dawiya pelê jî vedihewîne.
Ji hev veqetandî, dema ku bi strukturên tevlihev ên pelên .segy re dixebitin, hêjayî balkişandina fonksiyona pakêtê ye. Ji ber ku ew dihêle hûn ne tenê bi karanîna bişkok û navnîşan bigihîjin şop û sernivîsên kesane, lê di heman demê de wan biguhezînin û dûv re wan li pelek binivîsin. Gelek hûrguliyên teknîkî yên pêkanîna GeologyIO li derveyî çarçoweya vê gotarê ne û dibe ku ravekirinek cûda heq dikin.
Têkiliya analîza spektralê di lêgerîna erdhejê de
Kapasîteya îtxalkirina daneyên erdhejê li Wolfram Mathematica dihêle hûn fonksiyona hilberandina sînyala ji bo daneyên ceribandinê bikar bînin. Ji ber ku her şopa erdhejê rêzek demê temsîl dike, yek ji amûrên sereke yên lêkolîna wan analîza spektral e. Di nav şert û mercên ji bo analîzkirina berhevoka frekansa daneyên erdhejê de, em dikarin, wek nimûne, jêrîn bi nav bikin:
- Cûreyên cûda yên pêlan bi pêkhateya frekansa cihêreng têne destnîşan kirin. Ev dihêle hûn pêlên kêrhatî ronî bikin û pêlên destwerdanê bitepisînin.
- Taybetmendiyên kevir ên wekî porozî û têrbûn dikare bandorê li pêkhateya frekansê bike. Ev gengaz dike ku kevirên xwedan taybetmendiyên çêtirîn nas bikin.
- Tebeqên bi qalindiyên cihêreng di rêjeyên frekansa cuda de dibe sedema anomaliyan.
Xala sêyemîn di çarçoveya vê gotarê de xala sereke ye. Li jêr perçeyek kodê ye ji bo hesabkirina şopên erdhejê di doza qatek bi qalindahiya cihêreng - modelek kêzikê. Ev model bi kevneşopî di keşfên erdhejê de tê lêkolîn kirin da ku bandorên navbeynkariyê analîz bike dema ku pêlên ku ji gelek qatan têne xuyang kirin li ser hev têne danîn.
nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]Modela avahiyek pincarê
Leza pêlê di hundurê kêzikê de 4500 m/s e, li derveyê kêzikê 4000 m/s e, û tîrêjê 2200 g/cm³ domdar tê hesibandin. Ji bo modelek weha, em rêjeyên refleksê û şopên erdhejê hesab dikin.
rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]Şopên erdhejê yên ji bo modela wedge
Ji rêza şopên erdhejê yên ku di vê jimarê de tên nîşandan, beşa erdhejê tê gotin. Wekî ku hûn dikarin bibînin, şirovekirina wê jî dikare li ser astek intuitive jî were kirin, ji ber ku geometriya pêlên ronîkirî eşkere bi modela ku berê hatî destnîşan kirin re têkildar e. Ger hûn şopan bi hûrgulî analîz bikin, hûn ê ferq bikin ku şopên ji 1 heta bi qasî 30-an ji hev cûda nabin - refleksa ji banê avabûnê û ji binî ve hevdu nagirin. Ji şopa 31-emîn dest pê dike, refleks dest bi mudaxeleyê dikin. Û, her çend di modelê de, hevrêzên refleksê bi horizontî naguherin - şopên erdhejê bi guheztina qalindahiya avabûnê tundiya xwe diguherînin.
Werin em mezinahiya refleksê ya ji sînorê jorîn a avabûnê bihesibînin. Ji rêya 60emîn dest pê dike, tundiya refleksê zêde dibe û di rêya 70emîn de dibe herî zêde. Bi vî rengî destwerdana pêlan ji ban û binê qatan xwe nîşan dide, ku di hin rewşan de dibe sedema anomaliyên girîng di tomarên erdhejê de.
ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]Grafika firehiya pêla ronîkirî ya ji qiraxa jorîn a darê
Mantiqî ye ku gava sînyala frekansa kêmtir be, destwerdan dest pê dike ku di stûrbûna avabûnên mezin de xuya bibe, û di rewşa îşaretek frekansa bilind de, destwerdan di qalindiyên piçûktir de çêdibe. Parçeya koda jêrîn nîşanek bi frekansên 35 Hz, 55 Hz û 85 Hz diafirîne.
waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]Komek sînyalên çavkaniyê bi frekansên 35 Hz, 55Hz, 85Hz
Bi hesabkirina şopên erdhejê û xêzkirina grafikên mezinahiya pêlên ronîkirî, em dikarin bibînin ku ji bo frekansên cihêreng anomalîyek di stûrbûna pêkhatina cihêreng de tê dîtin.
tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];
lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]Grafikên amplitudên pêla ronîkirî ya ji keviya jorîn a golê ji bo frekansên cihêreng
Hêza derxistina encaman li ser qalindahiya avabûnê ji encamên çavdêriyên erdhejê zehf bikêr e, ji ber ku yek ji karên sereke di lêgerîna neftê de nirxandina xalên herî hêvîdar ên ji bo danîna bîrekê ye (ango, wan deverên ku avabûn lê ye. stûrtir). Wekî din, di beşa jeolojîk de dibe ku tiştên ku çêbûna wan dibe sedema guherînek tûj di qalindahiya avabûnê de hebin. Ev analîza spektralê ji bo xwendina wan amûrek bi bandor dike. Di beşa paşîn a gotarê de em ê tiştên weha jeolojîk bi hûrgulî bifikirin.
Daneyên ezmûnî. We ew ji ku anîn û hûn di wan de li çi bigerin?
Materyalên ku di gotarê de hatine analîz kirin li Rojavayê Sîbîrya hatine bidestxistin. Herêm, wekî her kes bê îstîsna belkî jî dizane, herêma sereke ya neftê ya welatê me ye. Pêşveçûna çalak a depoyan li herêmê di salên 60-î yên sedsala borî de dest pê kir. Rêbaza sereke ya lêgerîna bîrên neftê lêgerîna erdhejê ye. Balkêş e ku meriv li wêneyên satelaytê yên vê herêmê binêre. Di astek piçûk de, hûn dikarin hejmareke mezin ji zozan û golan binihêrin; bi mezinkirina nexşeyê, hûn dikarin cîhên kolandina bîrên komê bibînin, û bi mezinkirina nexşeyê heya sînor, hûn dikarin paqijkirina profîlên ku li ser wan erdhejê hene jî ji hev cuda bikin. çavdêrî hatin kirin.
Wêneya satelîtê ya nexşeyên Yandex - devera bajarê Noyabrsk
Li yek ji zeviyan torgilokek pêlên baş
Kevirên neftê yên Sîbîryaya Rojavayî di kûrahiyek berfireh de - ji 1 km heya 5 km. Qebareya sereke ya kevirên ku rûn tê de hene di demên Jurassic û Cretaceous de pêk hatiye. Serdema Jurassic belkî ji bo gelek ji fîlma bi heman navî tê zanîn. ji ya nûjen gelekî cuda bû. Encyclopedia Britannica rêzek paleomaps heye ku her serdemek helogîkî diyar dike.
Present
serdema Jurassic
Ji kerema xwe not bikin ku di demên Jurassic de, axa Sîbîryaya Rojavayî qeraxek deryayê bû (erdek ku çem û deryayek hûrik derbas dibû). Ji ber ku avhewa rehet bû, em dikarin texmîn bikin ku dîmenek tîpîk a wê demê wiha xuya dikir:
Jurassic Siberia
Di vî wêneyî de ya ku ji bo me girîng e ne ew qas ajal û çûk e, lê wêneya çemê li paş e. Çem heman tişta jeolojîk e ku me berê li ser rawestand. Rastî ev e ku çalakiya çeman dihêle ku kevirên şemitok ên baş-rêkûpêk werin berhev kirin, ku wê hingê bibe depoyek ji bo neftê. Van rezervan dikarin xwedan şeklek xerîb, tevlihev (wek nivînek çem) bin û stûrahiya wan guhezbar heye - li nêzî peravan stûrbûn piçûk e, lê nêzîktirî navenda kanalê an li deverên meander ew zêde dibe. Ji ber vê yekê, çemên ku di Jurassic de çêbûne naha bi qasî sê kîlometran di kûrahiyê de ne û armanca lêgerîna rezervên neftê ne.
Daneyên ezmûnî. Proseskirin û dîtbarîkirin
Werin em tavilê di derheqê materyalên erdhejê yên ku di gotarê de têne xuyang kirin de rezervek çêbikin - ji ber ku hêjmara daneyên ku ji bo analîzê têne bikar anîn girîng e - tenê perçeyek ji rêzika orîjînal a şopên erdhejê di metna gotarê de cih digire. Ev ê dihêle ku her kes hesabên jorîn dubare bike.
Dema ku bi daneyên erdhejê re dixebitin, jeofîzîkek bi gelemperî nermalava pispor bikar tîne (gelek serokên pîşesaziyê hene ku pêşkeftinên wan bi rengek çalak têne bikar anîn, mînakî Petrel an Paradigm), ku dihêle hûn celebên daneyan analîz bikin û xwedan navgînek grafîkî ya hêsan e. Tevî hemî rehetiyê, van celeb nermalava kêmasiyên xwe jî hene - mînakî, pêkanîna algorîtmayên nûjen di guhertoyên stabîl de gelek dem digire, û îmkanên ji bo hesabên otomatîkî bi gelemperî sînordar in. Di rewşek weha de, karanîna pergalên matematîkê yên kompîturê û zimanên bernamesaziyê yên asta bilind, ku destûrê didin karanîna bingehek algorîtmîkî ya berfireh û di heman demê de, gelek rûtîn jî digirin, pir rehet dibe. Ev prensîba ku di Wolfram Mathematica de bi daneyên erdhejê re dixebitin tê bikar anîn. Ji bo xebata danûstendinê ya bi daneyan re nivîsandina fonksiyonên dewlemend negunca ye - girîngtir e ku meriv barkirina ji formek gelemperî pejirandî bicîh bîne, algorîtmayên xwestî li wan bicîh bîne û wan vegere ser formatek derveyî.
Li dû pilana pêşniyarkirî, em ê daneyên erdhejê yên orîjînal bar bikin û wan tê de nîşan bidin :
Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]Daneyên ku bi vî awayî hatine daxistin û îthalkirin rêyên ku li qadeke 10 bi 5 kîlometreyan hatine tomarkirin in. Ger dane bi karanîna rêbazek lêkolîna erdhejê ya sê-alî were bidestxistin (pêl ne li ser profîlên jeofîzîkî yên takekesî, lê hemwext li seranserê herêmê têne tomar kirin), peydakirina kubên daneyên erdhejê mimkun dibe. Ev tiştên sê-alî ne, beşên vertîkal û horizontî yên ku rê didin lêkolînek hûrgulî ya jîngeha jeolojîk. Di mînaka ku tête hesibandin de, em bi daneyên sê-alî re mijûl dibin. Em dikarin ji sernivîsa nivîsê, bi vî rengî, hin agahiyan bistînin
StringPartition[seismic3DSEGY["textheader"], 80] // TableFormC 1 EV PÊŞIYA DEMO E JI BO TESTÎNA PAKETA GEOLOGYIO
C 2
C 3
C 4
C 5 DATE NAV BIkarhêner: WOLFRAM BERSÎVEK
C 6 NAVÊ LÊKIRINÊ: LI CIHÊ LI SÎBIRYA
C 7 PÊŞÎ TÎPÊ 3D SÎZMÎK VOLUME
C 8
C 9
C10 Z RANGE: YEKEM 2200M DAWÎ 2400M
Ev berhevoka daneyê dê bes be ku em qonaxên sereke yên analîzkirina daneyan nîşan bidin. Şopên di pelê de bi rêz têne tomar kirin û her yek ji wan tiştek mîna jimareya jêrîn xuya dike - ev belavkirina mezinahiyên pêlên ronîkirî li ser eksê vertîkal (xebata kûrahiyê) ye.
ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2,
PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
LabelStyle -> Directive[Black, Italic], PlotRange -> All,
Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]Yek ji şopên beşa erdhejê
Dizanin ka çend şop li her alî devera lêkolînê hene, hûn dikarin rêzek daneya sê-alî biafirînin û wê bi karanîna fonksiyona Image3D[] nîşan bidin.
traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1; (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1; (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]Wêneya XNUMXD ya kubeke daneya erdhejê. (Eksena vertîkal - kûrahî)
Ger taybetmendiyên jeolojîk ên balkêş anomaliyên erdhejê yên tund çêbikin, wê hingê amûrên dîtbarî yên bi şefafî têne bikar anîn. Deverên "ne girîng" ên tomarkirinê dikarin nexuya bêne çêkirin, û tenê anomalî xuya bibin. Di Wolfram Mathematica de ev dikare bi kar were kirin и .
data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]},
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]Wêneyê kûba daneya erdhejê ku fonksiyonên Opacity[] û Raster3D[] bikar tîne
Mîna ku di mînaka sentetîk de, li ser beşên kuba orîjînal mirov dikare hin sînorên jeolojîk (tebeq) bi relyef guherbar nas bike.
Amûra sereke ya ji bo analîza spektral veguherîna Fourier e. Bi arîkariya wê, hûn dikarin spektora amplitude-frequency ya her şop an komek şopan binirxînin. Lêbelê, piştî veguheztina daneyan li qada frekansê, agahdarî li ser kîjan demjimêran (bixwîne di kîjan kûran de) frekansa diguhezîne winda dibe. Ji bo ku meriv bikaribe guheztinên sînyalê li ser eksê zeman (kûrahî) herêmî bike, veguherîna Fourier a pencereyê û hilweşandina pêlekê têne bikar anîn. Ev gotar hilweşandina wavelet bikar tîne. Teknolojiya analîzkirina wavelet di salên 90-an de di keşifkirina erdhejê de bi rengek çalak dest pê kir. Avantaja li ser veguherîna Fourier a pencereyê wekî çareseriya dema çêtir tê hesibandin.
Bi karanîna perçeya kodê ya jêrîn, hûn dikarin yek ji şopên erdhejê di nav pêkhateyên kesane de hilweşînin:
cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]Parvekirina şopekê di nav pêkhateyan de
Ji bo nirxandina ka enerjiya refleksê di demên hatina pêlên cûda de çawa tê dabeş kirin, skalogram (bi analog spektrogram) têne bikar anîn. Wekî qaîdeyek, di pratîkê de ne hewce ye ku hemî pêkhatan analîz bikin. Bi gelemperî, pêkhateyên kêm, navîn û bilind têne hilbijartin.
freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]Scalogram. Encama fonksiyonê
Zimanê Wolfram fonksiyonê ji bo veguherîna pêlek bikar tîne . Û sepana vê fonksiyonê ji bo tevahiya rêza şopan dê bi karanîna fonksiyonê were kirin . Li vir hêja ye ku yek ji hêza Wolfram Mathematica-ê were destnîşan kirin - şiyana karanîna paralelbûnê. . Di mînaka jorîn de, hewcedariya paralelbûnê tune - qebareya daneyan ne mezin e, lê dema ku bi berhevokên daneya ezmûnî yên ku bi sed hezaran şopan vedihewîne re dixebitin, ev pêdivî ye.
tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}]; Piştî pêkanîna fonksiyonê Daneyên nû yên ku bi frekansên hilbijartî re têkildar xuya dikin. Di mînaka jorîn de, ev frekans ev in: 38Hz, 33Hz, 27Hz. Hilbijartina frekansan bi gelemperî li ser bingeha ceribandinê tête kirin - ew nexşeyên bi bandor ji bo hevberdanên frekansa cihêreng digirin û ji nihêrîna erdnasek yeka herî agahdar hilbijêrin.
Heke hûn hewce ne ku encaman bi hevalên xwe re parve bikin an wan ji xerîdar re peyda bikin, hûn dikarin fonksiyona SEGYExport[] ya pakêta GeologyIO bikar bînin.
outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];Digel sê ji van kuban (beşên frekansa kêm, frekansa navîn, û frekansa bilind), tevlihevkirina RGB bi gelemperî ji bo dîtina daneyan bi hev re tê bikar anîn. Her pêkhateyek rengê xwe - sor, kesk, şîn tê veqetandin. Di Wolfram Mathematica de ev dikare bi karanîna fonksiyonê were kirin .
Encam wêneyên ku ji wan şîrovekirina jeolojîk dikare were kirin. Meanderên ku li ser beşê têne tomar kirin îmkana xêzkirina paleokannelên ku îhtîmal e ku rezervgeh bin û rezervên neftê di nav xwe de ne, bikin. Lêgerîn û analîzkirina analogên nûjen ên pergalek çemek wusa dihêle ku em beşên herî hêvîdar ên meanderan diyar bikin. Kanal bi xwe bi qatên qalind ên qûmê yên baş veqetandî têne diyar kirin û ji bo neftê depoyek baş in. Deverên li derveyî anomaliyên "lace" dişibin depoyên lehiyê yên nûjen. Depoyên lehiyê bi giranî bi kevirên axê têne temsîl kirin û kolandina li van deveran dê bêbandor be.
Parçeya RGB ya kuba daneyê. Di navendê de (hinekî çepê navendê) hûn dikarin çemê meander bişopînin.
Parçeya RGB ya kuba daneyê. Li milê çepê hûn dikarin çemê meander bişopînin.
Di hin rewşan de, kalîteya daneyên erdhejê dihêle ku wêneyên berbiçav zelaltir bibin. Ev bi metodolojiya xebata zeviyê ve girêdayî ye, alavên ku ji hêla algorîtmaya kêmkirina deng ve têne bikar anîn. Di rewşên weha de, ne tenê perçeyên pergalên çem xuya dibin, lê di heman demê de tevahiya paleo-çemên dirêjkirî jî têne xuyang kirin.
Tevlihevkirina RGB ya sê hêmanên kubek daneya erdhejê (parçeya horizontî). Kûrahî bi qasî 2 km.
Wêneya satelîtê ya çemê Volga li nêzîkî Saratov
encamê
Wolfram Mathematica dikare daneyên erdhejê analîz bike û pirsgirêkên sepandî yên têkildarî lêgerîna mîneralan çareser bike, û pakêta GeologyIO vê pêvajoyê hêsantir dike. Struktura daneyên erdhejê wisa ye ku ji bo bilezkirina hesabên rêbazên çêkirî bikar tîne (, ,…) pir bikêrhatî ye û dihêle hûn mîqdarên mezin daneyê pêvajoyê bikin. Bi rêjeyek mezin, ev ji hêla taybetmendiyên hilanîna daneya pakêta GeologyIO ve tê hêsan kirin. Bi awayê, pakêt ne tenê di warê lêgerîna erdhejê ya sepandî de dikare were bikar anîn. Hema hema heman celeb daneyan di radar û erdhejnasiyê de têne bikar anîn. Heke pêşniyarên we hene ka meriv çawa encam çawa baştir bike, kîjan algorîtmayên analîza sînyalê ji arsenala Wolfram Mathematica ji bo daneyên weha têne bicîh kirin, an heke rexneyên we hebin, ji kerema xwe re bihêlin agahkişî.
Source: www.habr.com