🥇 وولفرم ميٿميٽيڪا جيو فزڪس ۾

بلاگ جي ليکڪ جي مهرباني Anton Ekimenko هن جي رپورٽ لاء

تعارف

هي نوٽ ڪانفرنس جي نتيجي ۾ لکيو ويو هو Wolfram روسي ٽيڪنالاجي ڪانفرنس ۽ منهنجي ڏنل رپورٽ جو خلاصو شامل آهي. واقعي جون ۾ سينٽ پيٽرسبرگ ۾ ٿي گذريو. انهي ڳالهه تي غور ڪندي ته آئون ڪانفرنس سائيٽ کان هڪ بلاڪ ڪم ڪريان ٿو، مان مدد نه ڪري سگهيو پر هن واقعي ۾ شرڪت ڪئي. 2016 ۽ 2017 ۾، مون ڪانفرنس جون رپورٽون ٻڌيون، ۽ ھن سال مون ھڪڙي پريزنٽيشن ڏني. پهرين، هڪ دلچسپ (اهو مون کي لڳي ٿو) موضوع ظاهر ٿيو آهي، جنهن سان اسان ترقي ڪري رهيا آهيون ڪريل بيلوف، ۽ ٻيو، روسي فيڊريشن جي پابندين واري پاليسي جي حوالي سان قانون سازي جي ڊگهي مطالعي کان پوء، انٽرپرائز تي جتي آئون ڪم ڪريان ٿو، ٻه لائسنس ظاهر ڪيا ويا آهن. ولفرام ميٿاميٽڪس.

پنهنجي تقرير جي موضوع ڏانهن وڌڻ کان اڳ، مان واقعي جي سٺي تنظيم کي نوٽ ڪرڻ چاهيندس. ڪانفرنس جو دورو ڪندڙ صفحو ڪازان ڪيٿڊرل جي تصوير استعمال ڪري ٿو. گرجا گھر سينٽ پيٽرسبرگ جي مکيه ڪشش مان ھڪڙو آھي ۽ اھو ھال مان بلڪل صاف نظر اچي ٿو جنھن ۾ ڪانفرنس ٿي ھئي.

سينٽ پيٽرسبرگ اسٽيٽ اڪنامڪ يونيورسٽي جي داخلا تي، شرڪت ڪندڙن شاگردن مان اسسٽنٽ سان ملاقات ڪئي - انهن کي گم ٿيڻ جي اجازت نه ڏني. رجسٽريشن دوران، ننڍيون يادگارون ڏنيون ويون (هڪ رانديڪو - هڪ چمڪندڙ اسپائڪ، هڪ قلم، وولفرم علامتن سان اسٽيڪرز). ڪانفرنس جي شيڊول ۾ لنچ ۽ ڪافي جو وقفو به شامل هو. مون گروپ جي ڀت تي لذيذ ڪافي ۽ پائي بابت اڳ ۾ ئي نوٽ ڪيو آهي - شيف عظيم آهن. هن تعارفي حصي سان، مان زور ڏيڻ چاهيان ٿو ته واقعي خود، ان جي شڪل ۽ مقام اڳ ۾ ئي مثبت جذبات آڻيندي.

اها رپورٽ جيڪا مون ۽ ڪريل بيلوف پاران تيار ڪئي وئي هئي، ان کي سڏيو ويندو آهي "استعمال ٿيل جيو فزڪس ۾ مسئلن کي حل ڪرڻ لاءِ Wolfram Mathematica. زلزلي واري ڊيٽا جو چشمي تجزيو يا "جتي قديم نديون وهن ٿيون." رپورٽ جو مواد ٻن حصن تي پکڙيل آهي: پهريون، ۾ موجود الگورتھم جو استعمال ولفرام ميٿاميٽڪس جيو فزيڪل ڊيٽا جي تجزيي لاءِ، ۽ ٻيو، هي آهي ته جيو فزيڪل ڊيٽا کي وولفرم ميٿميٽيڪا ۾ ڪيئن رکڻو آهي.

زلزلي جي ڳولا

پهرين توهان کي جيو فزڪس ۾ هڪ مختصر سير ڪرڻ جي ضرورت آهي. جيو فزڪس اها سائنس آهي جيڪا پٿر جي جسماني ملڪيتن جو مطالعو ڪري ٿي. خير، ڇاڪاڻ ته پٿرن ۾ مختلف خاصيتون آهن: برقي، مقناطيسي، لچڪدار، جيو فزڪس جا ساڳيا طريقا آهن: اليڪٽريڪل پروسپيڪٽنگ، مقناطيسي امڪاني، زلزلي جي اڳڪٿي... هن آرٽيڪل جي حوالي سان، اسان صرف وڌيڪ تفصيل سان زلزلي جي امڪانن تي بحث ڪنداسين. زلزلي جي ڳولا تيل ۽ گئس جي ڳولا جو مکيه طريقو آهي. اهو طريقو لچڪدار وائبريشن جي اتساهه تي مبني آهي ۽ مطالعي واري علائقي کي ٺهڪندڙ پٿر مان ردعمل جي بعد ۾ رڪارڊنگ. وائبريشن زمين تي (ڊائنامائيٽ يا غير ڌماڪيدار وائبريشن ذريعن سان لچڪدار وائبريشن جي ذريعن سان) يا سمنڊ ۾ (ايئر گنن سان) پرجوش آهن. لچڪدار وائبريشن پٿر جي ماس ذريعي پروپيگنڊا ٿين ٿا، مختلف ملڪيتن سان پرتن جي حدن تي ڦهليل ۽ ظاهر ٿي رهيا آهن. موٽڻ واريون لهرون مٿاڇري تي موٽنديون آهن ۽ زمين تي جيوفونز (عام طور تي اليڪٽرروڊائينامڪ ڊيوائسز ذريعي رڪارڊ ڪيون وينديون آهن جن کي ڪوئل ۾ مقناطيس جي حرڪت تي ٻڌل هوندو آهي) يا سمنڊ ۾ هائيڊروفون (پيزو اليڪٽرڪ اثر جي بنياد تي). موجن جي اچڻ وقت، ڪو به ارضياتي سطحن جي کوٽائي جو اندازو لڳائي سگهي ٿو.

