جیو فزکس میں وولفرم ریاضی

بلاگ کے مصنف کا شکریہ انتون ایکی مینکو اس کی رپورٹ کے لیے

تعارف

یہ نوٹ کانفرنس کے تناظر میں لکھا گیا تھا۔ Wolfram روسی ٹیکنالوجی کانفرنس اور میری دی گئی رپورٹ کا خلاصہ شامل ہے۔ یہ تقریب جون میں سینٹ پیٹرزبرگ میں ہوئی تھی۔ اس بات پر غور کرتے ہوئے کہ میں کانفرنس سائٹ سے ایک بلاک پر کام کرتا ہوں، میں اس تقریب میں شرکت کے لیے مدد نہیں کر سکا۔ 2016 اور 2017 میں، میں نے کانفرنس کی رپورٹس سنی، اور اس سال میں نے ایک پریزنٹیشن دی۔ سب سے پہلے، ایک دلچسپ (یہ مجھے لگتا ہے) موضوع سامنے آیا ہے، جس کے ساتھ ہم ترقی کر رہے ہیں۔ کریل بیلوفاور دوسرا، پابندیوں کی پالیسی سے متعلق روسی فیڈریشن کی قانون سازی کے ایک طویل مطالعہ کے بعد، جس انٹرپرائز میں میں کام کرتا ہوں، زیادہ سے زیادہ دو لائسنس سامنے آئے۔ وولفرم میتھیمیٹا.

اپنی تقریر کے موضوع پر جانے سے پہلے، میں اس تقریب کی اچھی تنظیم کو نوٹ کرنا چاہوں گا۔ کانفرنس کا دورہ کرنے والا صفحہ کازان کیتھیڈرل کی تصویر استعمال کرتا ہے۔ کیتھیڈرل سینٹ پیٹرزبرگ کے اہم پرکشش مقامات میں سے ایک ہے اور جس ہال میں کانفرنس ہوئی تھی اس سے بہت واضح طور پر دکھائی دیتا ہے۔

سینٹ پیٹرزبرگ اسٹیٹ اکنامک یونیورسٹی کے داخلی راستے پر، شرکاء سے طلباء میں سے معاونین نے ملاقات کی - انہوں نے انہیں کھونے نہیں دیا۔ رجسٹریشن کے دوران، چھوٹے تحائف دیے گئے (ایک کھلونا - ایک چمکتا ہوا اسپائک، ایک قلم، وولفرام کی علامتوں والے اسٹیکرز)۔ کانفرنس کے شیڈول میں لنچ اور کافی کا وقفہ بھی شامل تھا۔ میں نے پہلے ہی گروپ کی دیوار پر لذیذ کافی اور پائی کے بارے میں نوٹ کیا ہے - شیف بہت اچھے ہیں۔ اس تعارفی حصے کے ساتھ، میں اس بات پر زور دینا چاہوں گا کہ واقعہ خود، اس کی شکل اور مقام پہلے سے ہی مثبت جذبات کو جنم دے رہے ہیں۔

میرے اور کریل بیلوف کی طرف سے تیار کردہ رپورٹ کا نام ہے "استعمال شدہ جیو فزکس میں مسائل کو حل کرنے کے لیے وولفرم ریاضی کا استعمال۔ زلزلہ کے اعداد و شمار یا "جہاں قدیم دریا بہتے تھے۔" رپورٹ کا مواد دو حصوں پر محیط ہے: پہلا، الگورتھم کا استعمال وولفرم میتھیمیٹا جیو فزیکل ڈیٹا کا تجزیہ کرنے کے لیے، اور دوسرا، یہ ہے کہ جیو فزیکل ڈیٹا کو وولفرم میتھیمیٹیکا میں کیسے ڈالا جائے۔

سیسمک ایکسپلوریشن

پہلے آپ کو جیو فزکس میں ایک مختصر سیر کرنے کی ضرورت ہے۔ جیو فزکس وہ سائنس ہے جو چٹانوں کی طبعی خصوصیات کا مطالعہ کرتی ہے۔ ٹھیک ہے، چونکہ چٹانوں میں مختلف خصوصیات ہیں: برقی، مقناطیسی، لچکدار، اس لیے جیو فزکس کے متعلقہ طریقے ہیں: الیکٹریکل اسپیکٹنگ، میگنیٹک پراسپیکٹنگ، سیسمک پراسپیکٹنگ... اس آرٹیکل کے تناظر میں، ہم صرف زلزلے کے امکانات پر مزید تفصیل سے بات کریں گے۔ تیل اور گیس کی تلاش کا بنیادی طریقہ زلزلہ کی تلاش ہے۔ یہ طریقہ لچکدار کمپن کی حوصلہ افزائی اور مطالعہ کے علاقے کو تشکیل دینے والی چٹانوں سے ردعمل کی ریکارڈنگ پر مبنی ہے۔ کمپن زمین پر (بارود یا لچکدار کمپن کے غیر دھماکہ خیز کمپن ذرائع کے ساتھ) یا سمندر میں (ایئر گن کے ساتھ) پرجوش ہوتی ہے۔ لچکدار کمپن چٹان کے بڑے پیمانے پر پھیلتی ہے، مختلف خصوصیات کے ساتھ تہوں کی حدود میں ریفریکٹ اور منعکس ہوتی ہے۔ انعکاس شدہ لہریں سطح پر واپس آتی ہیں اور زمین پر جیو فونز (عموماً الیکٹرو ڈائنامک ڈیوائسز جو کنڈلی میں معلق مقناطیس کی حرکت پر مبنی ہوتی ہیں) یا سمندر میں ہائیڈرو فونز (پیزو الیکٹرک اثر کی بنیاد پر) ریکارڈ کی جاتی ہیں۔ لہروں کی آمد کے وقت، کوئی بھی ارضیاتی تہوں کی گہرائی کا اندازہ لگا سکتا ہے۔

سیسمک برتن کھینچنے کا سامان


ایئر گن لچکدار کمپن کو جوش دیتی ہے۔


لہریں چٹان کے بڑے پیمانے پر گزرتی ہیں اور ہائیڈروفونز کے ذریعہ ریکارڈ کی جاتی ہیں۔


جیو فزیکل سروے کا تحقیقی جہاز "ایوان گبکن" سینٹ پیٹرزبرگ میں بلاگوویشچینسکی پل کے قریب گھاٹ پر

سیسمک سگنل ماڈل

