භූ භෞතික විද්‍යාවේ වුල්ෆ්‍රම් ගණිතය

බ්ලොග් කතුවරයාට ස්තුතියි ඇන්ටන් එකිමෙන්කෝ ඔහුගේ වාර්තාව සඳහා

හැඳින්වීම

මේ සටහන ලියැවුණේ සමුළුවට සමගාමීවයි Wolfram රුසියානු තාක්ෂණ සමුළුව සහ මා ලබා දුන් වාර්තාවේ සාරාංශයක් අඩංගු වේ. මෙම උත්සවය ජුනි මාසයේදී ශාන්ත පීටර්ස්බර්ග්හිදී පැවැත්විණි. මම සම්මන්ත්‍රණ අඩවියෙන් වැඩ කරන බව සලකන විට, මට මෙම අවස්ථාවට සහභාගී නොවී සිටීමට නොහැකි විය. 2016 සහ 2017 දී මම සම්මන්ත්‍රණ වාර්තාවලට සවන් දුන් අතර මේ වසරේ මම ඉදිරිපත් කිරීමක් ලබා දුන්නා. පළමුවෙන්ම, අපි සංවර්ධනය කරමින් සිටින සිත්ගන්නා (මට පෙනෙන) මාතෘකාවක් දර්ශනය වී ඇත කිරිල් බෙලෝව්, සහ දෙවනුව, සම්බාධක ප්‍රතිපත්තිය සම්බන්ධයෙන් රුසියානු සමූහාණ්ඩුවේ නීති සම්පාදනය පිළිබඳ දිගු අධ්‍යයනයකින් පසුව, මා සේවය කරන ව්‍යවසායයේ බලපත්‍ර දෙකක් තරම් ප්‍රමාණයක් දර්ශනය විය. වුල්ෆ්රාම් ගණිතය.

මගේ කතාවේ මාතෘකාවට යාමට පෙර, උත්සවයේ හොඳ සංවිධානයක් සටහන් කිරීමට මම කැමැත්තෙමි. සමුළුවේ පිවිසුම් පිටුව කසාන් ආසන දෙව්මැදුරේ රූපයක් භාවිතා කරයි. ආසන දෙව්මැදුර ශාන්ත පීටර්ස්බර්ග් හි ප්‍රධාන ආකර්ෂණයන්ගෙන් එකක් වන අතර සමුළුව පැවති ශාලාවේ සිට ඉතා පැහැදිලිව දැකගත හැකිය.

ශාන්ත පීටර්ස්බර්ග් ප්‍රාන්ත ආර්ථික විශ්ව විද්‍යාලයට ඇතුළුවීමේදී, සිසුන් අතරින් සහායකයින් විසින් හ්භාගීවනනනට හමු විය - ඔවුන් අතරමං වීමට ඉඩ දුන්නේ නැත. ලියාපදිංචි කිරීමේදී, කුඩා සිහිවටන ලබා දෙන ලදී (සෙල්ලම් බඩු - දැල්වෙන ස්පයික්, පෑන, වුල්ෆ්‍රම් සංකේත සහිත ස්ටිකර්). දිවා ආහාරය සහ කෝපි විවේකය ද සම්මන්ත්‍රණ කාලසටහනට ඇතුළත් විය. කණ්ඩායමේ බිත්තියේ රසවත් කෝපි සහ පයි ගැන මම දැනටමත් සටහන් කර ඇත - සූපවේදීන් විශිෂ්ටයි. මෙම හඳුන්වාදීමේ කොටස සමඟ, සිද්ධියම, එහි ආකෘතිය සහ ස්ථානය දැනටමත් ධනාත්මක හැඟීම් ගෙන එන බව අවධාරණය කිරීමට කැමැත්තෙමි.

මම සහ කිරිල් බෙලෝව් විසින් සකස් කරන ලද වාර්තාව “ව්‍යවහාරික භූ භෞතික විද්‍යාවේ ගැටලු විසඳීමට වුල්ෆ්‍රම් ගණිතය භාවිතා කිරීම. භූ කම්පන දත්ත හෝ "පැරණි ගංගා ගලා ගිය තැන්වල" වර්ණාවලි විශ්ලේෂණය. වාර්තාවේ අන්තර්ගතය කොටස් දෙකක් ආවරණය කරයි: පළමුව, ලබා ගත හැකි ඇල්ගොරිතම භාවිතය වුල්ෆ්රාම් ගණිතය භූ භෞතික දත්ත විශ්ලේෂණය සඳහා, සහ දෙවනුව, Wolfram Mathematica වෙත භූ භෞතික දත්ත ඇතුළත් කරන්නේ කෙසේද යන්නයි.

භූ කම්පන ගවේෂණය

මුලින්ම ඔබ භූ භෞතික විද්යාව සඳහා කෙටි විනෝද චාරිකාවක් කළ යුතුය. භූ භෞතික විද්‍යාව යනු පාෂාණවල භෞතික ගුණ අධ්‍යයනය කරන විද්‍යාවයි. හොඳයි, පාෂාණවලට විවිධ ගුණ ඇති බැවින්: විද්‍යුත්, චුම්භක, ප්‍රත්‍යාස්ථ, භූ භෞතික විද්‍යාවේ අනුරූප ක්‍රම තිබේ: විද්‍යුත් අපේක්ෂාව, චුම්බක අපේක්ෂාව, භූ කම්පන අපේක්ෂාව... මෙම ලිපියේ සන්දර්භය තුළ, අපි වඩාත් විස්තරාත්මකව භූ කම්පන අපේක්ෂාව ගැන පමණක් සාකච්ඡා කරමු. තෙල් හා ගෑස් සෙවීමේ ප්‍රධාන ක්‍රමය භූ කම්පන ගවේෂණයයි. මෙම ක්‍රමය පදනම් වී ඇත්තේ ප්‍රත්‍යාස්ථ කම්පනවල උද්දීපනය සහ අධ්‍යයන ප්‍රදේශය රචනා කරන පාෂාණවලින් ලැබෙන ප්‍රතිචාරය පසුව පටිගත කිරීම මත ය. කම්පන ගොඩබිම (ඩයිනමයිට් හෝ ප්‍රත්‍යාස්ථ කම්පනවල පුපුරන සුලු නොවන කම්පන ප්‍රභවයන් සමඟ) හෝ මුහුදේදී (වායු තුවක්කු සමඟ) උද්වේගකරයි. ප්‍රත්‍යාස්ථ කම්පන පාෂාණ ස්කන්ධය හරහා ප්‍රචාරණය වන අතර, වර්තනය වන අතර විවිධ ගුණාංග සහිත ස්ථරවල මායිම්වල පරාවර්තනය වේ. පරාවර්තනය කරන ලද තරංග නැවත මතුපිටට පැමිණෙන අතර ගොඩබිම (සාමාන්‍යයෙන් දඟරයක අත්හිටුවන ලද චුම්බක චලනය මත පදනම් වූ විද්‍යුත් ගතික උපාංග) හෝ මුහුදේ ඇති හයිඩ්‍රොෆෝන (පයිසෝ ඉලෙක්ට්‍රික් ආචරණය මත පදනම්ව) භූෆෝන් මගින් පටිගත කරනු ලැබේ. තරංග පැමිණීමේ කාලය වන විට, භූගෝලීය ස්ථරවල ගැඹුර විනිශ්චය කළ හැකිය.

