Примена дистрибуираних услуга у Иандек.Цлоуд користећи Графану као пример

Здраво свима! У оквиру свог курса истраживао сам могућности такве домаће клауд платформе као што је Иандек.Цлоуд. Платформа нуди различите услуге за решавање практичних проблема. Међутим, понекад је потребно да поставите сопствену апликацију у облаку са прилично обимном инфраструктуром заснованом на овим услугама. У овом чланку желим да поделим своје искуство у примени такве апликације.

Шта желите да добијете?

Графана — моћан алат за решавање аналитичких проблема или праћење проблема било ког система. У својој основној конфигурацији, ово је виртуелна машина са Графана веб сервером, као и база података (ЦлицкХоусе, ИнфлукДБ, итд.) са скупом података на коме ће се базирати аналитика.

Након покретања виртуелне машине са веб сервером, можете отићи на њен хост и добити прелеп кориснички интерфејс, навести базе података као изворе за даљи рад, креирати контролне табле и графиконе.

Основна верзија има један значајан недостатак - уопште није отпорна на грешке. Односно, целокупна функционалност апликације зависи од одрживости једне виртуелне машине. Ако одбије или 10 људи истовремено отвори кориснички интерфејс, онда ће настати проблеми.

Они се могу једноставно решити: само треба да... поставите много идентичних виртуелних машина са веб сервером и поставите их под Л3 балансер. Али овде није све тако јасно. Графана складишти корисничка подешавања (путања до база података, контролне табле, графиконе, итд.) директно на диск своје виртуелне машине. Дакле, ако променимо нека подешавања у корисничком интерфејсу, ове промене ће се одразити само на виртуелној машини на коју нам је послао балансер. Ово ће довести до недоследних подешавања за нашу апликацију, што ће изазвати проблеме са покретањем и коришћењем.

Овде ће друга база података доћи у помоћ, на пример, МиСКЛ или његов еквивалент. Кажемо Графани да треба да чува корисничка подешавања у овој „резервној“ бази података. Након тога, биће довољно да на свакој машини једном наведете путању до ове базе података и уредите сва остала корисничка подешавања на било којој од виртуелних машина; она ће се проширити на остале.

Ево дијаграма коначне инфраструктуре апликације:

Научимо да подигнемо рукама

МиСКЛ и ЦлицкХоусе

Пре постављања такве апликације једним кликом на дугме, било је неопходно научити како да рукујете сваком од њених компоненти и да их интегришете једну са другом.

Овде ће нам помоћи Иандек.Цлоуд, који пружа Л3 балансере, ЦлицкХоусе и МиСКЛ као управљане услуге. Корисник само треба да одреди параметре и сачека док платформа све не доведе у радни ред.

Регистровао сам се, направио облак и налог за плаћање. Након тога, отишао сам у облак и поставио МиСКЛ и ЦлицкХоусе кластере са минималним подешавањима. Чекао сам док се не активирају.

Такође морате да запамтите да креирате базу података у сваком кластеру и да конфигуришете приступ њој користећи пријаву и лозинку. Овде нећу улазити у детаље - све је очигледно у интерфејсу.

Неочигледан детаљ је био да ове базе података имају много хостова, који обезбеђују њихову толеранцију грешака. Међутим, Графана захтева тачно један хост за сваку базу података са којом ради. Дуго читање документација Облаци су ме довели до одлуке. Испоставило се да је домаћин врсте c-<cluster_id>.rw.mdb.yandexcloud.net мапиран на тренутни активни главни хост кластера са одговарајућим ИД-ом. Ово ћемо дати Графани.

веб сервер

Сада је на веб серверу. Хајде да подигнемо обичну виртуелну машину са Линуксом и ручно конфигуришемо Графану на њој.

Повежимо се преко ссх-а и инсталирамо потребне пакете.

sudo apt-get install -y apt-transport-https software-properties-common wget
wget -q -O - https://packages.grafana.com/gpg.key | sudo apt-key add -
sudo add-apt-repository "deb https://packages.grafana.com/enterprise/deb stable main"
sudo apt-get update
sudo apt-get install -y grafana-enterprise 

Након тога, покренимо Графану под системцтл и инсталирамо додатак за рад са ЦлицкХоусе (да, није испоручен у основном пакету).