چٹانوں میں مختلف جسمانی خصوصیات ہیں۔ زلزلہ کی تلاش کے لیے، لچکدار خصوصیات بنیادی طور پر اہم ہیں - لچکدار کمپن اور کثافت کے پھیلاؤ کی رفتار۔ اگر دو تہوں میں ایک جیسی یا ایک جیسی خصوصیات ہیں، تو لہر ان کے درمیان کی حد کو "نوٹ نہیں کرے گی"۔ اگر تہوں میں لہر کی رفتار مختلف ہوتی ہے، تو انعکاس تہوں کی باؤنڈری پر ہوگا۔ خواص میں جتنا زیادہ فرق ہوگا، عکاسی اتنی ہی شدید ہوگی۔ اس کی شدت کا تعین ریفلیکشن گتانک (rc):

جہاں ρ پتھر کی کثافت ہے، ν لہر کی رفتار ہے، 1 اور 2 اوپری اور نچلی تہوں کی نشاندہی کرتے ہیں۔

سب سے آسان اور کثرت سے استعمال ہونے والے سیسمک سگنل ماڈلز میں سے ایک کنولوشن ماڈل ہے، جب ریکارڈ شدہ سیسمک ٹریس کو پروبنگ پلس کے ساتھ عکاسی گتانک کے تسلسل کے کنولیشن کے نتیجے کے طور پر پیش کیا جاتا ہے:

کہاں s(t) — سیسمک ٹریس، یعنی ہر وہ چیز جو ہائیڈرو فون یا جیو فون کے ذریعے ریکارڈنگ کے ایک مقررہ وقت کے دوران ریکارڈ کی گئی تھی، w(t) - ایئر گن سے پیدا ہونے والا سگنل، n(t) - بے ترتیب شور.

آئیے مثال کے طور پر ایک مصنوعی سیسمک ٹریس کا حساب لگاتے ہیں۔ ہم ابتدائی سگنل کے طور پر ریکر پلس کا استعمال کریں گے، جو زلزلے کی تلاش میں وسیع پیمانے پر استعمال ہوتی ہے۔

length=0.050; (*Signal lenght*)
dt=0.001;(*Sample rate of signal*)
t=Range[-length/2,(length)/2,dt];(*Signal time*)
f=35;(*Central frequency*)
wavelet=(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)];
ListLinePlot[wavelet, Frame->True,PlotRange->Full,Filling->Axis,PlotStyle->Black,
PlotLabel->Style["Initial wavelet",Black,20],
LabelStyle->Directive[Black,Italic],
FillingStyle->{White,Black},ImageSize->Large,InterpolationOrder->2]

ابتدائی سیسمک امپلس


ہم 300 ms اور 600 ms کی گہرائی میں دو حدود طے کریں گے، اور ریفلیکشن گتانک بے ترتیب نمبر ہوں گے۔

rcExample=ConstantArray[0,1000];
rcExample[[300]]=RandomReal[{-1,0}];
rcExample[[600]]=RandomReal[{0,1}];
ListPlot[rcExample,Filling->0,Frame->True,Axes->False,PlotStyle->Black,
PlotLabel->Style["Reflection Coefficients",Black,20],
LabelStyle->Directive[Black,Italic]]

ریفلیکشن گتانک کی ترتیب


آئیے سیسمک ٹریس کا حساب لگائیں اور ڈسپلے کریں۔ چونکہ عکاسی کے گتانک میں مختلف علامات ہوتے ہیں، اس لیے ہمیں زلزلے کے نشان پر دو باری باری مظاہر ملتے ہیں۔

traceExamle=ListConvolve[wavelet[[1;;;;1]],rcExample];
ListPlot[traceExamle,
PlotStyle->Black,Filling->0,Frame->True,Axes->False,
PlotLabel->Style["Seismic trace",Black,20],
LabelStyle->Directive[Black,Italic]]

نقلی ٹریک


اس مثال کے لئے، یہ ایک بکنگ کرنے کے لئے ضروری ہے - حقیقت میں، تہوں کی گہرائی کا تعین کیا جاتا ہے، کورس کے، میٹر میں، اور زلزلہ ٹریس کا حساب وقت ڈومین کے لئے ہوتا ہے. گہرائیوں کو میٹر میں سیٹ کرنا اور تہوں میں رفتار کو جانتے ہوئے آمد کے اوقات کا حساب لگانا زیادہ درست ہوگا۔ اس صورت میں، میں نے فوری طور پر پرتوں کو وقت کے محور پر سیٹ کیا۔

اگر ہم فیلڈ ریسرچ کے بارے میں بات کرتے ہیں، تو اس طرح کے مشاہدات کے نتیجے میں اسی طرح کی ٹائم سیریز (زلزلے کے نشانات) کی ایک بڑی تعداد ریکارڈ کی جاتی ہے. مثال کے طور پر، 25 کلومیٹر لمبی اور 15 کلومیٹر چوڑی سائٹ کا مطالعہ کرتے وقت، جہاں، کام کے نتیجے میں، ہر ٹریس 25x25 میٹر کی پیمائش کرنے والے سیل کی خصوصیت کرتا ہے (ایسے سیل کو بن کہا جاتا ہے)، حتمی ڈیٹا اری میں 600000 نشانات ہوں گے۔ 1 ایم ایس کے نمونے لینے کے وقت اور 5 سیکنڈ کے ریکارڈنگ کے وقت کے ساتھ، حتمی ڈیٹا فائل 11 جی بی سے زیادہ ہو گی، اور اصل "خام" مواد کا حجم سینکڑوں گیگا بائٹس ہو سکتا ہے۔

ان کے ساتھ کام کرنے کا طریقہ وولفرم میتھیمیٹا?

پیکیج جیولوجی آئی او

پیکج کی ترقی کا آغاز ہوا۔ سوال روسی بولنے والے سپورٹ گروپ کی VK دیوار پر۔ کمیونٹی کے جوابات کی بدولت بہت جلد ایک حل مل گیا۔ اور نتیجے کے طور پر، یہ ایک سنگین ترقی میں اضافہ ہوا. متعلقہ وولفرم کمیونٹی وال پوسٹ یہاں تک کہ اسے ماڈریٹرز نے بھی نشان زد کیا۔ فی الحال، پیکیج درج ذیل ڈیٹا کی اقسام کے ساتھ کام کرنے کی حمایت کرتا ہے جو ارضیاتی صنعت میں فعال طور پر استعمال ہوتے ہیں:

1. ZMAP اور IRAP فارمیٹس میں نقشہ کے ڈیٹا کی درآمد
2. ایل اے ایس فارمیٹ کنویں میں پیمائش کی درآمد
3. سیسمک فائلوں کی شکل کا ان پٹ اور آؤٹ پٹ SEGY

پیکج کو انسٹال کرنے کے لیے، آپ کو اسمبل شدہ پیکج کے ڈاؤن لوڈ پیج پر دی گئی ہدایات پر عمل کرنا ہوگا، یعنی کسی بھی میں درج ذیل کوڈ پر عمل کریں۔ ریاضی کی نوٹ بک:

If[PacletInformation["GeologyIO"] === {}, PacletInstall[URLDownload[
    "https://wolfr.am/FiQ5oFih", 
    FileNameJoin[{CreateDirectory[], "GeologyIO-0.2.2.paclet"}]
]]]

جس کے بعد پیکیج ڈیفالٹ فولڈر میں انسٹال ہو جائے گا، جس کا راستہ درج ذیل حاصل کیا جا سکتا ہے۔

FileNameJoin[{$UserBasePacletsDirectory, "Repository"}]

مثال کے طور پر، ہم پیکیج کی اہم صلاحیتوں کا مظاہرہ کریں گے۔ کال روایتی طور پر Wolfram Language میں پیکجز کے لیے کی جاتی ہے:

Get["GeologyIO`"]

پیکیج کا استعمال کرتے ہوئے تیار کیا گیا ہے۔ وولفرم ورک بینچ. یہ آپ کو دستاویزات کے ساتھ پیکیج کی اہم فعالیت کے ساتھ جانے کی اجازت دیتا ہے، جو کہ پریزنٹیشن فارمیٹ کے لحاظ سے خود Wolfram Mathematica کی دستاویزات سے مختلف نہیں ہے، اور پہلے جاننے والے کے لیے ٹیسٹ فائلوں کے ساتھ پیکیج فراہم کرتا ہے۔

اس طرح کی فائل، خاص طور پر، "Marmousi.segy" فائل ہے - یہ ارضیاتی حصے کا مصنوعی ماڈل ہے، جسے فرانسیسی پیٹرولیم انسٹی ٹیوٹ نے تیار کیا تھا۔ اس ماڈل کا استعمال کرتے ہوئے، ڈویلپرز ویو فیلڈ ماڈلنگ، ڈیٹا پروسیسنگ، سیسمک ٹریس انورسیشن وغیرہ کے لیے اپنے الگورتھم کی جانچ کرتے ہیں۔ مارموسی ماڈل خود اس ذخیرہ میں محفوظ ہے جہاں سے پیکیج خود ڈاؤن لوڈ کیا گیا تھا۔ فائل حاصل کرنے کے لیے، درج ذیل کوڈ کو چلائیں:

If[Not[FileExistsQ["Marmousi.segy"]], 
URLDownload["https://wolfr.am/FiQGh7rk", "Marmousi.segy"];]
marmousi = SEGYImport["Marmousi.segy"]

نتیجہ درآمد کریں - SEGYData آبجیکٹ


SEGY فارمیٹ میں مشاہدات کے بارے میں مختلف معلومات کو ذخیرہ کرنا شامل ہے۔ سب سے پہلے، یہ ٹیکسٹ تبصرے ہیں. اس میں کام کے مقام، پیمائش کرنے والی کمپنیوں کے نام وغیرہ کے بارے میں معلومات شامل ہیں۔ ہمارے معاملے میں، اس ہیڈر کو ٹیکسٹ ہیڈر کلید کے ساتھ ایک درخواست کے ذریعے بلایا جاتا ہے۔ یہاں ایک مختصر متن کا ہیڈر ہے:

Short[marmousi["TextHeader"]]

"مارموسی ڈیٹا سیٹ انسٹی ٹیوٹ میں تیار کیا گیا تھا ...کم از کم رفتار 1500 m/s اور زیادہ سے زیادہ 5500 m/s)"

آپ "ٹریسز" کلید کا استعمال کرتے ہوئے زلزلے کے نشانات تک رسائی حاصل کر کے اصل ارضیاتی ماڈل کو ظاہر کر سکتے ہیں (پیکج کی ایک خصوصیت یہ ہے کہ کیز غیر حساس ہیں):

ArrayPlot[Transpose[marmousi["traces"]], PlotTheme -> "Detailed"]

ماڈل مارموسی۔


فی الحال، پیکج آپ کو بڑی فائلوں کے پرزوں میں ڈیٹا لوڈ کرنے کی بھی اجازت دیتا ہے، جس سے ان فائلوں پر کارروائی ممکن ہو جاتی ہے جن کا سائز دسیوں گیگا بائٹس تک پہنچ سکتا ہے۔ پیکج کے فنکشنز میں ڈیٹا کو .segy میں ایکسپورٹ کرنے اور فائل کے آخر میں جزوی طور پر شامل کرنے کے فنکشن بھی شامل ہیں۔

علیحدہ طور پر، یہ .segy فائلوں کے پیچیدہ ڈھانچے کے ساتھ کام کرتے وقت پیکیج کی فعالیت کو نوٹ کرنے کے قابل ہے۔ چونکہ یہ آپ کو کلیدوں اور اشاریہ جات کا استعمال کرتے ہوئے نہ صرف انفرادی نشانات اور ہیڈر تک رسائی حاصل کرنے کی اجازت دیتا ہے بلکہ انہیں تبدیل کرنے اور پھر انہیں فائل میں لکھنے کی بھی اجازت دیتا ہے۔ GeologyIO کے نفاذ کی بہت سی تکنیکی تفصیلات اس مضمون کے دائرہ کار سے باہر ہیں اور شاید ایک الگ وضاحت کی مستحق ہیں۔

سیسمک ایکسپلوریشن میں سپیکٹرل تجزیہ کی مطابقت

Wolfram Mathematica میں سیسمک ڈیٹا درآمد کرنے کی صلاحیت آپ کو تجرباتی ڈیٹا کے لیے بلٹ ان سگنل پروسیسنگ کی فعالیت کو استعمال کرنے کی اجازت دیتی ہے۔ چونکہ ہر سیسمک ٹریس ایک ٹائم سیریز کی نمائندگی کرتا ہے، اس لیے ان کا مطالعہ کرنے کا ایک اہم ٹول سپیکٹرل تجزیہ ہے۔ سیسمک ڈیٹا کی فریکوئنسی کمپوزیشن کا تجزیہ کرنے کے لیے ضروری شرائط میں سے، ہم مثال کے طور پر درج ذیل نام دے سکتے ہیں:

1. مختلف قسم کی لہریں مختلف فریکوئنسی کی ساخت کی طرف سے خصوصیات ہیں. یہ آپ کو مفید لہروں کو نمایاں کرنے اور مداخلت کی لہروں کو دبانے کی اجازت دیتا ہے۔
2. چٹان کی خصوصیات جیسے پورسٹی اور سنترپتی تعدد کی ساخت کو متاثر کر سکتی ہیں۔ اس سے بہترین خصوصیات والی چٹانوں کی شناخت ممکن ہو جاتی ہے۔
3. مختلف موٹائی والی پرتیں مختلف تعدد کی حدود میں بے ضابطگیوں کا سبب بنتی ہیں۔

تیسرا نکتہ اس مضمون کے تناظر میں اہم ہے۔ ذیل میں مختلف موٹائی والی پرت کی صورت میں زلزلے کے نشانات کا حساب لگانے کے لیے ایک کوڈ کا ٹکڑا ہے - ایک ویج ماڈل۔ اس ماڈل کا روایتی طور پر زلزلہ کی تلاش میں مطالعہ کیا جاتا ہے تاکہ مداخلت کے اثرات کا تجزیہ کیا جا سکے جب کئی تہوں سے منعکس ہونے والی لہریں ایک دوسرے پر لگائی جاتی ہیں۔

nx=200;(* Number of grid points in X direction*)
ny=200;(* Number of grid points in Y direction*)
T=2;(*Total propagation time*)
(*Velocity and density*)
modellv=Table[4000,{i,1,ny},{j,1,nx}];(* P-wave velocity in m/s*)
rho=Table[2200,{i,1,ny},{j,1,nx}];(* Density in g/cm^3, used constant density*)
Table[modellv[[150-Round[i*0.5];;,i]]=4500;,{i,1,200}];
Table[modellv[[;;70,i]]=4500;,{i,1,200}];
(*Plotting model*)
MatrixPlot[modellv,PlotLabel->Style["Model of layer",Black,20],
LabelStyle->Directive[Black,Italic]]

پنچ آؤٹ فارمیشن کا ماڈل


ویج کے اندر لہر کی رفتار 4500 m/s ہے، ویج کے باہر 4000 m/s، اور کثافت کو مستقل 2200 g/cm³ سمجھا جاتا ہے۔ اس طرح کے ماڈل کے لیے، ہم عکاسی کے گتانکوں اور زلزلے کے نشانات کا حساب لگاتے ہیں۔

rc=Table[N[(modellv[[All,i]]-PadLeft[modellv[[All,i]],201,4000][[1;;200]])/(modellv[[All,i]]+PadLeft[modellv[[All,i]],201,4500][[1;;200]])],{i,1,200}];
traces=Table[ListConvolve[wavelet[[1;;;;1]],rc[[i]]],{i,1,200}];
starttrace=10;
endtrace=200;
steptrace=10;
trasenum=Range[starttrace,endtrace,steptrace];
traserenum=Range[Length@trasenum];
tracedist=0.5;
Rotate[Show[
Reverse[Table[
	ListLinePlot[traces[[trasenum[[i]]]]*50+trasenum[[i]]*tracedist,Filling->{1->{trasenum[[i]]*tracedist,{RGBColor[0.97,0.93,0.68],Black}}},PlotStyle->Directive[Gray,Thin],PlotRange->Full,InterpolationOrder->2,Axes->False,Background->RGBColor[0.97,0.93,0.68]],
		{i,1,Length@trasenum}]],ListLinePlot[Transpose[{ConstantArray[45,80],Range[80]}],PlotStyle->Red],PlotRange->All,Frame->True],270Degree]

ویج ماڈل کے لیے زلزلے کے نشانات


اس اعداد و شمار میں دکھائے گئے زلزلے کے نشانات کی ترتیب کو سیسمک سیکشن کہا جاتا ہے۔ جیسا کہ آپ دیکھ سکتے ہیں، اس کی تشریح ایک بدیہی سطح پر بھی کی جا سکتی ہے، کیونکہ منعکس لہروں کی جیومیٹری واضح طور پر اس ماڈل سے مطابقت رکھتی ہے جس کی پہلے وضاحت کی گئی تھی۔ اگر آپ نشانات کا مزید تفصیل سے تجزیہ کریں، تو آپ دیکھیں گے کہ 1 سے تقریباً 30 نشانات میں فرق نہیں ہے - تشکیل کی چھت اور نیچے سے عکاسی ایک دوسرے کو اوورلیپ نہیں کرتی ہے۔ 31 ویں ٹریس سے شروع ہو کر، مظاہر مداخلت کرنا شروع کر دیتے ہیں۔ اور، اگرچہ ماڈل میں، عکاسی کے گتانک افقی طور پر تبدیل نہیں ہوتے ہیں - ساخت کی موٹائی میں تبدیلی کے ساتھ ہی زلزلے کے نشانات اپنی شدت کو تبدیل کرتے ہیں۔

آئیے تشکیل کی اوپری حد سے عکاسی کے طول و عرض پر غور کریں۔ 60ویں روٹ سے انعکاس کی شدت بڑھنے لگتی ہے اور 70ویں روٹ پر یہ زیادہ سے زیادہ ہو جاتی ہے۔ اس طرح چھت اور تہوں کے نیچے سے لہروں کی مداخلت خود کو ظاہر کرتی ہے، جس سے بعض صورتوں میں زلزلے کے ریکارڈ میں اہم بے ضابطگیاں پیدا ہوتی ہیں۔