زلزلي واري جهاز کي ڇڪڻ جو سامان

هوائي بندوق لچڪدار کمپن کي حوصلا افزائي ڪري ٿو

موجون پٿر جي ماس مان گذري ٿو ۽ هائڊروفونز ذريعي رڪارڊ ٿيل آهن

جيو فزيڪل سروي تحقيقي جهاز "ايوان گوبڪن" سينٽ پيٽرسبرگ ۾ بلاگووشچنسڪي پل جي ويجهو پيئر تي

زلزلي سگنل ماڊل

پٿر مختلف جسماني خاصيتون آهن. زلزلي جي ڳولا لاء، لچڪدار خاصيتون بنيادي طور تي اهم آهن - لچڪدار کمپن ۽ کثافت جي پروپيگيشن جي رفتار. جيڪڏهن ٻه تہه هڪجهڙا يا هڪجهڙا خاصيتون آهن، ته پوءِ موج انهن جي وچ واري حد کي ”نوٽيس نه ڪندي“. جيڪڏهن تہن ۾ لهرن جي رفتار مختلف آهي، ته پوءِ انعڪاس تہن جي چوديواري تي ٿيندو. ملڪيتن ۾ جيترو وڏو فرق، اوترو ئي وڌيڪ شديد عڪس. ان جي شدت جو اندازو لڳايو ويندو ريفليڪانس ڪوفيشينٽ (rc):

جتي ρ پٿر جي کثافت آهي، ν موج جي رفتار آهي، 1 ۽ 2 مٿين ۽ هيٺين تہن کي ظاهر ڪن ٿا.

سڀ کان آسان ۽ اڪثر استعمال ٿيندڙ زلزلي سگنل ماڊلز مان هڪ آهي ڪنوولوشن ماڊل، جڏهن رڪارڊ ٿيل سيسمڪ ٽريس کي پروبنگ پلس سان ريفريڪشن ڪوئفينٽس جي تسلسل جي ڪنوولوشن جي نتيجي طور پيش ڪيو ويندو آهي:

ڪٿي s(t) - زلزلي جو نشان، يعني ھر شيء جيڪا ھائيڊروفون يا جيوفون طرفان رڪارڊ ڪئي وئي ھئي ھڪ مقرر وقت دوران، w(t) - سگنل ايئر گن پاران ٺاهيل، ن (ٽي) - بي ترتيب شور.

اچو ته مثال طور هڪ مصنوعي زلزلي جي نشاني جو اندازو لڳايو. اسان ريڪر پلس استعمال ڪنداسين، وڏي پيماني تي زلزلي جي ڳولا ۾ استعمال ڪيو ويندو، شروعاتي سگنل جي طور تي.

length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]

شروعاتي زلزلي جو تسلسل

اسان 300 ms ۽ 600 ms جي کوٽائي تي ٻه حدون مقرر ڪنداسين، ۽ ريفريڪشن ڪوئفينٽس بي ترتيب نمبر هوندا.

rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]

ريفريڪشن ڪوئفينٽس جو تسلسل

اچو ته حساب ڪريون ۽ زلزلي جو نشان ڏيکاريو. جيئن ته ريفريڪشن ڪوئفينٽس ۾ مختلف نشانيون آهن، ان ڪري اسان کي سيسمڪ ٽريس تي ٻه متبادل موٽ مليا آهن.

traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]

ٺهيل ٽريڪ

هن مثال لاء، هڪ رزرويشن ڪرڻ ضروري آهي - حقيقت ۾، تہن جي کوٽائي جو اندازو لڳايو ويو آهي، يقينا، ميٽرن ۾، ۽ زلزلي جي سراغ جي حساب وقت جي ڊومين لاء ٿيندي آهي. اهو وڌيڪ صحيح ٿيندو ته کوٽائي کي ميٽرن ۾ مقرر ڪيو وڃي ۽ پرت جي رفتار کي ڄاڻندي آمد جي وقت جو اندازو لڳايو وڃي. انهي حالت ۾، مون فوري طور تي وقت جي محور تي تہه مقرر ڪيو.

جيڪڏهن اسان فيلڊ ريسرچ جي باري ۾ ڳالهايون ٿا، ته پوء اهڙن مشاهدن جي نتيجي ۾ هڪ وڏي تعداد ۾ ساڳئي وقت جي سيريز (زمين جا نشان) رڪارڊ ڪيا ويا آهن. مثال طور، جڏهن 25 ڪلوميٽر ڊگھي ۽ 15 ڪلوميٽر ويڪر واري سائيٽ جو مطالعو ڪيو وڃي، جتي ڪم جي نتيجي ۾، هر سراغ هڪ سيل کي 25x25 ميٽر جي ماپ ڪري ٿو (اهڙي سيل کي بن سڏيو ويندو آهي)، حتمي ڊيٽا جي صف ۾ 600000 نشان شامل هوندا. 1 ايم ايس جي نموني جي وقت ۽ 5 سيڪنڊن جي رڪارڊنگ وقت سان، حتمي ڊيٽا فائل 11 GB کان وڌيڪ هوندي، ۽ اصل "خام" مواد جو حجم سوين گيگا بائيٽ ٿي سگهي ٿو.