භූ කම්පන යාත්රා ඇදගෙන යාමේ උපකරණ


වායු තුවක්කුව ඉලාස්ටික් කම්පන උද්දීපනය කරයි


තරංග පාෂාණ ස්කන්ධය හරහා ගමන් කරන අතර හයිඩ්‍රොෆෝන මගින් පටිගත කරනු ලැබේ


ශාන්ත පීටර්ස්බර්ග්හි Blagoveshchensky පාලම අසල තොටුපළෙහි භූ භෞතික සමීක්ෂණ පර්යේෂණ නෞකාව "අයිවන් ගුබ්කින්"

භූ කම්පන සංඥා ආකෘතිය

පාෂාණවලට විවිධ භෞතික ගුණ ඇත. භූ කම්පන ගවේෂණය සඳහා, ප්රත්යාස්ථ ගුණ මූලික වශයෙන් වැදගත් වේ - ප්රත්යාස්ථ කම්පන සහ ඝනත්වය පැතිරීමේ වේගය. ස්ථර දෙකකට සමාන හෝ සමාන ගුණ තිබේ නම්, තරංගය ඒවා අතර මායිම "නොදැක්කා" නැත. ස්ථර වල තරංග වේගය වෙනස් වේ නම්, ස්ථර වල මායිමේ පරාවර්තනය සිදු වේ. ගුණාංගවල වෙනස වැඩි වන තරමට පරාවර්තනය වඩාත් තීව්‍ර වේ. එහි තීව්‍රතාවය පරාවර්තක සංගුණකය (rc) මගින් තීරණය කරනු ලැබේ:

මෙහි ρ යනු පාෂාණ ඝනත්වය, ν යනු තරංග වේගය, 1 සහ 2 ඉහළ සහ පහළ ස්ථර දක්වයි.

සරළම සහ බහුලව භාවිතා වන භූ කම්පන සංඥා ආකෘතිවලින් එකක් වන්නේ සංකෝචන ආකෘතියයි, වාර්තාගත භූ කම්පන හෝඩුවාවක් පිරික්සුම් ස්පන්දනයක් සහිත පරාවර්තන සංගුණක අනුක්‍රමයක සංකෝචනයක ප්‍රතිඵලයක් ලෙස නිරූපණය වන විට:

කොහෙද s(t) - භූ කම්පන හෝඩුවාවක්, i.e. ස්ථාවර පටිගත කිරීමේ කාලයක් තුළ හයිඩ්‍රොෆෝනයකින් හෝ භූෆෝනයකින් පටිගත කරන ලද සියල්ල, w(t) - වායු තුවක්කුව මගින් ජනනය කරන ලද සංඥාව, n(t) - අහඹු ශබ්දය.

අපි උදාහරණයක් ලෙස කෘතිම භූ කම්පන හෝඩුවාවක් ගණනය කරමු. අපි මූලික සංඥාව ලෙස භූ කම්පන ගවේෂණයේදී බහුලව භාවිතා වන Ricker ස්පන්දනය භාවිතා කරමු.

length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]

ආරම්භක භූ කම්පන ආවේගය


අපි 300 ms සහ 600 ms ගැඹුරේ මායිම් දෙකක් සකසන්නෙමු, සහ පරාවර්තන සංගුණක අහඹු සංඛ්යා වනු ඇත

rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]

පරාවර්තන සංගුණක අනුපිළිවෙල


භූ කම්පන හෝඩුවාව ගණනය කර පෙන්වමු. පරාවර්තන සංගුණකවල විවිධ සලකුණු ඇති බැවින්, භූ කම්පන හෝඩුවාවක් මත අපට විකල්ප පරාවර්තන දෙකක් ලැබේ.

traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]

අනුකරණය කළ ධාවන පථය


මෙම උදාහරණය සඳහා, එය වෙන් කරවා ගැනීම අවශ්ය වේ - යථාර්ථයේ දී, ස්ථර වල ගැඹුර තීරණය කරනු ලැබේ, ඇත්ත වශයෙන්ම, මීටර වලින්, සහ භූ කම්පන හෝඩුවාවක් ගණනය කිරීම කාල වසම සඳහා සිදු වේ. ගැඹුර මීටර වලින් සකසා ස්ථර වල ප්‍රවේග දැනගෙන පැමිණීමේ වේලාවන් ගණනය කිරීම වඩාත් නිවැරදි වනු ඇත. මෙම අවස්ථාවේදී, මම වහාම කාල අක්ෂය මත ස්ථර සකස් කරමි.

අපි ක්ෂේත්‍ර පර්යේෂණ ගැන කතා කරන්නේ නම්, එවැනි නිරීක්ෂණවල ප්‍රති result ලයක් ලෙස සමාන කාල ශ්‍රේණි (කම්පන හෝඩුවාවන්) විශාල ප්‍රමාණයක් වාර්තා වේ. නිදසුනක් ලෙස, කිලෝමීටර් 25 ක් දිග සහ කිලෝමීටර 15 ක් පළල වෙබ් අඩවියක් අධ්‍යයනය කරන විට, වැඩ කිරීමේ ප්‍රති result ලයක් ලෙස, සෑම හෝඩුවාවක්ම මීටර් 25x25 ක සෛලයක් සංලක්ෂිත කරයි (එවැනි සෛලයක් බඳුනක් ලෙස හැඳින්වේ), අවසාන දත්ත අරාවෙහි අංශු 600000 ක් අඩංගු වේ. නියැදීමේ කාලය 1 ms සහ තත්පර 5 ක පටිගත කිරීමේ කාලය සමඟ, අවසාන දත්ත ගොනුව 11 GB ට වඩා වැඩි වනු ඇති අතර, මුල් "අමු" ද්රව්යයේ පරිමාව ගිගාබයිට් සිය ගණනක් විය හැකිය.