ListLinePlot[GaussianFilter[Abs[traces[[All,46]]],3][[;;;;2]],
InterpolationOrder->2,Frame->True,PlotStyle->Black,
PlotLabel->Style["Amplitude of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
PlotRange->All]

پچر کے اوپری کنارے سے منعکس لہر کے طول و عرض کا گراف


یہ منطقی ہے کہ جب سگنل کم فریکوئنسی ہوتا ہے تو مداخلت بڑی تشکیل کی موٹائی پر ظاہر ہونا شروع ہوجاتی ہے، اور زیادہ تعدد سگنل کی صورت میں، مداخلت چھوٹی موٹائیوں پر ہوتی ہے۔ درج ذیل کوڈ کا ٹکڑا 35 ہرٹز، 55 ہرٹز اور 85 ہرٹز کی فریکوئنسی کے ساتھ ایک سگنل بناتا ہے۔

waveletSet=Table[(1.0-2.0*(Pi^2)*(f^2)*(t^2))*Exp[-(Pi^2)*(f^2)*(t^2)],
{f,{35,55,85}}];
ListLinePlot[waveletSet,PlotRange->Full,PlotStyle->Black,Frame->True,
PlotLabel->Style["Set of wavelets",Black,20],
LabelStyle->Directive[Black,Italic],
ImageSize->Large,InterpolationOrder->2]

35Hz، 55Hz، 85Hz کی فریکوئنسی کے ساتھ سورس سگنلز کا ایک سیٹ


زلزلہ کے نشانات کا حساب لگا کر اور عکاسی لہروں کے طول و عرض کے گراف کو پلاٹ کرنے سے، ہم دیکھ سکتے ہیں کہ مختلف تعدد کے لیے مختلف تشکیل کی موٹائیوں میں ایک بے ضابطگی دیکھی جاتی ہے۔

tracesSet=Table[ListConvolve[waveletSet[[j]][[1;;;;1]],rc[[i]]],{j,1,3},{i,1,200}];

lowFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[1]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
medFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[2]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];
highFreq=ListLinePlot[GaussianFilter[Abs[tracesSet[[3]][[All,46]]],3][[;;;;2]],InterpolationOrder->2,PlotStyle->Black,PlotRange->All];

Show[lowFreq,medFreq,highFreq,PlotRange->{{0,100},All},
PlotLabel->Style["Amplitudes of reflection",Black,20],
LabelStyle->Directive[Black,Italic],
Frame->True]

مختلف تعدد کے لیے پچر کے اوپری کنارے سے منعکس لہر کے طول و عرض کے گراف


زلزلہ کے مشاہدات کے نتائج سے تشکیل کی موٹائی کے بارے میں نتیجہ اخذ کرنے کی صلاحیت انتہائی مفید ہے، کیونکہ تیل کی تلاش میں ایک اہم کام کنواں بچھانے کے لیے سب سے زیادہ امید افزا نکات کا اندازہ لگانا ہے (یعنی وہ علاقے جہاں پر تشکیل ہوتی ہے۔ موٹا)۔ اس کے علاوہ، ارضیاتی سیکشن میں ایسی چیزیں ہوسکتی ہیں جن کی پیدائش کی وجہ سے تشکیل کی موٹائی میں تیز تبدیلی آتی ہے۔ یہ سپیکٹرل تجزیہ کو ان کے مطالعہ کے لیے ایک مؤثر ذریعہ بناتا ہے۔ مضمون کے اگلے حصے میں ہم ایسی ارضیاتی اشیاء پر مزید تفصیل سے غور کریں گے۔

تجرباتی ڈیٹا۔ آپ نے انہیں کہاں سے حاصل کیا اور ان میں کیا تلاش کرنا ہے؟

مضمون میں تجزیہ کردہ مواد مغربی سائبیریا میں حاصل کیے گئے تھے۔ یہ خطہ، جیسا کہ بغیر کسی استثناء کے شاید سبھی جانتے ہیں، ہمارے ملک کا تیل پیدا کرنے والا اہم خطہ ہے۔ گزشتہ صدی کے 60s میں خطے میں ذخائر کی فعال ترقی شروع ہوئی. تیل کے ذخائر کی تلاش کا بنیادی طریقہ زلزلہ کی تلاش ہے۔ اس علاقے کی سیٹلائٹ تصاویر کو دیکھنا دلچسپ ہے۔ چھوٹے پیمانے پر، آپ دلدلوں اور جھیلوں کی ایک بڑی تعداد کو نوٹ کر سکتے ہیں؛ نقشے کو بڑا کرکے، آپ کلسٹر کنواں کی کھدائی کی جگہیں دیکھ سکتے ہیں، اور نقشے کو حد تک بڑھا کر، آپ ان پروفائلز کی کلیئرنگ کو بھی الگ کر سکتے ہیں جن کے ساتھ زلزلہ مشاہدات کئے گئے.

Yandex نقشوں کی سیٹلائٹ تصویر - Noyabrsk شہر کا علاقہ


کھیتوں میں سے ایک پر کنواں پیڈ کا جال


مغربی سائبیریا کی تیل والی چٹانیں وسیع گہرائیوں میں پائی جاتی ہیں - 1 کلومیٹر سے 5 کلومیٹر تک۔ تیل پر مشتمل چٹانوں کا مرکزی حجم جراسک اور کریٹاسیئس دور میں تشکیل پایا تھا۔ جراسک دور شاید اسی نام کی فلم سے بہت سے لوگوں کو معلوم ہے۔ جراسک آب و ہوا جدید سے نمایاں طور پر مختلف تھا۔ انسائیکلوپیڈیا برٹانیکا میں پیلیومپس کی ایک سیریز ہے جو ہر ایک ہیلوجیکل دور کی خصوصیت رکھتی ہے۔

پیش کریں۔

جراسک دور


براہ کرم نوٹ کریں کہ جراسک دور میں، مغربی سائبیریا کا علاقہ ایک سمندری ساحل تھا (دریاؤں اور اتھلے سمندر سے گزرنے والی زمین)۔ چونکہ آب و ہوا آرام دہ تھی، اس لیے ہم فرض کر سکتے ہیں کہ اس وقت کا ایک عام منظر اس طرح نظر آتا تھا:

جراسک سائبیریا


اس تصویر میں جو چیز ہمارے لیے اہم ہے وہ جانور اور پرندے نہیں بلکہ پس منظر میں دریا کی تصویر ہے۔ دریا وہی ارضیاتی چیز ہے جسے ہم نے پہلے روکا تھا۔ حقیقت یہ ہے کہ دریاؤں کی سرگرمی اچھی طرح سے ترتیب شدہ ریت کے پتھروں کو جمع کرنے کی اجازت دیتی ہے، جو اس کے بعد تیل کے ذخائر بن جائیں گے۔ ان آبی ذخائر میں ایک عجیب، پیچیدہ شکل ہو سکتی ہے (جیسے ندی کے بستر) اور ان کی موٹائی متغیر ہوتی ہے - کناروں کے قریب موٹائی چھوٹی ہوتی ہے، لیکن چینل کے مرکز کے قریب یا درمیانی علاقوں میں یہ بڑھ جاتی ہے۔ لہذا، جراسک میں بننے والے دریا اب تقریباً تین کلومیٹر کی گہرائی میں ہیں اور تیل کے ذخائر کی تلاش کا مقصد ہیں۔