انهن سان ڪيئن ڪم ڪجي ولفرام ميٿاميٽڪس?

پيڪ جيولوجي آئي

پيڪيج جي ترقي شروع ٿي مسئلو روسي ڳالهائيندڙ سپورٽ گروپ جي VK ڀت تي. ڪميونٽي جي جوابن جي مهرباني، هڪ حل تمام جلدي مليو. ۽ نتيجي طور، اهو هڪ سنگين ترقي ۾ وڌايو. ملندڙ Wolfram ڪميونٽي وال پوسٽ اهو پڻ منتظمين طرفان نشان لڳل هو. في الحال، پيڪيج هيٺين قسمن جي ڊيٽا سان ڪم ڪرڻ جي حمايت ڪري ٿو جيڪي فعال طور تي جيولوجيڪل صنعت ۾ استعمال ڪيا ويا آهن:

ZMAP ۽ IRAP فارميٽ ۾ نقشي جي ڊيٽا جي درآمد
LAS فارميٽ ويلز ۾ ماپن جي درآمد
زلزلي فائلن جي فارميٽ جو ان پٽ ۽ آئوٽ SEGY

پيڪيج کي نصب ڪرڻ لاء، توهان کي گڏ ڪيل پيڪيج جي ڊائون لوڊ صفحي تي ڏنل هدايتن تي عمل ڪرڻ گهرجي، يعني. ھيٺ ڏنل ڪوڊ تي عمل ڪريو رياضي جو نوٽ بڪ:

If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
    "https://wolfr.am/FiQ5oFih", 
    FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]

جنهن کان پوءِ پيڪيج کي ڊفالٽ فولڊر ۾ انسٽال ڪيو ويندو، جنهن جو رستو هن ريت حاصل ڪري سگهجي ٿو:

FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]

مثال طور، اسان پيش ڪنداسين پيڪيج جي بنيادي صلاحيتن کي. ڪال روايتي طور تي ڪيو ويندو آهي پيڪيجز لاءِ Wolfram Language:

Get["GeologyIO`"]

پيڪيج استعمال ڪندي ترقي ڪئي وئي آهي Wolfram Workbench. هي توهان کي اجازت ڏئي ٿو ته پيڪيج جي بنيادي ڪارڪردگي سان گڏ دستاويزن سان، جيڪا پيشڪش جي فارميٽ جي لحاظ کان مختلف ناهي، خود Wolfram Mathematica جي دستاويزن کان، ۽ پهرين واقفيت لاء ٽيسٽ فائلن سان پيڪيج مهيا ڪرڻ لاء.

اهڙي فائل، خاص طور تي، فائل آهي "Marmousi.segy" - هي هڪ جيولوجيڪل سيڪشن جو هڪ مصنوعي نمونو آهي، جيڪو فرانسيسي پيٽروليم انسٽيٽيوٽ پاران تيار ڪيو ويو آهي. ھن ماڊل کي استعمال ڪندي، ڊولپرز پنھنجي الگورٿمز کي وائڊ فيلڊ ماڊلنگ، ڊيٽا پروسيسنگ، سيسمڪ ٽريس انورسيشن وغيره لاءِ ٽيسٽ ڪندا آھن. مارموسي ماڊل پاڻ کي مخزن ۾ محفوظ ڪيو ويو آهي جتان پيڪيج پاڻ کي ڊائون لوڊ ڪيو ويو. فائل حاصل ڪرڻ لاء، ھيٺ ڏنل ڪوڊ کي هلائڻ لاء:

If[Not[FileExistsQ["Marmousi.segy"]], 
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]

درآمد جو نتيجو - SEGYData اعتراض

SEGY فارميٽ ۾ مشاهدن بابت مختلف معلومات کي محفوظ ڪرڻ شامل آهي. پهرين، اهي ٽيڪسٽ رايا آهن. ھن ۾ ڪم جي جڳھ بابت معلومات شامل آھي، ڪمپنين جا نالا جيڪي ماپ ڪيا آھن، وغيره. اسان جي حالت ۾، هي هيڊر هڪ درخواست سان سڏيو ويندو آهي TextHeader Key. هتي هڪ مختصر ٽيڪسٽ هيڊر آهي:

Short[marmousi["TextHeader"]]

"مارموسي ڊيٽا سيٽ انسٽيٽوٽ تي ٺاهي وئي ... گھٽ ۾ گھٽ رفتار 1500 m/s ۽ وڌ ۾ وڌ 5500 m/s)"

توھان حقيقي جيولوجيڪل ماڊل کي ڏيکاري سگھوٿا زلزلي جي نشانين تائين رسائي حاصل ڪندي ”ٽريسس“ ڪي (پيڪيج جي ھڪڙي خصوصيت اھو آھي ته ڪنجيون غير حساس آھن):

ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]

ماڊل مارموسي

في الحال، پيڪيج توهان کي وڏي فائلن مان حصن ۾ ڊيٽا لوڊ ڪرڻ جي اجازت ڏئي ٿي، ان کي فائلن کي پروسيس ڪرڻ ممڪن بڻائي ٿو جن جي سائيز ڏهن گيگا بائيٽ تائين پهچي سگهي ٿي. پيڪيج جي افعال ۾ ڊيٽا کي .segy ۾ برآمد ڪرڻ ۽ جزوي طور تي فائل جي آخر ۾ شامل ڪرڻ لاءِ ڪم شامل آھن.