sudo systemctl start grafana-server
sudo systemctl enable grafana-server
sudo grafana-cli plugins install vertamedia-clickhouse-datasource

То је то, након тога једноставном командом

sudo service grafana-server start

покренућемо веб сервер. Сада можете да унесете спољну ИП адресу виртуелне машине у претраживач, одредите порт 3000 и видите прелеп Графана кориснички интерфејс.

Али немојте журити, пре него што подесите Графану, морате запамтити да јој кажете путању до МиСКЛ-а како бисте тамо сачували подешавања.

Целокупна конфигурација веб сервера Графана је у датотеци /etc/grafana/grafana.ini. Потребна линија изгледа овако:

;url =

Поставили смо хост на МиСКЛ кластер. Иста датотека садржи логин и лозинку за приступ Графани на горњој слици, које су подразумевано једнаке admin.

Можете користити сед команде:

sudo sed -i "s#.*;url =.*#url = mysql://${MYSQL_USERNAME}:${MYSQL_PASSWORD}@${MYSQL_CLUSTER_URI}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_user =.*#admin_user = ${GRAFANA_USERNAME}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_password =.*#admin_password = ${GRAFANA_PASSWORD}#" /etc/grafana/grafana.ini

Време је да поново покренете веб сервер!

sudo service grafana-server restart

Сада ћемо у корисничком интерфејсу Графане навести ЦлицкХоусе као извор података.

Успео сам да постигнем радну конфигурацију са следећим подешавањима:

Навео сам као УРЛ https://c-<cluster_id>.rw.mdb.yandexcloud.net:8443

Све! Имамо једну радну виртуелну машину са веб сервером повезаним на ЦХ и МиСКЛ. Већ можете да отпремите скуп података у ЦлицкХоусе и направите контролне табле. Међутим, још нисмо постигли свој циљ и нисмо развили пуноправну инфраструктуру.

Пацкер

Иандек.Цлоуд вам омогућава да креирате слику диска постојеће виртуелне машине, а на њеној основи - било који број машина идентичних једна другој. То је управо оно што ћемо користити. Да бисте згодно саставили слику, узмите алат Пацкер од ХасхиЦорп. Као улаз узима јсон датотеку са упутствима за састављање слике.

Наша јсон датотека ће се састојати од два блока: градитеља и провајдера. Први блок описује параметре саме слике као целине, а други блок описује упутства за њено попуњавање потребним садржајем.

градитељи

{
"builders": [
    {
      "type": "yandex",
      "endpoint": "{{user `endpoint`}}",
      "folder_id": "<folder_id>",
      "subnet_id": "{{user `subnet_id`}}",
      "zone": "{{user `zone`}}",
      "labels": {},
      "use_ipv4_nat": true,
      "use_internal_ip": false,
      "service_account_key_file": "<service_account_key_file>",
      "image_name": "grafana-{{timestamp}}",
      "image_family": "grafana",
      "image_labels": {},
      "image_description": "GRAFANA",
      "source_image_family": "ubuntu-1804-lts",
      "disk_size_gb": 3,
      "disk_type": "network-hdd",
      "ssh_username": "ubuntu"
    }
  ],
...
}

У овом шаблону потребно је да подесите идентификатор одељка у облаку где желите да креирате слику, као и путању до датотеке са кључевима са налога услуге који је претходно креиран у овом одељку. Више о креирању сервисних налога и кључева у облику датотеке можете прочитати у одговарајућем одељку документација.

Ова конфигурација каже да ће слика диска бити направљена на основу платформе ubuntu-1804-lts, постављен у одговарајући кориснички одељак у породици слика GRAFANA под називом grafana-{{timestamp}}.

Провисионерс

Сада долази занимљивији део конфигурације. Он ће описати редослед радњи које ће морати да се изврше на виртуелној машини пре замрзавања њеног стања у слику диска.

{
...,
"provisioners": [
    {
            "type": "shell",
            "pause_before": "5s",
            "scripts": [
                "prepare-ctg.sh"
            ]
        },
    {
            "type": "file",
            "source": "setup.sh",
            "destination": "/opt/grafana/setup.sh"
        },
        {
            "type": "shell",
        "execute_command": "sudo {{ .Vars }} bash '{{ .Path }}'",
            "pause_before": "5s",
            "scripts": [
                "install-packages.sh",
                "grafana-setup.sh",
                "run-setup-at-reboot.sh"
        ]
        }
  ]
}