تجرباتی ڈیٹا۔ پروسیسنگ اور ویژولائزیشن

آئیے مضمون میں دکھائے گئے زلزلہ کے مواد کے بارے میں فوری طور پر ایک ریزرویشن کریں - اس حقیقت کی وجہ سے کہ تجزیہ کے لیے استعمال کیے گئے ڈیٹا کی مقدار اہم ہے - مضمون کے متن میں زلزلہ کے نشانات کے اصل سیٹ کا صرف ایک ٹکڑا شامل کیا گیا ہے۔ یہ کسی کو بھی مندرجہ بالا حسابات کو دوبارہ پیش کرنے کی اجازت دے گا۔

زلزلہ کے اعداد و شمار کے ساتھ کام کرتے وقت، ایک جیو فزیکسٹ عام طور پر خصوصی سافٹ ویئر استعمال کرتا ہے (انڈسٹری کے کئی رہنما ہیں جن کی ترقی کو فعال طور پر استعمال کیا جاتا ہے، مثال کے طور پر پیٹرل یا پیراڈیم)، جو آپ کو مختلف قسم کے ڈیٹا کا تجزیہ کرنے کی اجازت دیتا ہے اور اس کا ایک آسان گرافیکل انٹرفیس ہوتا ہے۔ تمام تر سہولتوں کے باوجود، اس قسم کے سافٹ ویئر میں اپنی خامیاں بھی ہیں - مثال کے طور پر، مستحکم ورژن میں جدید الگورتھم کے نفاذ میں کافی وقت لگتا ہے، اور خودکار حسابات کے امکانات عام طور پر محدود ہوتے ہیں۔ ایسی صورت حال میں، کمپیوٹر کے ریاضی کے نظام اور اعلیٰ سطحی پروگرامنگ زبانوں کا استعمال کرنا بہت آسان ہو جاتا ہے، جو کہ ایک وسیع الگورتھمک بنیاد کے استعمال کی اجازت دیتی ہیں اور ساتھ ہی، بہت زیادہ معمولات کو اپناتی ہیں۔ یہ وہی اصول ہے جو Wolfram Mathematica میں زلزلے کے اعداد و شمار کے ساتھ کام کرنے کے لیے استعمال ہوتا ہے۔ ڈیٹا کے ساتھ انٹرایکٹو کام کے لیے بھرپور فنکشنلٹی لکھنا نامناسب ہے - یہ زیادہ اہم ہے کہ عام طور پر قبول شدہ فارمیٹ سے لوڈنگ کو یقینی بنایا جائے، ان پر مطلوبہ الگورتھم کو لاگو کیا جائے اور انہیں واپس ایک بیرونی فارمیٹ میں اپ لوڈ کیا جائے۔

مجوزہ اسکیم کے بعد، ہم اصل سیسمک ڈیٹا لوڈ کریں گے اور ان میں ڈسپلے کریں گے۔ وولفرم میتھیمیٹا:

Get["GeologyIO`"]
seismic3DZipPath = "seismic3D.zip";
seismic3DSEGYPath = "seismic3D.sgy";
If[FileExistsQ[seismic3DZipPath], DeleteFile[seismic3DZipPath]];
If[FileExistsQ[seismic3DSEGYPath], DeleteFile[seismic3DSEGYPath]];
URLDownload["https://wolfr.am/FiQIuZuH", seismic3DZipPath];
ExtractArchive[seismic3DZipPath];
seismic3DSEGY = SEGYImport[seismic3DSEGYPath]

اس طرح سے ڈاؤن لوڈ اور امپورٹ کیا جانے والا ڈیٹا 10 بائی 5 کلومیٹر کے علاقے پر ریکارڈ کیے گئے راستے ہیں۔ اگر اعداد و شمار کو سہ جہتی سیسمک سروے کے طریقہ کار کا استعمال کرتے ہوئے حاصل کیا جاتا ہے (لہروں کو انفرادی جیو فزیکل پروفائلز کے ساتھ ریکارڈ نہیں کیا جاتا ہے، بلکہ پورے علاقے میں بیک وقت ریکارڈ کیا جاتا ہے)، تو سیسمک ڈیٹا کیوبز حاصل کرنا ممکن ہو جاتا ہے۔ یہ تین جہتی اشیاء ہیں، عمودی اور افقی حصے جن کے ارضیاتی ماحول کے تفصیلی مطالعہ کی اجازت دیتے ہیں۔ زیر غور مثال میں، ہم تین جہتی ڈیٹا کے ساتھ کام کر رہے ہیں۔ ہم ٹیکسٹ ہیڈر سے کچھ معلومات حاصل کر سکتے ہیں، اس طرح

StringPartition[seismic3DSEGY["textheader"], 80] // TableForm

C 1 یہ جیولوجیو پیکج ٹیسٹ کے لیے ڈیمو فائل ہے
سی 2
سی 3
سی 4
C 5 DATE صارف کا نام: WOLFRAM USER
C 6 سروے کا نام: سائبیریا میں کہیں
C 7 فائل ٹائپ تھری ڈی سیزمک والیوم
سی 8
سی 9
C10 Z رینج: پہلا 2200M آخری 2400M

یہ ڈیٹا سیٹ ہمارے لیے ڈیٹا کے تجزیہ کے اہم مراحل کو ظاہر کرنے کے لیے کافی ہوگا۔ فائل میں موجود نشانات کو ترتیب وار ریکارڈ کیا جاتا ہے اور ان میں سے ہر ایک مندرجہ ذیل شکل کی طرح نظر آتا ہے - یہ عمودی محور (گہرائی کے محور) کے ساتھ عکاس لہروں کے طول و عرض کی تقسیم ہے۔

ListLinePlot[seismic3DSEGY["traces"][[100]], InterpolationOrder -> 2, 
 PlotStyle -> Black, PlotLabel -> Style["Seismic trace", Black, 20],
 LabelStyle -> Directive[Black, Italic], PlotRange -> All, 
 Frame -> True, ImageSize -> 1200, AspectRatio -> 1/5]