الڳ الڳ، اهو .segy فائلن جي پيچيده ڍانچي سان ڪم ڪرڻ دوران پيڪيج جي ڪارڪردگي کي ياد رکڻ جي قابل آهي. جيئن ته اهو توهان کي اجازت ڏئي ٿو نه صرف انفرادي نشانين ۽ هيڊرز تائين رسائي ڪنجي ۽ انڊيڪس استعمال ڪندي، پر انهن کي تبديل ڪرڻ ۽ پوءِ انهن کي فائل ۾ لکڻ لاءِ. GeologyIO جي عمل درآمد جا ڪيترائي ٽيڪنيڪل تفصيل هن مضمون جي دائري کان ٻاهر آهن ۽ شايد هڪ الڳ وضاحت جا مستحق آهن.

زلزلي جي ڳولا ۾ چشمي تجزيي جي مطابقت

Wolfram Mathematica ۾ زلزلي واري ڊيٽا کي درآمد ڪرڻ جي صلاحيت توهان کي تجرباتي ڊيٽا لاءِ بلٽ ان سگنل پروسيسنگ ڪارڪردگي استعمال ڪرڻ جي اجازت ڏئي ٿي. جيئن ته هر زلزلي جو نشان هڪ ٽائيم سيريز جي نمائندگي ڪري ٿو، انهن جي مطالعي لاء مکيه اوزار مان هڪ آهي چشمي تجزيي. زلزلي واري ڊيٽا جي تعدد جي جوڙجڪ جي تجزيي لاء لازمي شرطن مان، اسين نالو ڪري سگھون ٿا، مثال طور، هيٺيان:

مختلف قسم جي لهرن جي خاصيت مختلف تعدد جي ترتيب سان آهي. هي توهان کي مفيد لهرن کي اجاگر ڪرڻ ۽ مداخلت واري موج کي دٻائڻ جي اجازت ڏئي ٿو.
پٿر جا خاصيتون جهڙوڪ پورسيٽي ۽ سنترپشن تعدد جي مجموعي کي متاثر ڪري سگهن ٿا. اهو ممڪن بڻائي ٿو ته پٿر جي سڃاڻپ ڪرڻ لاء بهترين ملڪيت سان.
مختلف ٿلهي سان پرتون مختلف تعدد جي حدن ۾ بي ضابطگين جو سبب بڻجن ٿيون.

ٽيون نقطو هن مضمون جي حوالي سان اهم آهي. هيٺ ڏنل ڪوڊ جو ٽڪرو آهي زلزلي جا نشان ڳڻڻ لاءِ هڪ پرت جي صورت ۾ مختلف ٿلهي سان - هڪ پچر ماڊل. هي ماڊل روايتي طور تي زلزلي جي ڳولا ۾ مطالعو ڪيو ويندو آهي مداخلت جي اثرن جو تجزيو ڪرڻ لاءِ جڏهن ڪيترن ئي تہن مان ظاهر ٿيندڙ لهرن کي هڪ ٻئي تي سپر ڪيو ويندو آهي.

nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]

پنچ آئوٽ فارميشن جو ماڊل

ويج جي اندر موج جي رفتار 4500 m/s آهي، ويج جي ٻاهران 4000 m/s، ۽ کثافت کي 2200 g/cm³ سمجهيو وڃي ٿو. اهڙي نموني لاءِ، اسان ڳڻپيون ٿا موٽڻ جي کوٽائي ۽ زلزلي جا نشان.

rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
	ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
		{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]

ويج ماڊل لاءِ زلزلي جا نشان

هن شڪل ۾ ڏيکاريل زلزلي جي نشانين جي تسلسل کي سيسمڪ سيڪشن سڏيو ويندو آهي. جئين توهان ڏسي سگهو ٿا، ان جي تشريح پڻ هڪ وجداني سطح تي ٿي سگهي ٿي، ڇاڪاڻ ته ظاهر ٿيل لهرن جي جاميٽري واضح طور تي ان نموني سان ٺهڪي اچي ٿي جيڪا اڳ بيان ڪئي وئي هئي. جيڪڏهن توهان وڌيڪ تفصيل سان نشانن جو تجزيو ڪيو، توهان کي خبر پوندي ته 1 کان لڳ ڀڳ 30 تائين نشان مختلف نه آهن - ٺهڻ جي ڇت ۽ هيٺان کان عڪس هڪ ٻئي کي اوورليپ نه ڪندا آهن. 31 هين ٽريس کان شروع ٿيندڙ، عڪس مداخلت ڪرڻ شروع ڪن ٿا. ۽، جيتوڻيڪ ماڊل ۾، موٽڻ جي گنجائش افقي طور تي تبديل نه ڪندا آهن - زلزلي جا نشان انهن جي شدت کي تبديل ڪندا آهن جيئن ٺهڻ جي ٿلهي ۾ تبديلي اچي ٿي.

اچو ته ٺهڻ جي مٿئين حد کان عڪس جي طول و عرض تي غور ڪريو. 60 هين روٽ کان شروع ٿي، انعڪاس جي شدت وڌڻ لڳي ٿي ۽ 70 هين رستي تي وڌ ۾ وڌ ٿي وڃي ٿي. اهڙيءَ طرح ڇت ۽ هيٺئين تہه کان لهرن جي مداخلت پاڻ کي ظاهر ڪري ٿي، ڪجهه حالتن ۾ زلزلي جي رڪارڊ ۾ اهم بي ضابطگين ڏانهن.

ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]

پچر جي مٿئين پاسي کان ظاهر ٿيل موج جي طول و عرض جو گراف