ඔවුන් සමඟ වැඩ කරන්නේ කෙසේද වුල්ෆ්රාම් ගණිතය?

පැකේජය භූ විද්යාවIO

පැකේජයේ සංවර්ධනය ආරම්භ විය ප්රශ්නයකි රුසියානු කතා කරන සහායක කණ්ඩායමේ VK බිත්තිය මත. ප්‍රජාවගේ ප්‍රතිචාර වලට ස්තූතිවන්ත වන්නට, ඉතා ඉක්මනින් විසඳුමක් සොයා ගන්නා ලදී. එහි ප්‍රතිඵලයක් වශයෙන් එය බරපතළ වර්ධනයක් දක්වා වර්ධනය විය. අනුරූප වේ වුල්ෆ්‍රම් ප්‍රජා බිත්ති කණුව එය පරිපාලකයින් විසින් පවා සලකුණු කරන ලදී. දැනට, පැකේජය භූ විද්‍යාත්මක කර්මාන්තයේ සක්‍රියව භාවිතා කරන පහත දත්ත වර්ග සමඟ වැඩ කිරීමට සහාය වේ:

1. ZMAP සහ IRAP ආකෘතිවලින් සිතියම් දත්ත ආනයනය කිරීම
2. LAS ආකෘතියේ ළිංවල මිනුම් ආනයනය කිරීම
3. භූ කම්පන ගොනු ආකෘතියේ ආදානය සහ ප්‍රතිදානය SEGY

පැකේජය ස්ථාපනය කිරීම සඳහා, ඔබ එකලස් කරන ලද පැකේජයේ බාගැනීම් පිටුවේ ඇති උපදෙස් අනුගමනය කළ යුතුය, i.e. පහත කේතය ඕනෑම එකකින් ක්‍රියාත්මක කරන්න ගණිත සටහන් පොත:

If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
    "https://wolfr.am/FiQ5oFih", 
    FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]

පැකේජය පෙරනිමි ෆෝල්ඩරයේ ස්ථාපනය කිරීමෙන් පසුව, මාර්ගය පහත පරිදි ලබා ගත හැකිය:

FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]

උදාහරණයක් ලෙස, අපි පැකේජයේ ප්රධාන හැකියාවන් ප්රදර්ශනය කරමු. වුල්ෆ්‍රම් භාෂාවේ පැකේජ සඳහා ඇමතුම සම්ප්‍රදායිකව සිදු කෙරේ:

Get["GeologyIO`"]

පැකේජය සංවර්ධනය කර ඇත වුල්ෆ්‍රම් වැඩ බංකුව. ඉදිරිපත් කිරීමේ ආකෘතිය අනුව Wolfram Mathematica හි ප්‍රලේඛනයට වඩා වෙනස් නොවන ලේඛන සමඟ පැකේජයේ ප්‍රධාන ක්‍රියාකාරිත්වය සමඟ යාමට මෙය ඔබට ඉඩ සලසයි, සහ පළමු දැන හඳුනා ගැනීම සඳහා පරීක්ෂණ ගොනු සමඟ පැකේජය ලබා දීමට.

එවැනි ගොනුවක්, විශේෂයෙන්, "Marmousi.segy" ගොනුව වේ - මෙය ප්රංශ ඛනිජ තෙල් ආයතනය විසින් සංවර්ධනය කරන ලද භූ විද්යාත්මක අංශයක කෘතිම ආකෘතියකි. මෙම ආකෘතිය භාවිතා කරමින්, සංවර්ධකයින් තරංග ක්ෂේත්‍ර ආකෘති නිර්මාණය, දත්ත සැකසීම, භූ කම්පන හෝඩුවාවන් ප්‍රතිලෝම ආදිය සඳහා තමන්ගේම ඇල්ගොරිතම පරීක්ෂා කරයි. Marmousi ආකෘතියම පැකේජය බාගත කළ ගබඩාවේ ගබඩා කර ඇත. ගොනුව ලබා ගැනීම සඳහා, පහත කේතය ධාවනය කරන්න:

If[Not[FileExistsQ["Marmousi.segy"]], 
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]

ආයාත ප්‍රතිඵලය - SEGYData වස්තුව


SEGY ආකෘතියට නිරීක්ෂණ පිළිබඳ විවිධ තොරතුරු ගබඩා කිරීම ඇතුළත් වේ. පළමුව, මේවා පෙළ අදහස් වේ. කාර්යයේ පිහිටීම, මිනුම් සිදු කළ සමාගම්වල නම් ආදිය පිළිබඳ තොරතුරු මෙයට ඇතුළත් වේ. අපගේ නඩුවේදී, මෙම ශීර්ෂකය TextHeader යතුර සමඟ ඉල්ලීමක් මගින් කැඳවනු ලැබේ. කෙටි කළ පෙළ ශීර්ෂයක් මෙන්න:

Short[marmousi["TextHeader"]]

"Marmousi දත්ත කට්ටලය ආයතනයේ ජනනය කරන ලදී ... අවම වේගය 1500 m/s සහ උපරිම 5500 m/s)"

“ට්‍රේස්” යතුර භාවිතයෙන් භූ කම්පන හෝඩුවාවන් වෙත ප්‍රවේශ වීමෙන් ඔබට සැබෑ භූ විද්‍යාත්මක ආකෘතිය ප්‍රදර්ශනය කළ හැකිය (පැකේජයේ එක් අංගයක් නම් යතුරු අවස්ථා සංවේදී නොවන බවයි):

ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]

මාදිලිය Marmousi