سیسمک سیکشن کے نشانات میں سے ایک


یہ جانتے ہوئے کہ مطالعہ شدہ علاقے کی ہر سمت میں کتنے نشانات واقع ہیں، آپ تین جہتی ڈیٹا سرنی بنا سکتے ہیں اور اسے Image3D[] فنکشن کا استعمال کرتے ہوئے ڈسپلے کر سکتے ہیں۔

traces=seismic3DSEGY["traces"];
startIL=1050;EndIL=2000;stepIL=2; (*координата Х начала и конца съёмки и шаг трасс*)
startXL=1165;EndXL=1615;stepXL=2; (*координата Y начала и конца съёмки и шаг трасс*)
numIL=(EndIL-startIL)/stepIL+1;   (*количество трасс по оис Х*)
numXL=(EndXL-startXL)/stepIL+1;   (*количество трасс по оис Y*)
Image3D[ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}],ViewPoint->{-1, 0, 0},Background->RGBColor[0,0,0]]

سیسمک ڈیٹا کیوب کی XNUMXD تصویر۔ (عمودی محور - گہرائی)


اگر دلچسپی کی ارضیاتی خصوصیات شدید زلزلہ کی بے ضابطگیوں کو پیدا کرتی ہیں، تو شفافیت کے ساتھ تصور کے آلات استعمال کیے جا سکتے ہیں۔ ریکارڈنگ کے "غیر اہم" علاقوں کو پوشیدہ بنایا جا سکتا ہے، صرف بے ضابطگیوں کو نظر آتا ہے۔ Wolfram Mathematica میں یہ استعمال کر کے کیا جا سکتا ہے۔ دھندلاپن[] и Raster3D[].

data = ArrayReshape[Abs[traces/Max[Abs[traces[[All,1;;;;4]]]]],{numIL,numXL,101}];
Graphics3D[{Opacity[0.1], Raster3D[data, ColorFunction->"RainbowOpacity"]}, 
Boxed->False, SphericalRegion->True, ImageSize->840, Background->None]

Opacity[] اور Raster3D[] فنکشنز کا استعمال کرتے ہوئے سیسمک ڈیٹا کیوب امیج

جیسا کہ مصنوعی مثال میں ہے، اصل مکعب کے حصوں پر کوئی متغیر ریلیف کے ساتھ کچھ ارضیاتی حدود (پرتوں) کی شناخت کر سکتا ہے۔

سپیکٹرل تجزیہ کا بنیادی ٹول فوئیر ٹرانسفارم ہے۔ اس کی مدد سے، آپ ہر نشان یا نشانات کے گروپ کے طول و عرض-فریکوئنسی سپیکٹرم کا اندازہ لگا سکتے ہیں۔ تاہم، ڈیٹا کو فریکوئنسی ڈومین میں منتقل کرنے کے بعد، اس بارے میں معلومات ضائع ہو جاتی ہیں کہ کن اوقات میں (کس گہرائی میں پڑھیں) تعدد میں تبدیلی آتی ہے۔ وقت (گہرائی) محور پر سگنل کی تبدیلیوں کو لوکلائز کرنے کے لیے، ونڈو فوئیر ٹرانسفارم اور ویولیٹ سڑنے کا استعمال کیا جاتا ہے۔ اس مضمون میں ویولیٹ سڑن کا استعمال کیا گیا ہے۔ ویولیٹ تجزیہ ٹیکنالوجی 90 کی دہائی میں زلزلہ کی تلاش میں فعال طور پر استعمال ہونے لگی۔ ونڈو فوئیر ٹرانسفارم پر فائدہ بہتر ٹائم ریزولوشن سمجھا جاتا ہے۔

درج ذیل کوڈ کے ٹکڑے کا استعمال کرتے ہوئے، آپ زلزلے کے نشانات میں سے کسی ایک کو انفرادی اجزاء میں تحلیل کر سکتے ہیں:

cwd=ContinuousWaveletTransform[seismicSection["traces"][[100]]]
Show[
ListLinePlot[Re[cwd[[1]]],PlotRange->All],
ListLinePlot[seismicSection["traces"][[100]],
PlotStyle->Black,PlotRange->All],ImageSize->{1500,500},AspectRatio->Full,
PlotLabel->Style["Wavelet decomposition",Black,32],
LabelStyle->Directive[Black,Italic],
PlotRange->All,
Frame->True]

اجزاء میں ٹریس کا گلنا


اس بات کا اندازہ لگانے کے لیے کہ مختلف لہروں کی آمد کے اوقات میں عکاسی توانائی کیسے تقسیم ہوتی ہے، اسکیلوگرامس (ایک سپیکٹروگرام کے مشابہ) استعمال کیے جاتے ہیں۔ ایک اصول کے طور پر، عملی طور پر تمام اجزاء کا تجزیہ کرنے کی ضرورت نہیں ہے. عام طور پر، کم، درمیانی اور اعلی تعدد والے اجزاء کا انتخاب کیا جاتا ہے۔