اهو منطقي آهي ته جڏهن سگنل گهٽ فريڪوئنسي آهي، مداخلت وڏي ٺهڻ جي ٿلهي تي ظاهر ٿيڻ شروع ٿئي ٿي، ۽ هڪ اعلي تعدد سگنل جي صورت ۾، مداخلت ننڍي ٿلهي تي ٿيندي آهي. هيٺ ڏنل ڪوڊ جو ٽڪرو 35 Hz، 55 Hz ۽ 85 Hz جي تعدد سان سگنل ٺاهي ٿو.

waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]

35Hz، 55Hz، 85Hz جي تعدد سان ماخذ سگنلن جو هڪ سيٽ

زلزلي جي نشانين کي ڳڻڻ ۽ عڪاسي ٿيل موج جي ماپن جي گراف کي ترتيب ڏيڻ سان، اسان ڏسي سگهون ٿا ته مختلف تعدد لاء مختلف ٺهڻ جي ٿلهي تي هڪ بي ترتيب نظر اچي ٿي.

tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];

lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];

Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]

مختلف فريڪوئنسيز لاءِ پچر جي مٿئين ڪنڊ کان عڪاسي ٿيل لهرن جي طول و عرض جا گراف

زلزلي جي مشاهدن جي نتيجن مان ٺهڻ جي ٿلهي بابت نتيجن کي ڪڍڻ جي صلاحيت انتهائي ڪارائتو آهي، ڇاڪاڻ ته تيل جي ڳولا ۾ هڪ اهم ڪم اهو آهي ته هڪ کوهه کي وڇائڻ لاء سڀ کان وڌيڪ اميد رکندڙ نقطي جو جائزو وٺڻ (يعني، اهي علائقا جتي ٺهڻ واري جڳهه آهي. ٿلهو). ان کان سواء، جيولوجيڪل سيڪشن ۾ اهڙا شيون ٿي سگهن ٿيون جن جي پيدائش جي ٺهڻ جي ٿلهي ۾ تيز تبديلي جو سبب بڻائين. هي spectral تجزيو انهن جي مطالعي لاء هڪ مؤثر اوزار بڻائي ٿو. مضمون جي ايندڙ حصي ۾ اسان اهڙين ارضياتي شين تي وڌيڪ تفصيل سان غور ڪنداسين.

تجرباتي ڊيٽا. توهان انهن کي ڪٿي حاصل ڪيو ۽ انهن ۾ ڇا ڳولڻ لاء؟

مضمون ۾ تجزيو ڪيل مواد مغربي سائبيريا ۾ حاصل ڪيا ويا. علائقو، جيئن هرڪو بغير ڪنهن استثنا جي شايد ڄاڻي ٿو، اسان جي ملڪ جو مکيه تيل پيدا ڪندڙ علائقو آهي. گذريل صديء جي 60s ۾ علائقي ۾ ذخيرو جي فعال ترقي شروع ٿي. تيل جي ذخيرن کي ڳولڻ جو مکيه طريقو زلزلي جي ڳولا آهي. هن علائقي جي سيٽلائيٽ تصويرن کي ڏسڻ لاء دلچسپ آهي. ننڍي پيماني تي، توهان وڏي تعداد ۾ دلدل ۽ ڍنڍون نوٽ ڪري سگهو ٿا؛ نقشي کي وڌائڻ سان، توهان ڪلسٽر کوهه جي سوراخ ڪرڻ واري سائيٽن کي ڏسي سگهو ٿا، ۽ نقشي کي حد تائين وڌائڻ سان، توهان انهن پروفائلن جي صاف ڪرڻ ۾ فرق پڻ ڪري سگهو ٿا، جن سان گڏ زلزلي وارا. مشاهدا ڪيا ويا.

سيٽلائيٽ تصوير جي Yandex نقشن - Noyabrsk شهر جو علائقو

ھڪڙي ھڪڙي فيلڊ تي چڱي طرح پيڊن جو نيٽ ورڪ

مغربي سائبيريا جي تيل کڻڻ واري پٿر جي کوٽائي جي وسيع رينج ۾ ٿئي ٿي - 1 ڪلوميٽر کان 5 ڪلوميٽر تائين. تيل تي مشتمل پٿر جو مکيه مقدار جوراسڪ ۽ ڪيريٽيسس جي دور ۾ ٺهيل هو. جوراسڪ دور شايد ڪيترن ئي ماڻهن کي ساڳئي نالي جي فلم مان معلوم ٿئي ٿو. جوراسڪ آبهوا جديد کان خاص طور تي مختلف هئي. انسائيڪلوپيڊيا برٽينيڪا ۾ پيلي ميپس جو هڪ سلسلو آهي جيڪو هر هڪ هيلوجيڪل دور کي بيان ڪري ٿو.

موجود آهي

جوراسڪ دور

مهرباني ڪري نوٽ ڪريو ته جوراسڪ زماني ۾، مغربي سائبيريا جو علائقو هڪ سامونڊي ڪناري هو (زمين دريائن ۽ هڪ اڀرندڙ سمنڊ ذريعي پار ڪيو ويو). جيئن ته آبهوا آرامده هئي، اسان اهو فرض ڪري سگهون ٿا ته ان وقت جو هڪ عام نظارو هن طرح نظر آيو:

جوراسڪ سائبيريا