දැනට, පැකේජය ඔබට විශාල ගොනු වලින් කොටස් වශයෙන් දත්ත පැටවීමට ඉඩ සලසයි, එමඟින් ගිගාබයිට් දස ගණනකට ළඟා විය හැකි ගොනු සැකසීමට හැකි වේ. පැකේජයේ කාර්යයන් .segy වෙත දත්ත අපනයනය කිරීම සහ ගොනුවේ අවසානයට අර්ධ වශයෙන් එකතු කිරීම සඳහා වන කාර්යයන් ද ඇතුළත් වේ.

වෙනමම, .segy ගොනු වල සංකීර්ණ ව්යුහය සමඟ වැඩ කිරීමේදී පැකේජයේ ක්රියාකාරිත්වය සඳහන් කිරීම වටී. එය ඔබට යතුරු සහ දර්ශක භාවිතයෙන් තනි හෝඩුවාවන් සහ ශීර්ෂයන් වෙත ප්‍රවේශ වීමට පමණක් නොව, ඒවා වෙනස් කර ගොනුවකට ලිවීමටද ඉඩ සලසයි. GeologyIO ක්‍රියාත්මක කිරීමේ බොහෝ තාක්ෂණික තොරතුරු මෙම ලිපියේ විෂය පථයෙන් ඔබ්බට වන අතර බොහෝ විට වෙනම විස්තරයක් ලැබිය යුතුය.

භූ කම්පන ගවේෂණයේදී වර්ණාවලි විශ්ලේෂණයේ අදාළත්වය

Wolfram Mathematica වෙත භූ කම්පන දත්ත ආයාත කිරීමේ හැකියාව ඔබට පර්යේෂණාත්මක දත්ත සඳහා බිල්ට් සංඥා සැකසුම් ක්‍රියාකාරිත්වය භාවිතා කිරීමට ඉඩ සලසයි. සෑම භූ කම්පන හෝඩුවාවක්ම කාල ශ්‍රේණියක් නියෝජනය කරන බැවින්, ඒවා අධ්‍යයනය කිරීමේ ප්‍රධාන මෙවලමක් වන්නේ වර්ණාවලි විශ්ලේෂණයයි. භූ කම්පන දත්තවල සංඛ්‍යාත සංයුතිය විශ්ලේෂණය කිරීම සඳහා පූර්වාවශ්‍යතා අතර, අපට උදාහරණයක් ලෙස පහත සඳහන් දෑ නම් කළ හැකිය:

1. විවිධ තරංග වර්ග විවිධ සංඛ්යාත සංයුතිය මගින් සංලක්ෂිත වේ. මෙය ඔබට ප්රයෝජනවත් තරංග ඉස්මතු කිරීමට සහ මැදිහත්වීම් තරංග මර්දනය කිරීමට ඉඩ සලසයි.
2. සිදුරු හා සන්තෘප්තිය වැනි පාෂාණ ගුණාංග සංඛ්යාත සංයුතියට බලපෑ හැකිය. මෙමගින් හොඳම ගුණාංග සහිත පාෂාණ හඳුනා ගැනීමට හැකි වේ.
3. විවිධ ඝනකම් සහිත ස්ථර විවිධ සංඛ්යාත පරාසයන් තුළ විෂමතා ඇති කරයි.

මෙම ලිපියේ සන්දර්භය තුළ තුන්වන කරුණ ප්රධාන වේ. පහත දැක්වෙන්නේ විවිධ ඝණකම සහිත ස්ථරයක භූ කම්පන හෝඩුවාවන් ගණනය කිරීම සඳහා වන කේත කැබැල්ලකි - කුඤ්ඤ ආකෘතියකි. මෙම ආකෘතිය සාම්ප්‍රදායිකව භූ කම්පන ගවේෂණයේදී අධ්‍යයනය කරනු ලබන්නේ බොහෝ ස්තරවලින් පරාවර්තනය වන තරංග එකිනෙක මත අධිස්ථාපනය වන විට බාධා බලපෑම් විශ්ලේෂණය කිරීමටය.

nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]

පින්ච්-අවුට් සෑදීමේ ආකෘතිය


කූඤ්ඤය තුළ තරංග වේගය 4500 m/s, කූඤ්ඤයෙන් පිටත 4000 m/s, සහ ඝනත්වය නියත 2200 g/cm³ ලෙස උපකල්පනය කෙරේ. එවැනි ආකෘතියක් සඳහා, අපි පරාවර්තන සංගුණක සහ භූ කම්පන අංශු ගණනය කරමු.

rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
	ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
		{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]

කුඤ්ඤ ආකෘතිය සඳහා භූ කම්පන අංශු


මෙම රූපයේ දැක්වෙන භූ කම්පන අංශු අනුපිළිවෙල භූ කම්පන අංශයක් ලෙස හැඳින්වේ. ඔබට පෙනෙන පරිදි, පරාවර්තනය කරන ලද තරංගවල ජ්යාමිතිය පැහැදිලිවම කලින් සඳහන් කළ ආකෘතියට අනුරූප වන බැවින්, එහි අර්ථ නිරූපණය ද බුද්ධිමය මට්ටමකින් සිදු කළ හැකිය. ඔබ හෝඩුවාවන් වඩාත් විස්තරාත්මකව විශ්ලේෂණය කරන්නේ නම්, 1 සිට දළ වශයෙන් 30 දක්වා හෝඩුවාවන් වෙනස් නොවන බව ඔබට පෙනෙනු ඇත - ගොඩනැගීමේ වහලයේ සහ පහළ සිට පරාවර්තනය එකිනෙක අතිච්ඡාදනය නොවේ. 31 වන හෝඩුවාවේ සිට, පරාවර්තනයන් මැදිහත් වීමට පටන් ගනී. තවද, ආකෘතියේ වුවද, පරාවර්තන සංගුණක තිරස් අතට වෙනස් නොවේ - භූ කම්පන හෝඩුවාවන් සෑදීමේ ඝණකම වෙනස් වන විට ඒවායේ තීව්රතාවය වෙනස් වේ.

ගොඩනැගීමේ ඉහළ මායිමේ සිට පරාවර්තනයේ විස්තාරය සලකා බලමු. 60 වන මාර්ගයේ සිට, පරාවර්තනයේ තීව්රතාවය වැඩි වීමට පටන් ගන්නා අතර 70 වන මාර්ගයේ එය උපරිම වේ. සමහර අවස්ථාවල භූ කම්පන වාර්තාවේ සැලකිය යුතු විෂමතාවන්ට තුඩු දෙන ස්ථරවල වහලයේ සහ පතුලේ ඇති තරංගවල මැදිහත්වීම් ප්‍රකාශ වන්නේ එලෙස ය.

ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]