freq=(500/(#*contWD["Wavelet"]["FourierFactor"]))&/@(Thread[{Range[contWD["Octaves"]],1}]/.contWD["Scales"])//Round;
ticks=Transpose[{Range[Length[freq]],freq}];
WaveletScalogram[contWD,Frame->True,FrameTicks->{{ticks,Automatic},Automatic},FrameTicksStyle->Directive[Orange,12],
FrameLabel->{"Time","Frequency(Hz)"},LabelStyle->Directive[Black,Bold,14],
ColorFunction->"RustTones",ImageSize->Large]

اسکیلوگرام۔ فنکشن کا نتیجہ ویولیٹ اسکیلوگرام[]


وولفرم لینگویج ویولیٹ ٹرانسفارمیشن کے لیے فنکشن کا استعمال کرتی ہے۔ مسلسل ویولیٹ ٹرانسفارم[]. اور ٹریس کے پورے سیٹ پر اس فنکشن کا اطلاق فنکشن کا استعمال کرتے ہوئے کیا جائے گا۔ ٹیبل[]. یہاں یہ بات قابل توجہ ہے کہ وولفرم میتھیمیٹیکا کی ایک طاقت - متوازی استعمال کرنے کی صلاحیت متوازی میز[]. مندرجہ بالا مثال میں، متوازی کی کوئی ضرورت نہیں ہے - ڈیٹا کا حجم بڑا نہیں ہے، لیکن جب تجرباتی ڈیٹا سیٹس کے ساتھ کام کرتے ہیں جس میں سینکڑوں ہزاروں نشانات ہوتے ہیں، تو یہ ایک ضرورت ہے۔

tracesCWD=Table[Map[Hilbert[#,0]&,Re[ContinuousWaveletTransform[traces[[i]]][[1]]][[{13,15,18}]]],{i,1,Length@traces}]; 

فنکشن لگانے کے بعد مسلسل ویولیٹ ٹرانسفارم[] نئے ڈیٹا سیٹ منتخب تعدد کے مطابق ظاہر ہوتے ہیں۔ اوپر کی مثال میں، یہ تعدد ہیں: 38Hz، 33Hz، 27Hz۔ تعدد کا انتخاب اکثر جانچ کی بنیاد پر کیا جاتا ہے - وہ مختلف تعدد کے امتزاج کے لیے موثر نقشے حاصل کرتے ہیں اور ماہر ارضیات کے نقطہ نظر سے سب سے زیادہ معلوماتی نقشے کا انتخاب کرتے ہیں۔

اگر آپ کو نتائج کو ساتھیوں کے ساتھ شیئر کرنے یا گاہک کو فراہم کرنے کی ضرورت ہے، تو آپ GeologyIO پیکج کا SEGYExport[] فنکشن استعمال کر سکتے ہیں۔

outputdata=seismic3DSEGY;
outputdata["traces",1;;-1]=tracesCWD[[All,3]];
outputdata["textheader"]="Wavelet Decomposition Result";
outputdata["binaryheader","NumberDataTraces"]=Length[tracesCWD[[All,3]]];
SEGYExport["D:result.segy",outputdata];

ان میں سے تین کیوبز (کم تعدد، درمیانی تعدد، اور اعلی تعدد اجزاء) کے ساتھ، RGB ملاوٹ عام طور پر ڈیٹا کو ایک ساتھ دیکھنے کے لیے استعمال ہوتی ہے۔ ہر جزو کو اپنا رنگ تفویض کیا جاتا ہے - سرخ، سبز، نیلا. Wolfram Mathematica میں یہ فنکشن کا استعمال کرتے ہوئے کیا جا سکتا ہے۔ کلر کمبائن[].

نتیجہ وہ تصاویر ہیں جن سے ارضیاتی تشریح کی جا سکتی ہے۔ سیکشن پر ریکارڈ کیے گئے مینڈرز پیلیو چینلز کو بیان کرنا ممکن بناتے ہیں، جن کے ذخائر ہونے کا امکان زیادہ ہوتا ہے اور ان میں تیل کے ذخائر ہوتے ہیں۔ اس طرح کے دریا کے نظام کے جدید ینالاگوں کی تلاش اور تجزیہ ہمیں مینڈرز کے سب سے زیادہ امید افزا حصوں کا تعین کرنے کی اجازت دیتا ہے۔ چینلز بذات خود اچھی طرح سے ترتیب دیے گئے بلوا پتھر کی موٹی تہوں کی خصوصیت رکھتے ہیں اور تیل کے لیے ایک اچھا ذخیرہ ہیں۔ "فیتے" کی بے ضابطگیوں سے باہر کے علاقے جدید سیلابی میدان کے ذخائر سے ملتے جلتے ہیں۔ فلڈ پلین کے ذخائر بنیادی طور پر مٹی کے پتھروں سے ظاہر ہوتے ہیں اور ان علاقوں میں ڈرلنگ غیر موثر ہو گی۔

ڈیٹا کیوب کا RGB ٹکڑا۔ بیچ میں (مرکز کے بائیں طرف تھوڑا سا) آپ گھومتے ہوئے دریا کا سراغ لگا سکتے ہیں۔

ڈیٹا کیوب کا RGB ٹکڑا۔ بائیں جانب آپ گھمبیر دریا کا سراغ لگا سکتے ہیں۔


بعض صورتوں میں، زلزلے کے اعداد و شمار کا معیار نمایاں طور پر واضح تصاویر کی اجازت دیتا ہے۔ یہ فیلڈ ورک کے طریقہ کار پر منحصر ہے، شور کو کم کرنے والے الگورتھم کے ذریعے استعمال ہونے والا سامان۔ ایسے معاملات میں، نہ صرف دریا کے نظام کے ٹکڑے نظر آتے ہیں، بلکہ پوری توسیع شدہ پیلیو دریا بھی نظر آتے ہیں۔

سیسمک ڈیٹا کیوب (افقی سلائس) کے تین اجزاء کا آر جی بی مکسنگ۔ گہرائی تقریباً 2 کلومیٹر۔

سراتوف کے قریب دریائے وولگا کی سیٹلائٹ تصویر

حاصل يہ ہوا

Wolfram Mathematica آپ کو سیسمک ڈیٹا کا تجزیہ کرنے اور معدنیات کی تلاش سے متعلق لاگو مسائل کو حل کرنے کی اجازت دیتا ہے، اور GeologyIO پیکیج اس عمل کو مزید آسان بناتا ہے۔ زلزلہ کے اعداد و شمار کی ساخت ایسی ہے کہ حساب کو تیز کرنے کے لیے بلٹ ان طریقوں کا استعمال کرتے ہوئے (متوازی میز[], ParallelDo[],…) بہت موثر ہے اور آپ کو بڑی مقدار میں ڈیٹا پر کارروائی کرنے کی اجازت دیتا ہے۔ بڑی حد تک، جیولوجی آئی او پیکج کی ڈیٹا اسٹوریج کی خصوصیات سے اس کی سہولت ہوتی ہے۔ ویسے، پیکج نہ صرف لاگو زلزلہ کی تلاش کے میدان میں استعمال کیا جا سکتا ہے. تقریباً ایک ہی قسم کے ڈیٹا کو گراؤنڈ پینیٹریٹنگ ریڈار اور سیسمولوجی میں استعمال کیا جاتا ہے۔ اگر آپ کے پاس نتائج کو بہتر بنانے کے بارے میں تجاویز ہیں، تو Wolfram Mathematica arsenal سے کون سے سگنل تجزیہ الگورتھم ایسے ڈیٹا پر لاگو ہوتے ہیں، یا اگر آپ کے پاس کوئی تنقیدی تبصرے ہیں، تو براہ کرم ایک تبصرہ چھوڑ دو

ماخذ: www.habr.com