Овде су све акције подељене у 3 фазе. У првој фази се извршава једноставна скрипта која креира помоћни директоријум.

припреми-цтг.сх:

#!/bin/bash
sudo mkdir -p /opt/grafana
sudo chown -R ubuntu:ubuntu /opt/grafana

У следећој фази постављамо скрипту у овај директоријум, која ће морати да се покрене одмах након покретања виртуелне машине. Ова скрипта ће поставити корисничке варијабле које треба регистровати у конфигурацију Графане и поново покренути веб сервер.

сетуп.сх:

#!/bin/bash
CLUSTER_ID="<cluster_id>"
USERNAME="<username>"
PASSWORD="<password>"
sudo sed -i "s#.*;url =.*#url = mysql://${USERNAME}:${PASSWORD}@c-${CLUSTER_ID}.rw.mdb.yandexcloud.net#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_user =.*#admin_user = ${USERNAME}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_password =.*#admin_password = ${PASSWORD}#" /etc/grafana/grafana.ini
sudo service grafana-server restart

Након овога преостају још 3 ствари:
1) инсталирајте пакете
2) покрените Графана под системцтл и инсталирајте ЦлицкХоусе додатак
3) ставите сетуп.сх скрипту у ред за покретање одмах након укључивања виртуелне машине.

инсталл-пацкагес.сх:

#!/bin/bash
sudo systemd-run --property='After=apt-daily.service apt-daily-upgrade.service' --wait /bin/true
sudo apt-get install -y apt-transport-https
sudo apt-get install -y software-properties-common wget
wget -q -O - https://packages.grafana.com/gpg.key | sudo apt-key add -
sudo add-apt-repository "deb https://packages.grafana.com/enterprise/deb stable main"
sudo apt-get update
sudo apt-get install -y grafana-enterprise 

графана-сетуп.сх:

#!/bin/bash
sudo systemctl start grafana-server
sudo systemctl enable grafana-server
sudo grafana-cli plugins install vertamedia-clickhouse-datasource

рун-сетуп-ат-ребоот.сх:

#!/bin/bash
chmod +x /opt/grafana/setup.sh
cat > /etc/cron.d/first-boot <<EOF
PATH=/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin:/usr/games:/usr/local/games
@reboot root /bin/bash /opt/grafana/setup.sh > /var/log/yc-setup.log 2>&1
EOF
chmod +x /etc/cron.d/first-boot;

Сада остаје само да покренете Пацкер и добијете излазну слику постављену у наведени одељак. Када креирате виртуелну машину, можете да је изаберете као диск за покретање и након покретања добићете готов Графана веб сервер.

Група инстанци и балансер

Када имамо слику диска која нам омогућава да креирамо много идентичних Графана веб сервера, можемо да креирамо групу инстанци. На платформи Иандек.Цлоуд, овај термин се односи на унију виртуелних машина које имају исте карактеристике. Приликом креирања групе инстанце, конфигурише се прототип свих машина у овој групи, а затим и карактеристике саме групе (на пример, минимални и максимални број активних машина). Ако тренутни број не испуњава ове критеријуме, група инстанци ће сама уклонити непотребне машине или креирати нове по сопственој слици.

Као део нашег задатка, креираћемо групу инстанци веб сервера која ће бити генерисана из претходно креиране слике диска.

Оно што је заиста изванредно је подешавање групе последње инстанце. Циљна група у интеграцији са Лоад Баланцером ће вам помоћи да конфигуришете Л3 балансер на врху виртуелних машина ове групе кликом на неколико дугмади.

Приликом подешавања балансера применио сам две важне тачке:

1. Натерао сам балансер да прихвати кориснички саобраћај на порту 80 и преусмерио га на порт 3000 виртуелних машина, тачно тамо где живи Графана.
2. Поставио сам проверу одрживости машина тако што сам их пинговао на порт 3000.

Мини резиме

Коначно, успели смо да ручно применимо жељену инфраструктуру апликација и сада имамо веома отпорну услугу Графана. Потребно је само да знате ИП адресу балансера као улазне тачке у апликацију и домаћина ЦлицкХоусе кластера да бисте у њега учитали скуп података.

Деловало би као победа? Да, победа. Али нешто ме ипак збуњује. Цео горенаведени процес захтева много ручних корака и уопште није скалабилан; желео бих да га аутоматизујем ако је могуће. Томе ће бити посвећен следећи одељак.