කූඤ්ඤයේ ඉහළ කෙළවරේ සිට පරාවර්තනය කරන ලද තරංගයේ විස්තාරය පිළිබඳ ප්රස්ථාරය


සංඥාව අඩු-සංඛ්‍යාත වන විට, විශාල සෑදීමේ ඝනකමේදී බාධා කිරීම් පෙනෙන්නට පටන් ගන්නා අතර, අධි-සංඛ්‍යාත සංඥාවකදී, කුඩා ඝනකම්වලදී බාධා කිරීම් සිදුවේ. පහත කේත ස්නිපටය 35 Hz, 55 Hz සහ 85 Hz සංඛ්‍යාත සහිත සංඥාවක් නිර්මාණය කරයි.

waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]

35 Hz, 55Hz, 85Hz සංඛ්‍යාත සහිත ප්‍රභව සංඥා කට්ටලයක්


භූ කම්පන හෝඩුවාවන් ගණනය කිරීමෙන් සහ පරාවර්තිත තරංග විස්තාරවල ප්‍රස්ථාර සැකසීමෙන්, විවිධ සංඛ්‍යාත සඳහා විවිධ සෑදීමේ thickness ණකමෙහි විෂමතාවයක් දක්නට ලැබෙන බව අපට දැකගත හැකිය.

tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];

lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];

Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]

විවිධ සංඛ්‍යාත සඳහා කුඤ්ඤයේ ඉහළ දාරයේ සිට පරාවර්තනය වූ තරංගයේ විස්තාරක ප්‍රස්ථාර


භූ කම්පන නිරීක්ෂණවල ප්‍රති results ල වලින් සෑදීමේ thickness ණකම පිළිබඳ නිගමනවලට එළඹීමේ හැකියාව අතිශයින්ම ප්‍රයෝජනවත් වේ, මන්ද තෙල් ගවේෂණයේ එක් ප්‍රධාන කාර්යයක් වන්නේ ළිඳක් තැබීම සඳහා වඩාත්ම පොරොන්දු වූ කරුණු තක්සේරු කිරීමයි (එනම්, එය සෑදී ඇති ප්‍රදේශ. ඝනකම). ඊට අමතරව, භූ විද්‍යාත්මක කොටසෙහි, උත්පත්තියෙන් සෑදීමේ thickness ණකමෙහි තියුණු වෙනසක් ඇති කරන වස්තූන් තිබිය හැකිය. මෙමගින් වර්ණාවලි විශ්ලේෂණය ඒවා අධ්යයනය කිරීම සඳහා ඵලදායී මෙවලමක් බවට පත් කරයි. ලිපියේ ඊළඟ කොටසේදී අපි එවැනි භූගෝලීය වස්තූන් වඩාත් විස්තරාත්මකව සලකා බලමු.

පර්යේෂණාත්මක දත්ත. ඔබ ඒවා ලබා ගත්තේ කොහෙන්ද සහ ඒවායින් සෙවිය යුත්තේ කුමක්ද?

ලිපියේ විශ්ලේෂණය කරන ලද ද්රව්ය බටහිර සයිබීරියාවේ ලබා ගන්නා ලදී. ව්‍යතිරේකයකින් තොරව සෑම දෙනාම දන්නා පරිදි කලාපය අපේ රටේ ප්‍රධාන තෙල් නිපදවන කලාපයයි. පසුගිය ශතවර්ෂයේ 60 ගණන්වල කලාපයේ තැන්පතු වල ක්රියාකාරී සංවර්ධනය ආරම්භ විය. තෙල් නිධි සෙවීමේ ප්‍රධාන ක්‍රමය වන්නේ භූ කම්පන ගවේෂණයයි. මෙම භූමියේ චන්ද්‍රිකා ඡායාරූප දෙස බැලීම සිත්ගන්නා කරුණකි. කුඩා පරිමාණයෙන්, ඔබට වගුරු බිම් සහ විල් විශාල සංඛ්‍යාවක් සටහන් කළ හැකිය; සිතියම විශාල කිරීමෙන්, ඔබට පොකුරු ළිං කැණීමේ ස්ථාන දැකිය හැකි අතර, සිතියම සීමාවට විශාල කිරීමෙන්, ඔබට භූ කම්පන ඇති පැතිකඩවල නිෂ්කාශන වෙන්කර හඳුනාගත හැකිය. නිරීක්ෂණ සිදු කරන ලදී.

Yandex සිතියම් වල චන්ද්රිකා රූපය - Noyabrsk නගර ප්රදේශය


එක් ක්ෂේත්‍රයක ළිං පෑඩ් ජාලයක්


බටහිර සයිබීරියාවේ තෙල් සහිත පාෂාණ පුළුල් පරාසයක ගැඹුරකින් සිදු වේ - කිලෝමීටර 1 සිට 5 දක්වා. තෙල් අඩංගු පාෂාණවල ප්‍රධාන පරිමාව ජුරාසික් සහ ක්‍රිටේසියස් කාලවලදී පිහිටුවන ලදී. ජුරාසික් යුගය බොහෝ විට එම නමින්ම ඇති චිත්‍රපටයෙන් බොහෝ අය දන්නා කරුණකි. ජුරාසික් දේශගුණය නූතන එකට වඩා සැලකිය යුතු ලෙස වෙනස් විය. එන්සයික්ලොපීඩියා බ්‍රිටැනිකා විශ්වකෝෂයේ එක් එක් හීලොජිකල් යුගයන් නිරූපණය කරන පැලියෝමාප් මාලාවක් ඇත.

වර්තමානය

ජුරාසික් යුගය


ජුරාසික් යුගයේ බටහිර සයිබීරියාවේ භූමි ප්‍රදේශය මුහුදු වෙරළක් වූ බව කරුණාවෙන් සලකන්න (ගංගා සහ නොගැඹුරු මුහුදක් හරහා ගිය භූමිය). දේශගුණය සුවපහසු වූ බැවින්, එකල සාමාන්‍ය භූ දර්ශනයක් මේ ආකාරයෙන් දිස් වූ බව අපට උපකල්පනය කළ හැකිය:

ජුරාසික් සයිබීරියාව


මේ පින්තූරයේ අපට වැදගත් වන්නේ සතුන් සහ කුරුල්ලන් නොව, පසුබිමේ ඇති ගංගාවේ රූපයයි. ගඟ කියන්නේ අපි කලින් නතර කරපු භූගෝලීය වස්තුවම තමයි. කාරණය නම් ගංගාවල ක්‍රියාකාරිත්වය හොඳින් වර්ග කළ වැලිගල් සමුච්චය වීමට ඉඩ සලසයි, එය තෙල් සඳහා ජලාශයක් බවට පත්වනු ඇත. මෙම ජලාශවලට විකාර, සංකීර්ණ හැඩයක් (ගංගා ඇඳක් වැනි) තිබිය හැකි අතර ඒවාට විචල්‍ය ඝනකමක් ඇත - ඉවුරු අසල ඝණකම කුඩා වන නමුත් නාලිකාවේ මධ්‍යයට ආසන්නව හෝ වංගු සහිත ප්‍රදේශවල එය වැඩි වේ. ඉතින්, ජුරාසික් හි පිහිටුවා ඇති ගංගා දැන් කිලෝමීටර් තුනක් පමණ ගැඹුරින් පිහිටා ඇති අතර තෙල් සංචිත සෙවීමේ වස්තුව වේ.

පර්යේෂණාත්මක දත්ත. සැකසීම සහ දෘශ්‍යකරණය

ලිපියේ පෙන්වා ඇති භූ කම්පන ද්‍රව්‍ය සම්බන්ධයෙන් අපි වහාම වෙන්කරවා ගනිමු - විශ්ලේෂණය සඳහා භාවිතා කරන දත්ත ප්‍රමාණය සැලකිය යුතු බැවින් - ලිපියේ පෙළට ඇතුළත් කර ඇත්තේ මුල් භූ කම්පන අංශුවල කොටසක් පමණි. මෙමගින් ඕනෑම කෙනෙකුට ඉහත ගණනය කිරීම් ප්‍රතිනිෂ්පාදනය කිරීමට ඉඩ සැලසේ.

භූ කම්පන දත්ත සමඟ වැඩ කරන විට, භූ භෞතික විද්‍යා ist යෙකු සාමාන්‍යයෙන් විශේෂිත මෘදුකාංග භාවිතා කරයි (වර්ධන ක්‍රියාකාරීව භාවිතා කරන කර්මාන්ත නායකයින් කිහිප දෙනෙකු ඇත, උදාහරණයක් ලෙස Petrel හෝ Paradigm), එමඟින් ඔබට විවිධ වර්ගයේ දත්ත විශ්ලේෂණය කිරීමට සහ පහසු චිත්‍රක අතුරු මුහුණතක් ඇත. සියලු පහසුව තිබියදීත්, මෙම වර්ගයේ මෘදුකාංග ද ඔවුන්ගේ අඩුපාඩු තිබේ - නිදසුනක් ලෙස, ස්ථාවර අනුවාදවල නවීන ඇල්ගොරිතම ක්රියාත්මක කිරීම සඳහා බොහෝ කාලයක් ගත වන අතර, ගණනය කිරීම් ස්වයංක්රීය කිරීම සඳහා ඇති හැකියාව සාමාන්යයෙන් සීමිත වේ. එවැනි තත්වයක් තුළ, පරිගණක ගණිත පද්ධති සහ ඉහළ මට්ටමේ ක්‍රමලේඛන භාෂා භාවිතා කිරීම ඉතා පහසු වන අතර එමඟින් පුළුල් ඇල්ගොරිතම පදනමක් භාවිතා කිරීමට ඉඩ ලබා දෙන අතර ඒ සමඟම බොහෝ පුරුද්දක් ගනී. Wolfram Mathematica හි භූ කම්පන දත්ත සමඟ වැඩ කිරීමට භාවිතා කරන මූලධර්මය මෙයයි. දත්ත සමඟ අන්තර්ක්‍රියාකාරී වැඩ සඳහා පොහොසත් ක්‍රියාකාරිත්වය ලිවීම නුසුදුසු ය - සාමාන්‍යයෙන් පිළිගත් ආකෘතියකින් පැටවීම සහතික කිරීම, ඒවාට අවශ්‍ය ඇල්ගොරිතම යෙදීම සහ ඒවා බාහිර ආකෘතියකට නැවත උඩුගත කිරීම වඩාත් වැදගත් වේ.

යෝජිත යෝජනා ක්‍රමය අනුගමනය කරමින්, අපි මුල් භූ කම්පන දත්ත පූරණය කර ඒවා ප්‍රදර්ශනය කරන්නෙමු වුල්ෆ්රාම් ගණිතය:

Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]

මෙලෙස බාගත කර ආනයනය කරන දත්ත කිලෝමීටර් 10 ත් 5 ත් අතර ප්‍රදේශයක වාර්තා වී ඇති මාර්ග වේ. ත්‍රිමාණ භූ කම්පන සමීක්ෂණ ක්‍රමයක් භාවිතයෙන් දත්ත ලබා ගන්නේ නම් (තරංග සටහන් වන්නේ තනි භූ භෞතික පැතිකඩ ඔස්සේ නොව මුළු ප්‍රදේශය පුරාවටම) නම්, භූ කම්පන දත්ත කැට ලබා ගැනීමට හැකි වේ. මේවා ත්‍රිමාණ වස්තූන්, භූ විද්‍යාත්මක පරිසරය පිළිබඳ සවිස්තරාත්මක අධ්‍යයනයක් කිරීමට ඉඩ සලසන සිරස් සහ තිරස් කොටස් වේ. සලකා බැලූ උදාහරණයේ, අපි ත්රිමාණ දත්ත සමඟ කටයුතු කරන්නෙමු. අපිට මේ වගේ text header එකෙන් තොරතුරු ටිකක් ගන්න පුළුවන්

StringPartition[seismic3DSEGY["textheader"], 80] // TableForm

C 1 මෙය භූ විද්‍යාව පැකේජ පරීක්ෂණය සඳහා වූ නිදර්ශන ගොනුවකි
සී 2
සී 3
සී 4
C 5 දිනය පරිශීලක නාමය: WOLFRAM පරිශීලක
C 6 සමීක්ෂණයේ නම: සයිබීරියාවේ කොහේ හරි
C 7 ගොනු වර්ගය 3D භූ කම්පන පරිමාව
සී 8
සී 9
C10 Z පරාසය: පළමු 2200M අවසන් 2400M