هن تصوير ۾، جيڪو اسان لاء اهم آهي اهو جانور ۽ پکي نه آهي، پر پس منظر ۾ درياهه جي تصوير آهي. درياهه اُها ئي جيولوجيڪل شئي آهي جنهن کي اسان اڳ ۾ روڪيو هو. حقيقت اها آهي ته درياهن جي سرگرمين جي اجازت ڏئي ٿو ته چڱي طرح ترتيب ڏنل پٿر کي گڏ ڪري، جيڪو پوء تيل لاء هڪ ذخيرو بڻجي ويندو. اهي ذخيرا هڪ عجيب، پيچيده شڪل (جهڙوڪ درياهه جي پلنگ وانگر) هوندا آهن ۽ انهن جي ٿلهي هوندي آهي - ڪنارن جي ويجهو ٿلهي ننڍي هوندي آهي، پر چينل جي مرڪز جي ويجهو يا وچ واري علائقن ۾ اهو وڌي ويندو آهي. تنهن ڪري، جوراسڪ ۾ ٺهيل نديون هاڻي اٽڪل ٽن ڪلوميٽرن جي کوٽائي ۾ آهن ۽ تيل جي ذخيرن جي ڳولا جو مقصد آهن.

تجرباتي ڊيٽا. پروسيسنگ ۽ تصور

اچو ته آرٽيڪل ۾ ڏيکاريل زلزلي واري مواد جي حوالي سان فوري طور تي هڪ رزرويشن ڪريون - ان حقيقت جي ڪري ته تجزيو لاءِ استعمال ڪيل ڊيٽا جو مقدار اهم آهي - صرف زلزلي جي نشانين جي اصل سيٽ جو هڪ ٽڪرو مضمون جي متن ۾ شامل ڪيو ويو آهي. هي هر ڪنهن کي مٿي ڏنل حسابن کي ٻيهر پيش ڪرڻ جي اجازت ڏيندو.

جڏهن زلزلي واري ڊيٽا سان ڪم ڪري رهيو آهي، هڪ جيو فزڪسسٽ عام طور تي خاص سافٽ ويئر استعمال ڪندو آهي (ڪيترائي صنعت جا اڳواڻ آهن جن جي ترقيات فعال طور تي استعمال ٿينديون آهن، مثال طور پيٽرل يا پيراڊيم)، جيڪو توهان کي ڊيٽا جي مختلف قسمن جو تجزيو ڪرڻ جي اجازت ڏئي ٿو ۽ هڪ آسان گرافڪ انٽرفيس آهي. سڀني سهولتن جي باوجود، سافٽ ويئر جي انهن قسمن ۾ پڻ پنهنجون خاميون آهن - مثال طور، مستحڪم نسخن ۾ جديد الورورٿم جي عمل کي تمام گهڻو وقت وٺندو آهي، ۽ خودڪار حسابن لاء امڪان عام طور تي محدود آهن. اهڙي صورتحال ۾، ڪمپيوٽر جي رياضياتي سسٽم ۽ اعلي سطحي پروگرامنگ ٻولين کي استعمال ڪرڻ تمام آسان ٿي ويندو آهي، جيڪي هڪ وسيع الورورٿمڪ بنياد جي استعمال جي اجازت ڏين ٿا ۽ ساڳئي وقت، تمام گهڻو معمول تي وٺي ويندا آهن. هي اصول آهي جيڪو Wolfram Mathematica ۾ زلزلي واري ڊيٽا سان ڪم ڪرڻ لاءِ استعمال ڪيو ويندو آهي. ڊيٽا سان گڏ انٽرايڪٽو ڪم لاءِ ڀرپور ڪارڪردگي لکڻ نامناسب آهي - اهو وڌيڪ ضروري آهي ته عام طور تي قبول ٿيل فارميٽ مان لوڊ ڪرڻ کي يقيني بڻايو وڃي، انهن تي گهربل الگورتھم لاڳو ڪرڻ ۽ انهن کي واپس هڪ خارجي فارميٽ ۾ اپلوڊ ڪرڻ.

تجويز ڪيل اسڪيم تي عمل ڪندي، اسان اصل زلزلي واري ڊيٽا کي لوڊ ڪنداسين ۽ ان ۾ ڏيکارينداسين ولفرام ميٿاميٽڪس:

Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]

هن طريقي سان ڊائون لوڊ ۽ درآمد ٿيل ڊيٽا 10 کان 5 ڪلوميٽرن جي ايراضيءَ تي رڪارڊ ٿيل رستا آهن. جيڪڏهن ڊيٽا حاصل ڪئي وڃي ته ٽن-dimensional زلزلي سروي جي طريقي سان (موجن انفرادي جيو فزيڪل پروفائلز سان گڏ نه، پر سڄي علائقي تي هڪ ئي وقت ۾ رڪارڊ ٿيل آهن)، اهو ممڪن آهي ته سيسمڪ ڊيٽا ڪيب حاصل ڪرڻ ممڪن آهي. اهي ٽي-dimensional شيون آهن، عمودي ۽ افقي سيڪشن جن مان جيولوجيڪل ماحول جي تفصيلي مطالعي جي اجازت ڏين ٿا. غور ڪيو ويو مثال ۾، اسان ٽي-dimensional ڊيٽا سان ڊيل ڪري رهيا آهيون. اسان ٽيڪسٽ هيڊر مان ڪجهه معلومات حاصل ڪري سگهون ٿا، جهڙوڪ

StringPartition[seismic3DSEGY["textheader"], 80] // TableForm

سي 1 هي آهي ڊيمو فائل جيولوجيو پيڪيج ٽيسٽ لاءِ
سي 2
سي 3
سي 4
C 5 DATE استعمال ڪندڙ جو نالو: WOLFRAM USER
سي 6 سروي جو نالو: سائبيريا ۾ ڪٿي
سي 7 فائل ٽائپ 3D سيزمڪ حجم
سي 8
سي 9
C10 Z رينج: پهريون 2200M آخري 2400M