Терраформ интеграција

Поново ћемо користити алатку компаније ХасхиЦорп под називом Терраформ. Помоћи ће вам да примените целокупну инфраструктуру апликације једним кликом на дугме, на основу неколико променљивих које је корисник проследио. Хајде да напишемо рецепт који се може покренути више пута у различитим одељцима различитих корисника.

Сав рад са Терраформом своди се на писање конфигурационе датотеке (*.tf) и стварање инфраструктуре на основу тога.

Променљиве

На самом почетку фајла ћемо укључити варијабле које одређују где и како ће будућа инфраструктура бити распоређена.

variable "oauth_token" {
    type = string
    default = "<oauth-token>"
}
variable "cloud_id" {
    type = string
    default = "<cloud-id>"
}
variable "folder_id" {
    type = string
    default = "<folder_id>"
}
variable "service_account_id" {
    type = string
    default = "<service_account_id>"
}
variable "image_id" {
    type = string
    default = "<image_id>"
}
variable "username" {
    type = string
    default = "<username>"
}
variable "password" {
    type = string
    default = "<password>"
}
variable "dbname" {
    type = string
    default = "<dbname>"
}
variable "public_key_path" {
    type = string
    default = "<path to ssh public key>"
}

Цео процес примене апликације ће се свести на прављење слике диска и подешавање ових променљивих. Дозволите ми да објасним за шта су одговорни:

оаутх_токен — токен за приступ облаку. Може се добити од веза.
цлоуд_ид — идентификатор облака где ћемо применити апликацију
фолдер_ид — идентификатор одељка где ћемо применити апликацију
сервице_аццоунт_ид — идентификатор налога услуге у одговарајућем делу облака.
имаге_ид — идентификатор слике диска добијеног коришћењем Пацкер-а
корисничко име и лозинка — корисничко име и лозинка за приступ и базама података и веб серверу Графана
дбнаме — име базе података унутар ЦХ и МиСКЛ кластера
публиц_кеи_патх — путању до датотеке са вашим јавним ссх кључем, који можете користити за повезивање под именом ubuntu на виртуелне машине са веб серверима

Подешавање провајдера

Сада морате да конфигуришете провајдера Терраформ - у нашем случају, Иандек:

provider "yandex" {
  token     = var.oauth_token
  cloud_id  = var.cloud_id
  folder_id = var.folder_id
  zone      = "ru-central1-a"
}

Приметићете да овде користимо променљиве дефинисане изнад.

Мрежа и кластери

Сада ћемо направити мрежу у којој ће комуницирати елементи наше инфраструктуре, три подмреже (по једна у сваком региону) и подићи ЦХ и МиСКЛ кластере.

resource "yandex_vpc_network" "grafana_network" {}

resource "yandex_vpc_subnet" "subnet_a" {
  zone           = "ru-central1-a"
  network_id     = yandex_vpc_network.grafana_network.id
  v4_cidr_blocks = ["10.1.0.0/24"]
}

resource "yandex_vpc_subnet" "subnet_b" {
  zone           = "ru-central1-b"
  network_id     = yandex_vpc_network.grafana_network.id
  v4_cidr_blocks = ["10.2.0.0/24"]
}

resource "yandex_vpc_subnet" "subnet_c" {
  zone           = "ru-central1-c"
  network_id     = yandex_vpc_network.grafana_network.id
  v4_cidr_blocks = ["10.3.0.0/24"]
}

resource "yandex_mdb_clickhouse_cluster" "ch_cluster" {
  name        = "grafana-clickhouse"
  environment = "PRODUCTION"
  network_id  = yandex_vpc_network.grafana_network.id

  clickhouse {
    resources {
      resource_preset_id = "s2.micro"
      disk_type_id       = "network-ssd"
      disk_size          = 16
    }
  }

  zookeeper {
    resources {
      resource_preset_id = "s2.micro"
      disk_type_id       = "network-ssd"
      disk_size          = 10
    }
  }

  database {
    name = var.dbname
  }

  user {
    name     = var.username
    password = var.password
    permission {
      database_name = var.dbname
    }
  }

  host {
    type      = "CLICKHOUSE"
    zone      = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.subnet_a.id
  }

  host {
    type      = "CLICKHOUSE"
    zone      = "ru-central1-b"
    subnet_id = yandex_vpc_subnet.subnet_b.id
  }

  host {
    type      = "CLICKHOUSE"
    zone      = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.subnet_c.id
  }

  host {
    type      = "ZOOKEEPER"
    zone      = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.subnet_a.id
  }

  host {
    type      = "ZOOKEEPER"
    zone      = "ru-central1-b"
    subnet_id = yandex_vpc_subnet.subnet_b.id
  }

  host {
    type      = "ZOOKEEPER"
    zone      = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.subnet_c.id
  }
}