දත්ත විශ්ලේෂණයේ ප්‍රධාන අවධීන් නිරූපණය කිරීමට මෙම දත්ත කට්ටලය ප්‍රමාණවත් වේ. ගොනුවේ ඇති හෝඩුවාවන් අනුක්‍රමිකව සටහන් කර ඇති අතර ඒ සෑම එකක්ම පහත රූපයට සමාන වේ - මෙය සිරස් අක්ෂය (ගැඹුර අක්ෂය) දිගේ පරාවර්තක තරංගවල විස්තාරය බෙදා හැරීමයි.

ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2, 
 PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
 LabelStyle -> Directive[Black, Italic], PlotRange -> All, 
 Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]

භූ කම්පන අංශ හෝඩුවාවන් වලින් එකක්


අධ්‍යයනය කරන ලද ප්‍රදේශයේ එක් එක් දිශාවට අංශු කීයක් පිහිටා තිබේද යන්න දැන ගැනීමෙන්, ඔබට ත්‍රිමාන දත්ත අරාවක් ජනනය කර එය Image3D[] ශ්‍රිතය භාවිතයෙන් ප්‍රදර්ශනය කළ හැක.

traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1;   (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1;   (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]

භූ කම්පන දත්ත ඝනකයක ත්‍රිමාණ රූපය. (සිරස් අක්ෂය - ගැඹුර)


උනන්දුවෙහි භූ විද්‍යාත්මක ලක්ෂණ දැඩි භූ කම්පන විෂමතා ඇති කරයි නම්, විනිවිදභාවය සහිත දෘශ්‍යකරණ මෙවලම් භාවිතා කළ හැකිය. පටිගත කිරීමේ "වැදගත් නොවන" ප්‍රදේශ නොපෙනෙන බවට පත් කළ හැකි අතර, විෂමතා පමණක් දෘශ්‍යමාන වේ. Wolfram Mathematica හි මෙය භාවිතා කළ හැකිය පාරාන්ධතාව[] и Raster3D[].

data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]}, 
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]

පාරාන්ධතාවය[] සහ Raster3D[] ශ්‍රිත භාවිතා කරමින් භූ කම්පන දත්ත ඝනක රූපය

කෘතිම උදාහරණයේ දී මෙන්, මුල් ඝනකයේ කොටස් මත විචල්ය සහන සහිත සමහර භූගෝලීය මායිම් (ස්ථර) හඳුනාගත හැකිය.

වර්ණාවලි විශ්ලේෂණය සඳහා ප්රධාන මෙවලම වන්නේ ෆූරියර් පරිවර්තනයයි. එහි ආධාරයෙන්, ඔබට එක් එක් හෝඩුවාවක් හෝ ලුහුබැඳීම් සමූහයක විස්තාරය-සංඛ්‍යාත වර්ණාවලිය ඇගයීමට ලක් කළ හැකිය. කෙසේ වෙතත්, සංඛ්‍යාත වසම වෙත දත්ත මාරු කිරීමෙන් පසු, සංඛ්‍යාතය වෙනස් වන්නේ කුමන කාලවලදී (කිනම් ගැඹුරකින් කියවන්න) යන්න පිළිබඳ තොරතුරු නැති වී යයි. කාල (ගැඹුර) අක්ෂයේ සංඥා වෙනස්වීම් ස්ථානගත කිරීමට හැකි වීම සඳහා, ජනේල සහිත ෆූරියර් පරිවර්තනය සහ තරංග වියෝජනය භාවිතා වේ. මෙම ලිපිය තරංග වියෝජනය භාවිතා කරයි. තරංග විශ්ලේෂණ තාක්ෂණය 90 ගණන්වල භූ කම්පන ගවේෂණයේදී සක්‍රීයව භාවිතා කිරීමට පටන් ගත්තේය. ජනේල සහිත ෆූරියර් පරිණාමනයට වඩා වාසිය වඩා හොඳ කාල විභේදනය ලෙස සැලකේ.

පහත කේත කොටස භාවිතා කරමින්, ඔබට භූ කම්පන අංශු වලින් එකක් තනි සංරචක වලට වියෝජනය කළ හැකිය:

cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]

හෝඩුවාවක් සංරචක බවට වියෝජනය කිරීම


විවිධ තරංග පැමිණීමේ වේලාවන්හි පරාවර්තන ශක්තිය බෙදා හරින ආකාරය තක්සේරු කිරීම සඳහා, ස්කොලොග්‍රෑම් (වර්ණාවලීක්ෂයකට සමාන) භාවිතා වේ. රීතියක් ලෙස, ප්රායෝගිකව සියලුම සංරචක විශ්ලේෂණය කිරීම අවශ්ය නොවේ. සාමාන්යයෙන්, අඩු, මධ්යම සහ ඉහළ සංඛ්යාත සංරචක තෝරා ගනු ලැබේ.

freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]

Scalogram. කාර්යය ප්රතිඵලය WaveletScalogram[]


Wolfram භාෂාව තරංග පරිවර්තනය සඳහා ශ්‍රිතය භාවිතා කරයි අඛණ්ඩ තරංග පරිවර්තනය[]. තවද මෙම ශ්‍රිතය සම්පූර්ණ හෝඩුවාවන් කට්ටලයට යෙදීම ශ්‍රිතය භාවිතයෙන් සිදු කෙරේ වගුව[]. මෙහිදී Wolfram Mathematica හි එක් ශක්තීන් සඳහන් කිරීම වටී - සමාන්තරකරණය භාවිතා කිරීමේ හැකියාව සමාන්තර වගුව[]. ඉහත උදාහරණයේ දී, සමාන්තරකරණයක් අවශ්‍ය නොවේ - දත්ත පරිමාව විශාල නොවේ, නමුත් ලක්ෂ සංඛ්‍යාත හෝඩුවාවන් අඩංගු පර්යේෂණාත්මක දත්ත කට්ටල සමඟ වැඩ කරන විට, මෙය අවශ්‍ය වේ.

tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}]; 