هي ڊيٽا سيٽ اسان لاءِ ڊيٽا جي تجزيو جي بنيادي مرحلن کي ڏيکارڻ لاءِ ڪافي هوندو. فائل ۾ نشانن کي ترتيب سان رڪارڊ ڪيو ويو آهي ۽ انهن مان هر هڪ هيٺ ڏنل شڪل وانگر ڪجهه نظر اچي ٿو - اهو عمودي محور (گهرائي محور) سان ظاهر ٿيل لهرن جي طول و عرض جي تقسيم آهي.

ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2, 
 PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
 LabelStyle -> Directive[Black, Italic], PlotRange -> All, 
 Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]

سيسمڪ سيڪشن جي نشانين مان هڪ

اهو ڄاڻڻ ته ڪيترا نشان آهن جيڪي اڀياس ڪيل علائقي جي هر طرف ۾ واقع آهن، توهان هڪ ٽي-dimensional ڊيٽا سري ٺاهي سگهو ٿا ۽ تصوير 3D[] فنڪشن کي استعمال ڪندي ان کي ڊسپلي ڪري سگهو ٿا.

traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1;   (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1;   (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]

زلزلي واري ڊيٽا ڪعب جي 3D تصوير. (عمودي محور - کوٽائي)

جيڪڏھن دلچسپيءَ جون ارضياتي خصوصيتون شديد زلزلي جي اڻاٺ پيدا ڪن ٿيون، ته پوءِ شفافيت سان ڏسڻ جا اوزار استعمال ڪري سگھجن ٿا. رڪارڊنگ جا ”غير اهم“ علائقا پوشيده ڪري سگھجن ٿا، رڳو بيضابطگيون نظر اچن ٿيون. Wolfram Mathematica ۾ اهو استعمال ڪري سگهجي ٿو شفافيت[] и Raster3D[].

data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]}, 
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]

Seismic ڊيٽا ڪعبي تصوير Opacity[] ۽ Raster3D[] فنڪشن استعمال ڪندي

جيئن مصنوعي مثال ۾، اصل ڪعبي جي حصن تي ڪو به ڪي ارضياتي حدن (پرت) کي متغير رليف سان سڃاڻي سگھي ٿو.

اسپيڪٽرل تجزيي لاءِ بنيادي اوزار فوئرر ٽرانسفارم آهي. ان جي مدد سان، توھان اندازو ڪري سگھو ٿا طول و عرض-فريڪوئنسي اسپيڪٽرم جو ھر ھڪ سراغ يا گروھ جو نشان. جڏهن ته، فريڪوئنسي ڊومين ۾ ڊيٽا کي منتقل ڪرڻ کان پوء، معلومات گم ٿي ويندي آهي ڪهڙي وقت تي (پڙهو ڪهڙي کوٽائي تي) تعدد تبديل ٿي. وقت (گہرا) محور تي سگنل جي تبديلين کي مقامي ڪرڻ جي قابل ٿيڻ لاء، ونڊو فوئرر ٽرانسفارم ۽ ويجليٽ ڊومپوزيشن استعمال ڪيا ويا آهن. هي آرٽيڪل استعمال ڪري ٿو wavelet decomposition. 90 جي ڏهاڪي ۾ زلزلي جي ڳولا ۾ واهليٽ جي تجزياتي ٽيڪنالاجي کي فعال طور تي استعمال ٿيڻ شروع ڪيو. ونڊو ٿيل فورئر ٽرانسفارم تي فائدي کي بهتر وقت جي حل سمجهيو ويندو آهي.

هيٺ ڏنل ڪوڊ جي ٽڪري کي استعمال ڪندي، توهان زلزلي جي نشانين مان هڪ کي انفرادي اجزاء ۾ ختم ڪري سگهو ٿا:

cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]

اجزاء ۾ هڪ نشان جي decomposition

ان جو اندازو لڳائڻ لاءِ ته ريفريڪشن توانائي مختلف موج جي آمد جي وقت ۾ ڪيئن ورهائجي ٿي، اسڪالوگرامس (هڪ اسپيڪٽروگرام جي برابر) استعمال ڪيا وڃن ٿا. ضابطي جي طور تي، عملي طور تي سڀني اجزاء جو تجزيو ڪرڻ جي ڪا ضرورت ناهي. عام طور تي، گهٽ، وچولي ۽ اعلي تعدد جا حصا چونڊيا ويا آهن.

freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]

اسڪالوگرام. فنڪشن جو نتيجو WaveletScalogram[]

Wolfram Language وولٽ ٽرانسفارميشن لاءِ فنڪشن استعمال ڪري ٿي مسلسل وييلٽ ٽرانسفارم[]. ۽ ھن فنڪشن جي ايپليڪيشن کي نشانن جي پوري سيٽ تي عمل ڪيو ويندو فنڪشن استعمال ڪندي ٽيبل[]. هتي اهو ياد رکڻ جي قابل آهي ته Wolfram Mathematica جي طاقتن مان هڪ - متوازي استعمال ڪرڻ جي صلاحيت متوازي ٽيبل[]. مٿين مثال ۾، متوازي ڪرڻ جي ڪا ضرورت ناهي - ڊيٽا جو حجم وڏو ناهي، پر جڏهن تجرباتي ڊيٽا سيٽ سان ڪم ڪري رهيا آهن جن ۾ سوين هزارين نشان شامل آهن، اها هڪ ضرورت آهي.

tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}];