resource "yandex_mdb_mysql_cluster" "mysql_cluster" {
  name        = "grafana_mysql"
  environment = "PRODUCTION"
  network_id  = yandex_vpc_network.grafana_network.id
  version     = "8.0"

  resources {
    resource_preset_id = "s2.micro"
    disk_type_id       = "network-ssd"
    disk_size          = 16
  }

  database {
    name = var.dbname
  }

  user {
    name     = var.username
    password = var.password
    permission {
      database_name = var.dbname
      roles         = ["ALL"]
    }
  }

  host {
    zone      = "ru-central1-a"
    subnet_id = yandex_vpc_subnet.subnet_a.id
  }
  host {
    zone      = "ru-central1-b"
    subnet_id = yandex_vpc_subnet.subnet_b.id
  }
  host {
    zone      = "ru-central1-c"
    subnet_id = yandex_vpc_subnet.subnet_c.id
  }
}

Као што видите, сваки од два кластера је направљен прилично отпоран на грешке тако што је смештен у три зоне доступности.

Веб сервери

Чинило се да бисмо могли да наставимо у истом духу, али сам наишао на потешкоће. Пре тога сам прво подигао МиСКЛ кластер и тек након тога, знајући његов ИД, сакупио сам слику диска са потребном конфигурацијом, где сам одредио хост кластера. Али сада не знамо ИД кластера пре покретања Терраформ-а, укључујући и време прављења слике. Стога сам морао да прибегнем следећем трик.

Користећи Амазонову услугу метаподатака, проследићемо неке параметре виртуелној машини, које ће она прихватити и обрадити. Потребна нам је машина да оде до метаподатака иза хоста МиСКЛ кластера и корисничког имена-лозинке, које је корисник навео у Терраформ датотеци, након покретања. Хајде да мало променимо садржај датотеке setup.sh, који се покреће када је виртуелна машина укључена.

сетуп.сх:

#!/bin/bash
CLUSTER_URI="$(curl -H 'Metadata-Flavor:Google' http://169.254.169.254/computeMetadata/v1/instance/attributes/mysql_cluster_uri)"
USERNAME="$(curl -H 'Metadata-Flavor:Google' http://169.254.169.254/computeMetadata/v1/instance/attributes/username)"
PASSWORD="$(curl -H 'Metadata-Flavor:Google' http://169.254.169.254/computeMetadata/v1/instance/attributes/password)"
sudo sed -i "s#.*;url =.*#url = mysql://${USERNAME}:${PASSWORD}@${CLUSTER_URI}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_user =.*#admin_user = ${USERNAME}#" /etc/grafana/grafana.ini
sudo sed -i "s#.*;admin_password =.*#admin_password = ${PASSWORD}#" /etc/grafana/grafana.ini
sudo service grafana-server restart

Интанс група и балансер

Након што смо поново направили нову слику диска, коначно можемо додати нашу датотеку за Терраформ.

Хајде да назначимо да желимо да користимо постојећу слику диска:

data "yandex_compute_image" "grafana_image" {
  image_id = var.image_id
}

Сада направимо групу инстанци:

resource "yandex_compute_instance_group" "grafana_group" {
  name               = "grafana-group"
  folder_id          = var.folder_id
  service_account_id = var.service_account_id
  instance_template {
    platform_id = "standard-v1"
    resources {
      memory = 1
      cores  = 1
    }
    boot_disk {
      mode = "READ_WRITE"
      initialize_params {
        image_id = data.yandex_compute_image.grafana_image.id
        size     = 4
      }
    }
    network_interface {
      network_id = yandex_vpc_network.grafana_network.id
      subnet_ids = [yandex_vpc_subnet.subnet_a.id, yandex_vpc_subnet.subnet_b.id, yandex_vpc_subnet.subnet_c.id]
      nat = "true"
    }
    metadata = {
      mysql_cluster_uri = "c-${yandex_mdb_mysql_cluster.mysql_cluster.id}.rw.mdb.yandexcloud.net:3306/${var.dbname}"
      username = var.username
      password = var.password
      ssh-keys = "ubuntu:${file("${var.public_key_path}")}"
    }
    network_settings {
      type = "STANDARD"
    }
  }

  scale_policy {
    fixed_scale {
      size = 6
    }
  }

  allocation_policy {
    zones = ["ru-central1-a", "ru-central1-b", "ru-central1-c"]
  }

  deploy_policy {
    max_unavailable = 2
    max_creating    = 2
    max_expansion   = 2
    max_deleting    = 2
  }

  load_balancer {
    target_group_name = "grafana-target-group"
  }
}

Вреди обратити пажњу на то како смо то пренели у метаподатке cluster_uri, username и password. То су које ће виртуелна машина извадити при покретању и ставити у конфигурацију Графане.

Све зависи од балансера.

resource "yandex_lb_network_load_balancer" "grafana_balancer" {
  name = "grafana-balancer"

  listener {
    name = "grafana-listener"
    port = 80
    target_port = 3000
    external_address_spec {
      ip_version = "ipv4"
    }
  }

  attached_target_group {
    target_group_id = yandex_compute_instance_group.grafana_group.load_balancer.0.target_group_id

    healthcheck {
      name = "healthcheck"
      tcp_options {
        port = 3000
      }
    }
  }
}

Мало шећера

Остало је само мало. Након што се инфраструктура распореди, мораћете да одете на Графана УИ и ручно додате ЦХ кластер (чији ИД још треба да се добије) као извор података. Али Терраформ зна ИД кластера. Поверимо му да доведе ствар до краја.

Хајде да додамо новог провајдера - Графану, и дамо јој ИП адресу балансера као домаћина. Све промене које Терраформ направи на машини на којој њен балансер одреди ће расти у МиСКЛ, а самим тим и на свим другим машинама.

provider "grafana" {
  url  = "http://${[for s in yandex_lb_network_load_balancer.grafana_balancer.listener: s.external_address_spec.0.address].0}"
  auth = "${var.username}:${var.password}"
}

resource "grafana_data_source" "ch_data_source" {
  type          = "vertamedia-clickhouse-datasource"
  name          = "grafana"
  url           = "https://c-${yandex_mdb_clickhouse_cluster.ch_cluster.id}.rw.mdb.yandexcloud.net:8443"
  basic_auth_enabled = "true"
  basic_auth_username = var.username
  basic_auth_password = var.password
  is_default = "true"
  access_mode = "proxy"
}

Хајде да се почешљамо

Хајде да прикажемо ИП адресу балансера и домаћина ЦлицкХоусе кластера

output "grafana_balancer_ip_address" {
  value = [for s in yandex_lb_network_load_balancer.grafana_balancer.listener: s.external_address_spec.0.address].0
}

output "clickhouse_cluster_host" {
  value = "https://c-${yandex_mdb_clickhouse_cluster.ch_cluster.id}.rw.mdb.yandexcloud.net:8443"
}

Може покренути

Све! Наш конфигурациони фајл је спреман и можемо, постављањем променљивих, рећи Терраформу да подигне све што смо описали горе. Цео процес ми је трајао око 15 минута.
На крају можете видети прелепу поруку:

Apply complete! Resources: 9 added, 0 changed, 0 destroyed.
Outputs:

clickhouse_cluster_host = https://c-c9q14ipa2ngadqsbp2iq.rw.mdb.yandexcloud.net:8443
grafana_balancer_ip_address = 130.193.50.25

А у облаку ће бити видљиви елементи подигнуте инфраструктуре:

Сажимати

Сада, користећи Графану као пример, свако од вас може да примени апликације са великом архитектуром облака на платформи Иандек.Цлоуд. Корисни алати из ХасхиЦорп-а као што су Пацкер и Терраформ могу вам помоћи у томе. Надам се да ће некоме овај чланак бити користан :)

ПС У наставку ћу приложити линк до спремишта где можете пронаћи готове рецепте за Пацкер и Терраформ, чије сам фрагменте навео у овом чланку.

репозиторијум

Извор: ввв.хабр.цом