කාර්යය යෙදීමෙන් පසු අඛණ්ඩ තරංග පරිවර්තනය[] තෝරාගත් සංඛ්‍යාතවලට අනුරූපව නව දත්ත කට්ටල දිස්වේ. ඉහත උදාහරණයේ, මෙම සංඛ්‍යාත වන්නේ: 38Hz, 33Hz, 27Hz. සංඛ්‍යාත තෝරා ගැනීම බොහෝ විට සිදු කරනු ලබන්නේ පරීක්ෂණ පදනම මත ය - ඔවුන් විවිධ සංඛ්‍යාත සංයෝජන සඳහා ඵලදායි සිතියම් ලබා ගන්නා අතර භූ විද්‍යා ologist යෙකුගේ දෘෂ්ටිකෝණයෙන් වඩාත් තොරතුරු සහිත එකක් තෝරා ගනී.

ඔබට සගයන් සමඟ ප්‍රතිඵල බෙදා ගැනීමට හෝ ඒවා පාරිභෝගිකයාට ලබා දීමට අවශ්‍ය නම්, ඔබට GeologyIO පැකේජයේ SEGYExport[] ශ්‍රිතය භාවිත කළ හැක.

outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];

මෙම කැට තුනකින් (අඩු සංඛ්‍යාත, මධ්‍ය සංඛ්‍යාත සහ අධි-සංඛ්‍යාත සංරචක), RGB මිශ්‍රණය සාමාන්‍යයෙන් දත්ත එකට දෘශ්‍යමාන කිරීමට භාවිතා කරයි. සෑම සංරචකයකටම එහි වර්ණය පවරා ඇත - රතු, කොළ, නිල්. Wolfram Mathematica හි මෙය ශ්‍රිතය භාවිතයෙන් කළ හැක ColorCombine[].

එහි ප්‍රතිඵලය වන්නේ භූ විද්‍යාත්මක අර්ථ නිරූපණය කළ හැකි රූපයි. කොටසේ සටහන් කර ඇති වංගු මඟින් ජලාශ වීමට වැඩි ඉඩක් ඇති සහ තෙල් සංචිත අඩංගු පැලියෝචනල් නිරූපණය කිරීමට හැකි වේ. එවැනි ගංගා පද්ධතියක නවීන ප්‍රතිසමයන් සෙවීම සහ විශ්ලේෂණය මඟින් වංගු වල වඩාත් පොරොන්දු වූ කොටස් තීරණය කිරීමට අපට ඉඩ සලසයි. නාලිකා හොඳින් වර්ග කරන ලද වැලිගල් ඝන ස්ථරවලින් සංලක්ෂිත වන අතර තෙල් සඳහා හොඳ ජලාශයකි. "ලේස්" විෂමතාවයෙන් පිටත ප්රදේශ නවීන ගංවතුර තැන්පතු වලට සමාන වේ. ගංවතුර තැන්පතු ප්රධාන වශයෙන් මැටි පාෂාණවලින් නියෝජනය වන අතර මෙම කලාපවලට කැණීම අකාර්යක්ෂම වනු ඇත.

දත්ත ඝනකයේ RGB පෙත්ත. මධ්‍යයේ (මැදට මඳක් වම් පසින්) ඔබට වංගු සහිත ගංගාව සොයාගත හැකිය.

දත්ත ඝනකයේ RGB පෙත්ත. වම් පසින් ඔබට වංගු සහිත ගංගාව සොයාගත හැකිය.


සමහර අවස්ථාවලදී, භූ කම්පන දත්තවල ගුණාත්මක භාවය සැලකිය යුතු ලෙස පැහැදිලි රූප සඳහා ඉඩ සලසයි. මෙය ක්ෂේත්රයේ වැඩ ක්රමවේදය මත රඳා පවතී, ශබ්දය අඩු කිරීමේ ඇල්ගොරිතම භාවිතා කරන උපකරණ. එවැනි අවස්ථාවන්හිදී, ගංගා පද්ධතිවල කොටස් පමණක් නොව, සමස්ත දිගු පැලියෝ-ගංගා ද දැකිය හැකිය.

භූ කම්පන දත්ත ඝනකයක් (තිරස් පෙත්තක්) සංරචක තුනක් RGB මිශ්ර කිරීම. ගැඹුර ආසන්න වශයෙන් කිලෝමීටර 2 කි.

සරතොව් අසල වොල්ගා ගඟේ චන්ද්‍රිකා රූපය

නිගමනය

Wolfram Mathematica ඔබට භූ කම්පන දත්ත විශ්ලේෂණය කිරීමට සහ ඛනිජ ගවේෂණයට අදාළ ව්‍යවහාරික ගැටළු විසඳීමට ඉඩ සලසයි, සහ GeologyIO පැකේජය මෙම ක්‍රියාවලිය වඩාත් පහසු කරයි. භූ කම්පන දත්තවල ව්‍යුහය ගණනය කිරීම් වේගවත් කිරීම සඳහා ගොඩනඟන ලද ක්‍රම භාවිතා කරයි (සමාන්තර වගුව[], ParallelDo[],...) ඉතා කාර්යක්ෂම වන අතර ඔබට විශාල දත්ත ප්‍රමාණයක් සැකසීමට ඉඩ සලසයි. බොහෝ දුරට, GeologyIO පැකේජයේ දත්ත ගබඩා කිරීමේ විශේෂාංග මගින් මෙය පහසු කරනු ලැබේ. මාර්ගය වන විට, පැකේජය භාවිතා කළ හැක්කේ ව්යවහාරික භූ කම්පන ගවේෂණ ක්ෂේත්රයේ පමණක් නොවේ. ගොඩබිම විනිවිද යන රේඩාර් සහ භූ කම්පන විද්‍යාවේදී එකම වර්ගයේ දත්ත භාවිතා වේ. ඔබට ප්‍රතිඵලය වැඩි දියුණු කරන්නේ කෙසේද යන්න පිළිබඳ යෝජනා තිබේ නම්, Wolfram Mathematica අවි ගබඩාවේ සංඥා විශ්ලේෂණ ඇල්ගොරිතම එවැනි දත්ත සඳහා අදාළ වේ, නැතහොත් ඔබට කිසියම් විවේචනාත්මක අදහස් තිබේ නම්, කරුණාකර අදහස් දක්වන්න.

මූලාශ්රය: www.habr.com