فنڪشن کي لاڳو ڪرڻ کان پوء مسلسل وييلٽ ٽرانسفارم[] نوان ڊيٽا سيٽ ظاهر ٿيندا آهن چونڊيل تعدد سان ملندڙ. مٿين مثال ۾، اهي تعدد آهن: 38Hz، 33Hz، 27Hz. تعدد جو انتخاب اڪثر ڪري جانچ جي بنياد تي ڪيو ويندو آهي - اهي مختلف تعدد مجموعن لاءِ موثر نقشا حاصل ڪندا آهن ۽ هڪ ارضيات جي نقطي نظر کان سڀ کان وڌيڪ معلوماتي چونڊيندا آهن.

جيڪڏھن توھان کي نتيجن کي ڀائيوارن سان حصيداري ڪرڻ يا انھن کي ڪسٽمر کي مهيا ڪرڻ جي ضرورت آھي، توھان استعمال ڪري سگھو ٿا SEGYExport[] فنڪشن جي GeologyIO پيڪيج

outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];

انهن مان ٽن ڪعبن سان (گهٽ فريڪوئنسي، وچ فريڪوئنسي، ۽ هاءِ فريڪوئنسي جزا)، آر بي بي بلڊنگ عام طور تي ڊيٽا کي گڏ ڪرڻ لاءِ استعمال ڪيو ويندو آهي. هر جزو کي پنهنجو رنگ مقرر ڪيو ويو آهي - ڳاڙهو، سائو، نيرو. Wolfram Mathematica ۾ اهو ڪم استعمال ڪندي ڪري سگهجي ٿو Color Combine[].

نتيجو تصويرون آهن جن مان ارضياتي تشريح ڪري سگهجي ٿي. سيڪشن تي رڪارڊ ڪيل ميڊرز اهو ممڪن بڻائي ٿو ته پيلو چينلز کي بيان ڪرڻ، جيڪي ذخيرا هجڻ جا وڌيڪ امڪان آهن ۽ تيل جا ذخيرا شامل آهن. اهڙي درياهه جي نظام جي جديد analogues جي ڳولا ۽ تجزيي اسان کي وسعت جي سڀ کان وڌيڪ پرعزم حصن جو تعين ڪرڻ جي اجازت ڏئي ٿو. چينل پاڻ کي چڱي طرح ترتيب ڏنل پٿر جي ٿلهي تہن سان منسوب ڪيا ويا آهن ۽ تيل لاء سٺو ذخيرو آهن. ”ليس“ کان ٻاهر وارا علائقا جديد ٻوڏ جي ميدانن جي ذخيرن سان ملندڙ جلندڙ آهن. ٻوڏ جي ميدانن جا ذخيرا خاص طور تي مٽيءَ جي پٿرن جي نمائندگي ڪن ٿا ۽ انهن علائقن ۾ سوراخ ڪرڻ غير اثرائتو ٿيندو.

ڊيٽا ڪعب جو RGB سلائس. وچ ۾ (وچ کان ٿورو کاٻي پاسي) توھان ڳولي سگھوٿا موڙيندڙ نديءَ کي.

ڊيٽا ڪعب جو RGB سلائس. کاٻي پاسي کان، توهان درياهه جي وچ واري درياهه کي ڳولي سگهو ٿا.

ڪجهه حالتن ۾، زلزلي جي ڊيٽا جي معيار کي خاص طور تي واضح تصويرن جي اجازت ڏئي ٿي. اهو منحصر آهي فيلڊ ڪم جي طريقيڪار تي، شور جي گھٽتائي الورورٿم پاران استعمال ڪيل سامان. اهڙين حالتن ۾، نه رڳو درياهه جي نظام جا ٽڪرا، پر تمام وڌايل پيلو درياء پڻ نظر اچن ٿا.

زلزلي واري ڊيٽا ڪعب جي ٽن حصن جي آر بي بي جو ميلاپ (افقي سلائس). کوٽائي تقريبن 2 ڪلوميٽر.

Saratov جي ويجهو وولگا درياهه جي سيٽلائيٽ تصوير

ٿڪل

Wolfram Mathematica توهان کي زلزلي واري ڊيٽا جو تجزيو ڪرڻ ۽ معدنيات جي ڳولا سان لاڳاپيل مسئلن کي حل ڪرڻ جي اجازت ڏئي ٿو، ۽ جيولوجي آئي او پيڪيج هن عمل کي وڌيڪ آسان بڻائي ٿو. زلزلي واري ڊيٽا جي جوڙجڪ اهڙي آهي جنهن ۾ ٺاهيل طريقن کي استعمال ڪندي حساب کي تيز ڪرڻ (متوازي ٽيبل[], ParallelDo[],…) تمام ڪارائتو آهي ۽ توهان کي ڊيٽا جي وڏي مقدار تي عمل ڪرڻ جي اجازت ڏئي ٿو. وڏي حد تائين، هي GeologyIO پيڪيج جي ڊيٽا اسٽوريج خاصيتن جي ذريعي سهولت ڏني وئي آهي. رستي ۾، پيڪيج نه رڳو لاڳو ٿيل زلزلي جي ڳولا جي ميدان ۾ استعمال ڪري سگهجي ٿو. تقريباً ساڳي قسم جي ڊيٽا زمين جي اندر داخل ٿيندڙ راڊار ۽ سيسمولوجي ۾ استعمال ٿينديون آهن. جيڪڏهن توهان وٽ تجويزون آهن ته نتيجن کي ڪيئن بهتر ڪجي، اهڙي ڊيٽا تي Wolfram Mathematica Arsenal مان ڪهڙا سگنل تجزياتي الگورٿم لاڳو ٿين ٿا، يا جيڪڏهن توهان وٽ تنقيد آهي، ته مهرباني ڪري ڇڏي ڏيو. تبصرو.

جو ذريعو: www.habr.com

Wolfram Mathematica جيو فزڪس ۾